arch/mips/lib/strnlen_user.S

   1 /*
   2  * This file is subject to the terms and conditions of the GNU General Public
   3  * License.  See the file "COPYING" in the main directory of this archive
   4  * for more details.
   5  *
   6  * Copyright (c) 1996, 1998, 1999, 2004 by Ralf Baechle
   7  * Copyright (c) 1999 Silicon Graphics, Inc.
   8  */
   9 #include <asm/asm.h>
  10 #include <asm/asm-offsets.h>
  11 #include <asm/regdef.h>
  12
  13 #define EX(insn,reg,addr,handler)                       \
  14 9:      insn    reg, addr;                              \
  15         .section __ex_table,"a";                        \
  16         PTR     9b, handler;                            \
  17         .previous
  18
  19 /*
  20  * Return the size of a string including the ending NUL character up to a
  21  * maximum of a1 or 0 in case of error.
  22  *
  23  * Note: for performance reasons we deliberately accept that a user may
  24  *       make strlen_user and strnlen_user access the first few KSEG0
  25  *       bytes.  There's nothing secret there.  On 64-bit accessing beyond
  26  *       the maximum is a tad hairier ...
  27  */
  28         .macro __BUILD_STRNLEN_ASM func
  29 LEAF(__strnlen_\func\()_asm)
  30         LONG_L          v0, TI_ADDR_LIMIT($28)  # pointer ok?
  31         and             v0, a0
  32         bnez            v0, .Lfault\@
  33
  34 FEXPORT(__strnlen_\func\()_nocheck_asm)
  35         move            v0, a0
  36         PTR_ADDU        a1, a0                  # stop pointer
  37 1:      beq             v0, a1, 1f              # limit reached?
  38 .ifeqs "\func", "kernel"
  39         EX(lb, t0, (v0), .Lfault\@)
  40 .else
  41         EX(lbe, t0, (v0), .Lfault\@)
  42 .endif
  43         PTR_ADDIU       v0, 1
  44         bnez            t0, 1b
  45 1:      PTR_SUBU        v0, a0
  46         jr              ra
  47         END(__strnlen_\func\()_asm)
  48
  49 .Lfault\@:
  50         move            v0, zero
  51         jr              ra
  52         .endm
  53
  54 #ifndef CONFIG_EVA
  55         /* Set aliases */
  56         .global __strnlen_user_asm
  57         .global __strnlen_user_nocheck_asm
  58         .set __strnlen_user_asm, __strnlen_kernel_asm
  59         .set __strnlen_user_nocheck_asm, __strnlen_kernel_nocheck_asm
  60 #endif
  61
  62 __BUILD_STRNLEN_ASM kernel
  63
  64 #ifdef CONFIG_EVA
  65
  66         .set push
  67         .set eva
  68 __BUILD_STRNLEN_ASM user
  69         .set pop
  70 #endif