arch/i386/kernel/entry.S

   1 /*
   2  *  linux/arch/i386/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  */
   6
   7 /*
   8  * entry.S contains the system-call and fault low-level handling routines.
   9  * This also contains the timer-interrupt handler, as well as all interrupts
  10  * and faults that can result in a task-switch.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after a timer-interrupt and after each system call.
  14  *
  15  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  16  * on a 486.
  17  *
  18  * Stack layout in 'ret_from_system_call':
  19  *      ptrace needs to have all regs on the stack.
  20  *      if the order here is changed, it needs to be
  21  *      updated in fork.c:copy_process, signal.c:do_signal,
  22  *      ptrace.c and ptrace.h
  23  *
  24  *       0(%esp) - %ebx
  25  *       4(%esp) - %ecx
  26  *       8(%esp) - %edx
  27  *       C(%esp) - %esi
  28  *      10(%esp) - %edi
  29  *      14(%esp) - %ebp
  30  *      18(%esp) - %eax
  31  *      1C(%esp) - %ds
  32  *      20(%esp) - %es
  33  *      24(%esp) - %fs
  34  *      28(%esp) - orig_eax
  35  *      2C(%esp) - %eip
  36  *      30(%esp) - %cs
  37  *      34(%esp) - %eflags
  38  *      38(%esp) - %oldesp
  39  *      3C(%esp) - %oldss
  40  *
  41  * "current" is in register %ebx during any slow entries.
  42  */
  43
  44 #include <linux/linkage.h>
  45 #include <asm/thread_info.h>
  46 #include <asm/irqflags.h>
  47 #include <asm/errno.h>
  48 #include <asm/segment.h>
  49 #include <asm/smp.h>
  50 #include <asm/page.h>
  51 #include <asm/desc.h>
  52 #include <asm/percpu.h>
  53 #include <asm/dwarf2.h>
  54 #include "irq_vectors.h"
  55
  56 /*
  57  * We use macros for low-level operations which need to be overridden
  58  * for paravirtualization.  The following will never clobber any registers:
  59  *   INTERRUPT_RETURN (aka. "iret")
  60  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
  61  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
  62  *
  63  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
  64  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
  65  * Allowing a register to be clobbered can shrink the paravirt replacement
  66  * enough to patch inline, increasing performance.
  67  */
  68
  69 #define nr_syscalls ((syscall_table_size)/4)
  70
  71 CF_MASK         = 0x00000001
  72 TF_MASK         = 0x00000100
  73 IF_MASK         = 0x00000200
  74 DF_MASK         = 0x00000400
  75 NT_MASK         = 0x00004000
  76 VM_MASK         = 0x00020000
  77
  78 #ifdef CONFIG_PREEMPT
  79 #define preempt_stop(clobbers)  DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
  80 #else
  81 #define preempt_stop(clobbers)
  82 #define resume_kernel           restore_nocheck
  83 #endif
  84
  85 .macro TRACE_IRQS_IRET
  86 #ifdef CONFIG_TRACE_IRQFLAGS
  87         testl $IF_MASK,PT_EFLAGS(%esp)     # interrupts off?
  88         jz 1f
  89         TRACE_IRQS_ON
  90 1:
  91 #endif
  92 .endm
  93
  94 #ifdef CONFIG_VM86
  95 #define resume_userspace_sig    check_userspace
  96 #else
  97 #define resume_userspace_sig    resume_userspace
  98 #endif
  99
 100 #define SAVE_ALL \
 101         cld; \
 102         pushl %fs; \
 103         CFI_ADJUST_CFA_OFFSET 4;\
 104         /*CFI_REL_OFFSET fs, 0;*/\
 105         pushl %es; \
 106         CFI_ADJUST_CFA_OFFSET 4;\
 107         /*CFI_REL_OFFSET es, 0;*/\
 108         pushl %ds; \
 109         CFI_ADJUST_CFA_OFFSET 4;\
 110         /*CFI_REL_OFFSET ds, 0;*/\
 111         pushl %eax; \
 112         CFI_ADJUST_CFA_OFFSET 4;\
 113         CFI_REL_OFFSET eax, 0;\
 114         pushl %ebp; \
 115         CFI_ADJUST_CFA_OFFSET 4;\
 116         CFI_REL_OFFSET ebp, 0;\
 117         pushl %edi; \
 118         CFI_ADJUST_CFA_OFFSET 4;\
 119         CFI_REL_OFFSET edi, 0;\
 120         pushl %esi; \
 121         CFI_ADJUST_CFA_OFFSET 4;\
 122         CFI_REL_OFFSET esi, 0;\
 123         pushl %edx; \
 124         CFI_ADJUST_CFA_OFFSET 4;\
 125         CFI_REL_OFFSET edx, 0;\
 126         pushl %ecx; \
 127         CFI_ADJUST_CFA_OFFSET 4;\
 128         CFI_REL_OFFSET ecx, 0;\
 129         pushl %ebx; \
 130         CFI_ADJUST_CFA_OFFSET 4;\
 131         CFI_REL_OFFSET ebx, 0;\
 132         movl $(__USER_DS), %edx; \
 133         movl %edx, %ds; \
 134         movl %edx, %es; \
 135         movl $(__KERNEL_PDA), %edx; \
 136         movl %edx, %fs
 137
 138 #define RESTORE_INT_REGS \
 139         popl %ebx;      \
 140         CFI_ADJUST_CFA_OFFSET -4;\
 141         CFI_RESTORE ebx;\
 142         popl %ecx;      \
 143         CFI_ADJUST_CFA_OFFSET -4;\
 144         CFI_RESTORE ecx;\
 145         popl %edx;      \
 146         CFI_ADJUST_CFA_OFFSET -4;\
 147         CFI_RESTORE edx;\
 148         popl %esi;      \
 149         CFI_ADJUST_CFA_OFFSET -4;\
 150         CFI_RESTORE esi;\
 151         popl %edi;      \
 152         CFI_ADJUST_CFA_OFFSET -4;\
 153         CFI_RESTORE edi;\
 154         popl %ebp;      \
 155         CFI_ADJUST_CFA_OFFSET -4;\
 156         CFI_RESTORE ebp;\
 157         popl %eax;      \
 158         CFI_ADJUST_CFA_OFFSET -4;\
 159         CFI_RESTORE eax
 160
 161 #define RESTORE_REGS    \
 162         RESTORE_INT_REGS; \
 163 1:      popl %ds;       \
 164         CFI_ADJUST_CFA_OFFSET -4;\
 165         /*CFI_RESTORE ds;*/\
 166 2:      popl %es;       \
 167         CFI_ADJUST_CFA_OFFSET -4;\
 168         /*CFI_RESTORE es;*/\
 169 3:      popl %fs;       \
 170         CFI_ADJUST_CFA_OFFSET -4;\
 171         /*CFI_RESTORE fs;*/\
 172 .pushsection .fixup,"ax";       \
 173 4:      movl $0,(%esp); \
 174         jmp 1b;         \
 175 5:      movl $0,(%esp); \
 176         jmp 2b;         \
 177 6:      movl $0,(%esp); \
 178         jmp 3b;         \
 179 .section __ex_table,"a";\
 180         .align 4;       \
 181         .long 1b,4b;    \
 182         .long 2b,5b;    \
 183         .long 3b,6b;    \
 184 .popsection
 185
 186 #define RING0_INT_FRAME \
 187         CFI_STARTPROC simple;\
 188         CFI_SIGNAL_FRAME;\
 189         CFI_DEF_CFA esp, 3*4;\
 190         /*CFI_OFFSET cs, -2*4;*/\
 191         CFI_OFFSET eip, -3*4
 192
 193 #define RING0_EC_FRAME \
 194         CFI_STARTPROC simple;\
 195         CFI_SIGNAL_FRAME;\
 196         CFI_DEF_CFA esp, 4*4;\
 197         /*CFI_OFFSET cs, -2*4;*/\
 198         CFI_OFFSET eip, -3*4
 199
 200 #define RING0_PTREGS_FRAME \
 201         CFI_STARTPROC simple;\
 202         CFI_SIGNAL_FRAME;\
 203         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX;\
 204         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/\
 205         CFI_OFFSET eip, PT_EIP-PT_OLDESP;\
 206         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/\
 207         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/\
 208         CFI_OFFSET eax, PT_EAX-PT_OLDESP;\
 209         CFI_OFFSET ebp, PT_EBP-PT_OLDESP;\
 210         CFI_OFFSET edi, PT_EDI-PT_OLDESP;\
 211         CFI_OFFSET esi, PT_ESI-PT_OLDESP;\
 212         CFI_OFFSET edx, PT_EDX-PT_OLDESP;\
 213         CFI_OFFSET ecx, PT_ECX-PT_OLDESP;\
 214         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
 215
 216 ENTRY(ret_from_fork)
 217         CFI_STARTPROC
 218         pushl %eax
 219         CFI_ADJUST_CFA_OFFSET 4
 220         call schedule_tail
 221         GET_THREAD_INFO(%ebp)
 222         popl %eax
 223         CFI_ADJUST_CFA_OFFSET -4
 224         pushl $0x0202                   # Reset kernel eflags
 225         CFI_ADJUST_CFA_OFFSET 4
 226         popfl
 227         CFI_ADJUST_CFA_OFFSET -4
 228         jmp syscall_exit
 229         CFI_ENDPROC
 230
 231 /*
 232  * Return to user mode is not as complex as all this looks,
 233  * but we want the default path for a system call return to
 234  * go as quickly as possible which is why some of this is
 235  * less clear than it otherwise should be.
 236  */
 237
 238         # userspace resumption stub bypassing syscall exit tracing
 239         ALIGN
 240         RING0_PTREGS_FRAME
 241 ret_from_exception:
 242         preempt_stop(CLBR_ANY)
 243 ret_from_intr:
 244         GET_THREAD_INFO(%ebp)
 245 check_userspace:
 246         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
 247         movb PT_CS(%esp), %al
 248         andl $(VM_MASK | SEGMENT_RPL_MASK), %eax
 249         cmpl $USER_RPL, %eax
 250         jb resume_kernel                # not returning to v8086 or userspace
 251
 252 ENTRY(resume_userspace)
 253         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 254                                         # setting need_resched or sigpending
 255                                         # between sampling and the iret
 256         movl TI_flags(%ebp), %ecx
 257         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 258                                         # int/exception return?
 259         jne work_pending
 260         jmp restore_all
 261
 262 #ifdef CONFIG_PREEMPT
 263 ENTRY(resume_kernel)
 264         DISABLE_INTERRUPTS(CLBR_ANY)
 265         cmpl $0,TI_preempt_count(%ebp)  # non-zero preempt_count ?
 266         jnz restore_nocheck
 267 need_resched:
 268         movl TI_flags(%ebp), %ecx       # need_resched set ?
 269         testb $_TIF_NEED_RESCHED, %cl
 270         jz restore_all
 271         testl $IF_MASK,PT_EFLAGS(%esp)  # interrupts off (exception path) ?
 272         jz restore_all
 273         call preempt_schedule_irq
 274         jmp need_resched
 275 #endif
 276         CFI_ENDPROC
 277
 278 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 279    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 280
 281         # sysenter call handler stub
 282 ENTRY(sysenter_entry)
 283         CFI_STARTPROC simple
 284         CFI_SIGNAL_FRAME
 285         CFI_DEF_CFA esp, 0
 286         CFI_REGISTER esp, ebp
 287         movl TSS_sysenter_esp0(%esp),%esp
 288 sysenter_past_esp:
 289         /*
 290          * No need to follow this irqs on/off section: the syscall
 291          * disabled irqs and here we enable it straight after entry:
 292          */
 293         ENABLE_INTERRUPTS(CLBR_NONE)
 294         pushl $(__USER_DS)
 295         CFI_ADJUST_CFA_OFFSET 4
 296         /*CFI_REL_OFFSET ss, 0*/
 297         pushl %ebp
 298         CFI_ADJUST_CFA_OFFSET 4
 299         CFI_REL_OFFSET esp, 0
 300         pushfl
 301         CFI_ADJUST_CFA_OFFSET 4
 302         pushl $(__USER_CS)
 303         CFI_ADJUST_CFA_OFFSET 4
 304         /*CFI_REL_OFFSET cs, 0*/
 305 #ifndef CONFIG_COMPAT_VDSO
 306         /*
 307          * Push current_thread_info()->sysenter_return to the stack.
 308          * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
 309          * pushed above; +8 corresponds to copy_thread's esp0 setting.
 310          */
 311         pushl (TI_sysenter_return-THREAD_SIZE+8+4*4)(%esp)
 312 #else
 313         pushl $SYSENTER_RETURN
 314 #endif
 315         CFI_ADJUST_CFA_OFFSET 4
 316         CFI_REL_OFFSET eip, 0
 317
 318 /*
 319  * Load the potential sixth argument from user stack.
 320  * Careful about security.
 321  */
 322         cmpl $__PAGE_OFFSET-3,%ebp
 323         jae syscall_fault
 324 1:      movl (%ebp),%ebp
 325 .section __ex_table,"a"
 326         .align 4
 327         .long 1b,syscall_fault
 328 .previous
 329
 330         pushl %eax
 331         CFI_ADJUST_CFA_OFFSET 4
 332         SAVE_ALL
 333         GET_THREAD_INFO(%ebp)
 334
 335         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
 336         testw $(_TIF_SYSCALL_EMU|_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 337         jnz syscall_trace_entry
 338         cmpl $(nr_syscalls), %eax
 339         jae syscall_badsys
 340         call *sys_call_table(,%eax,4)
 341         movl %eax,PT_EAX(%esp)
 342         DISABLE_INTERRUPTS(CLBR_ECX|CLBR_EDX)
 343         TRACE_IRQS_OFF
 344         movl TI_flags(%ebp), %ecx
 345         testw $_TIF_ALLWORK_MASK, %cx
 346         jne syscall_exit_work
 347 /* if something modifies registers it must also disable sysexit */
 348         movl PT_EIP(%esp), %edx
 349         movl PT_OLDESP(%esp), %ecx
 350         xorl %ebp,%ebp
 351         TRACE_IRQS_ON
 352 1:      mov  PT_FS(%esp), %fs
 353         ENABLE_INTERRUPTS_SYSEXIT
 354         CFI_ENDPROC
 355 .pushsection .fixup,"ax"
 356 2:      movl $0,PT_FS(%esp)
 357         jmp 1b
 358 .section __ex_table,"a"
 359         .align 4
 360         .long 1b,2b
 361 .popsection
 362
 363         # system call handler stub
 364 ENTRY(system_call)
 365         RING0_INT_FRAME                 # can't unwind into user space anyway
 366         pushl %eax                      # save orig_eax
 367         CFI_ADJUST_CFA_OFFSET 4
 368         SAVE_ALL
 369         GET_THREAD_INFO(%ebp)
 370         testl $TF_MASK,PT_EFLAGS(%esp)
 371         jz no_singlestep
 372         orl $_TIF_SINGLESTEP,TI_flags(%ebp)
 373 no_singlestep:
 374                                         # system call tracing in operation / emulation
 375         /* Note, _TIF_SECCOMP is bit number 8, and so it needs testw and not testb */
 376         testw $(_TIF_SYSCALL_EMU|_TIF_SYSCALL_TRACE|_TIF_SECCOMP|_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 377         jnz syscall_trace_entry
 378         cmpl $(nr_syscalls), %eax
 379         jae syscall_badsys
 380 syscall_call:
 381         call *sys_call_table(,%eax,4)
 382         movl %eax,PT_EAX(%esp)          # store the return value
 383 syscall_exit:
 384         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 385                                         # setting need_resched or sigpending
 386                                         # between sampling and the iret
 387         TRACE_IRQS_OFF
 388         movl TI_flags(%ebp), %ecx
 389         testw $_TIF_ALLWORK_MASK, %cx   # current->work
 390         jne syscall_exit_work
 391
 392 restore_all:
 393         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
 394         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 395         # are returning to the kernel.
 396         # See comments in process.c:copy_thread() for details.
 397         movb PT_OLDSS(%esp), %ah
 398         movb PT_CS(%esp), %al
 399         andl $(VM_MASK | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 400         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
 401         CFI_REMEMBER_STATE
 402         je ldt_ss                       # returning to user-space with LDT SS
 403 restore_nocheck:
 404         TRACE_IRQS_IRET
 405 restore_nocheck_notrace:
 406         RESTORE_REGS
 407         addl $4, %esp                   # skip orig_eax/error_code
 408         CFI_ADJUST_CFA_OFFSET -4
 409 1:      INTERRUPT_RETURN
 410 .section .fixup,"ax"
 411 iret_exc:
 412         TRACE_IRQS_ON
 413         ENABLE_INTERRUPTS(CLBR_NONE)
 414         pushl $0                        # no error code
 415         pushl $do_iret_error
 416         jmp error_code
 417 .previous
 418 .section __ex_table,"a"
 419         .align 4
 420         .long 1b,iret_exc
 421 .previous
 422
 423         CFI_RESTORE_STATE
 424 ldt_ss:
 425         larl PT_OLDSS(%esp), %eax
 426         jnz restore_nocheck
 427         testl $0x00400000, %eax         # returning to 32bit stack?
 428         jnz restore_nocheck             # allright, normal return
 429
 430 #ifdef CONFIG_PARAVIRT
 431         /*
 432          * The kernel can't run on a non-flat stack if paravirt mode
 433          * is active.  Rather than try to fixup the high bits of
 434          * ESP, bypass this code entirely.  This may break DOSemu
 435          * and/or Wine support in a paravirt VM, although the option
 436          * is still available to implement the setting of the high
 437          * 16-bits in the INTERRUPT_RETURN paravirt-op.
 438          */
 439         cmpl $0, paravirt_ops+PARAVIRT_enabled
 440         jne restore_nocheck
 441 #endif
 442
 443         /* If returning to userspace with 16bit stack,
 444          * try to fix the higher word of ESP, as the CPU
 445          * won't restore it.
 446          * This is an "official" bug of all the x86-compatible
 447          * CPUs, which we can try to work around to make
 448          * dosemu and wine happy. */
 449         movl PT_OLDESP(%esp), %eax
 450         movl %esp, %edx
 451         call patch_espfix_desc
 452         pushl $__ESPFIX_SS
 453         CFI_ADJUST_CFA_OFFSET 4
 454         pushl %eax
 455         CFI_ADJUST_CFA_OFFSET 4
 456         DISABLE_INTERRUPTS(CLBR_EAX)
 457         TRACE_IRQS_OFF
 458         lss (%esp), %esp
 459         CFI_ADJUST_CFA_OFFSET -8
 460         jmp restore_nocheck
 461         CFI_ENDPROC
 462
 463         # perform work that needs to be done immediately before resumption
 464         ALIGN
 465         RING0_PTREGS_FRAME              # can't unwind into user space anyway
 466 work_pending:
 467         testb $_TIF_NEED_RESCHED, %cl
 468         jz work_notifysig
 469 work_resched:
 470         call schedule
 471         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 472                                         # setting need_resched or sigpending
 473                                         # between sampling and the iret
 474         TRACE_IRQS_OFF
 475         movl TI_flags(%ebp), %ecx
 476         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 477                                         # than syscall tracing?
 478         jz restore_all
 479         testb $_TIF_NEED_RESCHED, %cl
 480         jnz work_resched
 481
 482 work_notifysig:                         # deal with pending signals and
 483                                         # notify-resume requests
 484 #ifdef CONFIG_VM86
 485         testl $VM_MASK, PT_EFLAGS(%esp)
 486         movl %esp, %eax
 487         jne work_notifysig_v86          # returning to kernel-space or
 488                                         # vm86-space
 489         xorl %edx, %edx
 490         call do_notify_resume
 491         jmp resume_userspace_sig
 492
 493         ALIGN
 494 work_notifysig_v86:
 495         pushl %ecx                      # save ti_flags for do_notify_resume
 496         CFI_ADJUST_CFA_OFFSET 4
 497         call save_v86_state             # %eax contains pt_regs pointer
 498         popl %ecx
 499         CFI_ADJUST_CFA_OFFSET -4
 500         movl %eax, %esp
 501 #else
 502         movl %esp, %eax
 503 #endif
 504         xorl %edx, %edx
 505         call do_notify_resume
 506         jmp resume_userspace_sig
 507
 508         # perform syscall exit tracing
 509         ALIGN
 510 syscall_trace_entry:
 511         movl $-ENOSYS,PT_EAX(%esp)
 512         movl %esp, %eax
 513         xorl %edx,%edx
 514         call do_syscall_trace
 515         cmpl $0, %eax
 516         jne resume_userspace            # ret != 0 -> running under PTRACE_SYSEMU,
 517                                         # so must skip actual syscall
 518         movl PT_ORIG_EAX(%esp), %eax
 519         cmpl $(nr_syscalls), %eax
 520         jnae syscall_call
 521         jmp syscall_exit
 522
 523         # perform syscall exit tracing
 524         ALIGN
 525 syscall_exit_work:
 526         testb $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SINGLESTEP), %cl
 527         jz work_pending
 528         TRACE_IRQS_ON
 529         ENABLE_INTERRUPTS(CLBR_ANY)     # could let do_syscall_trace() call
 530                                         # schedule() instead
 531         movl %esp, %eax
 532         movl $1, %edx
 533         call do_syscall_trace
 534         jmp resume_userspace
 535         CFI_ENDPROC
 536
 537         RING0_INT_FRAME                 # can't unwind into user space anyway
 538 syscall_fault:
 539         pushl %eax                      # save orig_eax
 540         CFI_ADJUST_CFA_OFFSET 4
 541         SAVE_ALL
 542         GET_THREAD_INFO(%ebp)
 543         movl $-EFAULT,PT_EAX(%esp)
 544         jmp resume_userspace
 545
 546 syscall_badsys:
 547         movl $-ENOSYS,PT_EAX(%esp)
 548         jmp resume_userspace
 549         CFI_ENDPROC
 550
 551 #define FIXUP_ESPFIX_STACK \
 552         /* since we are on a wrong stack, we cant make it a C code :( */ \
 553         movl %fs:PDA_cpu, %ebx; \
 554         PER_CPU(cpu_gdt_descr, %ebx); \
 555         movl GDS_address(%ebx), %ebx; \
 556         GET_DESC_BASE(GDT_ENTRY_ESPFIX_SS, %ebx, %eax, %ax, %al, %ah); \
 557         addl %esp, %eax; \
 558         pushl $__KERNEL_DS; \
 559         CFI_ADJUST_CFA_OFFSET 4; \
 560         pushl %eax; \
 561         CFI_ADJUST_CFA_OFFSET 4; \
 562         lss (%esp), %esp; \
 563         CFI_ADJUST_CFA_OFFSET -8;
 564 #define UNWIND_ESPFIX_STACK \
 565         movl %ss, %eax; \
 566         /* see if on espfix stack */ \
 567         cmpw $__ESPFIX_SS, %ax; \
 568         jne 27f; \
 569         movl $__KERNEL_DS, %eax; \
 570         movl %eax, %ds; \
 571         movl %eax, %es; \
 572         /* switch to normal stack */ \
 573         FIXUP_ESPFIX_STACK; \
 574 27:;
 575
 576 /*
 577  * Build the entry stubs and pointer table with
 578  * some assembler magic.
 579  */
 580 .data
 581 ENTRY(interrupt)
 582 .text
 583
 584 vector=0
 585 ENTRY(irq_entries_start)
 586         RING0_INT_FRAME
 587 .rept NR_IRQS
 588         ALIGN
 589  .if vector
 590         CFI_ADJUST_CFA_OFFSET -4
 591  .endif
 592 1:      pushl $~(vector)
 593         CFI_ADJUST_CFA_OFFSET 4
 594         jmp common_interrupt
 595 .data
 596         .long 1b
 597 .text
 598 vector=vector+1
 599 .endr
 600
 601 /*
 602  * the CPU automatically disables interrupts when executing an IRQ vector,
 603  * so IRQ-flags tracing has to follow that:
 604  */
 605         ALIGN
 606 common_interrupt:
 607         SAVE_ALL
 608         TRACE_IRQS_OFF
 609         movl %esp,%eax
 610         call do_IRQ
 611         jmp ret_from_intr
 612         CFI_ENDPROC
 613
 614 #define BUILD_INTERRUPT(name, nr)       \
 615 ENTRY(name)                             \
 616         RING0_INT_FRAME;                \
 617         pushl $~(nr);                   \
 618         CFI_ADJUST_CFA_OFFSET 4;        \
 619         SAVE_ALL;                       \
 620         TRACE_IRQS_OFF                  \
 621         movl %esp,%eax;                 \
 622         call smp_/**/name;              \
 623         jmp ret_from_intr;              \
 624         CFI_ENDPROC
 625
 626 /* The include is where all of the SMP etc. interrupts come from */
 627 #include "entry_arch.h"
 628
 629 /* This alternate entry is needed because we hijack the apic LVTT */
 630 #if defined(CONFIG_VMI) && defined(CONFIG_X86_LOCAL_APIC)
 631 BUILD_INTERRUPT(apic_vmi_timer_interrupt,LOCAL_TIMER_VECTOR)
 632 #endif
 633
 634 KPROBE_ENTRY(page_fault)
 635         RING0_EC_FRAME
 636         pushl $do_page_fault
 637         CFI_ADJUST_CFA_OFFSET 4
 638         ALIGN
 639 error_code:
 640         /* the function address is in %fs's slot on the stack */
 641         pushl %es
 642         CFI_ADJUST_CFA_OFFSET 4
 643         /*CFI_REL_OFFSET es, 0*/
 644         pushl %ds
 645         CFI_ADJUST_CFA_OFFSET 4
 646         /*CFI_REL_OFFSET ds, 0*/
 647         pushl %eax
 648         CFI_ADJUST_CFA_OFFSET 4
 649         CFI_REL_OFFSET eax, 0
 650         pushl %ebp
 651         CFI_ADJUST_CFA_OFFSET 4
 652         CFI_REL_OFFSET ebp, 0
 653         pushl %edi
 654         CFI_ADJUST_CFA_OFFSET 4
 655         CFI_REL_OFFSET edi, 0
 656         pushl %esi
 657         CFI_ADJUST_CFA_OFFSET 4
 658         CFI_REL_OFFSET esi, 0
 659         pushl %edx
 660         CFI_ADJUST_CFA_OFFSET 4
 661         CFI_REL_OFFSET edx, 0
 662         pushl %ecx
 663         CFI_ADJUST_CFA_OFFSET 4
 664         CFI_REL_OFFSET ecx, 0
 665         pushl %ebx
 666         CFI_ADJUST_CFA_OFFSET 4
 667         CFI_REL_OFFSET ebx, 0
 668         cld
 669         pushl %fs
 670         CFI_ADJUST_CFA_OFFSET 4
 671         /*CFI_REL_OFFSET fs, 0*/
 672         movl $(__KERNEL_PDA), %ecx
 673         movl %ecx, %fs
 674         UNWIND_ESPFIX_STACK
 675         popl %ecx
 676         CFI_ADJUST_CFA_OFFSET -4
 677         /*CFI_REGISTER es, ecx*/
 678         movl PT_FS(%esp), %edi          # get the function address
 679         movl PT_ORIG_EAX(%esp), %edx    # get the error code
 680         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
 681         mov  %ecx, PT_FS(%esp)
 682         /*CFI_REL_OFFSET fs, ES*/
 683         movl $(__USER_DS), %ecx
 684         movl %ecx, %ds
 685         movl %ecx, %es
 686         movl %esp,%eax                  # pt_regs pointer
 687         call *%edi
 688         jmp ret_from_exception
 689         CFI_ENDPROC
 690 KPROBE_END(page_fault)
 691
 692 ENTRY(coprocessor_error)
 693         RING0_INT_FRAME
 694         pushl $0
 695         CFI_ADJUST_CFA_OFFSET 4
 696         pushl $do_coprocessor_error
 697         CFI_ADJUST_CFA_OFFSET 4
 698         jmp error_code
 699         CFI_ENDPROC
 700
 701 ENTRY(simd_coprocessor_error)
 702         RING0_INT_FRAME
 703         pushl $0
 704         CFI_ADJUST_CFA_OFFSET 4
 705         pushl $do_simd_coprocessor_error
 706         CFI_ADJUST_CFA_OFFSET 4
 707         jmp error_code
 708         CFI_ENDPROC
 709
 710 ENTRY(device_not_available)
 711         RING0_INT_FRAME
 712         pushl $-1                       # mark this as an int
 713         CFI_ADJUST_CFA_OFFSET 4
 714         SAVE_ALL
 715         GET_CR0_INTO_EAX
 716         testl $0x4, %eax                # EM (math emulation bit)
 717         jne device_not_available_emulate
 718         preempt_stop(CLBR_ANY)
 719         call math_state_restore
 720         jmp ret_from_exception
 721 device_not_available_emulate:
 722         pushl $0                        # temporary storage for ORIG_EIP
 723         CFI_ADJUST_CFA_OFFSET 4
 724         call math_emulate
 725         addl $4, %esp
 726         CFI_ADJUST_CFA_OFFSET -4
 727         jmp ret_from_exception
 728         CFI_ENDPROC
 729
 730 /*
 731  * Debug traps and NMI can happen at the one SYSENTER instruction
 732  * that sets up the real kernel stack. Check here, since we can't
 733  * allow the wrong stack to be used.
 734  *
 735  * "TSS_sysenter_esp0+12" is because the NMI/debug handler will have
 736  * already pushed 3 words if it hits on the sysenter instruction:
 737  * eflags, cs and eip.
 738  *
 739  * We just load the right stack, and push the three (known) values
 740  * by hand onto the new stack - while updating the return eip past
 741  * the instruction that would have done it for sysenter.
 742  */
 743 #define FIX_STACK(offset, ok, label)            \
 744         cmpw $__KERNEL_CS,4(%esp);              \
 745         jne ok;                                 \
 746 label:                                          \
 747         movl TSS_sysenter_esp0+offset(%esp),%esp;       \
 748         CFI_DEF_CFA esp, 0;                     \
 749         CFI_UNDEFINED eip;                      \
 750         pushfl;                                 \
 751         CFI_ADJUST_CFA_OFFSET 4;                \
 752         pushl $__KERNEL_CS;                     \
 753         CFI_ADJUST_CFA_OFFSET 4;                \
 754         pushl $sysenter_past_esp;               \
 755         CFI_ADJUST_CFA_OFFSET 4;                \
 756         CFI_REL_OFFSET eip, 0
 757
 758 KPROBE_ENTRY(debug)
 759         RING0_INT_FRAME
 760         cmpl $sysenter_entry,(%esp)
 761         jne debug_stack_correct
 762         FIX_STACK(12, debug_stack_correct, debug_esp_fix_insn)
 763 debug_stack_correct:
 764         pushl $-1                       # mark this as an int
 765         CFI_ADJUST_CFA_OFFSET 4
 766         SAVE_ALL
 767         xorl %edx,%edx                  # error code 0
 768         movl %esp,%eax                  # pt_regs pointer
 769         call do_debug
 770         jmp ret_from_exception
 771         CFI_ENDPROC
 772 KPROBE_END(debug)
 773
 774 /*
 775  * NMI is doubly nasty. It can happen _while_ we're handling
 776  * a debug fault, and the debug fault hasn't yet been able to
 777  * clear up the stack. So we first check whether we got  an
 778  * NMI on the sysenter entry path, but after that we need to
 779  * check whether we got an NMI on the debug path where the debug
 780  * fault happened on the sysenter path.
 781  */
 782 KPROBE_ENTRY(nmi)
 783         RING0_INT_FRAME
 784         pushl %eax
 785         CFI_ADJUST_CFA_OFFSET 4
 786         movl %ss, %eax
 787         cmpw $__ESPFIX_SS, %ax
 788         popl %eax
 789         CFI_ADJUST_CFA_OFFSET -4
 790         je nmi_espfix_stack
 791         cmpl $sysenter_entry,(%esp)
 792         je nmi_stack_fixup
 793         pushl %eax
 794         CFI_ADJUST_CFA_OFFSET 4
 795         movl %esp,%eax
 796         /* Do not access memory above the end of our stack page,
 797          * it might not exist.
 798          */
 799         andl $(THREAD_SIZE-1),%eax
 800         cmpl $(THREAD_SIZE-20),%eax
 801         popl %eax
 802         CFI_ADJUST_CFA_OFFSET -4
 803         jae nmi_stack_correct
 804         cmpl $sysenter_entry,12(%esp)
 805         je nmi_debug_stack_check
 806 nmi_stack_correct:
 807         /* We have a RING0_INT_FRAME here */
 808         pushl %eax
 809         CFI_ADJUST_CFA_OFFSET 4
 810         SAVE_ALL
 811         xorl %edx,%edx          # zero error code
 812         movl %esp,%eax          # pt_regs pointer
 813         call do_nmi
 814         jmp restore_nocheck_notrace
 815         CFI_ENDPROC
 816
 817 nmi_stack_fixup:
 818         RING0_INT_FRAME
 819         FIX_STACK(12,nmi_stack_correct, 1)
 820         jmp nmi_stack_correct
 821
 822 nmi_debug_stack_check:
 823         /* We have a RING0_INT_FRAME here */
 824         cmpw $__KERNEL_CS,16(%esp)
 825         jne nmi_stack_correct
 826         cmpl $debug,(%esp)
 827         jb nmi_stack_correct
 828         cmpl $debug_esp_fix_insn,(%esp)
 829         ja nmi_stack_correct
 830         FIX_STACK(24,nmi_stack_correct, 1)
 831         jmp nmi_stack_correct
 832
 833 nmi_espfix_stack:
 834         /* We have a RING0_INT_FRAME here.
 835          *
 836          * create the pointer to lss back
 837          */
 838         pushl %ss
 839         CFI_ADJUST_CFA_OFFSET 4
 840         pushl %esp
 841         CFI_ADJUST_CFA_OFFSET 4
 842         addw $4, (%esp)
 843         /* copy the iret frame of 12 bytes */
 844         .rept 3
 845         pushl 16(%esp)
 846         CFI_ADJUST_CFA_OFFSET 4
 847         .endr
 848         pushl %eax
 849         CFI_ADJUST_CFA_OFFSET 4
 850         SAVE_ALL
 851         FIXUP_ESPFIX_STACK              # %eax == %esp
 852         xorl %edx,%edx                  # zero error code
 853         call do_nmi
 854         RESTORE_REGS
 855         lss 12+4(%esp), %esp            # back to espfix stack
 856         CFI_ADJUST_CFA_OFFSET -24
 857 1:      INTERRUPT_RETURN
 858         CFI_ENDPROC
 859 .section __ex_table,"a"
 860         .align 4
 861         .long 1b,iret_exc
 862 .previous
 863 KPROBE_END(nmi)
 864
 865 #ifdef CONFIG_PARAVIRT
 866 ENTRY(native_iret)
 867 1:      iret
 868 .section __ex_table,"a"
 869         .align 4
 870         .long 1b,iret_exc
 871 .previous
 872
 873 ENTRY(native_irq_enable_sysexit)
 874         sti
 875         sysexit
 876 #endif
 877
 878 KPROBE_ENTRY(int3)
 879         RING0_INT_FRAME
 880         pushl $-1                       # mark this as an int
 881         CFI_ADJUST_CFA_OFFSET 4
 882         SAVE_ALL
 883         xorl %edx,%edx          # zero error code
 884         movl %esp,%eax          # pt_regs pointer
 885         call do_int3
 886         jmp ret_from_exception
 887         CFI_ENDPROC
 888 KPROBE_END(int3)
 889
 890 ENTRY(overflow)
 891         RING0_INT_FRAME
 892         pushl $0
 893         CFI_ADJUST_CFA_OFFSET 4
 894         pushl $do_overflow
 895         CFI_ADJUST_CFA_OFFSET 4
 896         jmp error_code
 897         CFI_ENDPROC
 898
 899 ENTRY(bounds)
 900         RING0_INT_FRAME
 901         pushl $0
 902         CFI_ADJUST_CFA_OFFSET 4
 903         pushl $do_bounds
 904         CFI_ADJUST_CFA_OFFSET 4
 905         jmp error_code
 906         CFI_ENDPROC
 907
 908 ENTRY(invalid_op)
 909         RING0_INT_FRAME
 910         pushl $0
 911         CFI_ADJUST_CFA_OFFSET 4
 912         pushl $do_invalid_op
 913         CFI_ADJUST_CFA_OFFSET 4
 914         jmp error_code
 915         CFI_ENDPROC
 916
 917 ENTRY(coprocessor_segment_overrun)
 918         RING0_INT_FRAME
 919         pushl $0
 920         CFI_ADJUST_CFA_OFFSET 4
 921         pushl $do_coprocessor_segment_overrun
 922         CFI_ADJUST_CFA_OFFSET 4
 923         jmp error_code
 924         CFI_ENDPROC
 925
 926 ENTRY(invalid_TSS)
 927         RING0_EC_FRAME
 928         pushl $do_invalid_TSS
 929         CFI_ADJUST_CFA_OFFSET 4
 930         jmp error_code
 931         CFI_ENDPROC
 932
 933 ENTRY(segment_not_present)
 934         RING0_EC_FRAME
 935         pushl $do_segment_not_present
 936         CFI_ADJUST_CFA_OFFSET 4
 937         jmp error_code
 938         CFI_ENDPROC
 939
 940 ENTRY(stack_segment)
 941         RING0_EC_FRAME
 942         pushl $do_stack_segment
 943         CFI_ADJUST_CFA_OFFSET 4
 944         jmp error_code
 945         CFI_ENDPROC
 946
 947 KPROBE_ENTRY(general_protection)
 948         RING0_EC_FRAME
 949         pushl $do_general_protection
 950         CFI_ADJUST_CFA_OFFSET 4
 951         jmp error_code
 952         CFI_ENDPROC
 953 KPROBE_END(general_protection)
 954
 955 ENTRY(alignment_check)
 956         RING0_EC_FRAME
 957         pushl $do_alignment_check
 958         CFI_ADJUST_CFA_OFFSET 4
 959         jmp error_code
 960         CFI_ENDPROC
 961
 962 ENTRY(divide_error)
 963         RING0_INT_FRAME
 964         pushl $0                        # no error code
 965         CFI_ADJUST_CFA_OFFSET 4
 966         pushl $do_divide_error
 967         CFI_ADJUST_CFA_OFFSET 4
 968         jmp error_code
 969         CFI_ENDPROC
 970
 971 #ifdef CONFIG_X86_MCE
 972 ENTRY(machine_check)
 973         RING0_INT_FRAME
 974         pushl $0
 975         CFI_ADJUST_CFA_OFFSET 4
 976         pushl machine_check_vector
 977         CFI_ADJUST_CFA_OFFSET 4
 978         jmp error_code
 979         CFI_ENDPROC
 980 #endif
 981
 982 ENTRY(spurious_interrupt_bug)
 983         RING0_INT_FRAME
 984         pushl $0
 985         CFI_ADJUST_CFA_OFFSET 4
 986         pushl $do_spurious_interrupt_bug
 987         CFI_ADJUST_CFA_OFFSET 4
 988         jmp error_code
 989         CFI_ENDPROC
 990
 991 ENTRY(kernel_thread_helper)
 992         pushl $0                # fake return address for unwinder
 993         CFI_STARTPROC
 994         movl %edx,%eax
 995         push %edx
 996         CFI_ADJUST_CFA_OFFSET 4
 997         call *%ebx
 998         push %eax
 999         CFI_ADJUST_CFA_OFFSET 4
1000         call do_exit
1001         CFI_ENDPROC
1002 ENDPROC(kernel_thread_helper)
1003
1004 .section .rodata,"a"
1005 #include "syscall_table.S"
1006
1007 syscall_table_size=(.-sys_call_table)