arch/s390/kernel/entry.S

   1 /*
   2  *  arch/s390/kernel/entry.S
   3  *    S390 low-level entry points.
   4  *
   5  *    Copyright (C) IBM Corp. 1999,2006
   6  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
   7  *               Hartmut Penner (hp@de.ibm.com),
   8  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
   9  *               Heiko Carstens <heiko.carstens@de.ibm.com>
  10  */
  11
  12 #include <linux/linkage.h>
  13 #include <linux/init.h>
  14 #include <asm/cache.h>
  15 #include <asm/errno.h>
  16 #include <asm/ptrace.h>
  17 #include <asm/thread_info.h>
  18 #include <asm/asm-offsets.h>
  19 #include <asm/unistd.h>
  20 #include <asm/page.h>
  21
  22 /*
  23  * Stack layout for the system_call stack entry.
  24  * The first few entries are identical to the user_regs_struct.
  25  */
  26 SP_PTREGS    =  STACK_FRAME_OVERHEAD
  27 SP_ARGS      =  STACK_FRAME_OVERHEAD + __PT_ARGS
  28 SP_PSW       =  STACK_FRAME_OVERHEAD + __PT_PSW
  29 SP_R0        =  STACK_FRAME_OVERHEAD + __PT_GPRS
  30 SP_R1        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 4
  31 SP_R2        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 8
  32 SP_R3        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 12
  33 SP_R4        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 16
  34 SP_R5        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 20
  35 SP_R6        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 24
  36 SP_R7        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 28
  37 SP_R8        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 32
  38 SP_R9        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 36
  39 SP_R10       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 40
  40 SP_R11       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 44
  41 SP_R12       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 48
  42 SP_R13       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 52
  43 SP_R14       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 56
  44 SP_R15       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 60
  45 SP_ORIG_R2   =  STACK_FRAME_OVERHEAD + __PT_ORIG_GPR2
  46 SP_ILC       =  STACK_FRAME_OVERHEAD + __PT_ILC
  47 SP_SVCNR     =  STACK_FRAME_OVERHEAD + __PT_SVCNR
  48 SP_SIZE      =  STACK_FRAME_OVERHEAD + __PT_SIZE
  49
  50 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  51                  _TIF_MCCK_PENDING | _TIF_RESTART_SVC | _TIF_PER_TRAP )
  52 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  53                  _TIF_MCCK_PENDING)
  54 _TIF_SYSCALL = (_TIF_SYSCALL_TRACE>>8 | _TIF_SYSCALL_AUDIT>>8 | \
  55                 _TIF_SECCOMP>>8 | _TIF_SYSCALL_TRACEPOINT>>8)
  56
  57 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
  58 STACK_SIZE  = 1 << STACK_SHIFT
  59
  60 #define BASED(name) name-system_call(%r13)
  61
  62 #ifdef CONFIG_TRACE_IRQFLAGS
  63         .macro  TRACE_IRQS_ON
  64         basr    %r2,%r0
  65         l       %r1,BASED(.Ltrace_irq_on_caller)
  66         basr    %r14,%r1
  67         .endm
  68
  69         .macro  TRACE_IRQS_OFF
  70         basr    %r2,%r0
  71         l       %r1,BASED(.Ltrace_irq_off_caller)
  72         basr    %r14,%r1
  73         .endm
  74 #else
  75 #define TRACE_IRQS_ON
  76 #define TRACE_IRQS_OFF
  77 #endif
  78
  79 #ifdef CONFIG_LOCKDEP
  80         .macro  LOCKDEP_SYS_EXIT
  81         tm      SP_PSW+1(%r15),0x01     # returning to user ?
  82         jz      0f
  83         l       %r1,BASED(.Llockdep_sys_exit)
  84         basr    %r14,%r1
  85 0:
  86         .endm
  87 #else
  88 #define LOCKDEP_SYS_EXIT
  89 #endif
  90
  91 /*
  92  * Register usage in interrupt handlers:
  93  *    R9  - pointer to current task structure
  94  *    R13 - pointer to literal pool
  95  *    R14 - return register for function calls
  96  *    R15 - kernel stack pointer
  97  */
  98
  99         .macro  UPDATE_VTIME lc_from,lc_to,lc_sum
 100         lm      %r10,%r11,\lc_from
 101         sl      %r10,\lc_to
 102         sl      %r11,\lc_to+4
 103         bc      3,BASED(0f)
 104         sl      %r10,BASED(.Lc_1)
 105 0:      al      %r10,\lc_sum
 106         al      %r11,\lc_sum+4
 107         bc      12,BASED(1f)
 108         al      %r10,BASED(.Lc_1)
 109 1:      stm     %r10,%r11,\lc_sum
 110         .endm
 111
 112         .macro  SAVE_ALL_SVC psworg,savearea
 113         stm     %r12,%r15,\savearea
 114         l       %r13,__LC_SVC_NEW_PSW+4 # load &system_call to %r13
 115         l       %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 116         s       %r15,BASED(.Lc_spsize)  # make room for registers & psw
 117         .endm
 118
 119         .macro  SAVE_ALL_BASE savearea
 120         stm     %r12,%r15,\savearea
 121         l       %r13,__LC_SVC_NEW_PSW+4 # load &system_call to %r13
 122         .endm
 123
 124         .macro  SAVE_ALL_PGM psworg,savearea
 125         tm      \psworg+1,0x01          # test problem state bit
 126 #ifdef CONFIG_CHECK_STACK
 127         bnz     BASED(1f)
 128         tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
 129         bnz     BASED(2f)
 130         la      %r12,\psworg
 131         b       BASED(stack_overflow)
 132 #else
 133         bz      BASED(2f)
 134 #endif
 135 1:      l       %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 136 2:      s       %r15,BASED(.Lc_spsize)  # make room for registers & psw
 137         .endm
 138
 139         .macro  SAVE_ALL_ASYNC psworg,savearea
 140         stm     %r12,%r15,\savearea
 141         l       %r13,__LC_SVC_NEW_PSW+4 # load &system_call to %r13
 142         la      %r12,\psworg
 143         tm      \psworg+1,0x01          # test problem state bit
 144         bnz     BASED(1f)               # from user -> load async stack
 145         clc     \psworg+4(4),BASED(.Lcritical_end)
 146         bhe     BASED(0f)
 147         clc     \psworg+4(4),BASED(.Lcritical_start)
 148         bl      BASED(0f)
 149         l       %r14,BASED(.Lcleanup_critical)
 150         basr    %r14,%r14
 151         tm      1(%r12),0x01            # retest problem state after cleanup
 152         bnz     BASED(1f)
 153 0:      l       %r14,__LC_ASYNC_STACK   # are we already on the async stack ?
 154         slr     %r14,%r15
 155         sra     %r14,STACK_SHIFT
 156 #ifdef CONFIG_CHECK_STACK
 157         bnz     BASED(1f)
 158         tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
 159         bnz     BASED(2f)
 160         b       BASED(stack_overflow)
 161 #else
 162         bz      BASED(2f)
 163 #endif
 164 1:      l       %r15,__LC_ASYNC_STACK
 165 2:      s       %r15,BASED(.Lc_spsize)  # make room for registers & psw
 166         .endm
 167
 168         .macro  CREATE_STACK_FRAME savearea
 169         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
 170         st      %r2,SP_ORIG_R2(%r15)    # store original content of gpr 2
 171         mvc     SP_R12(16,%r15),\savearea # move %r12-%r15 to stack
 172         stm     %r0,%r11,SP_R0(%r15)    # store gprs %r0-%r11 to kernel stack
 173         .endm
 174
 175         .macro  RESTORE_ALL psworg,sync
 176         mvc     \psworg(8),SP_PSW(%r15) # move user PSW to lowcore
 177         .if !\sync
 178         ni      \psworg+1,0xfd          # clear wait state bit
 179         .endif
 180         lm      %r0,%r15,SP_R0(%r15)    # load gprs 0-15 of user
 181         stpt    __LC_EXIT_TIMER
 182         lpsw    \psworg                 # back to caller
 183         .endm
 184
 185         .macro REENABLE_IRQS
 186         mvc     __SF_EMPTY(1,%r15),SP_PSW(%r15)
 187         ni      __SF_EMPTY(%r15),0xbf
 188         ssm     __SF_EMPTY(%r15)
 189         .endm
 190
 191         .section .kprobes.text, "ax"
 192
 193 /*
 194  * Scheduler resume function, called by switch_to
 195  *  gpr2 = (task_struct *) prev
 196  *  gpr3 = (task_struct *) next
 197  * Returns:
 198  *  gpr2 = prev
 199  */
 200         .globl  __switch_to
 201 __switch_to:
 202         basr    %r1,0
 203 0:      l       %r4,__THREAD_info(%r2)          # get thread_info of prev
 204         l       %r5,__THREAD_info(%r3)          # get thread_info of next
 205         tm      __TI_flags+3(%r4),_TIF_MCCK_PENDING # machine check pending?
 206         bz      1f-0b(%r1)
 207         ni      __TI_flags+3(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
 208         oi      __TI_flags+3(%r5),_TIF_MCCK_PENDING     # set it in next
 209 1:      stm     %r6,%r15,__SF_GPRS(%r15)        # store gprs of prev task
 210         st      %r15,__THREAD_ksp(%r2)          # store kernel stack of prev
 211         l       %r15,__THREAD_ksp(%r3)          # load kernel stack of next
 212         lctl    %c4,%c4,__TASK_pid(%r3)         # load pid to control reg. 4
 213         lm      %r6,%r15,__SF_GPRS(%r15)        # load gprs of next task
 214         st      %r3,__LC_CURRENT                # store task struct of next
 215         st      %r5,__LC_THREAD_INFO            # store thread info of next
 216         ahi     %r5,STACK_SIZE                  # end of kernel stack of next
 217         st      %r5,__LC_KERNEL_STACK           # store end of kernel stack
 218         br      %r14
 219
 220 __critical_start:
 221 /*
 222  * SVC interrupt handler routine. System calls are synchronous events and
 223  * are executed with interrupts enabled.
 224  */
 225
 226         .globl  system_call
 227 system_call:
 228         stpt    __LC_SYNC_ENTER_TIMER
 229 sysc_saveall:
 230         SAVE_ALL_SVC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 231         CREATE_STACK_FRAME __LC_SAVE_AREA
 232         mvc     SP_PSW(8,%r15),__LC_SVC_OLD_PSW
 233         mvc     SP_ILC(4,%r15),__LC_SVC_ILC
 234         l       %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 235 sysc_vtime:
 236         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 237 sysc_stime:
 238         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 239 sysc_update:
 240         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 241 sysc_do_svc:
 242         xr      %r7,%r7
 243         icm     %r7,3,SP_SVCNR(%r15)    # load svc number and test for svc 0
 244         bnz     BASED(sysc_nr_ok)       # svc number > 0
 245         # svc 0: system call number in %r1
 246         cl      %r1,BASED(.Lnr_syscalls)
 247         bnl     BASED(sysc_nr_ok)
 248         sth     %r1,SP_SVCNR(%r15)
 249         lr      %r7,%r1           # copy svc number to %r7
 250 sysc_nr_ok:
 251         sll     %r7,2             # svc number *4
 252         l       %r10,BASED(.Lsysc_table)
 253         tm      __TI_flags+2(%r12),_TIF_SYSCALL
 254         mvc     SP_ARGS(4,%r15),SP_R7(%r15)
 255         l       %r8,0(%r7,%r10)   # get system call addr.
 256         bnz     BASED(sysc_tracesys)
 257         basr    %r14,%r8          # call sys_xxxx
 258         st      %r2,SP_R2(%r15)   # store return value (change R2 on stack)
 259
 260 sysc_return:
 261         LOCKDEP_SYS_EXIT
 262 sysc_tif:
 263         tm      __TI_flags+3(%r12),_TIF_WORK_SVC
 264         bnz     BASED(sysc_work)  # there is work to do (signals etc.)
 265 sysc_restore:
 266         RESTORE_ALL __LC_RETURN_PSW,1
 267 sysc_done:
 268
 269 #
 270 # There is work to do, but first we need to check if we return to userspace.
 271 #
 272 sysc_work:
 273         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 274         bno     BASED(sysc_restore)
 275
 276 #
 277 # One of the work bits is on. Find out which one.
 278 #
 279 sysc_work_tif:
 280         tm      __TI_flags+3(%r12),_TIF_MCCK_PENDING
 281         bo      BASED(sysc_mcck_pending)
 282         tm      __TI_flags+3(%r12),_TIF_NEED_RESCHED
 283         bo      BASED(sysc_reschedule)
 284         tm      __TI_flags+3(%r12),_TIF_SIGPENDING
 285         bo      BASED(sysc_sigpending)
 286         tm      __TI_flags+3(%r12),_TIF_NOTIFY_RESUME
 287         bo      BASED(sysc_notify_resume)
 288         tm      __TI_flags+3(%r12),_TIF_RESTART_SVC
 289         bo      BASED(sysc_restart)
 290         tm      __TI_flags+3(%r12),_TIF_PER_TRAP
 291         bo      BASED(sysc_singlestep)
 292         b       BASED(sysc_return)      # beware of critical section cleanup
 293
 294 #
 295 # _TIF_NEED_RESCHED is set, call schedule
 296 #
 297 sysc_reschedule:
 298         l       %r1,BASED(.Lschedule)
 299         la      %r14,BASED(sysc_return)
 300         br      %r1                     # call scheduler
 301
 302 #
 303 # _TIF_MCCK_PENDING is set, call handler
 304 #
 305 sysc_mcck_pending:
 306         l       %r1,BASED(.Ls390_handle_mcck)
 307         la      %r14,BASED(sysc_return)
 308         br      %r1                     # TIF bit will be cleared by handler
 309
 310 #
 311 # _TIF_SIGPENDING is set, call do_signal
 312 #
 313 sysc_sigpending:
 314         ni      __TI_flags+3(%r12),255-_TIF_PER_TRAP # clear TIF_PER_TRAP
 315         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 316         l       %r1,BASED(.Ldo_signal)
 317         basr    %r14,%r1                # call do_signal
 318         tm      __TI_flags+3(%r12),_TIF_RESTART_SVC
 319         bo      BASED(sysc_restart)
 320         tm      __TI_flags+3(%r12),_TIF_PER_TRAP
 321         bo      BASED(sysc_singlestep)
 322         b       BASED(sysc_return)
 323
 324 #
 325 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
 326 #
 327 sysc_notify_resume:
 328         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 329         l       %r1,BASED(.Ldo_notify_resume)
 330         la      %r14,BASED(sysc_return)
 331         br      %r1                     # call do_notify_resume
 332
 333
 334 #
 335 # _TIF_RESTART_SVC is set, set up registers and restart svc
 336 #
 337 sysc_restart:
 338         ni      __TI_flags+3(%r12),255-_TIF_RESTART_SVC # clear TIF_RESTART_SVC
 339         l       %r7,SP_R2(%r15)         # load new svc number
 340         mvc     SP_R2(4,%r15),SP_ORIG_R2(%r15) # restore first argument
 341         lm      %r2,%r6,SP_R2(%r15)     # load svc arguments
 342         sth     %r7,SP_SVCNR(%r15)
 343         b       BASED(sysc_nr_ok)       # restart svc
 344
 345 #
 346 # _TIF_PER_TRAP is set, call do_per_trap
 347 #
 348 sysc_singlestep:
 349         ni      __TI_flags+3(%r12),255-_TIF_PER_TRAP # clear TIF_PER_TRAP
 350         xc      SP_SVCNR(2,%r15),SP_SVCNR(%r15)         # clear svc number
 351         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 352         l       %r1,BASED(.Lhandle_per) # load adr. of per handler
 353         la      %r14,BASED(sysc_return) # load adr. of system return
 354         br      %r1                     # branch to do_per_trap
 355
 356 #
 357 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
 358 # and after the system call
 359 #
 360 sysc_tracesys:
 361         l       %r1,BASED(.Ltrace_entry)
 362         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 363         la      %r3,0
 364         xr      %r0,%r0
 365         icm     %r0,3,SP_SVCNR(%r15)
 366         st      %r0,SP_R2(%r15)
 367         basr    %r14,%r1
 368         cl      %r2,BASED(.Lnr_syscalls)
 369         bnl     BASED(sysc_tracenogo)
 370         lr      %r7,%r2
 371         sll     %r7,2                   # svc number *4
 372         l       %r8,0(%r7,%r10)
 373 sysc_tracego:
 374         lm      %r3,%r6,SP_R3(%r15)
 375         mvc     SP_ARGS(4,%r15),SP_R7(%r15)
 376         l       %r2,SP_ORIG_R2(%r15)
 377         basr    %r14,%r8                # call sys_xxx
 378         st      %r2,SP_R2(%r15)         # store return value
 379 sysc_tracenogo:
 380         tm      __TI_flags+2(%r12),_TIF_SYSCALL
 381         bz      BASED(sysc_return)
 382         l       %r1,BASED(.Ltrace_exit)
 383         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 384         la      %r14,BASED(sysc_return)
 385         br      %r1
 386
 387 #
 388 # a new process exits the kernel with ret_from_fork
 389 #
 390         .globl  ret_from_fork
 391 ret_from_fork:
 392         l       %r13,__LC_SVC_NEW_PSW+4
 393         l       %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 394         tm      SP_PSW+1(%r15),0x01     # forking a kernel thread ?
 395         bo      BASED(0f)
 396         st      %r15,SP_R15(%r15)       # store stack pointer for new kthread
 397 0:      l       %r1,BASED(.Lschedtail)
 398         basr    %r14,%r1
 399         TRACE_IRQS_ON
 400         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 401         b       BASED(sysc_tracenogo)
 402
 403 #
 404 # kernel_execve function needs to deal with pt_regs that is not
 405 # at the usual place
 406 #
 407         .globl  kernel_execve
 408 kernel_execve:
 409         stm     %r12,%r15,48(%r15)
 410         lr      %r14,%r15
 411         l       %r13,__LC_SVC_NEW_PSW+4
 412         s       %r15,BASED(.Lc_spsize)
 413         st      %r14,__SF_BACKCHAIN(%r15)
 414         la      %r12,SP_PTREGS(%r15)
 415         xc      0(__PT_SIZE,%r12),0(%r12)
 416         l       %r1,BASED(.Ldo_execve)
 417         lr      %r5,%r12
 418         basr    %r14,%r1
 419         ltr     %r2,%r2
 420         be      BASED(0f)
 421         a       %r15,BASED(.Lc_spsize)
 422         lm      %r12,%r15,48(%r15)
 423         br      %r14
 424         # execve succeeded.
 425 0:      stnsm   __SF_EMPTY(%r15),0xfc   # disable interrupts
 426         l       %r15,__LC_KERNEL_STACK  # load ksp
 427         s       %r15,BASED(.Lc_spsize)  # make room for registers & psw
 428         mvc     SP_PTREGS(__PT_SIZE,%r15),0(%r12)       # copy pt_regs
 429         l       %r12,__LC_THREAD_INFO
 430         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
 431         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 432         l       %r1,BASED(.Lexecve_tail)
 433         basr    %r14,%r1
 434         b       BASED(sysc_return)
 435
 436 /*
 437  * Program check handler routine
 438  */
 439
 440         .globl  pgm_check_handler
 441 pgm_check_handler:
 442 /*
 443  * First we need to check for a special case:
 444  * Single stepping an instruction that disables the PER event mask will
 445  * cause a PER event AFTER the mask has been set. Example: SVC or LPSW.
 446  * For a single stepped SVC the program check handler gets control after
 447  * the SVC new PSW has been loaded. But we want to execute the SVC first and
 448  * then handle the PER event. Therefore we update the SVC old PSW to point
 449  * to the pgm_check_handler and branch to the SVC handler after we checked
 450  * if we have to load the kernel stack register.
 451  * For every other possible cause for PER event without the PER mask set
 452  * we just ignore the PER event (FIXME: is there anything we have to do
 453  * for LPSW?).
 454  */
 455         stpt    __LC_SYNC_ENTER_TIMER
 456         SAVE_ALL_BASE __LC_SAVE_AREA
 457         tm      __LC_PGM_INT_CODE+1,0x80 # check whether we got a per exception
 458         bnz     BASED(pgm_per)          # got per exception -> special case
 459         SAVE_ALL_PGM __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 460         CREATE_STACK_FRAME __LC_SAVE_AREA
 461         xc      SP_ILC(4,%r15),SP_ILC(%r15)
 462         mvc     SP_PSW(8,%r15),__LC_PGM_OLD_PSW
 463         l       %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 464         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 465         bz      BASED(pgm_no_vtime)
 466         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 467         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 468         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 469 pgm_no_vtime:
 470         l       %r3,__LC_PGM_ILC        # load program interruption code
 471         l       %r4,__LC_TRANS_EXC_CODE
 472         REENABLE_IRQS
 473         la      %r8,0x7f
 474         nr      %r8,%r3
 475         sll     %r8,2
 476         l       %r1,BASED(.Ljump_table)
 477         l       %r1,0(%r8,%r1)          # load address of handler routine
 478         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 479         basr    %r14,%r1                # branch to interrupt-handler
 480 pgm_exit:
 481         b       BASED(sysc_return)
 482
 483 #
 484 # handle per exception
 485 #
 486 pgm_per:
 487         tm      __LC_PGM_OLD_PSW,0x40   # test if per event recording is on
 488         bnz     BASED(pgm_per_std)      # ok, normal per event from user space
 489 # ok its one of the special cases, now we need to find out which one
 490         clc     __LC_PGM_OLD_PSW(8),__LC_SVC_NEW_PSW
 491         be      BASED(pgm_svcper)
 492 # no interesting special case, ignore PER event
 493         lm      %r12,%r15,__LC_SAVE_AREA
 494         lpsw    0x28
 495
 496 #
 497 # Normal per exception
 498 #
 499 pgm_per_std:
 500         SAVE_ALL_PGM __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 501         CREATE_STACK_FRAME __LC_SAVE_AREA
 502         mvc     SP_PSW(8,%r15),__LC_PGM_OLD_PSW
 503         l       %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 504         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 505         bz      BASED(pgm_no_vtime2)
 506         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 507         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 508         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 509 pgm_no_vtime2:
 510         l       %r1,__TI_task(%r12)
 511         tm      SP_PSW+1(%r15),0x01     # kernel per event ?
 512         bz      BASED(kernel_per)
 513         mvc     __THREAD_per_cause(2,%r1),__LC_PER_CAUSE
 514         mvc     __THREAD_per_address(4,%r1),__LC_PER_ADDRESS
 515         mvc     __THREAD_per_paid(1,%r1),__LC_PER_PAID
 516         oi      __TI_flags+3(%r12),_TIF_PER_TRAP # set TIF_PER_TRAP
 517         l       %r3,__LC_PGM_ILC        # load program interruption code
 518         l       %r4,__LC_TRANS_EXC_CODE
 519         REENABLE_IRQS
 520         la      %r8,0x7f
 521         nr      %r8,%r3                 # clear per-event-bit and ilc
 522         be      BASED(pgm_exit2)        # only per or per+check ?
 523         sll     %r8,2
 524         l       %r1,BASED(.Ljump_table)
 525         l       %r1,0(%r8,%r1)          # load address of handler routine
 526         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 527         basr    %r14,%r1                # branch to interrupt-handler
 528 pgm_exit2:
 529         b       BASED(sysc_return)
 530
 531 #
 532 # it was a single stepped SVC that is causing all the trouble
 533 #
 534 pgm_svcper:
 535         SAVE_ALL_PGM __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 536         CREATE_STACK_FRAME __LC_SAVE_AREA
 537         mvc     SP_PSW(8,%r15),__LC_SVC_OLD_PSW
 538         mvc     SP_ILC(4,%r15),__LC_SVC_ILC
 539         l       %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 540         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 541         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 542         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 543         l       %r8,__TI_task(%r12)
 544         mvc     __THREAD_per_cause(2,%r8),__LC_PER_CAUSE
 545         mvc     __THREAD_per_address(4,%r8),__LC_PER_ADDRESS
 546         mvc     __THREAD_per_paid(1,%r8),__LC_PER_PAID
 547         oi      __TI_flags+3(%r12),_TIF_PER_TRAP # set TIF_PER_TRAP
 548         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 549         lm      %r2,%r6,SP_R2(%r15)     # load svc arguments
 550         b       BASED(sysc_do_svc)
 551
 552 #
 553 # per was called from kernel, must be kprobes
 554 #
 555 kernel_per:
 556         REENABLE_IRQS
 557         xc      SP_SVCNR(2,%r15),SP_SVCNR(%r15)
 558         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 559         l       %r1,BASED(.Lhandle_per) # load adr. of per handler
 560         basr    %r14,%r1                # branch to do_single_step
 561         b       BASED(pgm_exit)
 562
 563 /*
 564  * IO interrupt handler routine
 565  */
 566
 567         .globl io_int_handler
 568 io_int_handler:
 569         stck    __LC_INT_CLOCK
 570         stpt    __LC_ASYNC_ENTER_TIMER
 571         SAVE_ALL_ASYNC __LC_IO_OLD_PSW,__LC_SAVE_AREA+16
 572         CREATE_STACK_FRAME __LC_SAVE_AREA+16
 573         mvc     SP_PSW(8,%r15),0(%r12)  # move user PSW to stack
 574         l       %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 575         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 576         bz      BASED(io_no_vtime)
 577         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 578         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 579         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 580 io_no_vtime:
 581         TRACE_IRQS_OFF
 582         l       %r1,BASED(.Ldo_IRQ)     # load address of do_IRQ
 583         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 584         basr    %r14,%r1                # branch to standard irq handler
 585 io_return:
 586         LOCKDEP_SYS_EXIT
 587         TRACE_IRQS_ON
 588 io_tif:
 589         tm      __TI_flags+3(%r12),_TIF_WORK_INT
 590         bnz     BASED(io_work)          # there is work to do (signals etc.)
 591 io_restore:
 592         RESTORE_ALL __LC_RETURN_PSW,0
 593 io_done:
 594
 595 #
 596 # There is work todo, find out in which context we have been interrupted:
 597 # 1) if we return to user space we can do all _TIF_WORK_INT work
 598 # 2) if we return to kernel code and preemptive scheduling is enabled check
 599 #    the preemption counter and if it is zero call preempt_schedule_irq
 600 # Before any work can be done, a switch to the kernel stack is required.
 601 #
 602 io_work:
 603         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 604         bo      BASED(io_work_user)     # yes -> do resched & signal
 605 #ifdef CONFIG_PREEMPT
 606         # check for preemptive scheduling
 607         icm     %r0,15,__TI_precount(%r12)
 608         bnz     BASED(io_restore)       # preemption disabled
 609         tm      __TI_flags+3(%r12),_TIF_NEED_RESCHED
 610         bno     BASED(io_restore)
 611         # switch to kernel stack
 612         l       %r1,SP_R15(%r15)
 613         s       %r1,BASED(.Lc_spsize)
 614         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 615         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 616         lr      %r15,%r1
 617         # TRACE_IRQS_ON already done at io_return, call
 618         # TRACE_IRQS_OFF to keep things symmetrical
 619         TRACE_IRQS_OFF
 620         l       %r1,BASED(.Lpreempt_schedule_irq)
 621         basr    %r14,%r1                # call preempt_schedule_irq
 622         b       BASED(io_return)
 623 #else
 624         b       BASED(io_restore)
 625 #endif
 626
 627 #
 628 # Need to do work before returning to userspace, switch to kernel stack
 629 #
 630 io_work_user:
 631         l       %r1,__LC_KERNEL_STACK
 632         s       %r1,BASED(.Lc_spsize)
 633         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 634         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 635         lr      %r15,%r1
 636
 637 #
 638 # One of the work bits is on. Find out which one.
 639 # Checked are: _TIF_SIGPENDING, _TIF_NOTIFY_RESUME, _TIF_NEED_RESCHED
 640 #               and _TIF_MCCK_PENDING
 641 #
 642 io_work_tif:
 643         tm      __TI_flags+3(%r12),_TIF_MCCK_PENDING
 644         bo      BASED(io_mcck_pending)
 645         tm      __TI_flags+3(%r12),_TIF_NEED_RESCHED
 646         bo      BASED(io_reschedule)
 647         tm      __TI_flags+3(%r12),_TIF_SIGPENDING
 648         bo      BASED(io_sigpending)
 649         tm      __TI_flags+3(%r12),_TIF_NOTIFY_RESUME
 650         bo      BASED(io_notify_resume)
 651         b       BASED(io_return)        # beware of critical section cleanup
 652
 653 #
 654 # _TIF_MCCK_PENDING is set, call handler
 655 #
 656 io_mcck_pending:
 657         # TRACE_IRQS_ON already done at io_return
 658         l       %r1,BASED(.Ls390_handle_mcck)
 659         basr    %r14,%r1                # TIF bit will be cleared by handler
 660         TRACE_IRQS_OFF
 661         b       BASED(io_return)
 662
 663 #
 664 # _TIF_NEED_RESCHED is set, call schedule
 665 #
 666 io_reschedule:
 667         # TRACE_IRQS_ON already done at io_return
 668         l       %r1,BASED(.Lschedule)
 669         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 670         basr    %r14,%r1                # call scheduler
 671         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 672         TRACE_IRQS_OFF
 673         b       BASED(io_return)
 674
 675 #
 676 # _TIF_SIGPENDING is set, call do_signal
 677 #
 678 io_sigpending:
 679         # TRACE_IRQS_ON already done at io_return
 680         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 681         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 682         l       %r1,BASED(.Ldo_signal)
 683         basr    %r14,%r1                # call do_signal
 684         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 685         TRACE_IRQS_OFF
 686         b       BASED(io_return)
 687
 688 #
 689 # _TIF_SIGPENDING is set, call do_signal
 690 #
 691 io_notify_resume:
 692         # TRACE_IRQS_ON already done at io_return
 693         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 694         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 695         l       %r1,BASED(.Ldo_notify_resume)
 696         basr    %r14,%r1                # call do_signal
 697         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 698         TRACE_IRQS_OFF
 699         b       BASED(io_return)
 700
 701 /*
 702  * External interrupt handler routine
 703  */
 704
 705         .globl  ext_int_handler
 706 ext_int_handler:
 707         stck    __LC_INT_CLOCK
 708         stpt    __LC_ASYNC_ENTER_TIMER
 709         SAVE_ALL_ASYNC __LC_EXT_OLD_PSW,__LC_SAVE_AREA+16
 710         CREATE_STACK_FRAME __LC_SAVE_AREA+16
 711         mvc     SP_PSW(8,%r15),0(%r12)  # move user PSW to stack
 712         l       %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 713         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 714         bz      BASED(ext_no_vtime)
 715         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 716         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 717         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 718 ext_no_vtime:
 719         TRACE_IRQS_OFF
 720         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 721         l       %r3,__LC_CPU_ADDRESS    # get cpu address + interruption code
 722         l       %r4,__LC_EXT_PARAMS     # get external parameters
 723         l       %r1,BASED(.Ldo_extint)
 724         basr    %r14,%r1
 725         b       BASED(io_return)
 726
 727 __critical_end:
 728
 729 /*
 730  * Machine check handler routines
 731  */
 732
 733         .globl mcck_int_handler
 734 mcck_int_handler:
 735         stck    __LC_MCCK_CLOCK
 736         spt     __LC_CPU_TIMER_SAVE_AREA        # revalidate cpu timer
 737         lm      %r0,%r15,__LC_GPREGS_SAVE_AREA  # revalidate gprs
 738         SAVE_ALL_BASE __LC_SAVE_AREA+32
 739         la      %r12,__LC_MCK_OLD_PSW
 740         tm      __LC_MCCK_CODE,0x80     # system damage?
 741         bo      BASED(mcck_int_main)    # yes -> rest of mcck code invalid
 742         mvc     __LC_MCCK_ENTER_TIMER(8),__LC_CPU_TIMER_SAVE_AREA
 743         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
 744         bo      BASED(1f)
 745         la      %r14,__LC_SYNC_ENTER_TIMER
 746         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
 747         bl      BASED(0f)
 748         la      %r14,__LC_ASYNC_ENTER_TIMER
 749 0:      clc     0(8,%r14),__LC_EXIT_TIMER
 750         bl      BASED(0f)
 751         la      %r14,__LC_EXIT_TIMER
 752 0:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
 753         bl      BASED(0f)
 754         la      %r14,__LC_LAST_UPDATE_TIMER
 755 0:      spt     0(%r14)
 756         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
 757 1:      tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
 758         bno     BASED(mcck_int_main)    # no -> skip cleanup critical
 759         tm      __LC_MCK_OLD_PSW+1,0x01 # test problem state bit
 760         bnz     BASED(mcck_int_main)    # from user -> load async stack
 761         clc     __LC_MCK_OLD_PSW+4(4),BASED(.Lcritical_end)
 762         bhe     BASED(mcck_int_main)
 763         clc     __LC_MCK_OLD_PSW+4(4),BASED(.Lcritical_start)
 764         bl      BASED(mcck_int_main)
 765         l       %r14,BASED(.Lcleanup_critical)
 766         basr    %r14,%r14
 767 mcck_int_main:
 768         l       %r14,__LC_PANIC_STACK   # are we already on the panic stack?
 769         slr     %r14,%r15
 770         sra     %r14,PAGE_SHIFT
 771         be      BASED(0f)
 772         l       %r15,__LC_PANIC_STACK   # load panic stack
 773 0:      s       %r15,BASED(.Lc_spsize)  # make room for registers & psw
 774         CREATE_STACK_FRAME __LC_SAVE_AREA+32
 775         mvc     SP_PSW(8,%r15),0(%r12)
 776         l       %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
 777         tm      __LC_MCCK_CODE+2,0x08   # mwp of old psw valid?
 778         bno     BASED(mcck_no_vtime)    # no -> skip cleanup critical
 779         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 780         bz      BASED(mcck_no_vtime)
 781         UPDATE_VTIME __LC_EXIT_TIMER,__LC_MCCK_ENTER_TIMER,__LC_USER_TIMER
 782         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 783         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_MCCK_ENTER_TIMER
 784 mcck_no_vtime:
 785         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 786         l       %r1,BASED(.Ls390_mcck)
 787         basr    %r14,%r1                # call machine check handler
 788         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 789         bno     BASED(mcck_return)
 790         l       %r1,__LC_KERNEL_STACK   # switch to kernel stack
 791         s       %r1,BASED(.Lc_spsize)
 792         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 793         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 794         lr      %r15,%r1
 795         stosm   __SF_EMPTY(%r15),0x04   # turn dat on
 796         tm      __TI_flags+3(%r12),_TIF_MCCK_PENDING
 797         bno     BASED(mcck_return)
 798         TRACE_IRQS_OFF
 799         l       %r1,BASED(.Ls390_handle_mcck)
 800         basr    %r14,%r1                # call machine check handler
 801         TRACE_IRQS_ON
 802 mcck_return:
 803         mvc     __LC_RETURN_MCCK_PSW(8),SP_PSW(%r15) # move return PSW
 804         ni      __LC_RETURN_MCCK_PSW+1,0xfd # clear wait state bit
 805         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
 806         bno     BASED(0f)
 807         lm      %r0,%r15,SP_R0(%r15)    # load gprs 0-15
 808         stpt    __LC_EXIT_TIMER
 809         lpsw    __LC_RETURN_MCCK_PSW    # back to caller
 810 0:      lm      %r0,%r15,SP_R0(%r15)    # load gprs 0-15
 811         lpsw    __LC_RETURN_MCCK_PSW    # back to caller
 812
 813         RESTORE_ALL __LC_RETURN_MCCK_PSW,0
 814
 815 /*
 816  * Restart interruption handler, kick starter for additional CPUs
 817  */
 818 #ifdef CONFIG_SMP
 819         __CPUINIT
 820         .globl restart_int_handler
 821 restart_int_handler:
 822         basr    %r1,0
 823 restart_base:
 824         spt     restart_vtime-restart_base(%r1)
 825         stck    __LC_LAST_UPDATE_CLOCK
 826         mvc     __LC_LAST_UPDATE_TIMER(8),restart_vtime-restart_base(%r1)
 827         mvc     __LC_EXIT_TIMER(8),restart_vtime-restart_base(%r1)
 828         l       %r15,__LC_SAVE_AREA+60  # load ksp
 829         lctl    %c0,%c15,__LC_CREGS_SAVE_AREA # get new ctl regs
 830         lam     %a0,%a15,__LC_AREGS_SAVE_AREA
 831         lm      %r6,%r15,__SF_GPRS(%r15) # load registers from clone
 832         l       %r1,__LC_THREAD_INFO
 833         mvc     __LC_USER_TIMER(8),__TI_user_timer(%r1)
 834         mvc     __LC_SYSTEM_TIMER(8),__TI_system_timer(%r1)
 835         xc      __LC_STEAL_TIMER(8),__LC_STEAL_TIMER
 836         stosm   __SF_EMPTY(%r15),0x04   # now we can turn dat on
 837         basr    %r14,0
 838         l       %r14,restart_addr-.(%r14)
 839         basr    %r14,%r14               # branch to start_secondary
 840 restart_addr:
 841         .long   start_secondary
 842         .align  8
 843 restart_vtime:
 844         .long   0x7fffffff,0xffffffff
 845         .previous
 846 #else
 847 /*
 848  * If we do not run with SMP enabled, let the new CPU crash ...
 849  */
 850         .globl restart_int_handler
 851 restart_int_handler:
 852         basr    %r1,0
 853 restart_base:
 854         lpsw    restart_crash-restart_base(%r1)
 855         .align  8
 856 restart_crash:
 857         .long   0x000a0000,0x00000000
 858 restart_go:
 859 #endif
 860
 861         .section .kprobes.text, "ax"
 862
 863 #ifdef CONFIG_CHECK_STACK
 864 /*
 865  * The synchronous or the asynchronous stack overflowed. We are dead.
 866  * No need to properly save the registers, we are going to panic anyway.
 867  * Setup a pt_regs so that show_trace can provide a good call trace.
 868  */
 869 stack_overflow:
 870         l       %r15,__LC_PANIC_STACK   # change to panic stack
 871         sl      %r15,BASED(.Lc_spsize)
 872         mvc     SP_PSW(8,%r15),0(%r12)  # move user PSW to stack
 873         stm     %r0,%r11,SP_R0(%r15)    # store gprs %r0-%r11 to kernel stack
 874         la      %r1,__LC_SAVE_AREA
 875         ch      %r12,BASED(.L0x020)     # old psw addr == __LC_SVC_OLD_PSW ?
 876         be      BASED(0f)
 877         ch      %r12,BASED(.L0x028)     # old psw addr == __LC_PGM_OLD_PSW ?
 878         be      BASED(0f)
 879         la      %r1,__LC_SAVE_AREA+16
 880 0:      mvc     SP_R12(16,%r15),0(%r1)  # move %r12-%r15 to stack
 881         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15) # clear back chain
 882         l       %r1,BASED(1f)           # branch to kernel_stack_overflow
 883         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 884         br      %r1
 885 1:      .long   kernel_stack_overflow
 886 #endif
 887
 888 cleanup_table_system_call:
 889         .long   system_call + 0x80000000, sysc_do_svc + 0x80000000
 890 cleanup_table_sysc_tif:
 891         .long   sysc_tif + 0x80000000, sysc_restore + 0x80000000
 892 cleanup_table_sysc_restore:
 893         .long   sysc_restore + 0x80000000, sysc_done + 0x80000000
 894 cleanup_table_io_tif:
 895         .long   io_tif + 0x80000000, io_restore + 0x80000000
 896 cleanup_table_io_restore:
 897         .long   io_restore + 0x80000000, io_done + 0x80000000
 898
 899 cleanup_critical:
 900         clc     4(4,%r12),BASED(cleanup_table_system_call)
 901         bl      BASED(0f)
 902         clc     4(4,%r12),BASED(cleanup_table_system_call+4)
 903         bl      BASED(cleanup_system_call)
 904 0:
 905         clc     4(4,%r12),BASED(cleanup_table_sysc_tif)
 906         bl      BASED(0f)
 907         clc     4(4,%r12),BASED(cleanup_table_sysc_tif+4)
 908         bl      BASED(cleanup_sysc_tif)
 909 0:
 910         clc     4(4,%r12),BASED(cleanup_table_sysc_restore)
 911         bl      BASED(0f)
 912         clc     4(4,%r12),BASED(cleanup_table_sysc_restore+4)
 913         bl      BASED(cleanup_sysc_restore)
 914 0:
 915         clc     4(4,%r12),BASED(cleanup_table_io_tif)
 916         bl      BASED(0f)
 917         clc     4(4,%r12),BASED(cleanup_table_io_tif+4)
 918         bl      BASED(cleanup_io_tif)
 919 0:
 920         clc     4(4,%r12),BASED(cleanup_table_io_restore)
 921         bl      BASED(0f)
 922         clc     4(4,%r12),BASED(cleanup_table_io_restore+4)
 923         bl      BASED(cleanup_io_restore)
 924 0:
 925         br      %r14
 926
 927 cleanup_system_call:
 928         mvc     __LC_RETURN_PSW(8),0(%r12)
 929         clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+4)
 930         bh      BASED(0f)
 931         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_MCCK_ENTER_TIMER
 932         c       %r12,BASED(.Lmck_old_psw)
 933         be      BASED(0f)
 934         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
 935 0:      c       %r12,BASED(.Lmck_old_psw)
 936         la      %r12,__LC_SAVE_AREA+32
 937         be      BASED(0f)
 938         la      %r12,__LC_SAVE_AREA+16
 939 0:      clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+8)
 940         bhe     BASED(cleanup_vtime)
 941         clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn)
 942         bh      BASED(0f)
 943         mvc     __LC_SAVE_AREA(16),0(%r12)
 944 0:      st      %r13,4(%r12)
 945         l       %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 946         s       %r15,BASED(.Lc_spsize)  # make room for registers & psw
 947         st      %r15,12(%r12)
 948         CREATE_STACK_FRAME __LC_SAVE_AREA
 949         mvc     SP_PSW(8,%r15),__LC_SVC_OLD_PSW
 950         mvc     SP_ILC(4,%r15),__LC_SVC_ILC
 951         mvc     0(4,%r12),__LC_THREAD_INFO
 952 cleanup_vtime:
 953         clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+12)
 954         bhe     BASED(cleanup_stime)
 955         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 956 cleanup_stime:
 957         clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+16)
 958         bh      BASED(cleanup_update)
 959         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 960 cleanup_update:
 961         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 962         mvc     __LC_RETURN_PSW+4(4),BASED(cleanup_table_system_call+4)
 963         la      %r12,__LC_RETURN_PSW
 964         br      %r14
 965 cleanup_system_call_insn:
 966         .long   sysc_saveall + 0x80000000
 967         .long   system_call + 0x80000000
 968         .long   sysc_vtime + 0x80000000
 969         .long   sysc_stime + 0x80000000
 970         .long   sysc_update + 0x80000000
 971
 972 cleanup_sysc_tif:
 973         mvc     __LC_RETURN_PSW(4),0(%r12)
 974         mvc     __LC_RETURN_PSW+4(4),BASED(cleanup_table_sysc_tif)
 975         la      %r12,__LC_RETURN_PSW
 976         br      %r14
 977
 978 cleanup_sysc_restore:
 979         clc     4(4,%r12),BASED(cleanup_sysc_restore_insn)
 980         be      BASED(2f)
 981         mvc     __LC_EXIT_TIMER(8),__LC_MCCK_ENTER_TIMER
 982         c       %r12,BASED(.Lmck_old_psw)
 983         be      BASED(0f)
 984         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
 985 0:      clc     4(4,%r12),BASED(cleanup_sysc_restore_insn+4)
 986         be      BASED(2f)
 987         mvc     __LC_RETURN_PSW(8),SP_PSW(%r15)
 988         c       %r12,BASED(.Lmck_old_psw)
 989         la      %r12,__LC_SAVE_AREA+32
 990         be      BASED(1f)
 991         la      %r12,__LC_SAVE_AREA+16
 992 1:      mvc     0(16,%r12),SP_R12(%r15)
 993         lm      %r0,%r11,SP_R0(%r15)
 994         l       %r15,SP_R15(%r15)
 995 2:      la      %r12,__LC_RETURN_PSW
 996         br      %r14
 997 cleanup_sysc_restore_insn:
 998         .long   sysc_done - 4 + 0x80000000
 999         .long   sysc_done - 8 + 0x80000000
