arch/cris/kernel/vmlinux.lds.S

   1 /* ld script to make the Linux/CRIS kernel
   2  * Authors: Bjorn Wesen (bjornw@axis.com)
   3  *
   4  * It is VERY DANGEROUS to fiddle around with the symbols in this
   5  * script. It is for example quite vital that all generated sections
   6  * that are used are actually named here, otherwise the linker will
   7  * put them at the end, where the init stuff is which is FREED after
   8  * the kernel has booted.
   9  */
  10
  11 #include <asm-generic/vmlinux.lds.h>
  12 #include <asm/page.h>
  13
  14 #ifdef CONFIG_ETRAX_VMEM_SIZE
  15 #define __CONFIG_ETRAX_VMEM_SIZE CONFIG_ETRAX_VMEM_SIZE
  16 #else
  17 #define __CONFIG_ETRAX_VMEM_SIZE 0
  18 #endif
  19
  20
  21 jiffies = jiffies_64;
  22 SECTIONS
  23 {
  24         . = DRAM_VIRTUAL_BASE;
  25         dram_start = .;
  26 #ifdef CONFIG_ETRAX_ARCH_V10
  27         ibr_start = .;
  28 #else
  29         ebp_start = .;
  30         /* The boot section is only necessary until the VCS top */
  31         /* level testbench includes both flash and DRAM. */
  32         .boot : { *(.boot) }
  33 #endif
  34
  35         /* see head.S and pages reserved at the start */
  36         . = DRAM_VIRTUAL_BASE + 0x4000;
  37
  38         _text = .;                      /* Text and read-only data. */
  39         text_start = .;                 /* Lots of aliases. */
  40         _stext = .;
  41         __stext = .;
  42         .text : {
  43                 HEAD_TEXT
  44                 TEXT_TEXT
  45                 SCHED_TEXT
  46                 LOCK_TEXT
  47                 *(.fixup)
  48                 *(.text.__*)
  49         }
  50
  51         _etext = . ;                    /* End of text section. */
  52         __etext = .;
  53
  54         EXCEPTION_TABLE(4)
  55
  56         _sdata = .;
  57         RODATA
  58
  59         . = ALIGN (4);
  60         ___data_start = . ;
  61         __Sdata = . ;
  62         .data : {                       /* Data */
  63                 CACHELINE_ALIGNED_DATA(32)
  64                 READ_MOSTLY_DATA(32)
  65                 DATA_DATA
  66         }
  67         __edata = . ;                   /* End of data section. */
  68         _edata = . ;
  69
  70         INIT_TASK_DATA_SECTION(PAGE_SIZE)
  71
  72         . = ALIGN(PAGE_SIZE);           /* Init code and data. */
  73         __init_begin = .;
  74         INIT_TEXT_SECTION(PAGE_SIZE)
  75         .init.data : { INIT_DATA }
  76         .init.setup : { INIT_SETUP(16) }
  77         .initcall.init : {
  78                 INIT_CALLS
  79         }
  80
  81         .con_initcall.init : {
  82                 CON_INITCALL
  83         }
  84         SECURITY_INIT
  85
  86         /* .exit.text is discarded at runtime, not link time,
  87          * to deal with references from __bug_table
  88          */
  89         .exit.text : {
  90                 EXIT_TEXT
  91         }
  92         .exit.data : {
  93                 EXIT_DATA
  94         }
  95
  96 #ifdef CONFIG_ETRAX_ARCH_V10
  97 #ifdef CONFIG_BLK_DEV_INITRD
  98         .init.ramfs : {
  99                 __initramfs_start = .;
 100                 *(.init.ramfs)
 101                 __initramfs_end = .;
 102         }
 103 #endif
 104 #endif
 105         __vmlinux_end = .;              /* Last address of the physical file. */
 106 #ifdef CONFIG_ETRAX_ARCH_V32
 107         PERCPU_SECTION(32)
 108
 109         .init.ramfs : {
 110                 INIT_RAM_FS
 111         }
 112 #endif
 113
 114         /*
 115          * We fill to the next page, so we can discard all init
 116          * pages without needing to consider what payload might be
 117          * appended to the kernel image.
 118          */
 119         . = ALIGN(PAGE_SIZE);
 120
 121         __init_end = .;
 122
 123         __data_end = . ;                /* Move to _edata ? */
 124         BSS_SECTION(1, 1, 1)
 125
 126         . =  ALIGN (0x20);
 127         _end = .;
 128         __end = .;
 129
 130         dram_end = dram_start + (CONFIG_ETRAX_DRAM_SIZE - __CONFIG_ETRAX_VMEM_SIZE)*1024*1024;
 131
 132         DISCARDS
 133 }