arch/arm64/lib/copy_to_user.S

   1 /*
   2  * Copyright (C) 2012 ARM Ltd.
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License version 2 as
   6  * published by the Free Software Foundation.
   7  *
   8  * This program is distributed in the hope that it will be useful,
   9  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11  * GNU General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License
  14  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15  */
  16
  17 #include <linux/linkage.h>
  18 #include <asm/assembler.h>
  19
  20 /*
  21  * Copy to user space from a kernel buffer (alignment handled by the hardware)
  22  *
  23  * Parameters:
  24  *      x0 - to
  25  *      x1 - from
  26  *      x2 - n
  27  * Returns:
  28  *      x0 - bytes not copied
  29  */
  30 ENTRY(__copy_to_user)
  31         add     x4, x0, x2                      // upper user buffer boundary
  32         subs    x2, x2, #8
  33         b.mi    2f
  34 1:
  35         ldr     x3, [x1], #8
  36         subs    x2, x2, #8
  37 USER(9f, str    x3, [x0], #8    )
  38         b.pl    1b
  39 2:      adds    x2, x2, #4
  40         b.mi    3f
  41         ldr     w3, [x1], #4
  42         sub     x2, x2, #4
  43 USER(9f, str    w3, [x0], #4    )
  44 3:      adds    x2, x2, #2
  45         b.mi    4f
  46         ldrh    w3, [x1], #2
  47         sub     x2, x2, #2
  48 USER(9f, strh   w3, [x0], #2    )
  49 4:      adds    x2, x2, #1
  50         b.mi    5f
  51         ldrb    w3, [x1]
  52 USER(9f, strb   w3, [x0]        )
  53 5:      mov     x0, #0
  54         ret
  55 ENDPROC(__copy_to_user)
  56
  57         .section .fixup,"ax"
  58         .align  2
  59 9:      sub     x0, x4, x0                      // bytes not copied
  60         ret
  61         .previous