arch/s390/kernel/entry.S

   1 /*
   2  *  arch/s390/kernel/entry.S
   3  *    S390 low-level entry points.
   4  *
   5  *    Copyright (C) IBM Corp. 1999,2006
   6  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
   7  *               Hartmut Penner (hp@de.ibm.com),
   8  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
   9  *               Heiko Carstens <heiko.carstens@de.ibm.com>
  10  */
  11
  12 #include <linux/sys.h>
  13 #include <linux/linkage.h>
  14 #include <linux/init.h>
  15 #include <asm/cache.h>
  16 #include <asm/lowcore.h>
  17 #include <asm/errno.h>
  18 #include <asm/ptrace.h>
  19 #include <asm/thread_info.h>
  20 #include <asm/asm-offsets.h>
  21 #include <asm/unistd.h>
  22 #include <asm/page.h>
  23
  24 /*
  25  * Stack layout for the system_call stack entry.
  26  * The first few entries are identical to the user_regs_struct.
  27  */
  28 SP_PTREGS    =  STACK_FRAME_OVERHEAD
  29 SP_ARGS      =  STACK_FRAME_OVERHEAD + __PT_ARGS
  30 SP_PSW       =  STACK_FRAME_OVERHEAD + __PT_PSW
  31 SP_R0        =  STACK_FRAME_OVERHEAD + __PT_GPRS
  32 SP_R1        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 4
  33 SP_R2        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 8
  34 SP_R3        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 12
  35 SP_R4        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 16
  36 SP_R5        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 20
  37 SP_R6        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 24
  38 SP_R7        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 28
  39 SP_R8        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 32
  40 SP_R9        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 36
  41 SP_R10       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 40
  42 SP_R11       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 44
  43 SP_R12       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 48
  44 SP_R13       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 52
  45 SP_R14       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 56
  46 SP_R15       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 60
  47 SP_ORIG_R2   =  STACK_FRAME_OVERHEAD + __PT_ORIG_GPR2
  48 SP_ILC       =  STACK_FRAME_OVERHEAD + __PT_ILC
  49 SP_SVCNR     =  STACK_FRAME_OVERHEAD + __PT_SVCNR
  50 SP_SIZE      =  STACK_FRAME_OVERHEAD + __PT_SIZE
  51
  52 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  53                  _TIF_MCCK_PENDING | _TIF_RESTART_SVC | _TIF_SINGLE_STEP )
  54 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  55                  _TIF_MCCK_PENDING)
  56 _TIF_SYSCALL = (_TIF_SYSCALL_TRACE>>8 | _TIF_SYSCALL_AUDIT>>8 | _TIF_SECCOMP>>8)
  57
  58 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
  59 STACK_SIZE  = 1 << STACK_SHIFT
  60
  61 #define BASED(name) name-system_call(%r13)
  62
  63 #ifdef CONFIG_TRACE_IRQFLAGS
  64         .macro  TRACE_IRQS_ON
  65         basr    %r2,%r0
  66         l       %r1,BASED(.Ltrace_irq_on_caller)
  67         basr    %r14,%r1
  68         .endm
  69
  70         .macro  TRACE_IRQS_OFF
  71         basr    %r2,%r0
  72         l       %r1,BASED(.Ltrace_irq_off_caller)
  73         basr    %r14,%r1
  74         .endm
  75
  76         .macro  TRACE_IRQS_CHECK
  77         basr    %r2,%r0
  78         tm      SP_PSW(%r15),0x03       # irqs enabled?
  79         jz      0f
  80         l       %r1,BASED(.Ltrace_irq_on_caller)
  81         basr    %r14,%r1
  82         j       1f
  83 0:      l       %r1,BASED(.Ltrace_irq_off_caller)
  84         basr    %r14,%r1
  85 1:
  86         .endm
  87 #else
  88 #define TRACE_IRQS_ON
  89 #define TRACE_IRQS_OFF
  90 #define TRACE_IRQS_CHECK
  91 #endif
  92
  93 #ifdef CONFIG_LOCKDEP
  94         .macro  LOCKDEP_SYS_EXIT
  95         tm      SP_PSW+1(%r15),0x01     # returning to user ?
  96         jz      0f
  97         l       %r1,BASED(.Llockdep_sys_exit)
  98         basr    %r14,%r1
  99 0:
 100         .endm
 101 #else
 102 #define LOCKDEP_SYS_EXIT
 103 #endif
 104
 105 /*
 106  * Register usage in interrupt handlers:
 107  *    R9  - pointer to current task structure
 108  *    R13 - pointer to literal pool
 109  *    R14 - return register for function calls
 110  *    R15 - kernel stack pointer
 111  */
 112
 113         .macro  UPDATE_VTIME lc_from,lc_to,lc_sum
 114         lm      %r10,%r11,\lc_from
 115         sl      %r10,\lc_to
 116         sl      %r11,\lc_to+4
 117         bc      3,BASED(0f)
 118         sl      %r10,BASED(.Lc_1)
 119 0:      al      %r10,\lc_sum
 120         al      %r11,\lc_sum+4
 121         bc      12,BASED(1f)
 122         al      %r10,BASED(.Lc_1)
 123 1:      stm     %r10,%r11,\lc_sum
 124         .endm
 125
 126         .macro  SAVE_ALL_BASE savearea
 127         stm     %r12,%r15,\savearea
 128         l       %r13,__LC_SVC_NEW_PSW+4 # load &system_call to %r13
 129         .endm
 130
 131         .macro  SAVE_ALL_SVC psworg,savearea
 132         la      %r12,\psworg
 133         l       %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 134         .endm
 135
 136         .macro  SAVE_ALL_SYNC psworg,savearea
 137         la      %r12,\psworg
 138         tm      \psworg+1,0x01          # test problem state bit
 139         bz      BASED(2f)               # skip stack setup save
 140         l       %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 141 #ifdef CONFIG_CHECK_STACK
 142         b       BASED(3f)
 143 2:      tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
 144         bz      BASED(stack_overflow)
 145 3:
 146 #endif
 147 2:
 148         .endm
 149
 150         .macro  SAVE_ALL_ASYNC psworg,savearea
 151         la      %r12,\psworg
 152         tm      \psworg+1,0x01          # test problem state bit
 153         bnz     BASED(1f)               # from user -> load async stack
 154         clc     \psworg+4(4),BASED(.Lcritical_end)
 155         bhe     BASED(0f)
 156         clc     \psworg+4(4),BASED(.Lcritical_start)
 157         bl      BASED(0f)
 158         l       %r14,BASED(.Lcleanup_critical)
 159         basr    %r14,%r14
 160         tm      1(%r12),0x01            # retest problem state after cleanup
 161         bnz     BASED(1f)
 162 0:      l       %r14,__LC_ASYNC_STACK   # are we already on the async stack ?
 163         slr     %r14,%r15
 164         sra     %r14,STACK_SHIFT
 165         be      BASED(2f)
 166 1:      l       %r15,__LC_ASYNC_STACK
 167 #ifdef CONFIG_CHECK_STACK
 168         b       BASED(3f)
 169 2:      tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
 170         bz      BASED(stack_overflow)
 171 3:
 172 #endif
 173 2:
 174         .endm
 175
 176         .macro  CREATE_STACK_FRAME psworg,savearea
 177         s       %r15,BASED(.Lc_spsize)  # make room for registers & psw
 178         mvc     SP_PSW(8,%r15),0(%r12)  # move user PSW to stack
 179         st      %r2,SP_ORIG_R2(%r15)    # store original content of gpr 2
 180         icm     %r12,3,__LC_SVC_ILC
 181         stm     %r0,%r11,SP_R0(%r15)    # store gprs %r0-%r11 to kernel stack
 182         st      %r12,SP_SVCNR(%r15)
 183         mvc     SP_R12(16,%r15),\savearea # move %r12-%r15 to stack
 184         la      %r12,0
 185         st      %r12,__SF_BACKCHAIN(%r15)       # clear back chain
 186         .endm
 187
 188         .macro  RESTORE_ALL psworg,sync
 189         mvc     \psworg(8),SP_PSW(%r15) # move user PSW to lowcore
 190         .if !\sync
 191         ni      \psworg+1,0xfd          # clear wait state bit
 192         .endif
 193         lm      %r0,%r15,SP_R0(%r15)    # load gprs 0-15 of user
 194         stpt    __LC_EXIT_TIMER
 195         lpsw    \psworg                 # back to caller
 196         .endm
 197
 198 /*
 199  * Scheduler resume function, called by switch_to
 200  *  gpr2 = (task_struct *) prev
 201  *  gpr3 = (task_struct *) next
 202  * Returns:
 203  *  gpr2 = prev
 204  */
 205         .globl  __switch_to
 206 __switch_to:
 207         basr    %r1,0
 208 __switch_to_base:
 209         tm      __THREAD_per(%r3),0xe8          # new process is using per ?
 210         bz      __switch_to_noper-__switch_to_base(%r1) # if not we're fine
 211         stctl   %c9,%c11,__SF_EMPTY(%r15)       # We are using per stuff
 212         clc     __THREAD_per(12,%r3),__SF_EMPTY(%r15)
 213         be      __switch_to_noper-__switch_to_base(%r1) # we got away w/o bashing TLB's
 214         lctl    %c9,%c11,__THREAD_per(%r3)      # Nope we didn't
 215 __switch_to_noper:
 216         l       %r4,__THREAD_info(%r2)          # get thread_info of prev
 217         tm      __TI_flags+3(%r4),_TIF_MCCK_PENDING # machine check pending?
 218         bz      __switch_to_no_mcck-__switch_to_base(%r1)
 219         ni      __TI_flags+3(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
 220         l       %r4,__THREAD_info(%r3)          # get thread_info of next
 221         oi      __TI_flags+3(%r4),_TIF_MCCK_PENDING # set it in next
 222 __switch_to_no_mcck:
 223         stm     %r6,%r15,__SF_GPRS(%r15)# store __switch_to registers of prev task
 224         st      %r15,__THREAD_ksp(%r2)  # store kernel stack to prev->tss.ksp
 225         l       %r15,__THREAD_ksp(%r3)  # load kernel stack from next->tss.ksp
 226         lm      %r6,%r15,__SF_GPRS(%r15)# load __switch_to registers of next task
 227         st      %r3,__LC_CURRENT        # __LC_CURRENT = current task struct
 228         lctl    %c4,%c4,__TASK_pid(%r3) # load pid to control reg. 4
 229         l       %r3,__THREAD_info(%r3)  # load thread_info from task struct
 230         st      %r3,__LC_THREAD_INFO
 231         ahi     %r3,STACK_SIZE
 232         st      %r3,__LC_KERNEL_STACK   # __LC_KERNEL_STACK = new kernel stack
 233         br      %r14
 234
 235 __critical_start:
 236 /*
 237  * SVC interrupt handler routine. System calls are synchronous events and
 238  * are executed with interrupts enabled.
 239  */
 240
 241         .globl  system_call
 242 system_call:
 243         stpt    __LC_SYNC_ENTER_TIMER
 244 sysc_saveall:
 245         SAVE_ALL_BASE __LC_SAVE_AREA
 246         SAVE_ALL_SVC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 247         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 248         lh      %r7,0x8a          # get svc number from lowcore
 249 sysc_vtime:
 250         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 251 sysc_stime:
 252         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 253 sysc_update:
 254         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 255 sysc_do_svc:
 256         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 257         ltr     %r7,%r7                 # test for svc 0
 258         bnz     BASED(sysc_nr_ok)       # svc number > 0
 259         # svc 0: system call number in %r1
 260         cl      %r1,BASED(.Lnr_syscalls)
 261         bnl     BASED(sysc_nr_ok)
 262         lr      %r7,%r1           # copy svc number to %r7
 263 sysc_nr_ok:
 264         mvc     SP_ARGS(4,%r15),SP_R7(%r15)
 265 sysc_do_restart:
 266         sth     %r7,SP_SVCNR(%r15)
 267         sll     %r7,2             # svc number *4
 268         l       %r8,BASED(.Lsysc_table)
 269         tm      __TI_flags+2(%r9),_TIF_SYSCALL
 270         l       %r8,0(%r7,%r8)    # get system call addr.
 271         bnz     BASED(sysc_tracesys)
 272         basr    %r14,%r8          # call sys_xxxx
 273         st      %r2,SP_R2(%r15)   # store return value (change R2 on stack)
 274
 275 sysc_return:
 276         tm      __TI_flags+3(%r9),_TIF_WORK_SVC
 277         bnz     BASED(sysc_work)  # there is work to do (signals etc.)
 278 sysc_restore:
 279 #ifdef CONFIG_TRACE_IRQFLAGS
 280         la      %r1,BASED(sysc_restore_trace_psw)
 281         lpsw    0(%r1)
 282 sysc_restore_trace:
 283         TRACE_IRQS_CHECK
 284         LOCKDEP_SYS_EXIT
 285 #endif
 286 sysc_leave:
 287         RESTORE_ALL __LC_RETURN_PSW,1
 288 sysc_done:
 289
 290 #ifdef CONFIG_TRACE_IRQFLAGS
 291         .align  8
 292         .globl  sysc_restore_trace_psw
 293 sysc_restore_trace_psw:
 294         .long   0, sysc_restore_trace + 0x80000000
 295 #endif
 296
 297 #
 298 # recheck if there is more work to do
 299 #
 300 sysc_work_loop:
 301         tm      __TI_flags+3(%r9),_TIF_WORK_SVC
 302         bz      BASED(sysc_restore)     # there is no work to do
 303 #
 304 # One of the work bits is on. Find out which one.
 305 #
 306 sysc_work:
 307         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 308         bno     BASED(sysc_restore)
 309         tm      __TI_flags+3(%r9),_TIF_MCCK_PENDING
 310         bo      BASED(sysc_mcck_pending)
 311         tm      __TI_flags+3(%r9),_TIF_NEED_RESCHED
 312         bo      BASED(sysc_reschedule)
 313         tm      __TI_flags+3(%r9),_TIF_SIGPENDING
 314         bnz     BASED(sysc_sigpending)
 315         tm      __TI_flags+3(%r9),_TIF_NOTIFY_RESUME
 316         bnz     BASED(sysc_notify_resume)
 317         tm      __TI_flags+3(%r9),_TIF_RESTART_SVC
 318         bo      BASED(sysc_restart)
 319         tm      __TI_flags+3(%r9),_TIF_SINGLE_STEP
 320         bo      BASED(sysc_singlestep)
 321         b       BASED(sysc_restore)
 322 sysc_work_done:
 323
 324 #
 325 # _TIF_NEED_RESCHED is set, call schedule
 326 #
 327 sysc_reschedule:
 328         l       %r1,BASED(.Lschedule)
 329         la      %r14,BASED(sysc_work_loop)
 330         br      %r1                     # call scheduler
 331
 332 #
 333 # _TIF_MCCK_PENDING is set, call handler
 334 #
 335 sysc_mcck_pending:
 336         l       %r1,BASED(.Ls390_handle_mcck)
 337         la      %r14,BASED(sysc_work_loop)
 338         br      %r1                     # TIF bit will be cleared by handler
 339
 340 #
 341 # _TIF_SIGPENDING is set, call do_signal
 342 #
 343 sysc_sigpending:
 344         ni      __TI_flags+3(%r9),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
 345         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 346         l       %r1,BASED(.Ldo_signal)
 347         basr    %r14,%r1                # call do_signal
 348         tm      __TI_flags+3(%r9),_TIF_RESTART_SVC
 349         bo      BASED(sysc_restart)
 350         tm      __TI_flags+3(%r9),_TIF_SINGLE_STEP
 351         bo      BASED(sysc_singlestep)
 352         b       BASED(sysc_work_loop)
 353
 354 #
 355 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
 356 #
 357 sysc_notify_resume:
 358         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 359         l       %r1,BASED(.Ldo_notify_resume)
 360         la      %r14,BASED(sysc_work_loop)
 361         br      %r1                     # call do_notify_resume
 362
 363
 364 #
 365 # _TIF_RESTART_SVC is set, set up registers and restart svc
 366 #
 367 sysc_restart:
 368         ni      __TI_flags+3(%r9),255-_TIF_RESTART_SVC # clear TIF_RESTART_SVC
 369         l       %r7,SP_R2(%r15)         # load new svc number
 370         mvc     SP_R2(4,%r15),SP_ORIG_R2(%r15) # restore first argument
 371         lm      %r2,%r6,SP_R2(%r15)     # load svc arguments
 372         b       BASED(sysc_do_restart)  # restart svc
 373
 374 #
 375 # _TIF_SINGLE_STEP is set, call do_single_step
 376 #
 377 sysc_singlestep:
 378         ni      __TI_flags+3(%r9),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
 379         mvi     SP_SVCNR(%r15),0xff     # set trap indication to pgm check
 380         mvi     SP_SVCNR+1(%r15),0xff
 381         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 382         l       %r1,BASED(.Lhandle_per) # load adr. of per handler
 383         la      %r14,BASED(sysc_return) # load adr. of system return
 384         br      %r1                     # branch to do_single_step
 385
 386 #
 387 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
 388 # and after the system call
 389 #
 390 sysc_tracesys:
 391         l       %r1,BASED(.Ltrace_entry)
 392         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 393         la      %r3,0
 394         srl     %r7,2
 395         st      %r7,SP_R2(%r15)
 396         basr    %r14,%r1
 397         cl      %r2,BASED(.Lnr_syscalls)
 398         bnl     BASED(sysc_tracenogo)
 399         l       %r8,BASED(.Lsysc_table)
 400         lr      %r7,%r2
 401         sll     %r7,2                   # svc number *4
 402         l       %r8,0(%r7,%r8)
 403 sysc_tracego:
 404         lm      %r3,%r6,SP_R3(%r15)
 405         l       %r2,SP_ORIG_R2(%r15)
 406         basr    %r14,%r8                # call sys_xxx
 407         st      %r2,SP_R2(%r15)         # store return value
 408 sysc_tracenogo:
 409         tm      __TI_flags+2(%r9),_TIF_SYSCALL
 410         bz      BASED(sysc_return)
 411         l       %r1,BASED(.Ltrace_exit)
 412         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 413         la      %r14,BASED(sysc_return)
 414         br      %r1
 415
 416 #
 417 # a new process exits the kernel with ret_from_fork
 418 #
 419         .globl  ret_from_fork
 420 ret_from_fork:
 421         l       %r13,__LC_SVC_NEW_PSW+4
 422         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 423         tm      SP_PSW+1(%r15),0x01     # forking a kernel thread ?
 424         bo      BASED(0f)
 425         st      %r15,SP_R15(%r15)       # store stack pointer for new kthread
 426 0:      l       %r1,BASED(.Lschedtail)
 427         basr    %r14,%r1
 428         TRACE_IRQS_ON
 429         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 430         b       BASED(sysc_tracenogo)
 431
 432 #
 433 # kernel_execve function needs to deal with pt_regs that is not
 434 # at the usual place
 435 #
 436         .globl  kernel_execve
 437 kernel_execve:
 438         stm     %r12,%r15,48(%r15)
 439         lr      %r14,%r15
 440         l       %r13,__LC_SVC_NEW_PSW+4
 441         s       %r15,BASED(.Lc_spsize)
 442         st      %r14,__SF_BACKCHAIN(%r15)
 443         la      %r12,SP_PTREGS(%r15)
 444         xc      0(__PT_SIZE,%r12),0(%r12)
 445         l       %r1,BASED(.Ldo_execve)
 446         lr      %r5,%r12
 447         basr    %r14,%r1
 448         ltr     %r2,%r2
 449         be      BASED(0f)
 450         a       %r15,BASED(.Lc_spsize)
 451         lm      %r12,%r15,48(%r15)
 452         br      %r14
 453         # execve succeeded.
 454 0:      stnsm   __SF_EMPTY(%r15),0xfc   # disable interrupts
 455         l       %r15,__LC_KERNEL_STACK  # load ksp
 456         s       %r15,BASED(.Lc_spsize)  # make room for registers & psw
 457         l       %r9,__LC_THREAD_INFO
 458         mvc     SP_PTREGS(__PT_SIZE,%r15),0(%r12)       # copy pt_regs
 459         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
 460         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 461         l       %r1,BASED(.Lexecve_tail)
 462         basr    %r14,%r1
 463         b       BASED(sysc_return)
 464
 465 /*
 466  * Program check handler routine
 467  */
 468
 469         .globl  pgm_check_handler
 470 pgm_check_handler:
 471 /*
 472  * First we need to check for a special case:
 473  * Single stepping an instruction that disables the PER event mask will
 474  * cause a PER event AFTER the mask has been set. Example: SVC or LPSW.
 475  * For a single stepped SVC the program check handler gets control after
 476  * the SVC new PSW has been loaded. But we want to execute the SVC first and
 477  * then handle the PER event. Therefore we update the SVC old PSW to point
 478  * to the pgm_check_handler and branch to the SVC handler after we checked
 479  * if we have to load the kernel stack register.
 480  * For every other possible cause for PER event without the PER mask set
 481  * we just ignore the PER event (FIXME: is there anything we have to do
 482  * for LPSW?).
 483  */
 484         stpt    __LC_SYNC_ENTER_TIMER
 485         SAVE_ALL_BASE __LC_SAVE_AREA
 486         tm      __LC_PGM_INT_CODE+1,0x80 # check whether we got a per exception
 487         bnz     BASED(pgm_per)          # got per exception -> special case
 488         SAVE_ALL_SYNC __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 489         CREATE_STACK_FRAME __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 490         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 491         bz      BASED(pgm_no_vtime)
 492         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 493         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 494         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 495 pgm_no_vtime:
 496         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 497         TRACE_IRQS_OFF
 498         l       %r3,__LC_PGM_ILC        # load program interruption code
 499         la      %r8,0x7f
 500         nr      %r8,%r3
 501 pgm_do_call:
 502         l       %r7,BASED(.Ljump_table)
 503         sll     %r8,2
 504         l       %r7,0(%r8,%r7)          # load address of handler routine
 505         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 506         la      %r14,BASED(sysc_return)
 507         br      %r7                     # branch to interrupt-handler
 508
 509 #
 510 # handle per exception
 511 #
 512 pgm_per:
 513         tm      __LC_PGM_OLD_PSW,0x40   # test if per event recording is on
 514         bnz     BASED(pgm_per_std)      # ok, normal per event from user space
 515 # ok its one of the special cases, now we need to find out which one
 516         clc     __LC_PGM_OLD_PSW(8),__LC_SVC_NEW_PSW
 517         be      BASED(pgm_svcper)
 518 # no interesting special case, ignore PER event
 519         lm      %r12,%r15,__LC_SAVE_AREA
 520         lpsw    0x28
 521
 522 #
 523 # Normal per exception
 524 #
 525 pgm_per_std:
 526         SAVE_ALL_SYNC __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 527         CREATE_STACK_FRAME __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 528         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 529         bz      BASED(pgm_no_vtime2)
 530         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 531         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 532         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 533 pgm_no_vtime2:
 534         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 535         TRACE_IRQS_OFF
 536         l       %r1,__TI_task(%r9)
 537         mvc     __THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
 538         mvc     __THREAD_per+__PER_address(4,%r1),__LC_PER_ADDRESS
 539         mvc     __THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
 540         oi      __TI_flags+3(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
 541         tm      SP_PSW+1(%r15),0x01     # kernel per event ?
 542         bz      BASED(kernel_per)
 543         l       %r3,__LC_PGM_ILC        # load program interruption code
 544         la      %r8,0x7f
 545         nr      %r8,%r3                 # clear per-event-bit and ilc
 546         be      BASED(sysc_return)      # only per or per+check ?
 547         b       BASED(pgm_do_call)
 548
 549 #
 550 # it was a single stepped SVC that is causing all the trouble
 551 #
 552 pgm_svcper:
 553         SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 554         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 555         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 556         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 557         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 558         lh      %r7,0x8a                # get svc number from lowcore
 559         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 560         TRACE_IRQS_OFF
 561         l       %r1,__TI_task(%r9)
 562         mvc     __THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
 563         mvc     __THREAD_per+__PER_address(4,%r1),__LC_PER_ADDRESS
 564         mvc     __THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
 565         oi      __TI_flags+3(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
 566         TRACE_IRQS_ON
 567         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 568         b       BASED(sysc_do_svc)
 569
 570 #
 571 # per was called from kernel, must be kprobes
 572 #
 573 kernel_per:
 574         mvi     SP_SVCNR(%r15),0xff     # set trap indication to pgm check
 575         mvi     SP_SVCNR+1(%r15),0xff
 576         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 577         l       %r1,BASED(.Lhandle_per) # load adr. of per handler
 578         la      %r14,BASED(sysc_restore)# load adr. of system return
 579         br      %r1                     # branch to do_single_step
 580
 581 /*
 582  * IO interrupt handler routine
 583  */
 584
 585         .globl io_int_handler
 586 io_int_handler:
 587         stck    __LC_INT_CLOCK
 588         stpt    __LC_ASYNC_ENTER_TIMER
 589         SAVE_ALL_BASE __LC_SAVE_AREA+16
 590         SAVE_ALL_ASYNC __LC_IO_OLD_PSW,__LC_SAVE_AREA+16
 591         CREATE_STACK_FRAME __LC_IO_OLD_PSW,__LC_SAVE_AREA+16
 592         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 593         bz      BASED(io_no_vtime)
 594         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 595         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 596         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 597 io_no_vtime:
 598         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 599         TRACE_IRQS_OFF
 600         l       %r1,BASED(.Ldo_IRQ)     # load address of do_IRQ
 601         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 602         basr    %r14,%r1                # branch to standard irq handler
 603 io_return:
 604         tm      __TI_flags+3(%r9),_TIF_WORK_INT
 605         bnz     BASED(io_work)          # there is work to do (signals etc.)
 606 io_restore:
 607 #ifdef CONFIG_TRACE_IRQFLAGS
 608         la      %r1,BASED(io_restore_trace_psw)
 609         lpsw    0(%r1)
 610 io_restore_trace:
 611         TRACE_IRQS_CHECK
 612         LOCKDEP_SYS_EXIT
 613 #endif
 614 io_leave:
 615         RESTORE_ALL __LC_RETURN_PSW,0
 616 io_done:
 617
 618 #ifdef CONFIG_TRACE_IRQFLAGS
 619         .align  8
 620         .globl  io_restore_trace_psw
 621 io_restore_trace_psw:
 622         .long   0, io_restore_trace + 0x80000000
 623 #endif
 624
 625 #
 626 # switch to kernel stack, then check the TIF bits
 627 #
 628 io_work:
 629         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 630 #ifndef CONFIG_PREEMPT
 631         bno     BASED(io_restore)       # no-> skip resched & signal
 632 #else
 633         bnz     BASED(io_work_user)     # no -> check for preemptive scheduling
 634         # check for preemptive scheduling
 635         icm     %r0,15,__TI_precount(%r9)
 636         bnz     BASED(io_restore)       # preemption disabled
 637         l       %r1,SP_R15(%r15)
 638         s       %r1,BASED(.Lc_spsize)
 639         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 640         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 641         lr      %r15,%r1
 642 io_resume_loop:
 643         tm      __TI_flags+3(%r9),_TIF_NEED_RESCHED
 644         bno     BASED(io_restore)
 645         l       %r1,BASED(.Lpreempt_schedule_irq)
 646         la      %r14,BASED(io_resume_loop)
 647         br      %r1                     # call schedule
 648 #endif
 649
 650 io_work_user:
 651         l       %r1,__LC_KERNEL_STACK
 652         s       %r1,BASED(.Lc_spsize)
 653         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 654         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 655         lr      %r15,%r1
 656 #
 657 # One of the work bits is on. Find out which one.
 658 # Checked are: _TIF_SIGPENDING, _TIF_NEED_RESCHED
 659 #               and _TIF_MCCK_PENDING
 660 #
 661 io_work_loop:
 662         tm      __TI_flags+3(%r9),_TIF_MCCK_PENDING
 663         bo      BASED(io_mcck_pending)
 664         tm      __TI_flags+3(%r9),_TIF_NEED_RESCHED
 665         bo      BASED(io_reschedule)
 666         tm      __TI_flags+3(%r9),_TIF_SIGPENDING
 667         bnz     BASED(io_sigpending)
 668         tm      __TI_flags+3(%r9),_TIF_NOTIFY_RESUME
 669         bnz     BASED(io_notify_resume)
 670         b       BASED(io_restore)
 671 io_work_done:
 672
 673 #
 674 # _TIF_MCCK_PENDING is set, call handler
 675 #
 676 io_mcck_pending:
 677         l       %r1,BASED(.Ls390_handle_mcck)
 678         basr    %r14,%r1                # TIF bit will be cleared by handler
 679         b       BASED(io_work_loop)
 680
 681 #
 682 # _TIF_NEED_RESCHED is set, call schedule
 683 #
 684 io_reschedule:
 685         TRACE_IRQS_ON
 686         l       %r1,BASED(.Lschedule)
 687         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 688         basr    %r14,%r1                # call scheduler
 689         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 690         TRACE_IRQS_OFF
 691         tm      __TI_flags+3(%r9),_TIF_WORK_INT
 692         bz      BASED(io_restore)       # there is no work to do
 693         b       BASED(io_work_loop)
 694
 695 #
 696 # _TIF_SIGPENDING is set, call do_signal
 697 #
 698 io_sigpending:
 699         TRACE_IRQS_ON
 700         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 701         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 702         l       %r1,BASED(.Ldo_signal)
 703         basr    %r14,%r1                # call do_signal
 704         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 705         TRACE_IRQS_OFF
 706         b       BASED(io_work_loop)
 707
 708 #
 709 # _TIF_SIGPENDING is set, call do_signal
 710 #
 711 io_notify_resume:
 712         TRACE_IRQS_ON
 713         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 714         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 715         l       %r1,BASED(.Ldo_notify_resume)
 716         basr    %r14,%r1                # call do_signal
 717         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 718         TRACE_IRQS_OFF
 719         b       BASED(io_work_loop)
 720
 721 /*
 722  * External interrupt handler routine
 723  */
 724
 725         .globl  ext_int_handler
 726 ext_int_handler:
 727         stck    __LC_INT_CLOCK
 728         stpt    __LC_ASYNC_ENTER_TIMER
 729         SAVE_ALL_BASE __LC_SAVE_AREA+16
 730         SAVE_ALL_ASYNC __LC_EXT_OLD_PSW,__LC_SAVE_AREA+16
 731         CREATE_STACK_FRAME __LC_EXT_OLD_PSW,__LC_SAVE_AREA+16
 732         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 733         bz      BASED(ext_no_vtime)
 734         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 735         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 736         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 737 ext_no_vtime:
 738         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 739         TRACE_IRQS_OFF
 740         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 741         lh      %r3,__LC_EXT_INT_CODE   # get interruption code
 742         l       %r1,BASED(.Ldo_extint)
 743         basr    %r14,%r1
 744         b       BASED(io_return)
 745
 746 __critical_end:
 747
 748 /*
 749  * Machine check handler routines
 750  */
 751
 752         .globl mcck_int_handler
 753 mcck_int_handler:
 754         stck    __LC_INT_CLOCK
 755         spt     __LC_CPU_TIMER_SAVE_AREA        # revalidate cpu timer
 756         lm      %r0,%r15,__LC_GPREGS_SAVE_AREA  # revalidate gprs
 757         SAVE_ALL_BASE __LC_SAVE_AREA+32
 758         la      %r12,__LC_MCK_OLD_PSW
 759         tm      __LC_MCCK_CODE,0x80     # system damage?
 760         bo      BASED(mcck_int_main)    # yes -> rest of mcck code invalid
 761         mvc     __LC_SAVE_AREA+52(8),__LC_ASYNC_ENTER_TIMER
 762         mvc     __LC_ASYNC_ENTER_TIMER(8),__LC_CPU_TIMER_SAVE_AREA
 763         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
 764         bo      BASED(1f)
 765         la      %r14,__LC_SYNC_ENTER_TIMER
 766         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
 767         bl      BASED(0f)
 768         la      %r14,__LC_ASYNC_ENTER_TIMER
 769 0:      clc     0(8,%r14),__LC_EXIT_TIMER
 770         bl      BASED(0f)
 771         la      %r14,__LC_EXIT_TIMER
 772 0:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
 773         bl      BASED(0f)
 774         la      %r14,__LC_LAST_UPDATE_TIMER
 775 0:      spt     0(%r14)
 776         mvc     __LC_ASYNC_ENTER_TIMER(8),0(%r14)
 777 1:      tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
 778         bno     BASED(mcck_int_main)    # no -> skip cleanup critical
 779         tm      __LC_MCK_OLD_PSW+1,0x01 # test problem state bit
 780         bnz     BASED(mcck_int_main)    # from user -> load async stack
 781         clc     __LC_MCK_OLD_PSW+4(4),BASED(.Lcritical_end)
 782         bhe     BASED(mcck_int_main)
 783         clc     __LC_MCK_OLD_PSW+4(4),BASED(.Lcritical_start)
 784         bl      BASED(mcck_int_main)
 785         l       %r14,BASED(.Lcleanup_critical)
 786         basr    %r14,%r14
 787 mcck_int_main:
 788         l       %r14,__LC_PANIC_STACK   # are we already on the panic stack?
 789         slr     %r14,%r15
 790         sra     %r14,PAGE_SHIFT
 791         be      BASED(0f)
 792         l       %r15,__LC_PANIC_STACK   # load panic stack
 793 0:      CREATE_STACK_FRAME __LC_MCK_OLD_PSW,__LC_SAVE_AREA+32
 794         tm      __LC_MCCK_CODE+2,0x08   # mwp of old psw valid?
 795         bno     BASED(mcck_no_vtime)    # no -> skip cleanup critical
 796         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 797         bz      BASED(mcck_no_vtime)
 798         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 799         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 800         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 801 mcck_no_vtime:
 802         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 803         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 804         l       %r1,BASED(.Ls390_mcck)
 805         basr    %r14,%r1                # call machine check handler
 806         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 807         bno     BASED(mcck_return)
 808         l       %r1,__LC_KERNEL_STACK   # switch to kernel stack
 809         s       %r1,BASED(.Lc_spsize)
 810         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 811         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 812         lr      %r15,%r1
 813         stosm   __SF_EMPTY(%r15),0x04   # turn dat on
 814         tm      __TI_flags+3(%r9),_TIF_MCCK_PENDING
 815         bno     BASED(mcck_return)
 816         TRACE_IRQS_OFF
 817         l       %r1,BASED(.Ls390_handle_mcck)
 818         basr    %r14,%r1                # call machine check handler
 819         TRACE_IRQS_ON
 820 mcck_return:
 821         mvc     __LC_RETURN_MCCK_PSW(8),SP_PSW(%r15) # move return PSW
 822         ni      __LC_RETURN_MCCK_PSW+1,0xfd # clear wait state bit
 823         mvc     __LC_ASYNC_ENTER_TIMER(8),__LC_SAVE_AREA+52
 824         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
 825         bno     BASED(0f)
 826         lm      %r0,%r15,SP_R0(%r15)    # load gprs 0-15
 827         stpt    __LC_EXIT_TIMER
 828         lpsw    __LC_RETURN_MCCK_PSW    # back to caller
 829 0:      lm      %r0,%r15,SP_R0(%r15)    # load gprs 0-15
 830         lpsw    __LC_RETURN_MCCK_PSW    # back to caller
 831
 832         RESTORE_ALL __LC_RETURN_MCCK_PSW,0
 833
 834 /*
 835  * Restart interruption handler, kick starter for additional CPUs
 836  */
 837 #ifdef CONFIG_SMP
 838         __CPUINIT
 839         .globl restart_int_handler
 840 restart_int_handler:
 841         basr    %r1,0
 842 restart_base:
 843         spt     restart_vtime-restart_base(%r1)
 844         stck    __LC_LAST_UPDATE_CLOCK
 845         mvc     __LC_LAST_UPDATE_TIMER(8),restart_vtime-restart_base(%r1)
 846         mvc     __LC_EXIT_TIMER(8),restart_vtime-restart_base(%r1)
 847         l       %r15,__LC_SAVE_AREA+60  # load ksp
 848         lctl    %c0,%c15,__LC_CREGS_SAVE_AREA # get new ctl regs
 849         lam     %a0,%a15,__LC_AREGS_SAVE_AREA
 850         lm      %r6,%r15,__SF_GPRS(%r15) # load registers from clone
 851         l       %r1,__LC_THREAD_INFO
 852         mvc     __LC_USER_TIMER(8),__TI_user_timer(%r1)
 853         mvc     __LC_SYSTEM_TIMER(8),__TI_system_timer(%r1)
 854         xc      __LC_STEAL_TIMER(8),__LC_STEAL_TIMER
 855         stosm   __SF_EMPTY(%r15),0x04   # now we can turn dat on
 856         basr    %r14,0
 857         l       %r14,restart_addr-.(%r14)
 858         br      %r14                    # branch to start_secondary
 859 restart_addr:
 860         .long   start_secondary
 861         .align  8
 862 restart_vtime:
 863         .long   0x7fffffff,0xffffffff
 864         .previous
 865 #else
 866 /*
 867  * If we do not run with SMP enabled, let the new CPU crash ...
 868  */
 869         .globl restart_int_handler
 870 restart_int_handler:
 871         basr    %r1,0
 872 restart_base:
 873         lpsw    restart_crash-restart_base(%r1)
 874         .align  8
 875 restart_crash:
 876         .long   0x000a0000,0x00000000
 877 restart_go:
 878 #endif
 879
 880 #ifdef CONFIG_CHECK_STACK
 881 /*
 882  * The synchronous or the asynchronous stack overflowed. We are dead.
 883  * No need to properly save the registers, we are going to panic anyway.
 884  * Setup a pt_regs so that show_trace can provide a good call trace.
 885  */
 886 stack_overflow:
 887         l       %r15,__LC_PANIC_STACK   # change to panic stack
 888         sl      %r15,BASED(.Lc_spsize)
 889         mvc     SP_PSW(8,%r15),0(%r12)  # move user PSW to stack
 890         stm     %r0,%r11,SP_R0(%r15)    # store gprs %r0-%r11 to kernel stack
 891         la      %r1,__LC_SAVE_AREA
 892         ch      %r12,BASED(.L0x020)     # old psw addr == __LC_SVC_OLD_PSW ?
 893         be      BASED(0f)
 894         ch      %r12,BASED(.L0x028)     # old psw addr == __LC_PGM_OLD_PSW ?
 895         be      BASED(0f)
 896         la      %r1,__LC_SAVE_AREA+16
 897 0:      mvc     SP_R12(16,%r15),0(%r1)  # move %r12-%r15 to stack
 898         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15) # clear back chain
 899         l       %r1,BASED(1f)           # branch to kernel_stack_overflow
 900         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 901         br      %r1
 902 1:      .long   kernel_stack_overflow
 903 #endif
 904
 905 cleanup_table_system_call:
 906         .long   system_call + 0x80000000, sysc_do_svc + 0x80000000
 907 cleanup_table_sysc_return:
 908         .long   sysc_return + 0x80000000, sysc_leave + 0x80000000
 909 cleanup_table_sysc_leave:
 910         .long   sysc_leave + 0x80000000, sysc_done + 0x80000000
 911 cleanup_table_sysc_work_loop:
 912         .long   sysc_work_loop + 0x80000000, sysc_work_done + 0x80000000
 913 cleanup_table_io_return:
 914         .long   io_return + 0x80000000, io_leave + 0x80000000
 915 cleanup_table_io_leave:
 916         .long   io_leave + 0x80000000, io_done + 0x80000000
 917 cleanup_table_io_work_loop:
 918         .long   io_work_loop + 0x80000000, io_work_done + 0x80000000
 919
 920 cleanup_critical:
 921         clc     4(4,%r12),BASED(cleanup_table_system_call)
 922         bl      BASED(0f)
 923         clc     4(4,%r12),BASED(cleanup_table_system_call+4)
 924         bl      BASED(cleanup_system_call)
 925 0:
 926         clc     4(4,%r12),BASED(cleanup_table_sysc_return)
 927         bl      BASED(0f)
 928         clc     4(4,%r12),BASED(cleanup_table_sysc_return+4)
 929         bl      BASED(cleanup_sysc_return)
 930 0:
 931         clc     4(4,%r12),BASED(cleanup_table_sysc_leave)
 932         bl      BASED(0f)
 933         clc     4(4,%r12),BASED(cleanup_table_sysc_leave+4)
 934         bl      BASED(cleanup_sysc_leave)
 935 0:
 936         clc     4(4,%r12),BASED(cleanup_table_sysc_work_loop)
 937         bl      BASED(0f)
 938         clc     4(4,%r12),BASED(cleanup_table_sysc_work_loop+4)
 939         bl      BASED(cleanup_sysc_return)
 940 0:
 941         clc     4(4,%r12),BASED(cleanup_table_io_return)
 942         bl      BASED(0f)
 943         clc     4(4,%r12),BASED(cleanup_table_io_return+4)
 944         bl      BASED(cleanup_io_return)
 945 0:
 946         clc     4(4,%r12),BASED(cleanup_table_io_leave)
 947         bl      BASED(0f)
 948         clc     4(4,%r12),BASED(cleanup_table_io_leave+4)
 949         bl      BASED(cleanup_io_leave)
 950 0:
 951         clc     4(4,%r12),BASED(cleanup_table_io_work_loop)
 952         bl      BASED(0f)
 953         clc     4(4,%r12),BASED(cleanup_table_io_work_loop+4)
 954         bl      BASED(cleanup_io_return)
 955 0:
 956         br      %r14
 957
 958 cleanup_system_call:
 959         mvc     __LC_RETURN_PSW(8),0(%r12)
 960         c       %r12,BASED(.Lmck_old_psw)
 961         be      BASED(0f)
 962         la      %r12,__LC_SAVE_AREA+16
 963         b       BASED(1f)
 964 0:      la      %r12,__LC_SAVE_AREA+32
 965 1:
 966         clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+4)
 967         bh      BASED(0f)
 968         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
 969 0:      clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+8)
 970         bhe     BASED(cleanup_vtime)
 971         clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn)
 972         bh      BASED(0f)
 973         mvc     __LC_SAVE_AREA(16),0(%r12)
 974 0:      st      %r13,4(%r12)
 975         st      %r12,__LC_SAVE_AREA+48  # argh
 976         SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 977         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 978         l       %r12,__LC_SAVE_AREA+48  # argh
 979         st      %r15,12(%r12)
 980         lh      %r7,0x8a
 981 cleanup_vtime:
 982         clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+12)
 983         bhe     BASED(cleanup_stime)
 984         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 985 cleanup_stime:
 986         clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+16)
 987         bh      BASED(cleanup_update)
 988         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 989 cleanup_update:
 990         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 991         mvc     __LC_RETURN_PSW+4(4),BASED(cleanup_table_system_call+4)
 992         la      %r12,__LC_RETURN_PSW
 993         br      %r14
 994 cleanup_system_call_insn:
 995         .long   sysc_saveall + 0x80000000
 996         .long   system_call + 0x80000000
 997         .long   sysc_vtime + 0x80000000
 998         .long   sysc_stime + 0x80000000
 999         .long   sysc_update + 0x80000000
