arch/arm64/kernel/vmlinux.lds.S

   1 /*
   2  * ld script to make ARM Linux kernel
   3  * taken from the i386 version by Russell King
   4  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5  */
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/cache.h>
   9 #include <asm/kernel-pgtable.h>
  10 #include <asm/thread_info.h>
  11 #include <asm/memory.h>
  12 #include <asm/page.h>
  13 #include <asm/pgtable.h>
  14
  15 #include "image.h"
  16
  17 /* .exit.text needed in case of alternative patching */
  18 #define ARM_EXIT_KEEP(x)        x
  19 #define ARM_EXIT_DISCARD(x)
  20
  21 OUTPUT_ARCH(aarch64)
  22 ENTRY(_text)
  23
  24 jiffies = jiffies_64;
  25
  26 #define HYPERVISOR_TEXT                                 \
  27         /*                                              \
  28          * Align to 4 KB so that                        \
  29          * a) the HYP vector table is at its minimum    \
  30          *    alignment of 2048 bytes                   \
  31          * b) the HYP init code will not cross a page   \
  32          *    boundary if its size does not exceed      \
  33          *    4 KB (see related ASSERT() below)         \
  34          */                                             \
  35         . = ALIGN(SZ_4K);                               \
  36         VMLINUX_SYMBOL(__hyp_idmap_text_start) = .;     \
  37         *(.hyp.idmap.text)                              \
  38         VMLINUX_SYMBOL(__hyp_idmap_text_end) = .;       \
  39         VMLINUX_SYMBOL(__hyp_text_start) = .;           \
  40         *(.hyp.text)                                    \
  41         VMLINUX_SYMBOL(__hyp_text_end) = .;
  42
  43 #define IDMAP_TEXT                                      \
  44         . = ALIGN(SZ_4K);                               \
  45         VMLINUX_SYMBOL(__idmap_text_start) = .;         \
  46         *(.idmap.text)                                  \
  47         VMLINUX_SYMBOL(__idmap_text_end) = .;
  48
  49 #ifdef CONFIG_HIBERNATION
  50 #define HIBERNATE_TEXT                                  \
  51         . = ALIGN(SZ_4K);                               \
  52         VMLINUX_SYMBOL(__hibernate_exit_text_start) = .;\
  53         *(.hibernate_exit.text)                         \
  54         VMLINUX_SYMBOL(__hibernate_exit_text_end) = .;
  55 #else
  56 #define HIBERNATE_TEXT
  57 #endif
  58
  59 /*
  60  * The size of the PE/COFF section that covers the kernel image, which
  61  * runs from stext to _edata, must be a round multiple of the PE/COFF
  62  * FileAlignment, which we set to its minimum value of 0x200. 'stext'
  63  * itself is 4 KB aligned, so padding out _edata to a 0x200 aligned
  64  * boundary should be sufficient.
  65  */
  66 PECOFF_FILE_ALIGNMENT = 0x200;
  67
  68 #ifdef CONFIG_EFI
  69 #define PECOFF_EDATA_PADDING    \
  70         .pecoff_edata_padding : { BYTE(0); . = ALIGN(PECOFF_FILE_ALIGNMENT); }
  71 #else
  72 #define PECOFF_EDATA_PADDING
  73 #endif
  74
  75 #if defined(CONFIG_DEBUG_ALIGN_RODATA)
  76 /*
  77  *  4 KB granule:   1 level 2 entry
  78  * 16 KB granule: 128 level 3 entries, with contiguous bit
  79  * 64 KB granule:  32 level 3 entries, with contiguous bit
  80  */
  81 #define SEGMENT_ALIGN                   SZ_2M
  82 #else
  83 /*
  84  *  4 KB granule:  16 level 3 entries, with contiguous bit
  85  * 16 KB granule:   4 level 3 entries, without contiguous bit
  86  * 64 KB granule:   1 level 3 entry
  87  */
  88 #define SEGMENT_ALIGN                   SZ_64K
  89 #endif
  90
  91 SECTIONS
  92 {
  93         /*
  94          * XXX: The linker does not define how output sections are
  95          * assigned to input sections when there are multiple statements
  96          * matching the same input section name.  There is no documented
  97          * order of matching.
  98          */
  99         /DISCARD/ : {
 100                 ARM_EXIT_DISCARD(EXIT_TEXT)
 101                 ARM_EXIT_DISCARD(EXIT_DATA)
 102                 EXIT_CALL
 103                 *(.discard)
 104                 *(.discard.*)
 105                 *(.interp .dynamic)
 106         }
 107
 108         . = KIMAGE_VADDR + TEXT_OFFSET;
 109
 110         .head.text : {
 111                 _text = .;
 112                 HEAD_TEXT
 113         }
 114         .text : {                       /* Real text segment            */
 115                 _stext = .;             /* Text and read-only data      */
 116                         __exception_text_start = .;
 117                         *(.exception.text)
 118                         __exception_text_end = .;
 119                         IRQENTRY_TEXT
 120                         SOFTIRQENTRY_TEXT
 121                         ENTRY_TEXT
 122                         TEXT_TEXT
 123                         SCHED_TEXT
 124                         LOCK_TEXT
 125                         KPROBES_TEXT
 126                         HYPERVISOR_TEXT
 127                         IDMAP_TEXT
 128                         HIBERNATE_TEXT
 129                         *(.fixup)
 130                         *(.gnu.warning)
 131                 . = ALIGN(16);
 132                 *(.got)                 /* Global offset table          */
 133         }
 134
 135         . = ALIGN(SEGMENT_ALIGN);
 136         _etext = .;                     /* End of text section */
 137
 138         RO_DATA(PAGE_SIZE)              /* everything from this point to     */
 139         EXCEPTION_TABLE(8)              /* __init_begin will be marked RO NX */
 140         NOTES
 141
 142         . = ALIGN(SEGMENT_ALIGN);
 143         __init_begin = .;
 144
 145         INIT_TEXT_SECTION(8)
 146         .exit.text : {
 147                 ARM_EXIT_KEEP(EXIT_TEXT)
 148         }
 149
 150         .init.data : {
 151                 INIT_DATA
 152                 INIT_SETUP(16)
 153                 INIT_CALLS
 154                 CON_INITCALL
 155                 SECURITY_INITCALL
 156                 INIT_RAM_FS
 157                 *(.init.rodata.* .init.bss)     /* from the EFI stub */
 158         }
 159         .exit.data : {
 160                 ARM_EXIT_KEEP(EXIT_DATA)
 161         }
 162
 163         PERCPU_SECTION(L1_CACHE_BYTES)
 164
 165         . = ALIGN(4);
 166         .altinstructions : {
 167                 __alt_instructions = .;
 168                 *(.altinstructions)
 169                 __alt_instructions_end = .;
 170         }
 171         .altinstr_replacement : {
 172                 *(.altinstr_replacement)
 173         }
 174         .rela : ALIGN(8) {
 175                 *(.rela .rela*)
 176         }
 177         .dynsym : ALIGN(8) {
 178                 *(.dynsym)
 179         }
 180         .dynstr : {
 181                 *(.dynstr)
 182         }
 183         .hash : {
 184                 *(.hash)
 185         }
 186
 187         __rela_offset   = ADDR(.rela) - KIMAGE_VADDR;
 188         __rela_size     = SIZEOF(.rela);
 189         __dynsym_offset = ADDR(.dynsym) - KIMAGE_VADDR;
 190
 191         . = ALIGN(SEGMENT_ALIGN);
 192         __init_end = .;
 193
 194         _data = .;
 195         _sdata = .;
 196         RW_DATA_SECTION(L1_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
 197         PECOFF_EDATA_PADDING
 198         _edata = .;
 199
 200         BSS_SECTION(0, 0, 0)
 201
 202         . = ALIGN(PAGE_SIZE);
 203         idmap_pg_dir = .;
 204         . += IDMAP_DIR_SIZE;
 205         swapper_pg_dir = .;
 206         . += SWAPPER_DIR_SIZE;
 207
 208         _end = .;
 209
 210         STABS_DEBUG
 211
 212         HEAD_SYMBOLS
 213 }
 214
 215 /*
 216  * The HYP init code and ID map text can't be longer than a page each,
 217  * and should not cross a page boundary.
 218  */
 219 ASSERT(__hyp_idmap_text_end - (__hyp_idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
 220         "HYP init code too big or misaligned")
 221 ASSERT(__idmap_text_end - (__idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
 222         "ID map text too big or misaligned")
 223 #ifdef CONFIG_HIBERNATION
 224 ASSERT(__hibernate_exit_text_end - (__hibernate_exit_text_start & ~(SZ_4K - 1))
 225         <= SZ_4K, "Hibernate exit text too big or misaligned")
 226 #endif
 227
 228 /*
 229  * If padding is applied before .head.text, virt<->phys conversions will fail.
 230  */
 231 ASSERT(_text == (KIMAGE_VADDR + TEXT_OFFSET), "HEAD is misaligned")