arch/m68knommu/platform/coldfire/entry.S

   1 /*
   2  *  linux/arch/m68knommu/platform/5307/entry.S
   3  *
   4  *  Copyright (C) 1999-2007, Greg Ungerer (gerg@snapgear.com)
   5  *  Copyright (C) 1998  D. Jeff Dionne <jeff@lineo.ca>,
   6  *                      Kenneth Albanowski <kjahds@kjahds.com>,
   7  *  Copyright (C) 2000  Lineo Inc. (www.lineo.com)
   8  *  Copyright (C) 2004-2006  Macq Electronique SA. (www.macqel.com)
   9  *
  10  * Based on:
  11  *
  12  *  linux/arch/m68k/kernel/entry.S
  13  *
  14  *  Copyright (C) 1991, 1992  Linus Torvalds
  15  *
  16  * This file is subject to the terms and conditions of the GNU General Public
  17  * License.  See the file README.legal in the main directory of this archive
  18  * for more details.
  19  *
  20  * Linux/m68k support by Hamish Macdonald
  21  *
  22  * 68060 fixes by Jesper Skov
  23  * ColdFire support by Greg Ungerer (gerg@snapgear.com)
  24  * 5307 fixes by David W. Miller
  25  * linux 2.4 support David McCullough <davidm@snapgear.com>
  26  * Bug, speed and maintainability fixes by Philippe De Muyter <phdm@macqel.be>
  27  */
  28
  29 #include <linux/sys.h>
  30 #include <linux/linkage.h>
  31 #include <asm/unistd.h>
  32 #include <asm/thread_info.h>
  33 #include <asm/errno.h>
  34 #include <asm/setup.h>
  35 #include <asm/segment.h>
  36 #include <asm/asm-offsets.h>
  37 #include <asm/entry.h>
  38
  39 #ifdef CONFIG_COLDFIRE_SW_A7
  40 /*
  41  *      Define software copies of the supervisor and user stack pointers.
  42  */
  43 .bss
  44 sw_ksp:
  45 .long   0
  46 sw_usp:
  47 .long   0
  48 #endif /* CONFIG_COLDFIRE_SW_A7 */
  49
  50 .text
  51
  52 .globl system_call
  53 .globl resume
  54 .globl ret_from_exception
  55 .globl ret_from_signal
  56 .globl sys_call_table
  57 .globl inthandler
  58 .globl fasthandler
  59
  60 enosys:
  61         mov.l   #sys_ni_syscall,%d3
  62         bra     1f
  63
  64 ENTRY(system_call)
  65         SAVE_ALL
  66         move    #0x2000,%sr             /* enable intrs again */
  67
  68         cmpl    #NR_syscalls,%d0
  69         jcc     enosys
  70         lea     sys_call_table,%a0
  71         lsll    #2,%d0                  /* movel %a0@(%d0:l:4),%d3 */
  72         movel   %a0@(%d0),%d3
  73         jeq     enosys
  74
  75 1:
  76         movel   %sp,%d2                 /* get thread_info pointer */
  77         andl    #-THREAD_SIZE,%d2       /* at start of kernel stack */
  78         movel   %d2,%a0
  79         movel   %a0@,%a1                /* save top of frame */
  80         movel   %sp,%a1@(TASK_THREAD+THREAD_ESP0)
  81         btst    #(TIF_SYSCALL_TRACE%8),%a0@(TI_FLAGS+(31-TIF_SYSCALL_TRACE)/8)
  82         bnes    1f
  83
  84         movel   %d3,%a0
  85         jbsr    %a0@
  86         movel   %d0,%sp@(PT_OFF_D0)     /* save the return value */
  87         jra     ret_from_exception
  88 1:
  89         movel   #-ENOSYS,%d2            /* strace needs -ENOSYS in PT_OFF_D0 */
  90         movel   %d2,PT_OFF_D0(%sp)      /* on syscall entry */
  91         subql   #4,%sp
  92         SAVE_SWITCH_STACK
  93         jbsr    syscall_trace_enter
  94         RESTORE_SWITCH_STACK
  95         addql   #4,%sp
  96         movel   %d3,%a0
  97         jbsr    %a0@
  98         movel   %d0,%sp@(PT_OFF_D0)             /* save the return value */
  99         subql   #4,%sp                  /* dummy return address */
 100         SAVE_SWITCH_STACK
 101         jbsr    syscall_trace_leave
 102
 103 ret_from_signal:
 104         RESTORE_SWITCH_STACK
 105         addql   #4,%sp
 106
 107 ret_from_exception:
 108         move    #0x2700,%sr             /* disable intrs */
 109         btst    #5,%sp@(PT_OFF_SR)      /* check if returning to kernel */
 110         jeq     Luser_return            /* if so, skip resched, signals */
 111
 112 #ifdef CONFIG_PREEMPT
 113         movel   %sp,%d1                 /* get thread_info pointer */
 114         andl    #-THREAD_SIZE,%d1       /* at base of kernel stack */
 115         movel   %d1,%a0
 116         movel   %a0@(TI_FLAGS),%d1      /* get thread_info->flags */
 117         andl    #(1<<TIF_NEED_RESCHED),%d1
 118         jeq     Lkernel_return
 119
 120         movel   %a0@(TI_PREEMPTCOUNT),%d1
 121         cmpl    #0,%d1
 122         jne     Lkernel_return
 123
 124         pea     Lkernel_return
 125         jmp     preempt_schedule_irq    /* preempt the kernel */
 126 #endif
 127
 128 Lkernel_return:
 129         moveml  %sp@,%d1-%d5/%a0-%a2
 130         lea     %sp@(32),%sp            /* space for 8 regs */
 131         movel   %sp@+,%d0
 132         addql   #4,%sp                  /* orig d0 */
 133         addl    %sp@+,%sp               /* stk adj */
 134         rte
 135
 136 Luser_return:
 137         movel   %sp,%d1                 /* get thread_info pointer */
 138         andl    #-THREAD_SIZE,%d1       /* at base of kernel stack */
 139         movel   %d1,%a0
 140         movel   %a0@(TI_FLAGS),%d1      /* get thread_info->flags */
 141         andl    #0xefff,%d1
 142         jne     Lwork_to_do             /* still work to do */
 143
 144 Lreturn:
 145         RESTORE_USER
 146
 147 Lwork_to_do:
 148         movel   %a0@(TI_FLAGS),%d1      /* get thread_info->flags */
 149         move    #0x2000,%sr             /* enable intrs again */
 150         btst    #TIF_NEED_RESCHED,%d1
 151         jne     reschedule
 152
 153         /* GERG: do we need something here for TRACEing?? */
 154
 155 Lsignal_return:
 156         subql   #4,%sp                  /* dummy return address */
 157         SAVE_SWITCH_STACK
 158         pea     %sp@(SWITCH_STACK_SIZE)
 159         jsr     do_signal
 160         addql   #4,%sp
 161         RESTORE_SWITCH_STACK
 162         addql   #4,%sp
 163         jmp     Luser_return
 164
 165 /*
 166  * This is the generic interrupt handler (for all hardware interrupt
 167  * sources). Calls upto high level code to do all the work.
 168  */
 169 ENTRY(inthandler)
 170         SAVE_ALL
 171         moveq   #-1,%d0
 172         movel   %d0,%sp@(PT_OFF_ORIG_D0)
 173
 174         movew   %sp@(PT_OFF_FORMATVEC),%d0 /* put exception # in d0 */
 175         andl    #0x03fc,%d0             /* mask out vector only */
 176
 177         movel   %sp,%sp@-               /* push regs arg */
 178         lsrl    #2,%d0                  /* calculate real vector # */
 179         movel   %d0,%sp@-               /* push vector number */
 180         jbsr    do_IRQ                  /* call high level irq handler */
 181         lea     %sp@(8),%sp             /* pop args off stack */
 182
 183         bra     ret_from_exception
 184
 185 /*
 186  * Beware - when entering resume, prev (the current task) is
 187  * in a0, next (the new task) is in a1,so don't change these
 188  * registers until their contents are no longer needed.
 189  * This is always called in supervisor mode, so don't bother to save
 190  * and restore sr; user's process sr is actually in the stack.
 191  */
 192 ENTRY(resume)
 193         movel   %a0, %d1                        /* get prev thread in d1 */
 194         RDUSP
 195         movel   %a2,%a0@(TASK_THREAD+THREAD_USP)
 196
 197         SAVE_SWITCH_STACK
 198         movel   %sp,%a0@(TASK_THREAD+THREAD_KSP) /* save kernel stack pointer */
 199         movel   %a1@(TASK_THREAD+THREAD_KSP),%sp /* restore new thread stack */
 200         RESTORE_SWITCH_STACK
 201
 202         movel   %a1@(TASK_THREAD+THREAD_USP),%a0 /* restore thread user stack */
 203         WRUSP
 204         rts