arch/parisc/kernel/vmlinux.lds.S

   1 /*    Kernel link layout for various "sections"
   2  *
   3  *    Copyright (C) 1999-2003 Matthew Wilcox <willy at parisc-linux.org>
   4  *    Copyright (C) 2000-2003 Paul Bame <bame at parisc-linux.org>
   5  *    Copyright (C) 2000 John Marvin <jsm at parisc-linux.org>
   6  *    Copyright (C) 2000 Michael Ang <mang with subcarrier.org>
   7  *    Copyright (C) 2002 Randolph Chung <tausq with parisc-linux.org>
   8  *    Copyright (C) 2003 James Bottomley <jejb with parisc-linux.org>
   9  *    Copyright (C) 2006 Helge Deller <deller@gmx.de>
  10  *
  11  *
  12  *    This program is free software; you can redistribute it and/or modify
  13  *    it under the terms of the GNU General Public License as published by
  14  *    the Free Software Foundation; either version 2 of the License, or
  15  *    (at your option) any later version.
  16  *
  17  *    This program is distributed in the hope that it will be useful,
  18  *    but WITHOUT ANY WARRANTY; without even the implied warranty of
  19  *    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20  *    GNU General Public License for more details.
  21  *
  22  *    You should have received a copy of the GNU General Public License
  23  *    along with this program; if not, write to the Free Software
  24  *    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  25  */
  26 #include <asm-generic/vmlinux.lds.h>
  27 /* needed for the processor specific cache alignment size */
  28 #include <asm/cache.h>
  29 #include <asm/page.h>
  30 #include <asm/asm-offsets.h>
  31 #include <asm/thread_info.h>
  32
  33 /* ld script to make hppa Linux kernel */
  34 #ifndef CONFIG_64BIT
  35 OUTPUT_FORMAT("elf32-hppa-linux")
  36 OUTPUT_ARCH(hppa)
  37 #else
  38 OUTPUT_FORMAT("elf64-hppa-linux")
  39 OUTPUT_ARCH(hppa:hppa2.0w)
  40 #endif
  41
  42 ENTRY(_stext)
  43 #ifndef CONFIG_64BIT
  44 jiffies = jiffies_64 + 4;
  45 #else
  46 jiffies = jiffies_64;
  47 #endif
  48 SECTIONS
  49 {
  50         . = KERNEL_BINARY_TEXT_START;
  51
  52         _text = .;              /* Text and read-only data */
  53         .text ALIGN(16) : {
  54                 HEAD_TEXT
  55                 TEXT_TEXT
  56                 SCHED_TEXT
  57                 LOCK_TEXT
  58                 KPROBES_TEXT
  59                 IRQENTRY_TEXT
  60                 *(.text.do_softirq)
  61                 *(.text.sys_exit)
  62                 *(.text.do_sigaltstack)
  63                 *(.text.do_fork)
  64                 *(.text.*)
  65                 *(.fixup)
  66                 *(.lock.text)           /* out-of-line lock text */
  67                 *(.gnu.warning)
  68         } = 0
  69         /* End of text section */
  70         _etext = .;
  71
  72         /* Start of data section */
  73         _sdata = .;
  74
  75         RODATA
  76
  77         /* writeable */
  78         /* Make sure this is page aligned so
  79          * that we can properly leave these
  80          * as writable
  81          */
  82         . = ALIGN(PAGE_SIZE);
  83         data_start = .;
  84
  85         /* unwind info */
  86         .PARISC.unwind : {
  87                 __start___unwind = .;
  88                 *(.PARISC.unwind)
  89                 __stop___unwind = .;
  90         }
  91
  92         EXCEPTION_TABLE(16)
  93         NOTES
  94
  95         /* Data */
  96         RW_DATA_SECTION(L1_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
  97
  98         /* PA-RISC locks requires 16-byte alignment */
  99         . = ALIGN(16);
 100         .data..lock_aligned : {
 101                 *(.data..lock_aligned)
 102         }
 103
 104         /* End of data section */
 105         _edata = .;
 106
 107         /* BSS */
 108         __bss_start = .;
 109         /* page table entries need to be PAGE_SIZE aligned */
 110         . = ALIGN(PAGE_SIZE);
 111         .data..vmpages : {
 112                 *(.data..vm0.pmd)
 113                 *(.data..vm0.pgd)
 114                 *(.data..vm0.pte)
 115         }
 116         .bss : {
 117                 *(.bss)
 118                 *(COMMON)
 119         }
 120         __bss_stop = .;
 121
 122 #ifdef CONFIG_64BIT
 123         . = ALIGN(16);
 124         /* Linkage tables */
 125         .opd : {
 126                 *(.opd)
 127         } PROVIDE (__gp = .);
 128         .plt : {
 129                 *(.plt)
 130         }
 131         .dlt : {
 132                 *(.dlt)
 133         }
 134 #endif
 135
 136         /* reserve space for interrupt stack by aligning __init* to 16k */
 137         . = ALIGN(16384);
 138         __init_begin = .;
 139         INIT_TEXT_SECTION(16384)
 140         . = ALIGN(PAGE_SIZE);
 141         INIT_DATA_SECTION(16)
 142         /* we have to discard exit text and such at runtime, not link time */
 143         .exit.text :
 144         {
 145                 EXIT_TEXT
 146         }
 147         .exit.data :
 148         {
 149                 EXIT_DATA
 150         }
 151
 152         PERCPU_SECTION(L1_CACHE_BYTES)
 153         . = ALIGN(PAGE_SIZE);
 154         __init_end = .;
 155         /* freed after init ends here */
 156         _end = . ;
 157
 158         STABS_DEBUG
 159         .note 0 : { *(.note) }
 160
 161         /* Sections to be discarded */
 162         DISCARDS
 163         /DISCARD/ : {
 164 #ifdef CONFIG_64BIT
 165                 /* temporary hack until binutils is fixed to not emit these
 166                  * for static binaries
 167                  */
 168                 *(.interp)
 169                 *(.dynsym)
 170                 *(.dynstr)
 171                 *(.dynamic)
 172                 *(.hash)
 173                 *(.gnu.hash)
 174 #endif
 175         }
 176 }