1000
1001 cleanup_io_tif:
1002         mvc     __LC_RETURN_PSW(4),0(%r12)
1003         mvc     __LC_RETURN_PSW+4(4),BASED(cleanup_table_io_tif)
1004         la      %r12,__LC_RETURN_PSW
1005         br      %r14
1006
1007 cleanup_io_restore:
1008         clc     4(4,%r12),BASED(cleanup_io_restore_insn)
1009         be      BASED(1f)
1010         mvc     __LC_EXIT_TIMER(8),__LC_MCCK_ENTER_TIMER
1011         clc     4(4,%r12),BASED(cleanup_io_restore_insn+4)
1012         be      BASED(1f)
1013         mvc     __LC_RETURN_PSW(8),SP_PSW(%r15)
1014         mvc     __LC_SAVE_AREA+32(16),SP_R12(%r15)
1015         lm      %r0,%r11,SP_R0(%r15)
1016         l       %r15,SP_R15(%r15)
1017 1:      la      %r12,__LC_RETURN_PSW
1018         br      %r14
1019 cleanup_io_restore_insn:
1020         .long   io_done - 4 + 0x80000000
1021         .long   io_done - 8 + 0x80000000
1022
1023 /*
1024  * Integer constants
1025  */
1026                 .align  4
1027 .Lc_spsize:     .long   SP_SIZE
1028 .Lc_overhead:   .long   STACK_FRAME_OVERHEAD
1029 .Lnr_syscalls:  .long   NR_syscalls
1030 .L0x018:        .short  0x018
1031 .L0x020:        .short  0x020
1032 .L0x028:        .short  0x028
1033 .L0x030:        .short  0x030
1034 .L0x038:        .short  0x038
1035 .Lc_1:          .long   1
1036
1037 /*
1038  * Symbol constants
1039  */
1040 .Ls390_mcck:    .long   s390_do_machine_check
1041 .Ls390_handle_mcck:
1042                 .long   s390_handle_mcck
1043 .Lmck_old_psw:  .long   __LC_MCK_OLD_PSW
1044 .Ldo_IRQ:       .long   do_IRQ
1045 .Ldo_extint:    .long   do_extint
1046 .Ldo_signal:    .long   do_signal
1047 .Ldo_notify_resume:
1048                 .long   do_notify_resume
1049 .Lhandle_per:   .long   do_per_trap
1050 .Ldo_execve:    .long   do_execve
1051 .Lexecve_tail:  .long   execve_tail
1052 .Ljump_table:   .long   pgm_check_table
1053 .Lschedule:     .long   schedule
1054 #ifdef CONFIG_PREEMPT
1055 .Lpreempt_schedule_irq:
1056                 .long   preempt_schedule_irq
1057 #endif
1058 .Ltrace_entry:  .long   do_syscall_trace_enter
1059 .Ltrace_exit:   .long   do_syscall_trace_exit
1060 .Lschedtail:    .long   schedule_tail
1061 .Lsysc_table:   .long   sys_call_table
1062 #ifdef CONFIG_TRACE_IRQFLAGS
1063 .Ltrace_irq_on_caller:
1064                 .long   trace_hardirqs_on_caller
1065 .Ltrace_irq_off_caller:
1066                 .long   trace_hardirqs_off_caller
1067 #endif
1068 #ifdef CONFIG_LOCKDEP
1069 .Llockdep_sys_exit:
1070                 .long   lockdep_sys_exit
1071 #endif
1072 .Lcritical_start:
1073                 .long   __critical_start + 0x80000000
1074 .Lcritical_end:
1075                 .long   __critical_end + 0x80000000
1076 .Lcleanup_critical:
1077                 .long   cleanup_critical
1078
1079                 .section .rodata, "a"
1080 #define SYSCALL(esa,esame,emu)  .long esa
1081         .globl  sys_call_table
1082 sys_call_table:
1083 #include "syscalls.S"
1084 #undef SYSCALL