arch/blackfin/mach-common/dpmc_modes.S

   1 /*
   2  * Copyright 2004-2008 Analog Devices Inc.
   3  *
   4  * Licensed under the GPL-2 or later.
   5  */
   6
   7 #include <linux/linkage.h>
   8 #include <asm/blackfin.h>
   9 #include <mach/irq.h>
  10 #include <asm/dpmc.h>
  11
  12 .section .l1.text
  13
  14 ENTRY(_sleep_mode)
  15         [--SP] = ( R7:0, P5:0 );
  16         [--SP] =  RETS;
  17
  18         call _set_sic_iwr;
  19
  20         P0.H = hi(PLL_CTL);
  21         P0.L = lo(PLL_CTL);
  22         R1 = W[P0](z);
  23         BITSET (R1, 3);
  24         W[P0] = R1.L;
  25
  26         CLI R2;
  27         SSYNC;
  28         IDLE;
  29         STI R2;
  30
  31         call _test_pll_locked;
  32
  33         R0 = IWR_ENABLE(0);
  34         R1 = IWR_DISABLE_ALL;
  35         R2 = IWR_DISABLE_ALL;
  36
  37         call _set_sic_iwr;
  38
  39         P0.H = hi(PLL_CTL);
  40         P0.L = lo(PLL_CTL);
  41         R7 = w[p0](z);
  42         BITCLR (R7, 3);
  43         BITCLR (R7, 5);
  44         w[p0] = R7.L;
  45         IDLE;
  46         call _test_pll_locked;
  47
  48         RETS = [SP++];
  49         ( R7:0, P5:0 ) = [SP++];
  50         RTS;
  51 ENDPROC(_sleep_mode)
  52
  53 ENTRY(_hibernate_mode)
  54         [--SP] = ( R7:0, P5:0 );
  55         [--SP] =  RETS;
  56
  57         R3 = R0;
  58         R0 = IWR_DISABLE_ALL;
  59         R1 = IWR_DISABLE_ALL;
  60         R2 = IWR_DISABLE_ALL;
  61         call _set_sic_iwr;
  62         call _set_dram_srfs;
  63         SSYNC;
  64
  65         P0.H = hi(VR_CTL);
  66         P0.L = lo(VR_CTL);
  67
  68         W[P0] = R3.L;
  69         CLI R2;
  70         IDLE;
  71 .Lforever:
  72         jump .Lforever;
  73 ENDPROC(_hibernate_mode)
  74
  75 ENTRY(_sleep_deeper)
  76         [--SP] = ( R7:0, P5:0 );
  77         [--SP] =  RETS;
  78
  79         CLI R4;
  80
  81         P3 = R0;
  82         P4 = R1;
  83         P5 = R2;
  84
  85         R0 = IWR_ENABLE(0);
  86         R1 = IWR_DISABLE_ALL;
  87         R2 = IWR_DISABLE_ALL;
  88
  89         call _set_sic_iwr;
  90         call _set_dram_srfs;    /* Set SDRAM Self Refresh */
  91
  92         P0.H = hi(PLL_DIV);
  93         P0.L = lo(PLL_DIV);
  94         R6 = W[P0](z);
  95         R0.L = 0xF;
  96         W[P0] = R0.l;           /* Set Max VCO to SCLK divider */
  97
  98         P0.H = hi(PLL_CTL);
  99         P0.L = lo(PLL_CTL);
 100         R5 = W[P0](z);
 101         R0.L = (CONFIG_MIN_VCO_HZ/CONFIG_CLKIN_HZ) << 9;
 102         W[P0] = R0.l;           /* Set Min CLKIN to VCO multiplier */
 103
 104         SSYNC;
 105         IDLE;
 106
 107         call _test_pll_locked;
 108
 109         P0.H = hi(VR_CTL);
 110         P0.L = lo(VR_CTL);
 111         R7 = W[P0](z);
 112         R1 = 0x6;
 113         R1 <<= 16;
 114         R2 = 0x0404(Z);
 115         R1 = R1|R2;
 116
 117         R2 = DEPOSIT(R7, R1);
 118         W[P0] = R2;             /* Set Min Core Voltage */
 119
 120         SSYNC;
 121         IDLE;
 122
 123         call _test_pll_locked;
 124
 125         R0 = P3;
 126         R1 = P4;
 127         R3 = P5;
 128         call _set_sic_iwr;      /* Set Awake from IDLE */
 129
 130         P0.H = hi(PLL_CTL);
 131         P0.L = lo(PLL_CTL);
 132         R0 = W[P0](z);
 133         BITSET (R0, 3);
 134         W[P0] = R0.L;           /* Turn CCLK OFF */
 135         SSYNC;
 136         IDLE;
 137
 138         call _test_pll_locked;
 139
 140         R0 = IWR_ENABLE(0);
 141         R1 = IWR_DISABLE_ALL;
 142         R2 = IWR_DISABLE_ALL;
 143
 144         call _set_sic_iwr;      /* Set Awake from IDLE PLL */
 145
 146         P0.H = hi(VR_CTL);
 147         P0.L = lo(VR_CTL);
 148         W[P0]= R7;
 149
 150         SSYNC;
 151         IDLE;
 152
 153         call _test_pll_locked;
 154
 155         P0.H = hi(PLL_DIV);
 156         P0.L = lo(PLL_DIV);
 157         W[P0]= R6;              /* Restore CCLK and SCLK divider */
 158
 159         P0.H = hi(PLL_CTL);
 160         P0.L = lo(PLL_CTL);
 161         w[p0] = R5;             /* Restore VCO multiplier */
 162         IDLE;
 163         call _test_pll_locked;
 164
 165         call _unset_dram_srfs;  /* SDRAM Self Refresh Off */
 166
 167         STI R4;
 168
 169         RETS = [SP++];
 170         ( R7:0, P5:0 ) = [SP++];
 171         RTS;
 172 ENDPROC(_sleep_deeper)
 173
 174 ENTRY(_set_dram_srfs)
 175         /*  set the dram to self refresh mode */
 176         SSYNC;
 177 #if defined(EBIU_RSTCTL)        /* DDR */
 178         P0.H = hi(EBIU_RSTCTL);
 179         P0.L = lo(EBIU_RSTCTL);
 180         R2 = [P0];
 181         BITSET(R2, 3); /* SRREQ enter self-refresh mode */
 182         [P0] = R2;
 183         SSYNC;
 184 1:
 185         R2 = [P0];
 186         CC = BITTST(R2, 4);
 187         if !CC JUMP 1b;
 188 #else                           /* SDRAM */
 189         P0.L = lo(EBIU_SDGCTL);
 190         P0.H = hi(EBIU_SDGCTL);
 191         R2 = [P0];
 192         BITSET(R2, 24); /* SRFS enter self-refresh mode */
 193         [P0] = R2;
 194         SSYNC;
 195
 196         P0.L = lo(EBIU_SDSTAT);
 197         P0.H = hi(EBIU_SDSTAT);
 198 1:
 199         R2 = w[P0];
 200         SSYNC;
 201         cc = BITTST(R2, 1); /* SDSRA poll self-refresh status */
 202         if !cc jump 1b;
 203
 204         P0.L = lo(EBIU_SDGCTL);
 205         P0.H = hi(EBIU_SDGCTL);
 206         R2 = [P0];
 207         BITCLR(R2, 0); /* SCTLE disable CLKOUT */
 208         [P0] = R2;
 209 #endif
 210         RTS;
 211 ENDPROC(_set_dram_srfs)
 212
 213 ENTRY(_unset_dram_srfs)
 214         /*  set the dram out of self refresh mode */
 215 #if defined(EBIU_RSTCTL)        /* DDR */
 216         P0.H = hi(EBIU_RSTCTL);
 217         P0.L = lo(EBIU_RSTCTL);
 218         R2 = [P0];
 219         BITCLR(R2, 3); /* clear SRREQ bit */
 220         [P0] = R2;
 221 #elif defined(EBIU_SDGCTL)      /* SDRAM */
 222
 223         P0.L = lo(EBIU_SDGCTL); /* release CLKOUT from self-refresh */
 224         P0.H = hi(EBIU_SDGCTL);
 225         R2 = [P0];
 226         BITSET(R2, 0); /* SCTLE enable CLKOUT */
 227         [P0] = R2
 228         SSYNC;
 229
 230         P0.L = lo(EBIU_SDGCTL); /* release SDRAM from self-refresh */
 231         P0.H = hi(EBIU_SDGCTL);
 232         R2 = [P0];
 233         BITCLR(R2, 24); /* clear SRFS bit */
 234         [P0] = R2
 235 #endif
 236         SSYNC;
 237         RTS;
 238 ENDPROC(_unset_dram_srfs)
 239
 240 ENTRY(_set_sic_iwr)
 241 #ifdef SIC_IWR0
 242         P0.H = hi(SYSMMR_BASE);
 243         P0.L = lo(SYSMMR_BASE);
 244         [P0 + (SIC_IWR0 - SYSMMR_BASE)] = R0;
 245         [P0 + (SIC_IWR1 - SYSMMR_BASE)] = R1;
 246 # ifdef SIC_IWR2
 247         [P0 + (SIC_IWR2 - SYSMMR_BASE)] = R2;
 248 # endif
 249 #else
 250         P0.H = hi(SIC_IWR);
 251         P0.L = lo(SIC_IWR);
 252         [P0] = R0;
 253 #endif
 254
 255         SSYNC;
 256         RTS;
 257 ENDPROC(_set_sic_iwr)
 258
 259 ENTRY(_test_pll_locked)
 260         P0.H = hi(PLL_STAT);
 261         P0.L = lo(PLL_STAT);
 262 1:
 263         R0 = W[P0] (Z);
 264         CC = BITTST(R0,5);
 265         IF !CC JUMP 1b;
 266         RTS;
 267 ENDPROC(_test_pll_locked)
 268
 269 .section .text
 270
 271 #define PM_PUSH(x) \
 272         R0 = [P0 + (x - SRAM_BASE_ADDRESS)];\
 273         [--SP] =  R0;\
 274
 275 #define PM_POP(x) \
 276         R0 = [SP++];\
 277         [P0 + (x - SRAM_BASE_ADDRESS)] = R0;\
 278
 279 #define PM_SYS_PUSH(x) \
 280         R0 = [P0 + (x - PLL_CTL)];\
 281         [--SP] =  R0;\
 282
 283 #define PM_SYS_POP(x) \
 284         R0 = [SP++];\
 285         [P0 + (x - PLL_CTL)] = R0;\
 286
 287 #define PM_SYS_PUSH16(x) \
 288         R0 = w[P0 + (x - PLL_CTL)];\
 289         [--SP] =  R0;\
 290
 291 #define PM_SYS_POP16(x) \
 292         R0 = [SP++];\
 293         w[P0 + (x - PLL_CTL)] = R0;\
 294
 295 ENTRY(_do_hibernate)
 296         [--SP] = ( R7:0, P5:0 );
 297         [--SP] =  RETS;
 298         /* Save System MMRs */
 299         R2 = R0;
 300         P0.H = hi(PLL_CTL);
 301         P0.L = lo(PLL_CTL);
 302
 303 #ifdef SIC_IMASK0
 304         PM_SYS_PUSH(SIC_IMASK0)
 305 #endif
 306 #ifdef SIC_IMASK1
 307         PM_SYS_PUSH(SIC_IMASK1)
 308 #endif
 309 #ifdef SIC_IMASK2
 310         PM_SYS_PUSH(SIC_IMASK2)
 311 #endif
 312 #ifdef SIC_IMASK
 313         PM_SYS_PUSH(SIC_IMASK)
 314 #endif
 315 #ifdef SIC_IAR0
 316         PM_SYS_PUSH(SIC_IAR0)
 317         PM_SYS_PUSH(SIC_IAR1)
 318         PM_SYS_PUSH(SIC_IAR2)
 319 #endif
 320 #ifdef SIC_IAR3
 321         PM_SYS_PUSH(SIC_IAR3)
 322 #endif
 323 #ifdef SIC_IAR4
 324         PM_SYS_PUSH(SIC_IAR4)
 325         PM_SYS_PUSH(SIC_IAR5)
 326         PM_SYS_PUSH(SIC_IAR6)
 327 #endif
 328 #ifdef SIC_IAR7
 329         PM_SYS_PUSH(SIC_IAR7)
 330 #endif
 331 #ifdef SIC_IAR8
 332         PM_SYS_PUSH(SIC_IAR8)
 333         PM_SYS_PUSH(SIC_IAR9)
 334         PM_SYS_PUSH(SIC_IAR10)
 335         PM_SYS_PUSH(SIC_IAR11)
 336 #endif
 337
 338 #ifdef SIC_IWR
 339         PM_SYS_PUSH(SIC_IWR)
 340 #endif
 341 #ifdef SIC_IWR0
 342         PM_SYS_PUSH(SIC_IWR0)
 343 #endif
 344 #ifdef SIC_IWR1
 345         PM_SYS_PUSH(SIC_IWR1)
 346 #endif
 347 #ifdef SIC_IWR2
 348         PM_SYS_PUSH(SIC_IWR2)
 349 #endif
 350
 351 #ifdef PINT0_ASSIGN
 352         PM_SYS_PUSH(PINT0_MASK_SET)
 353         PM_SYS_PUSH(PINT1_MASK_SET)
 354         PM_SYS_PUSH(PINT2_MASK_SET)
 355         PM_SYS_PUSH(PINT3_MASK_SET)
 356         PM_SYS_PUSH(PINT0_ASSIGN)
 357         PM_SYS_PUSH(PINT1_ASSIGN)
 358         PM_SYS_PUSH(PINT2_ASSIGN)
 359         PM_SYS_PUSH(PINT3_ASSIGN)
 360         PM_SYS_PUSH(PINT0_INVERT_SET)
 361         PM_SYS_PUSH(PINT1_INVERT_SET)
 362         PM_SYS_PUSH(PINT2_INVERT_SET)
 363         PM_SYS_PUSH(PINT3_INVERT_SET)
 364         PM_SYS_PUSH(PINT0_EDGE_SET)
 365         PM_SYS_PUSH(PINT1_EDGE_SET)
 366         PM_SYS_PUSH(PINT2_EDGE_SET)
 367         PM_SYS_PUSH(PINT3_EDGE_SET)
 368 #endif
 369
 370         PM_SYS_PUSH(EBIU_AMBCTL0)
 371         PM_SYS_PUSH(EBIU_AMBCTL1)
 372         PM_SYS_PUSH16(EBIU_AMGCTL)
 373
 374 #ifdef EBIU_FCTL
 375         PM_SYS_PUSH(EBIU_MBSCTL)
 376         PM_SYS_PUSH(EBIU_MODE)
 377         PM_SYS_PUSH(EBIU_FCTL)
 378 #endif
 379
 380 #ifdef PORTCIO_FER
 381         PM_SYS_PUSH16(PORTCIO_DIR)
 382         PM_SYS_PUSH16(PORTCIO_INEN)
 383         PM_SYS_PUSH16(PORTCIO)
 384         PM_SYS_PUSH16(PORTCIO_FER)
 385         PM_SYS_PUSH16(PORTDIO_DIR)
 386         PM_SYS_PUSH16(PORTDIO_INEN)
 387         PM_SYS_PUSH16(PORTDIO)
 388         PM_SYS_PUSH16(PORTDIO_FER)
 389         PM_SYS_PUSH16(PORTEIO_DIR)
 390         PM_SYS_PUSH16(PORTEIO_INEN)
 391         PM_SYS_PUSH16(PORTEIO)
 392         PM_SYS_PUSH16(PORTEIO_FER)
 393 #endif
 394
 395         PM_SYS_PUSH16(SYSCR)
 396
 397         /* Save Core MMRs */
 398         P0.H = hi(SRAM_BASE_ADDRESS);
 399         P0.L = lo(SRAM_BASE_ADDRESS);
 400
 401         PM_PUSH(DMEM_CONTROL)
 402         PM_PUSH(DCPLB_ADDR0)
 403         PM_PUSH(DCPLB_ADDR1)
 404         PM_PUSH(DCPLB_ADDR2)
 405         PM_PUSH(DCPLB_ADDR3)
 406         PM_PUSH(DCPLB_ADDR4)
 407         PM_PUSH(DCPLB_ADDR5)
 408         PM_PUSH(DCPLB_ADDR6)
 409         PM_PUSH(DCPLB_ADDR7)
 410         PM_PUSH(DCPLB_ADDR8)
 411         PM_PUSH(DCPLB_ADDR9)
 412         PM_PUSH(DCPLB_ADDR10)
 413         PM_PUSH(DCPLB_ADDR11)
 414         PM_PUSH(DCPLB_ADDR12)
 415         PM_PUSH(DCPLB_ADDR13)
 416         PM_PUSH(DCPLB_ADDR14)
 417         PM_PUSH(DCPLB_ADDR15)
 418         PM_PUSH(DCPLB_DATA0)
 419         PM_PUSH(DCPLB_DATA1)
 420         PM_PUSH(DCPLB_DATA2)
 421         PM_PUSH(DCPLB_DATA3)
 422         PM_PUSH(DCPLB_DATA4)
 423         PM_PUSH(DCPLB_DATA5)
 424         PM_PUSH(DCPLB_DATA6)
 425         PM_PUSH(DCPLB_DATA7)
 426         PM_PUSH(DCPLB_DATA8)
 427         PM_PUSH(DCPLB_DATA9)
 428         PM_PUSH(DCPLB_DATA10)
 429         PM_PUSH(DCPLB_DATA11)
 430         PM_PUSH(DCPLB_DATA12)
 431         PM_PUSH(DCPLB_DATA13)
 432         PM_PUSH(DCPLB_DATA14)
 433         PM_PUSH(DCPLB_DATA15)
 434         PM_PUSH(IMEM_CONTROL)
 435         PM_PUSH(ICPLB_ADDR0)
 436         PM_PUSH(ICPLB_ADDR1)
 437         PM_PUSH(ICPLB_ADDR2)
 438         PM_PUSH(ICPLB_ADDR3)
 439         PM_PUSH(ICPLB_ADDR4)
 440         PM_PUSH(ICPLB_ADDR5)
 441         PM_PUSH(ICPLB_ADDR6)
 442         PM_PUSH(ICPLB_ADDR7)
 443         PM_PUSH(ICPLB_ADDR8)
 444         PM_PUSH(ICPLB_ADDR9)
 445         PM_PUSH(ICPLB_ADDR10)
 446         PM_PUSH(ICPLB_ADDR11)
 447         PM_PUSH(ICPLB_ADDR12)
 448         PM_PUSH(ICPLB_ADDR13)
 449         PM_PUSH(ICPLB_ADDR14)
 450         PM_PUSH(ICPLB_ADDR15)
 451         PM_PUSH(ICPLB_DATA0)
 452         PM_PUSH(ICPLB_DATA1)
 453         PM_PUSH(ICPLB_DATA2)
 454         PM_PUSH(ICPLB_DATA3)
 455         PM_PUSH(ICPLB_DATA4)
 456         PM_PUSH(ICPLB_DATA5)
 457         PM_PUSH(ICPLB_DATA6)
 458         PM_PUSH(ICPLB_DATA7)
 459         PM_PUSH(ICPLB_DATA8)
 460         PM_PUSH(ICPLB_DATA9)
 461         PM_PUSH(ICPLB_DATA10)
 462         PM_PUSH(ICPLB_DATA11)
 463         PM_PUSH(ICPLB_DATA12)
 464         PM_PUSH(ICPLB_DATA13)
 465         PM_PUSH(ICPLB_DATA14)
 466         PM_PUSH(ICPLB_DATA15)
 467         PM_PUSH(EVT0)
 468         PM_PUSH(EVT1)
 469         PM_PUSH(EVT2)
 470         PM_PUSH(EVT3)
 471         PM_PUSH(EVT4)
 472         PM_PUSH(EVT5)
 473         PM_PUSH(EVT6)
 474         PM_PUSH(EVT7)
 475         PM_PUSH(EVT8)
 476         PM_PUSH(EVT9)
 477         PM_PUSH(EVT10)
 478         PM_PUSH(EVT11)
 479         PM_PUSH(EVT12)
 480         PM_PUSH(EVT13)
 481         PM_PUSH(EVT14)
 482         PM_PUSH(EVT15)
 483         PM_PUSH(IMASK)
 484         PM_PUSH(ILAT)
 485         PM_PUSH(IPRIO)
 486         PM_PUSH(TCNTL)
 487         PM_PUSH(TPERIOD)
 488         PM_PUSH(TSCALE)
 489         PM_PUSH(TCOUNT)
 490         PM_PUSH(TBUFCTL)
 491
 492         /* Save Core Registers */
 493         [--sp] = SYSCFG;
 494         [--sp] = ( R7:0, P5:0 );
 495         [--sp] = fp;
 496         [--sp] = usp;
 497
 498         [--sp] = i0;
 499         [--sp] = i1;
 500         [--sp] = i2;
 501         [--sp] = i3;
 502
 503         [--sp] = m0;
 504         [--sp] = m1;
 505         [--sp] = m2;
 506         [--sp] = m3;
 507
 508         [--sp] = l0;
 509         [--sp] = l1;
 510         [--sp] = l2;
 511         [--sp] = l3;
 512
 513         [--sp] = b0;
 514         [--sp] = b1;
 515         [--sp] = b2;
 516         [--sp] = b3;
 517         [--sp] = a0.x;
 518         [--sp] = a0.w;
 519         [--sp] = a1.x;
 520         [--sp] = a1.w;
 521
 522         [--sp] = LC0;
 523         [--sp] = LC1;
 524         [--sp] = LT0;
 525         [--sp] = LT1;
 526         [--sp] = LB0;
 527         [--sp] = LB1;
 528
 529         [--sp] = ASTAT;
 530         [--sp] = CYCLES;
 531         [--sp] = CYCLES2;
 532
 533         [--sp] = RETS;
 534         r0 = RETI;
 535         [--sp] = r0;
 536         [--sp] = RETX;
 537         [--sp] = SEQSTAT;
 538
 539         /* Save Magic, return address and Stack Pointer */
 540         P0.H = 0;
 541         P0.L = 0;
 542         R0.H = 0xDEAD;  /* Hibernate Magic */
 543         R0.L = 0xBEEF;
 544         [P0++] = R0;    /* Store Hibernate Magic */
 545         R0.H = .Lpm_resume_here;
 546         R0.L = .Lpm_resume_here;
 547         [P0++] = R0;    /* Save Return Address */
 548         [P0++] = SP;    /* Save Stack Pointer */
 549         P0.H = _hibernate_mode;
 550         P0.L = _hibernate_mode;
 551         R0 = R2;
 552         call (P0); /* Goodbye */
 553
 554 .Lpm_resume_here:
 555
 556         /* Restore Core Registers */
 557         SEQSTAT = [sp++];
 558         RETX = [sp++];
 559         r0 = [sp++];
 560         RETI = r0;
 561         RETS = [sp++];
 562
 563         CYCLES2 = [sp++];
 564         CYCLES = [sp++];
 565         ASTAT = [sp++];
 566
 567         LB1 = [sp++];
 568         LB0 = [sp++];
 569         LT1 = [sp++];
 570         LT0 = [sp++];
 571         LC1 = [sp++];
 572         LC0 = [sp++];
 573
 574         a1.w = [sp++];
 575         a1.x = [sp++];
 576         a0.w = [sp++];
 577         a0.x = [sp++];
 578         b3 = [sp++];
 579         b2 = [sp++];
 580         b1 = [sp++];
 581         b0 = [sp++];
 582
 583         l3 = [sp++];
 584         l2 = [sp++];
 585         l1 = [sp++];
 586         l0 = [sp++];
 587
 588         m3 = [sp++];
 589         m2 = [sp++];
 590         m1 = [sp++];
 591         m0 = [sp++];
 592
 593         i3 = [sp++];
 594         i2 = [sp++];
 595         i1 = [sp++];
 596         i0 = [sp++];
 597
 598         usp = [sp++];
 599         fp = [sp++];
 600
 601         ( R7 : 0, P5 : 0) = [ SP ++ ];
 602         SYSCFG = [sp++];
 603
 604         /* Restore Core MMRs */
 605
 606         PM_POP(TBUFCTL)
 607         PM_POP(TCOUNT)
 608         PM_POP(TSCALE)
 609         PM_POP(TPERIOD)
 610         PM_POP(TCNTL)
 611         PM_POP(IPRIO)
 612         PM_POP(ILAT)
 613         PM_POP(IMASK)
 614         PM_POP(EVT15)
 615         PM_POP(EVT14)
 616         PM_POP(EVT13)
 617         PM_POP(EVT12)
 618         PM_POP(EVT11)
 619         PM_POP(EVT10)
 620         PM_POP(EVT9)
 621         PM_POP(EVT8)
 622         PM_POP(EVT7)
 623         PM_POP(EVT6)
 624         PM_POP(EVT5)
 625         PM_POP(EVT4)
 626         PM_POP(EVT3)
 627         PM_POP(EVT2)
 628         PM_POP(EVT1)
 629         PM_POP(EVT0)
 630         PM_POP(ICPLB_DATA15)
 631         PM_POP(ICPLB_DATA14)
 632         PM_POP(ICPLB_DATA13)
 633         PM_POP(ICPLB_DATA12)
 634         PM_POP(ICPLB_DATA11)
 635         PM_POP(ICPLB_DATA10)
 636         PM_POP(ICPLB_DATA9)
 637         PM_POP(ICPLB_DATA8)
 638         PM_POP(ICPLB_DATA7)
 639         PM_POP(ICPLB_DATA6)
 640         PM_POP(ICPLB_DATA5)
 641         PM_POP(ICPLB_DATA4)
 642         PM_POP(ICPLB_DATA3)
 643         PM_POP(ICPLB_DATA2)
 644         PM_POP(ICPLB_DATA1)
 645         PM_POP(ICPLB_DATA0)
 646         PM_POP(ICPLB_ADDR15)
 647         PM_POP(ICPLB_ADDR14)
 648         PM_POP(ICPLB_ADDR13)
 649         PM_POP(ICPLB_ADDR12)
 650         PM_POP(ICPLB_ADDR11)
 651         PM_POP(ICPLB_ADDR10)
 652         PM_POP(ICPLB_ADDR9)
 653         PM_POP(ICPLB_ADDR8)
 654         PM_POP(ICPLB_ADDR7)
 655         PM_POP(ICPLB_ADDR6)
 656         PM_POP(ICPLB_ADDR5)
 657         PM_POP(ICPLB_ADDR4)
 658         PM_POP(ICPLB_ADDR3)
 659         PM_POP(ICPLB_ADDR2)
 660         PM_POP(ICPLB_ADDR1)
 661         PM_POP(ICPLB_ADDR0)
 662         PM_POP(IMEM_CONTROL)
 663         PM_POP(DCPLB_DATA15)
 664         PM_POP(DCPLB_DATA14)
 665         PM_POP(DCPLB_DATA13)
 666         PM_POP(DCPLB_DATA12)
 667         PM_POP(DCPLB_DATA11)
 668         PM_POP(DCPLB_DATA10)
 669         PM_POP(DCPLB_DATA9)
 670         PM_POP(DCPLB_DATA8)
 671         PM_POP(DCPLB_DATA7)
 672         PM_POP(DCPLB_DATA6)
 673         PM_POP(DCPLB_DATA5)
 674         PM_POP(DCPLB_DATA4)
 675         PM_POP(DCPLB_DATA3)
 676         PM_POP(DCPLB_DATA2)
 677         PM_POP(DCPLB_DATA1)
 678         PM_POP(DCPLB_DATA0)
 679         PM_POP(DCPLB_ADDR15)
 680         PM_POP(DCPLB_ADDR14)
 681         PM_POP(DCPLB_ADDR13)
 682         PM_POP(DCPLB_ADDR12)
 683         PM_POP(DCPLB_ADDR11)
 684         PM_POP(DCPLB_ADDR10)
 685         PM_POP(DCPLB_ADDR9)
 686         PM_POP(DCPLB_ADDR8)
 687         PM_POP(DCPLB_ADDR7)
 688         PM_POP(DCPLB_ADDR6)
 689         PM_POP(DCPLB_ADDR5)
 690         PM_POP(DCPLB_ADDR4)
 691         PM_POP(DCPLB_ADDR3)
 692         PM_POP(DCPLB_ADDR2)
 693         PM_POP(DCPLB_ADDR1)
 694         PM_POP(DCPLB_ADDR0)
 695         PM_POP(DMEM_CONTROL)
 696
 697         /* Restore System MMRs */
 698
 699         P0.H = hi(PLL_CTL);
 700         P0.L = lo(PLL_CTL);
 701         PM_SYS_POP16(SYSCR)
 702
 703 #ifdef PORTCIO_FER
 704         PM_SYS_POP16(PORTEIO_FER)
 705         PM_SYS_POP16(PORTEIO)
 706         PM_SYS_POP16(PORTEIO_INEN)
 707         PM_SYS_POP16(PORTEIO_DIR)
 708         PM_SYS_POP16(PORTDIO_FER)
 709         PM_SYS_POP16(PORTDIO)
 710         PM_SYS_POP16(PORTDIO_INEN)
 711         PM_SYS_POP16(PORTDIO_DIR)
 712         PM_SYS_POP16(PORTCIO_FER)
 713         PM_SYS_POP16(PORTCIO)
 714         PM_SYS_POP16(PORTCIO_INEN)
 715         PM_SYS_POP16(PORTCIO_DIR)
 716 #endif
 717
 718 #ifdef EBIU_FCTL
 719         PM_SYS_POP(EBIU_FCTL)
 720         PM_SYS_POP(EBIU_MODE)
 721         PM_SYS_POP(EBIU_MBSCTL)
 722 #endif
 723         PM_SYS_POP16(EBIU_AMGCTL)
 724         PM_SYS_POP(EBIU_AMBCTL1)
 725         PM_SYS_POP(EBIU_AMBCTL0)
 726
 727 #ifdef PINT0_ASSIGN
 728         PM_SYS_POP(PINT3_EDGE_SET)
 729         PM_SYS_POP(PINT2_EDGE_SET)
 730         PM_SYS_POP(PINT1_EDGE_SET)
 731         PM_SYS_POP(PINT0_EDGE_SET)
 732         PM_SYS_POP(PINT3_INVERT_SET)
 733         PM_SYS_POP(PINT2_INVERT_SET)
 734         PM_SYS_POP(PINT1_INVERT_SET)
 735         PM_SYS_POP(PINT0_INVERT_SET)
 736         PM_SYS_POP(PINT3_ASSIGN)
 737         PM_SYS_POP(PINT2_ASSIGN)
 738         PM_SYS_POP(PINT1_ASSIGN)
 739         PM_SYS_POP(PINT0_ASSIGN)
 740         PM_SYS_POP(PINT3_MASK_SET)
 741         PM_SYS_POP(PINT2_MASK_SET)
 742         PM_SYS_POP(PINT1_MASK_SET)
 743         PM_SYS_POP(PINT0_MASK_SET)
 744 #endif
 745
 746 #ifdef SIC_IWR2
 747         PM_SYS_POP(SIC_IWR2)
 748 #endif
 749 #ifdef SIC_IWR1
 750         PM_SYS_POP(SIC_IWR1)
 751 #endif
 752 #ifdef SIC_IWR0
 753         PM_SYS_POP(SIC_IWR0)
 754 #endif
 755 #ifdef SIC_IWR
 756         PM_SYS_POP(SIC_IWR)
 757 #endif
 758
 759 #ifdef SIC_IAR8
 760         PM_SYS_POP(SIC_IAR11)
 761         PM_SYS_POP(SIC_IAR10)
 762         PM_SYS_POP(SIC_IAR9)
 763         PM_SYS_POP(SIC_IAR8)
 764 #endif
 765 #ifdef SIC_IAR7
 766         PM_SYS_POP(SIC_IAR7)
 767 #endif
 768 #ifdef SIC_IAR6
 769         PM_SYS_POP(SIC_IAR6)
 770         PM_SYS_POP(SIC_IAR5)
 771         PM_SYS_POP(SIC_IAR4)
 772 #endif
 773 #ifdef SIC_IAR3
 774         PM_SYS_POP(SIC_IAR3)
 775 #endif
 776 #ifdef SIC_IAR0
 777         PM_SYS_POP(SIC_IAR2)
 778         PM_SYS_POP(SIC_IAR1)
 779         PM_SYS_POP(SIC_IAR0)
 780 #endif
 781 #ifdef SIC_IMASK
 782         PM_SYS_POP(SIC_IMASK)
 783 #endif
 784 #ifdef SIC_IMASK2
 785         PM_SYS_POP(SIC_IMASK2)
 786 #endif
 787 #ifdef SIC_IMASK1
 788         PM_SYS_POP(SIC_IMASK1)
 789 #endif
 790 #ifdef SIC_IMASK0
 791         PM_SYS_POP(SIC_IMASK0)
 792 #endif
 793
 794         [--sp] = RETI;  /* Clear Global Interrupt Disable */
 795         SP += 4;
 796
 797         RETS = [SP++];
 798         ( R7:0, P5:0 ) = [SP++];
 799         RTS;
 800 ENDPROC(_do_hibernate)