1000
1001 cleanup_sysc_return:
1002         mvc     __LC_RETURN_PSW(4),0(%r12)
1003         mvc     __LC_RETURN_PSW+4(4),BASED(cleanup_table_sysc_return)
1004         la      %r12,__LC_RETURN_PSW
1005         br      %r14
1006
1007 cleanup_sysc_leave:
1008         clc     4(4,%r12),BASED(cleanup_sysc_leave_insn)
1009         be      BASED(2f)
1010         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
1011         clc     4(4,%r12),BASED(cleanup_sysc_leave_insn+4)
1012         be      BASED(2f)
1013         mvc     __LC_RETURN_PSW(8),SP_PSW(%r15)
1014         c       %r12,BASED(.Lmck_old_psw)
1015         bne     BASED(0f)
1016         mvc     __LC_SAVE_AREA+32(16),SP_R12(%r15)
1017         b       BASED(1f)
1018 0:      mvc     __LC_SAVE_AREA+16(16),SP_R12(%r15)
1019 1:      lm      %r0,%r11,SP_R0(%r15)
1020         l       %r15,SP_R15(%r15)
1021 2:      la      %r12,__LC_RETURN_PSW
1022         br      %r14
1023 cleanup_sysc_leave_insn:
1024         .long   sysc_done - 4 + 0x80000000
1025         .long   sysc_done - 8 + 0x80000000
1026
1027 cleanup_io_return:
1028         mvc     __LC_RETURN_PSW(4),0(%r12)
1029         mvc     __LC_RETURN_PSW+4(4),BASED(cleanup_table_io_work_loop)
1030         la      %r12,__LC_RETURN_PSW
1031         br      %r14
1032
1033 cleanup_io_leave:
1034         clc     4(4,%r12),BASED(cleanup_io_leave_insn)
1035         be      BASED(2f)
1036         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
1037         clc     4(4,%r12),BASED(cleanup_io_leave_insn+4)
1038         be      BASED(2f)
1039         mvc     __LC_RETURN_PSW(8),SP_PSW(%r15)
1040         c       %r12,BASED(.Lmck_old_psw)
1041         bne     BASED(0f)
1042         mvc     __LC_SAVE_AREA+32(16),SP_R12(%r15)
1043         b       BASED(1f)
1044 0:      mvc     __LC_SAVE_AREA+16(16),SP_R12(%r15)
1045 1:      lm      %r0,%r11,SP_R0(%r15)
1046         l       %r15,SP_R15(%r15)
1047 2:      la      %r12,__LC_RETURN_PSW
1048         br      %r14
1049 cleanup_io_leave_insn:
1050         .long   io_done - 4 + 0x80000000
1051         .long   io_done - 8 + 0x80000000
1052
1053 /*
1054  * Integer constants
1055  */
1056                 .align  4
1057 .Lc_spsize:     .long   SP_SIZE
1058 .Lc_overhead:   .long   STACK_FRAME_OVERHEAD
1059 .Lnr_syscalls:  .long   NR_syscalls
1060 .L0x018:        .short  0x018
1061 .L0x020:        .short  0x020
1062 .L0x028:        .short  0x028
1063 .L0x030:        .short  0x030
1064 .L0x038:        .short  0x038
1065 .Lc_1:          .long   1
1066
1067 /*
1068  * Symbol constants
1069  */
1070 .Ls390_mcck:    .long   s390_do_machine_check
1071 .Ls390_handle_mcck:
1072                 .long   s390_handle_mcck
1073 .Lmck_old_psw:  .long   __LC_MCK_OLD_PSW
1074 .Ldo_IRQ:       .long   do_IRQ
1075 .Ldo_extint:    .long   do_extint
1076 .Ldo_signal:    .long   do_signal
1077 .Ldo_notify_resume:
1078                 .long   do_notify_resume
1079 .Lhandle_per:   .long   do_single_step
1080 .Ldo_execve:    .long   do_execve
1081 .Lexecve_tail:  .long   execve_tail
1082 .Ljump_table:   .long   pgm_check_table
1083 .Lschedule:     .long   schedule
1084 #ifdef CONFIG_PREEMPT
1085 .Lpreempt_schedule_irq:
1086                 .long   preempt_schedule_irq
1087 #endif
1088 .Ltrace_entry:  .long   do_syscall_trace_enter
1089 .Ltrace_exit:   .long   do_syscall_trace_exit
1090 .Lschedtail:    .long   schedule_tail
1091 .Lsysc_table:   .long   sys_call_table
1092 #ifdef CONFIG_TRACE_IRQFLAGS
1093 .Ltrace_irq_on_caller:
1094                 .long   trace_hardirqs_on_caller
1095 .Ltrace_irq_off_caller:
1096                 .long   trace_hardirqs_off_caller
1097 #endif
1098 #ifdef CONFIG_LOCKDEP
1099 .Llockdep_sys_exit:
1100                 .long   lockdep_sys_exit
1101 #endif
1102 .Lcritical_start:
1103                 .long   __critical_start + 0x80000000
1104 .Lcritical_end:
1105                 .long   __critical_end + 0x80000000
1106 .Lcleanup_critical:
1107                 .long   cleanup_critical
1108
1109                 .section .rodata, "a"
1110 #define SYSCALL(esa,esame,emu)  .long esa
1111 sys_call_table:
1112 #include "syscalls.S"
1113 #undef SYSCALL