projects / deliverable / linux.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
blame | history | raw | HEAD
s390/smp: make absolute lowcore / cpu restart parameter accesses more robust
[deliverable/linux.git] / arch / s390 / kernel / entry64.S
1 /*
2 * arch/s390/kernel/entry64.S
3 * S390 low-level entry points.
4 *
5 * Copyright (C) IBM Corp. 1999,2012
6 * Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
7 * Hartmut Penner (hp@de.ibm.com),
8 * Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
9 * Heiko Carstens <heiko.carstens@de.ibm.com>
10 */
11
12 #include <linux/init.h>
13 #include <linux/linkage.h>
14 #include <asm/cache.h>
15 #include <asm/errno.h>
16 #include <asm/ptrace.h>
17 #include <asm/thread_info.h>
18 #include <asm/asm-offsets.h>
19 #include <asm/unistd.h>
20 #include <asm/page.h>
21 #include <asm/sigp.h>
22
23 __PT_R0 = __PT_GPRS
24 __PT_R1 = __PT_GPRS + 8
25 __PT_R2 = __PT_GPRS + 16
26 __PT_R3 = __PT_GPRS + 24
27 __PT_R4 = __PT_GPRS + 32
28 __PT_R5 = __PT_GPRS + 40
29 __PT_R6 = __PT_GPRS + 48
30 __PT_R7 = __PT_GPRS + 56
31 __PT_R8 = __PT_GPRS + 64
32 __PT_R9 = __PT_GPRS + 72
33 __PT_R10 = __PT_GPRS + 80
34 __PT_R11 = __PT_GPRS + 88
35 __PT_R12 = __PT_GPRS + 96
36 __PT_R13 = __PT_GPRS + 104
37 __PT_R14 = __PT_GPRS + 112
38 __PT_R15 = __PT_GPRS + 120
39
40 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
41 STACK_SIZE = 1 << STACK_SHIFT
42
43 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
44 _TIF_MCCK_PENDING | _TIF_PER_TRAP )
45 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
46 _TIF_MCCK_PENDING)
47 _TIF_TRACE = (_TIF_SYSCALL_TRACE | _TIF_SYSCALL_AUDIT | _TIF_SECCOMP | \
48 _TIF_SYSCALL_TRACEPOINT)
49 _TIF_EXIT_SIE = (_TIF_SIGPENDING | _TIF_NEED_RESCHED | _TIF_MCCK_PENDING)
50
51 #define BASED(name) name-system_call(%r13)
52
53 .macro TRACE_IRQS_ON
54 #ifdef CONFIG_TRACE_IRQFLAGS
55 basr %r2,%r0
56 brasl %r14,trace_hardirqs_on_caller
57 #endif
58 .endm
59
60 .macro TRACE_IRQS_OFF
61 #ifdef CONFIG_TRACE_IRQFLAGS
62 basr %r2,%r0
63 brasl %r14,trace_hardirqs_off_caller
64 #endif
65 .endm
66
67 .macro LOCKDEP_SYS_EXIT
68 #ifdef CONFIG_LOCKDEP
69 tm __PT_PSW+1(%r11),0x01 # returning to user ?
70 jz .+10
71 brasl %r14,lockdep_sys_exit
72 #endif
73 .endm
74
75 .macro SPP newpp
76 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
77 tm __LC_MACHINE_FLAGS+6,0x20 # MACHINE_FLAG_SPP
78 jz .+8
79 .insn s,0xb2800000,\newpp
80 #endif
81 .endm
82
83 .macro HANDLE_SIE_INTERCEPT scratch
84 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
85 tmhh %r8,0x0001 # interrupting from user ?
86 jnz .+42
87 lgr \scratch,%r9
88 slg \scratch,BASED(.Lsie_loop)
89 clg \scratch,BASED(.Lsie_length)
90 jhe .+22
91 lg %r9,BASED(.Lsie_loop)
92 SPP BASED(.Lhost_id) # set host id
93 #endif
94 .endm
95
96 .macro CHECK_STACK stacksize,savearea
97 #ifdef CONFIG_CHECK_STACK
98 tml %r15,\stacksize - CONFIG_STACK_GUARD
99 lghi %r14,\savearea
100 jz stack_overflow
101 #endif
102 .endm
103
104 .macro SWITCH_ASYNC savearea,stack,shift
105 tmhh %r8,0x0001 # interrupting from user ?
106 jnz 1f
107 lgr %r14,%r9
108 slg %r14,BASED(.Lcritical_start)
109 clg %r14,BASED(.Lcritical_length)
110 jhe 0f
111 lghi %r11,\savearea # inside critical section, do cleanup
112 brasl %r14,cleanup_critical
113 tmhh %r8,0x0001 # retest problem state after cleanup
114 jnz 1f
115 0: lg %r14,\stack # are we already on the target stack?
116 slgr %r14,%r15
117 srag %r14,%r14,\shift
118 jnz 1f
119 CHECK_STACK 1<<\shift,\savearea
120 j 2f
121 1: lg %r15,\stack # load target stack
122 2: aghi %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
123 la %r11,STACK_FRAME_OVERHEAD(%r15)
124 .endm
125
126 .macro UPDATE_VTIME scratch,enter_timer
127 lg \scratch,__LC_EXIT_TIMER
128 slg \scratch,\enter_timer
129 alg \scratch,__LC_USER_TIMER
130 stg \scratch,__LC_USER_TIMER
131 lg \scratch,__LC_LAST_UPDATE_TIMER
132 slg \scratch,__LC_EXIT_TIMER
133 alg \scratch,__LC_SYSTEM_TIMER
134 stg \scratch,__LC_SYSTEM_TIMER
135 mvc __LC_LAST_UPDATE_TIMER(8),\enter_timer
136 .endm
137
138 .macro LAST_BREAK scratch
139 srag \scratch,%r10,23
140 jz .+10
141 stg %r10,__TI_last_break(%r12)
142 .endm
143
144 .macro REENABLE_IRQS
145 stg %r8,__LC_RETURN_PSW
146 ni __LC_RETURN_PSW,0xbf
147 ssm __LC_RETURN_PSW
148 .endm
149
150 .macro STCK savearea
151 #ifdef CONFIG_HAVE_MARCH_Z9_109_FEATURES
152 .insn s,0xb27c0000,\savearea # store clock fast
153 #else
154 .insn s,0xb2050000,\savearea # store clock
155 #endif
156 .endm
157
158 .section .kprobes.text, "ax"
159
160 /*
161 * Scheduler resume function, called by switch_to
162 * gpr2 = (task_struct *) prev
163 * gpr3 = (task_struct *) next
164 * Returns:
165 * gpr2 = prev
166 */
167 ENTRY(__switch_to)
168 stmg %r6,%r15,__SF_GPRS(%r15) # store gprs of prev task
169 stg %r15,__THREAD_ksp(%r2) # store kernel stack of prev
170 lg %r4,__THREAD_info(%r2) # get thread_info of prev
171 lg %r5,__THREAD_info(%r3) # get thread_info of next
172 lgr %r15,%r5
173 aghi %r15,STACK_SIZE # end of kernel stack of next
174 stg %r3,__LC_CURRENT # store task struct of next
175 stg %r5,__LC_THREAD_INFO # store thread info of next
176 stg %r15,__LC_KERNEL_STACK # store end of kernel stack
177 lctl %c4,%c4,__TASK_pid(%r3) # load pid to control reg. 4
178 mvc __LC_CURRENT_PID+4(4,%r0),__TASK_pid(%r3) # store pid of next
179 lg %r15,__THREAD_ksp(%r3) # load kernel stack of next
180 tm __TI_flags+7(%r4),_TIF_MCCK_PENDING # machine check pending?
181 jz 0f
182 ni __TI_flags+7(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
183 oi __TI_flags+7(%r5),_TIF_MCCK_PENDING # set it in next
184 0: lmg %r6,%r15,__SF_GPRS(%r15) # load gprs of next task
185 br %r14
186
187 __critical_start:
188 /*
189 * SVC interrupt handler routine. System calls are synchronous events and
190 * are executed with interrupts enabled.
191 */
192
193 ENTRY(system_call)
194 stpt __LC_SYNC_ENTER_TIMER
195 sysc_stmg:
196 stmg %r8,%r15,__LC_SAVE_AREA_SYNC
197 lg %r10,__LC_LAST_BREAK
198 lg %r12,__LC_THREAD_INFO
199 larl %r13,system_call
200 sysc_per:
201 lg %r15,__LC_KERNEL_STACK
202 aghi %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
203 la %r11,STACK_FRAME_OVERHEAD(%r15) # pointer to pt_regs
204 sysc_vtime:
205 UPDATE_VTIME %r13,__LC_SYNC_ENTER_TIMER
206 LAST_BREAK %r13
207 stmg %r0,%r7,__PT_R0(%r11)
208 mvc __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
209 mvc __PT_PSW(16,%r11),__LC_SVC_OLD_PSW
210 mvc __PT_INT_CODE(4,%r11),__LC_SVC_ILC
211 sysc_do_svc:
212 oi __TI_flags+7(%r12),_TIF_SYSCALL
213 llgh %r8,__PT_INT_CODE+2(%r11)
214 slag %r8,%r8,2 # shift and test for svc 0
215 jnz sysc_nr_ok
216 # svc 0: system call number in %r1
217 llgfr %r1,%r1 # clear high word in r1
218 cghi %r1,NR_syscalls
219 jnl sysc_nr_ok
220 sth %r1,__PT_INT_CODE+2(%r11)
221 slag %r8,%r1,2
222 sysc_nr_ok:
223 larl %r10,sys_call_table # 64 bit system call table
224 #ifdef CONFIG_COMPAT
225 tm __TI_flags+5(%r12),(_TIF_31BIT>>16)
226 jno sysc_noemu
227 larl %r10,sys_call_table_emu # 31 bit system call table
228 sysc_noemu:
229 #endif
230 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
231 stg %r2,__PT_ORIG_GPR2(%r11)
232 stg %r7,STACK_FRAME_OVERHEAD(%r15)
233 lgf %r9,0(%r8,%r10) # get system call add.
234 tm __TI_flags+6(%r12),_TIF_TRACE >> 8
235 jnz sysc_tracesys
236 basr %r14,%r9 # call sys_xxxx
237 stg %r2,__PT_R2(%r11) # store return value
238
239 sysc_return:
240 LOCKDEP_SYS_EXIT
241 sysc_tif:
242 tm __PT_PSW+1(%r11),0x01 # returning to user ?
243 jno sysc_restore
244 tm __TI_flags+7(%r12),_TIF_WORK_SVC
245 jnz sysc_work # check for work
246 ni __TI_flags+7(%r12),255-_TIF_SYSCALL
247 sysc_restore:
248 lg %r14,__LC_VDSO_PER_CPU
249 lmg %r0,%r10,__PT_R0(%r11)
250 mvc __LC_RETURN_PSW(16),__PT_PSW(%r11)
251 stpt __LC_EXIT_TIMER
252 mvc __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
253 lmg %r11,%r15,__PT_R11(%r11)
254 lpswe __LC_RETURN_PSW
255 sysc_done:
256
257 #
258 # One of the work bits is on. Find out which one.
259 #
260 sysc_work:
261 tm __TI_flags+7(%r12),_TIF_MCCK_PENDING
262 jo sysc_mcck_pending
263 tm __TI_flags+7(%r12),_TIF_NEED_RESCHED
264 jo sysc_reschedule
265 tm __TI_flags+7(%r12),_TIF_SIGPENDING
266 jo sysc_sigpending
267 tm __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
268 jo sysc_notify_resume
269 tm __TI_flags+7(%r12),_TIF_PER_TRAP
270 jo sysc_singlestep
271 j sysc_return # beware of critical section cleanup
272
273 #
274 # _TIF_NEED_RESCHED is set, call schedule
275 #
276 sysc_reschedule:
277 larl %r14,sysc_return
278 jg schedule
279
280 #
281 # _TIF_MCCK_PENDING is set, call handler
282 #
283 sysc_mcck_pending:
284 larl %r14,sysc_return
285 jg s390_handle_mcck # TIF bit will be cleared by handler
286
287 #
288 # _TIF_SIGPENDING is set, call do_signal
289 #
290 sysc_sigpending:
291 ni __TI_flags+7(%r12),255-_TIF_PER_TRAP # clear TIF_PER_TRAP
292 lgr %r2,%r11 # pass pointer to pt_regs
293 brasl %r14,do_signal
294 tm __TI_flags+7(%r12),_TIF_SYSCALL
295 jno sysc_return
296 lmg %r2,%r7,__PT_R2(%r11) # load svc arguments
297 lghi %r8,0 # svc 0 returns -ENOSYS
298 lh %r1,__PT_INT_CODE+2(%r11) # load new svc number
299 cghi %r1,NR_syscalls
300 jnl sysc_nr_ok # invalid svc number -> do svc 0
301 slag %r8,%r1,2
302 j sysc_nr_ok # restart svc
303
304 #
305 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
306 #
307 sysc_notify_resume:
308 lgr %r2,%r11 # pass pointer to pt_regs
309 larl %r14,sysc_return
310 jg do_notify_resume
311
312 #
313 # _TIF_PER_TRAP is set, call do_per_trap
314 #
315 sysc_singlestep:
316 ni __TI_flags+7(%r12),255-(_TIF_SYSCALL | _TIF_PER_TRAP)
317 lgr %r2,%r11 # pass pointer to pt_regs
318 larl %r14,sysc_return
319 jg do_per_trap
320
321 #
322 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
323 # and after the system call
324 #
325 sysc_tracesys:
326 lgr %r2,%r11 # pass pointer to pt_regs
327 la %r3,0
328 llgh %r0,__PT_INT_CODE+2(%r11)
329 stg %r0,__PT_R2(%r11)
330 brasl %r14,do_syscall_trace_enter
331 lghi %r0,NR_syscalls
332 clgr %r0,%r2
333 jnh sysc_tracenogo
334 sllg %r8,%r2,2
335 lgf %r9,0(%r8,%r10)
336 sysc_tracego:
337 lmg %r3,%r7,__PT_R3(%r11)
338 stg %r7,STACK_FRAME_OVERHEAD(%r15)
339 lg %r2,__PT_ORIG_GPR2(%r11)
340 basr %r14,%r9 # call sys_xxx
341 stg %r2,__PT_R2(%r11) # store return value
342 sysc_tracenogo:
343 tm __TI_flags+6(%r12),_TIF_TRACE >> 8
344 jz sysc_return
345 lgr %r2,%r11 # pass pointer to pt_regs
346 larl %r14,sysc_return
347 jg do_syscall_trace_exit
348
349 #
350 # a new process exits the kernel with ret_from_fork
351 #
352 ENTRY(ret_from_fork)
353 la %r11,STACK_FRAME_OVERHEAD(%r15)
354 lg %r12,__LC_THREAD_INFO
355 tm __PT_PSW+1(%r11),0x01 # forking a kernel thread ?
356 jo 0f
357 stg %r15,__PT_R15(%r11) # store stack pointer for new kthread
358 0: brasl %r14,schedule_tail
359 TRACE_IRQS_ON
360 ssm __LC_SVC_NEW_PSW # reenable interrupts
361 j sysc_tracenogo
362
363 #
364 # kernel_execve function needs to deal with pt_regs that is not
365 # at the usual place
366 #
367 ENTRY(kernel_execve)
368 stmg %r12,%r15,96(%r15)
369 lgr %r14,%r15
370 aghi %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
371 stg %r14,__SF_BACKCHAIN(%r15)
372 la %r12,STACK_FRAME_OVERHEAD(%r15)
373 xc 0(__PT_SIZE,%r12),0(%r12)
374 lgr %r5,%r12
375 brasl %r14,do_execve
376 ltgfr %r2,%r2
377 je 0f
378 aghi %r15,(STACK_FRAME_OVERHEAD + __PT_SIZE)
379 lmg %r12,%r15,96(%r15)
380 br %r14
381 # execve succeeded.
382 0: ssm __LC_PGM_NEW_PSW # disable I/O and ext. interrupts
383 lg %r15,__LC_KERNEL_STACK # load ksp
384 aghi %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
385 la %r11,STACK_FRAME_OVERHEAD(%r15)
386 mvc 0(__PT_SIZE,%r11),0(%r12) # copy pt_regs
387 lg %r12,__LC_THREAD_INFO
388 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
389 ssm __LC_SVC_NEW_PSW # reenable interrupts
390 brasl %r14,execve_tail
391 j sysc_return
392
393 /*
394 * Program check handler routine
395 */
396
397 ENTRY(pgm_check_handler)
398 stpt __LC_SYNC_ENTER_TIMER
399 stmg %r8,%r15,__LC_SAVE_AREA_SYNC
400 lg %r10,__LC_LAST_BREAK
401 lg %r12,__LC_THREAD_INFO
402 larl %r13,system_call
403 lmg %r8,%r9,__LC_PGM_OLD_PSW
404 HANDLE_SIE_INTERCEPT %r14
405 tmhh %r8,0x0001 # test problem state bit
406 jnz 1f # -> fault in user space
407 tmhh %r8,0x4000 # PER bit set in old PSW ?
408 jnz 0f # -> enabled, can't be a double fault
409 tm __LC_PGM_ILC+3,0x80 # check for per exception
410 jnz pgm_svcper # -> single stepped svc
411 0: CHECK_STACK STACK_SIZE,__LC_SAVE_AREA_SYNC
412 j 2f
413 1: UPDATE_VTIME %r14,__LC_SYNC_ENTER_TIMER
414 LAST_BREAK %r14
415 lg %r15,__LC_KERNEL_STACK
416 2: aghi %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
417 la %r11,STACK_FRAME_OVERHEAD(%r15)
418 stmg %r0,%r7,__PT_R0(%r11)
419 mvc __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
420 stmg %r8,%r9,__PT_PSW(%r11)
421 mvc __PT_INT_CODE(4,%r11),__LC_PGM_ILC
422 mvc __PT_INT_PARM_LONG(8,%r11),__LC_TRANS_EXC_CODE
423 stg %r10,__PT_ARGS(%r11)
424 tm __LC_PGM_ILC+3,0x80 # check for per exception
425 jz 0f
426 lg %r1,__TI_task(%r12)
427 tmhh %r8,0x0001 # kernel per event ?
428 jz pgm_kprobe
429 oi __TI_flags+7(%r12),_TIF_PER_TRAP
430 mvc __THREAD_per_address(8,%r1),__LC_PER_ADDRESS
431 mvc __THREAD_per_cause(2,%r1),__LC_PER_CAUSE
432 mvc __THREAD_per_paid(1,%r1),__LC_PER_PAID
433 0: REENABLE_IRQS
434 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
435 larl %r1,pgm_check_table
436 llgh %r10,__PT_INT_CODE+2(%r11)
437 nill %r10,0x007f
438 sll %r10,3
439 je sysc_return
440 lg %r1,0(%r10,%r1) # load address of handler routine
441 lgr %r2,%r11 # pass pointer to pt_regs
442 basr %r14,%r1 # branch to interrupt-handler
443 j sysc_return
444
445 #
446 # PER event in supervisor state, must be kprobes
447 #
448 pgm_kprobe:
449 REENABLE_IRQS
450 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
451 lgr %r2,%r11 # pass pointer to pt_regs
452 brasl %r14,do_per_trap
453 j sysc_return
454
455 #
456 # single stepped system call
457 #
458 pgm_svcper:
459 oi __TI_flags+7(%r12),_TIF_PER_TRAP
460 mvc __LC_RETURN_PSW(8),__LC_SVC_NEW_PSW
461 larl %r14,sysc_per
462 stg %r14,__LC_RETURN_PSW+8
463 lpswe __LC_RETURN_PSW # branch to sysc_per and enable irqs
464
465 /*
466 * IO interrupt handler routine
467 */
468 ENTRY(io_int_handler)
469 STCK __LC_INT_CLOCK
470 stpt __LC_ASYNC_ENTER_TIMER
471 stmg %r8,%r15,__LC_SAVE_AREA_ASYNC
472 lg %r10,__LC_LAST_BREAK
473 lg %r12,__LC_THREAD_INFO
474 larl %r13,system_call
475 lmg %r8,%r9,__LC_IO_OLD_PSW
476 HANDLE_SIE_INTERCEPT %r14
477 SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
478 tmhh %r8,0x0001 # interrupting from user?
479 jz io_skip
480 UPDATE_VTIME %r14,__LC_ASYNC_ENTER_TIMER
481 LAST_BREAK %r14
482 io_skip:
483 stmg %r0,%r7,__PT_R0(%r11)
484 mvc __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
485 stmg %r8,%r9,__PT_PSW(%r11)
486 TRACE_IRQS_OFF
487 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
488 lgr %r2,%r11 # pass pointer to pt_regs
489 brasl %r14,do_IRQ
490 io_return:
491 LOCKDEP_SYS_EXIT
492 TRACE_IRQS_ON
493 io_tif:
494 tm __TI_flags+7(%r12),_TIF_WORK_INT
495 jnz io_work # there is work to do (signals etc.)
496 io_restore:
497 lg %r14,__LC_VDSO_PER_CPU
498 lmg %r0,%r10,__PT_R0(%r11)
499 mvc __LC_RETURN_PSW(16),__PT_PSW(%r11)
500 stpt __LC_EXIT_TIMER
501 mvc __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
502 lmg %r11,%r15,__PT_R11(%r11)
503 lpswe __LC_RETURN_PSW
504 io_done:
505
506 #
507 # There is work todo, find out in which context we have been interrupted:
508 # 1) if we return to user space we can do all _TIF_WORK_INT work
509 # 2) if we return to kernel code and kvm is enabled check if we need to
510 # modify the psw to leave SIE
511 # 3) if we return to kernel code and preemptive scheduling is enabled check
512 # the preemption counter and if it is zero call preempt_schedule_irq
513 # Before any work can be done, a switch to the kernel stack is required.
514 #
515 io_work:
516 tm __PT_PSW+1(%r11),0x01 # returning to user ?
517 jo io_work_user # yes -> do resched & signal
518 #ifdef CONFIG_PREEMPT
519 # check for preemptive scheduling
520 icm %r0,15,__TI_precount(%r12)
521 jnz io_restore # preemption is disabled
522 tm __TI_flags+7(%r12),_TIF_NEED_RESCHED
523 jno io_restore
524 # switch to kernel stack
525 lg %r1,__PT_R15(%r11)
526 aghi %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
527 mvc STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
528 xc __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
529 la %r11,STACK_FRAME_OVERHEAD(%r1)
530 lgr %r15,%r1
531 # TRACE_IRQS_ON already done at io_return, call
532 # TRACE_IRQS_OFF to keep things symmetrical
533 TRACE_IRQS_OFF
534 brasl %r14,preempt_schedule_irq
535 j io_return
536 #else
537 j io_restore
538 #endif
539
540 #
541 # Need to do work before returning to userspace, switch to kernel stack
542 #
543 io_work_user:
544 lg %r1,__LC_KERNEL_STACK
545 aghi %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
546 mvc STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
547 xc __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
548 la %r11,STACK_FRAME_OVERHEAD(%r1)
549 lgr %r15,%r1
550
551 #
552 # One of the work bits is on. Find out which one.
553 # Checked are: _TIF_SIGPENDING, _TIF_NOTIFY_RESUME, _TIF_NEED_RESCHED
554 # and _TIF_MCCK_PENDING
555 #
556 io_work_tif:
557 tm __TI_flags+7(%r12),_TIF_MCCK_PENDING
558 jo io_mcck_pending
559 tm __TI_flags+7(%r12),_TIF_NEED_RESCHED
560 jo io_reschedule
561 tm __TI_flags+7(%r12),_TIF_SIGPENDING
562 jo io_sigpending
563 tm __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
564 jo io_notify_resume
565 j io_return # beware of critical section cleanup
566
567 #
568 # _TIF_MCCK_PENDING is set, call handler
569 #
570 io_mcck_pending:
571 # TRACE_IRQS_ON already done at io_return
572 brasl %r14,s390_handle_mcck # TIF bit will be cleared by handler
573 TRACE_IRQS_OFF
574 j io_return
575
576 #
577 # _TIF_NEED_RESCHED is set, call schedule
578 #
579 io_reschedule:
580 # TRACE_IRQS_ON already done at io_return
581 ssm __LC_SVC_NEW_PSW # reenable interrupts
582 brasl %r14,schedule # call scheduler
583 ssm __LC_PGM_NEW_PSW # disable I/O and ext. interrupts
584 TRACE_IRQS_OFF
585 j io_return
586
587 #
588 # _TIF_SIGPENDING or is set, call do_signal
589 #
590 io_sigpending:
591 # TRACE_IRQS_ON already done at io_return
592 ssm __LC_SVC_NEW_PSW # reenable interrupts
593 lgr %r2,%r11 # pass pointer to pt_regs
594 brasl %r14,do_signal
595 ssm __LC_PGM_NEW_PSW # disable I/O and ext. interrupts
596 TRACE_IRQS_OFF
597 j io_return
598
599 #
600 # _TIF_NOTIFY_RESUME or is set, call do_notify_resume
601 #
602 io_notify_resume:
603 # TRACE_IRQS_ON already done at io_return
604 ssm __LC_SVC_NEW_PSW # reenable interrupts
605 lgr %r2,%r11 # pass pointer to pt_regs
606 brasl %r14,do_notify_resume
607 ssm __LC_PGM_NEW_PSW # disable I/O and ext. interrupts
608 TRACE_IRQS_OFF
609 j io_return
610
611 /*
612 * External interrupt handler routine
613 */
614 ENTRY(ext_int_handler)
615 STCK __LC_INT_CLOCK
616 stpt __LC_ASYNC_ENTER_TIMER
617 stmg %r8,%r15,__LC_SAVE_AREA_ASYNC
618 lg %r10,__LC_LAST_BREAK
619 lg %r12,__LC_THREAD_INFO
620 larl %r13,system_call
621 lmg %r8,%r9,__LC_EXT_OLD_PSW
622 HANDLE_SIE_INTERCEPT %r14
623 SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
624 tmhh %r8,0x0001 # interrupting from user ?
625 jz ext_skip
626 UPDATE_VTIME %r14,__LC_ASYNC_ENTER_TIMER
627 LAST_BREAK %r14
628 ext_skip:
629 stmg %r0,%r7,__PT_R0(%r11)
630 mvc __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
631 stmg %r8,%r9,__PT_PSW(%r11)
632 TRACE_IRQS_OFF
633 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
634 lghi %r1,4096
635 lgr %r2,%r11 # pass pointer to pt_regs
636 llgf %r3,__LC_EXT_CPU_ADDR # get cpu address + interruption code
637 llgf %r4,__LC_EXT_PARAMS # get external parameter
638 lg %r5,__LC_EXT_PARAMS2-4096(%r1) # get 64 bit external parameter
639 brasl %r14,do_extint
640 j io_return
641
642 /*
643 * Load idle PSW. The second "half" of this function is in cleanup_idle.
644 */
645 ENTRY(psw_idle)
646 stg %r4,__SF_EMPTY(%r15)
647 larl %r1,psw_idle_lpsw+4
648 stg %r1,__SF_EMPTY+8(%r15)
649 larl %r1,.Lvtimer_max
650 STCK __IDLE_ENTER(%r2)
651 ltr %r5,%r5
652 stpt __VQ_IDLE_ENTER(%r3)
653 jz psw_idle_lpsw
654 spt 0(%r1)
655 psw_idle_lpsw:
656 lpswe __SF_EMPTY(%r15)
657 br %r14
658 psw_idle_end:
659
660 __critical_end:
661
662 /*
663 * Machine check handler routines
664 */
665 ENTRY(mcck_int_handler)
666 STCK __LC_MCCK_CLOCK
667 la %r1,4095 # revalidate r1
668 spt __LC_CPU_TIMER_SAVE_AREA-4095(%r1) # revalidate cpu timer
669 lmg %r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)# revalidate gprs
670 lg %r10,__LC_LAST_BREAK
671 lg %r12,__LC_THREAD_INFO
672 larl %r13,system_call
673 lmg %r8,%r9,__LC_MCK_OLD_PSW
674 HANDLE_SIE_INTERCEPT %r14
675 tm __LC_MCCK_CODE,0x80 # system damage?
676 jo mcck_panic # yes -> rest of mcck code invalid
677 lghi %r14,__LC_CPU_TIMER_SAVE_AREA
678 mvc __LC_MCCK_ENTER_TIMER(8),0(%r14)
679 tm __LC_MCCK_CODE+5,0x02 # stored cpu timer value valid?
680 jo 3f
681 la %r14,__LC_SYNC_ENTER_TIMER
682 clc 0(8,%r14),__LC_ASYNC_ENTER_TIMER
683 jl 0f
684 la %r14,__LC_ASYNC_ENTER_TIMER
685 0: clc 0(8,%r14),__LC_EXIT_TIMER
686 jl 1f
687 la %r14,__LC_EXIT_TIMER
688 1: clc 0(8,%r14),__LC_LAST_UPDATE_TIMER
689 jl 2f
690 la %r14,__LC_LAST_UPDATE_TIMER
691 2: spt 0(%r14)
692 mvc __LC_MCCK_ENTER_TIMER(8),0(%r14)
693 3: tm __LC_MCCK_CODE+2,0x09 # mwp + ia of old psw valid?
694 jno mcck_panic # no -> skip cleanup critical
695 SWITCH_ASYNC __LC_GPREGS_SAVE_AREA+64,__LC_PANIC_STACK,PAGE_SHIFT
696 tm %r8,0x0001 # interrupting from user ?
697 jz mcck_skip
698 UPDATE_VTIME %r14,__LC_MCCK_ENTER_TIMER
699 LAST_BREAK %r14
700 mcck_skip:
701 lghi %r14,__LC_GPREGS_SAVE_AREA
702 mvc __PT_R0(128,%r11),0(%r14)
703 stmg %r8,%r9,__PT_PSW(%r11)
704 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
705 lgr %r2,%r11 # pass pointer to pt_regs
706 brasl %r14,s390_do_machine_check
707 tm __PT_PSW+1(%r11),0x01 # returning to user ?
708 jno mcck_return
709 lg %r1,__LC_KERNEL_STACK # switch to kernel stack
710 aghi %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
711 mvc STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
712 xc __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
713 la %r11,STACK_FRAME_OVERHEAD(%r1)
714 lgr %r15,%r1
715 ssm __LC_PGM_NEW_PSW # turn dat on, keep irqs off
716 tm __TI_flags+7(%r12),_TIF_MCCK_PENDING
717 jno mcck_return
718 TRACE_IRQS_OFF
719 brasl %r14,s390_handle_mcck
720 TRACE_IRQS_ON
721 mcck_return:
722 lg %r14,__LC_VDSO_PER_CPU
723 lmg %r0,%r10,__PT_R0(%r11)
724 mvc __LC_RETURN_MCCK_PSW(16),__PT_PSW(%r11) # move return PSW
725 tm __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
726 jno 0f
727 stpt __LC_EXIT_TIMER
728 mvc __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
729 0: lmg %r11,%r15,__PT_R11(%r11)
730 lpswe __LC_RETURN_MCCK_PSW
731
732 mcck_panic:
733 lg %r14,__LC_PANIC_STACK
734 slgr %r14,%r15
735 srag %r14,%r14,PAGE_SHIFT
736 jz 0f
737 lg %r15,__LC_PANIC_STACK
738 0: aghi %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
739 j mcck_skip
740
741 #
742 # PSW restart interrupt handler
743 #
744 ENTRY(restart_int_handler)
745 stg %r15,__LC_SAVE_AREA_RESTART
746 lg %r15,__LC_RESTART_STACK
747 aghi %r15,-__PT_SIZE # create pt_regs on stack
748 xc 0(__PT_SIZE,%r15),0(%r15)
749 stmg %r0,%r14,__PT_R0(%r15)
750 mvc __PT_R15(8,%r15),__LC_SAVE_AREA_RESTART
751 mvc __PT_PSW(16,%r15),__LC_RST_OLD_PSW # store restart old psw
752 aghi %r15,-STACK_FRAME_OVERHEAD # create stack frame on stack
753 xc 0(STACK_FRAME_OVERHEAD,%r15),0(%r15)
754 lg %r1,__LC_RESTART_FN # load fn, parm & source cpu
755 lg %r2,__LC_RESTART_DATA
756 lg %r3,__LC_RESTART_SOURCE
757 ltgr %r3,%r3 # test source cpu address
758 jm 1f # negative -> skip source stop
759 0: sigp %r4,%r3,SIGP_SENSE # sigp sense to source cpu
760 brc 10,0b # wait for status stored
761 1: basr %r14,%r1 # call function
762 stap __SF_EMPTY(%r15) # store cpu address
763 llgh %r3,__SF_EMPTY(%r15)
764 2: sigp %r4,%r3,SIGP_STOP # sigp stop to current cpu
765 brc 2,2b
766 3: j 3b
767
768 .section .kprobes.text, "ax"
769
770 #ifdef CONFIG_CHECK_STACK
771 /*
772 * The synchronous or the asynchronous stack overflowed. We are dead.
773 * No need to properly save the registers, we are going to panic anyway.
774 * Setup a pt_regs so that show_trace can provide a good call trace.
775 */
776 stack_overflow:
777 lg %r11,__LC_PANIC_STACK # change to panic stack
778 aghi %r11,-__PT_SIZE # create pt_regs
779 stmg %r0,%r7,__PT_R0(%r11)
780 stmg %r8,%r9,__PT_PSW(%r11)
781 mvc __PT_R8(64,%r11),0(%r14)
782 stg %r10,__PT_ORIG_GPR2(%r11) # store last break to orig_gpr2
783 lgr %r15,%r11
784 aghi %r15,-STACK_FRAME_OVERHEAD
785 xc __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
786 lgr %r2,%r11 # pass pointer to pt_regs
787 jg kernel_stack_overflow
788 #endif
789
790 .align 8
791 cleanup_table:
792 .quad system_call
793 .quad sysc_do_svc
794 .quad sysc_tif
795 .quad sysc_restore
796 .quad sysc_done
797 .quad io_tif
798 .quad io_restore
799 .quad io_done
800 .quad psw_idle
801 .quad psw_idle_end
802
803 cleanup_critical:
804 clg %r9,BASED(cleanup_table) # system_call
805 jl 0f
806 clg %r9,BASED(cleanup_table+8) # sysc_do_svc
807 jl cleanup_system_call
808 clg %r9,BASED(cleanup_table+16) # sysc_tif
809 jl 0f
810 clg %r9,BASED(cleanup_table+24) # sysc_restore
811 jl cleanup_sysc_tif
812 clg %r9,BASED(cleanup_table+32) # sysc_done
813 jl cleanup_sysc_restore
814 clg %r9,BASED(cleanup_table+40) # io_tif
815 jl 0f
816 clg %r9,BASED(cleanup_table+48) # io_restore
817 jl cleanup_io_tif
818 clg %r9,BASED(cleanup_table+56) # io_done
819 jl cleanup_io_restore
820 clg %r9,BASED(cleanup_table+64) # psw_idle
821 jl 0f
822 clg %r9,BASED(cleanup_table+72) # psw_idle_end
823 jl cleanup_idle
824 0: br %r14
825
826
827 cleanup_system_call:
828 # check if stpt has been executed
829 clg %r9,BASED(cleanup_system_call_insn)
830 jh 0f
831 mvc __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
832 cghi %r11,__LC_SAVE_AREA_ASYNC
833 je 0f
834 mvc __LC_SYNC_ENTER_TIMER(8),__LC_MCCK_ENTER_TIMER
835 0: # check if stmg has been executed
836 clg %r9,BASED(cleanup_system_call_insn+8)
837 jh 0f
838 mvc __LC_SAVE_AREA_SYNC(64),0(%r11)
839 0: # check if base register setup + TIF bit load has been done
840 clg %r9,BASED(cleanup_system_call_insn+16)
841 jhe 0f
842 # set up saved registers r10 and r12
843 stg %r10,16(%r11) # r10 last break
844 stg %r12,32(%r11) # r12 thread-info pointer
845 0: # check if the user time update has been done
846 clg %r9,BASED(cleanup_system_call_insn+24)
847 jh 0f
848 lg %r15,__LC_EXIT_TIMER
849 slg %r15,__LC_SYNC_ENTER_TIMER
850 alg %r15,__LC_USER_TIMER
851 stg %r15,__LC_USER_TIMER
852 0: # check if the system time update has been done
853 clg %r9,BASED(cleanup_system_call_insn+32)
854 jh 0f
855 lg %r15,__LC_LAST_UPDATE_TIMER
856 slg %r15,__LC_EXIT_TIMER
857 alg %r15,__LC_SYSTEM_TIMER
858 stg %r15,__LC_SYSTEM_TIMER
859 0: # update accounting time stamp
860 mvc __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
861 # do LAST_BREAK
862 lg %r9,16(%r11)
863 srag %r9,%r9,23
864 jz 0f
865 mvc __TI_last_break(8,%r12),16(%r11)
866 0: # set up saved register r11
867 lg %r15,__LC_KERNEL_STACK
868 aghi %r15,-__PT_SIZE
869 stg %r15,24(%r11) # r11 pt_regs pointer
870 # fill pt_regs
871 mvc __PT_R8(64,%r15),__LC_SAVE_AREA_SYNC
872 stmg %r0,%r7,__PT_R0(%r15)
873 mvc __PT_PSW(16,%r15),__LC_SVC_OLD_PSW
874 mvc __PT_INT_CODE(4,%r15),__LC_SVC_ILC
875 # setup saved register r15
876 aghi %r15,-STACK_FRAME_OVERHEAD
877 stg %r15,56(%r11) # r15 stack pointer
878 # set new psw address and exit
879 larl %r9,sysc_do_svc
880 br %r14
881 cleanup_system_call_insn:
882 .quad system_call
883 .quad sysc_stmg
884 .quad sysc_per
885 .quad sysc_vtime+18
886 .quad sysc_vtime+42
887
888 cleanup_sysc_tif:
889 larl %r9,sysc_tif
890 br %r14
891
892 cleanup_sysc_restore:
893 clg %r9,BASED(cleanup_sysc_restore_insn)
894 je 0f
895 lg %r9,24(%r11) # get saved pointer to pt_regs
896 mvc __LC_RETURN_PSW(16),__PT_PSW(%r9)
897 mvc 0(64,%r11),__PT_R8(%r9)
898 lmg %r0,%r7,__PT_R0(%r9)
899 0: lmg %r8,%r9,__LC_RETURN_PSW
900 br %r14
901 cleanup_sysc_restore_insn:
902 .quad sysc_done - 4
903
904 cleanup_io_tif:
905 larl %r9,io_tif
906 br %r14
907
908 cleanup_io_restore:
909 clg %r9,BASED(cleanup_io_restore_insn)
910 je 0f
911 lg %r9,24(%r11) # get saved r11 pointer to pt_regs
912 mvc __LC_RETURN_PSW(16),__PT_PSW(%r9)
913 mvc 0(64,%r11),__PT_R8(%r9)
914 lmg %r0,%r7,__PT_R0(%r9)
915 0: lmg %r8,%r9,__LC_RETURN_PSW
916 br %r14
917 cleanup_io_restore_insn:
918 .quad io_done - 4
919
920 cleanup_idle:
921 # copy interrupt clock & cpu timer
922 mvc __IDLE_EXIT(8,%r2),__LC_INT_CLOCK
923 mvc __VQ_IDLE_EXIT(8,%r3),__LC_ASYNC_ENTER_TIMER
924 cghi %r11,__LC_SAVE_AREA_ASYNC
925 je 0f
926 mvc __IDLE_EXIT(8,%r2),__LC_MCCK_CLOCK
927 mvc __VQ_IDLE_EXIT(8,%r3),__LC_MCCK_ENTER_TIMER
928 0: # check if stck & stpt have been executed
929 clg %r9,BASED(cleanup_idle_insn)
930 jhe 1f
931 mvc __IDLE_ENTER(8,%r2),__IDLE_EXIT(%r2)
932 mvc __VQ_IDLE_ENTER(8,%r3),__VQ_IDLE_EXIT(%r3)
933 j 2f
934 1: # check if the cpu timer has been reprogrammed
935 ltr %r5,%r5
936 jz 2f
937 spt __VQ_IDLE_ENTER(%r3)
938 2: # account system time going idle
939 lg %r9,__LC_STEAL_TIMER
940 alg %r9,__IDLE_ENTER(%r2)
941 slg %r9,__LC_LAST_UPDATE_CLOCK
942 stg %r9,__LC_STEAL_TIMER
943 mvc __LC_LAST_UPDATE_CLOCK(8),__IDLE_EXIT(%r2)
944 lg %r9,__LC_SYSTEM_TIMER
945 alg %r9,__LC_LAST_UPDATE_TIMER
946 slg %r9,__VQ_IDLE_ENTER(%r3)
947 stg %r9,__LC_SYSTEM_TIMER
948 mvc __LC_LAST_UPDATE_TIMER(8),__VQ_IDLE_EXIT(%r3)
949 # prepare return psw
950 nihh %r8,0xfffd # clear wait state bit
951 lg %r9,48(%r11) # return from psw_idle
952 br %r14
953 cleanup_idle_insn:
954 .quad psw_idle_lpsw
955
956 /*
957 * Integer constants
958 */
959 .align 8
960 .Lcritical_start:
961 .quad __critical_start
962 .Lcritical_length:
963 .quad __critical_end - __critical_start
964 .Lvtimer_max:
965 .quad 0x7fffffffffffffff
966
967
968 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
969 /*
970 * sie64a calling convention:
971 * %r2 pointer to sie control block
972 * %r3 guest register save area
973 */
974 ENTRY(sie64a)
975 stmg %r6,%r14,__SF_GPRS(%r15) # save kernel registers
976 stg %r2,__SF_EMPTY(%r15) # save control block pointer
977 stg %r3,__SF_EMPTY+8(%r15) # save guest register save area
978 xc __SF_EMPTY+16(8,%r15),__SF_EMPTY+16(%r15) # host id == 0
979 lmg %r0,%r13,0(%r3) # load guest gprs 0-13
980 sie_loop:
981 lg %r14,__LC_THREAD_INFO # pointer thread_info struct
982 tm __TI_flags+7(%r14),_TIF_EXIT_SIE
983 jnz sie_exit
984 lg %r14,__LC_GMAP # get gmap pointer
985 ltgr %r14,%r14
986 jz sie_gmap
987 lctlg %c1,%c1,__GMAP_ASCE(%r14) # load primary asce
988 sie_gmap:
989 lg %r14,__SF_EMPTY(%r15) # get control block pointer
990 SPP __SF_EMPTY(%r15) # set guest id
991 sie 0(%r14)
992 sie_done:
993 SPP __SF_EMPTY+16(%r15) # set host id
994 lg %r14,__LC_THREAD_INFO # pointer thread_info struct
995 sie_exit:
996 lctlg %c1,%c1,__LC_USER_ASCE # load primary asce
997 lg %r14,__SF_EMPTY+8(%r15) # load guest register save area
998 stmg %r0,%r13,0(%r14) # save guest gprs 0-13
999 lmg %r6,%r14,__SF_GPRS(%r15) # restore kernel registers
1000 lghi %r2,0
1001 br %r14
1002 sie_fault:
1003 lctlg %c1,%c1,__LC_USER_ASCE # load primary asce
1004 lg %r14,__LC_THREAD_INFO # pointer thread_info struct
1005 lg %r14,__SF_EMPTY+8(%r15) # load guest register save area
1006 stmg %r0,%r13,0(%r14) # save guest gprs 0-13
1007 lmg %r6,%r14,__SF_GPRS(%r15) # restore kernel registers
1008 lghi %r2,-EFAULT
1009 br %r14
1010
1011 .align 8
1012 .Lsie_loop:
1013 .quad sie_loop
1014 .Lsie_length:
1015 .quad sie_done - sie_loop
1016 .Lhost_id:
1017 .quad 0
1018
1019 .section __ex_table,"a"
1020 .quad sie_loop,sie_fault
1021 .previous
1022 #endif
1023
1024 .section .rodata, "a"
1025 #define SYSCALL(esa,esame,emu) .long esame
1026 .globl sys_call_table
1027 sys_call_table:
1028 #include "syscalls.S"
1029 #undef SYSCALL
1030
1031 #ifdef CONFIG_COMPAT
1032
1033 #define SYSCALL(esa,esame,emu) .long emu
1034 sys_call_table_emu:
1035 #include "syscalls.S"
1036 #undef SYSCALL
1037 #endif
Linux kernel - Deliverables
This page took 0.052955 seconds and 5 git commands to generate.