arch/sh64/kernel/vmlinux.lds.S

   1 /*
   2  * This file is subject to the terms and conditions of the GNU General Public
   3  * License.  See the file "COPYING" in the main directory of this archive
   4  * for more details.
   5  *
   6  * arch/sh5/vmlinux.lds.S
   7  *
   8  * ld script to make ST50 Linux kernel
   9  *
  10  * Copyright (C) 2000, 2001  Paolo Alberelli
  11  *
  12  * benedict.gaster@superh.com:   2nd May 2002
  13  *    Add definition of empty_zero_page to be the first page of kernel image.
  14  *
  15  * benedict.gaster@superh.com:   3rd May 2002
  16  *    Added support for ramdisk, removing statically linked romfs at the same time.
  17  *
  18  * lethal@linux-sh.org:          9th May 2003
  19  *    Kill off GLOBAL_NAME() usage and other CDC-isms.
  20  *
  21  * lethal@linux-sh.org:         19th May 2003
  22  *    Remove support for ancient toolchains.
  23  */
  24
  25 #include <asm/page.h>
  26 #include <asm/cache.h>
  27 #include <asm/processor.h>
  28 #include <asm/thread_info.h>
  29
  30 #define LOAD_OFFSET     CONFIG_CACHED_MEMORY_OFFSET
  31 #include <asm-generic/vmlinux.lds.h>
  32
  33 #ifdef NOTDEF
  34 #ifdef CONFIG_LITTLE_ENDIAN
  35 OUTPUT_FORMAT("elf32-sh64l-linux", "elf32-sh64l-linux", "elf32-sh64l-linux")
  36 #else
  37 OUTPUT_FORMAT("elf32-sh64", "elf32-sh64", "elf32-sh64")
  38 #endif
  39 #endif
  40
  41 OUTPUT_ARCH(sh:sh5)
  42
  43 #define C_PHYS(x) AT (ADDR(x) - LOAD_OFFSET)
  44
  45 ENTRY(__start)
  46 SECTIONS
  47 {
  48   . = CONFIG_CACHED_MEMORY_OFFSET + CONFIG_MEMORY_START + PAGE_SIZE;
  49   _text = .;                    /* Text and read-only data */
  50   text = .;                     /* Text and read-only data */
  51
  52   .empty_zero_page : C_PHYS(.empty_zero_page) {
  53         *(.empty_zero_page)
  54         } = 0
  55
  56   .text : C_PHYS(.text) {
  57         *(.text)
  58         *(.text64)
  59         *(.text..SHmedia32)
  60         SCHED_TEXT
  61         LOCK_TEXT
  62         *(.fixup)
  63         *(.gnu.warning)
  64 #ifdef CONFIG_LITTLE_ENDIAN
  65         } = 0x6ff0fff0
  66 #else
  67         } = 0xf0fff06f
  68 #endif
  69
  70   /* We likely want __ex_table to be Cache Line aligned */
  71   . = ALIGN(L1_CACHE_BYTES);            /* Exception table */
  72   __start___ex_table = .;
  73   __ex_table : C_PHYS(__ex_table) { *(__ex_table) }
  74   __stop___ex_table = .;
  75
  76   RODATA
  77
  78   _etext = .;                   /* End of text section */
  79
  80   .data : C_PHYS(.data) {                       /* Data */
  81         *(.data)
  82         CONSTRUCTORS
  83         }
  84
  85   . = ALIGN(PAGE_SIZE);
  86   .data.page_aligned : C_PHYS(.data.page_aligned) { *(.data.page_aligned) }
  87
  88   . = ALIGN(L1_CACHE_BYTES);
  89   __per_cpu_start = .;
  90   .data.percpu : C_PHYS(.data.percpu) { *(.data.percpu) }
  91   __per_cpu_end = . ;
  92   .data.cacheline_aligned : C_PHYS(.data.cacheline_aligned) { *(.data.cacheline_aligned) }
  93
  94   _edata = .;                   /* End of data section */
  95
  96   . = ALIGN(THREAD_SIZE);       /* init_task: structure size aligned */
  97   .data.init_task : C_PHYS(.data.init_task) { *(.data.init_task) }
  98
  99   . = ALIGN(PAGE_SIZE);         /* Init code and data */
 100   __init_begin = .;
 101   _sinittext = .;
 102   .init.text : C_PHYS(.init.text) { *(.init.text) }
 103   _einittext = .;
 104   .init.data : C_PHYS(.init.data) { *(.init.data) }
 105   . = ALIGN(L1_CACHE_BYTES);    /* Better if Cache Line aligned */
 106   __setup_start = .;
 107   .init.setup : C_PHYS(.init.setup) { *(.init.setup) }
 108   __setup_end = .;
 109   __initcall_start = .;
 110   .initcall.init : C_PHYS(.initcall.init) {
 111         INITCALLS
 112   }
 113   __initcall_end = .;
 114   __con_initcall_start = .;
 115   .con_initcall.init : C_PHYS(.con_initcall.init) { *(.con_initcall.init) }
 116   __con_initcall_end = .;
 117   SECURITY_INIT
 118   __initramfs_start = .;
 119   .init.ramfs : C_PHYS(.init.ramfs) { *(.init.ramfs) }
 120   __initramfs_end = .;
 121   . = ALIGN(PAGE_SIZE);
 122   __init_end = .;
 123
 124   /* Align to the biggest single data representation, head and tail */
 125   . = ALIGN(8);
 126   __bss_start = .;              /* BSS */
 127   .bss : C_PHYS(.bss) {
 128         *(.bss)
 129         }
 130   . = ALIGN(8);
 131   _end = . ;
 132
 133   /* Sections to be discarded */
 134   /DISCARD/ : {
 135         *(.exit.text)
 136         *(.exit.data)
 137         *(.exitcall.exit)
 138         }
 139
 140   /* Stabs debugging sections.  */
 141   .stab 0 : C_PHYS(.stab) { *(.stab) }
 142   .stabstr 0 : C_PHYS(.stabstr) { *(.stabstr) }
 143   .stab.excl 0 : C_PHYS(.stab.excl) { *(.stab.excl) }
 144   .stab.exclstr 0 : C_PHYS(.stab.exclstr) { *(.stab.exclstr) }
 145   .stab.index 0 : C_PHYS(.stab.index) { *(.stab.index) }
 146   .stab.indexstr 0 : C_PHYS(.stab.indexstr) { *(.stab.indexstr) }
 147   .comment 0 : C_PHYS(.comment) { *(.comment) }
 148   /* DWARF debug sections.
 149      Symbols in the DWARF debugging section are relative to the beginning
 150      of the section so we begin .debug at 0.  */
 151   /* DWARF 1 */
 152   .debug          0 : C_PHYS(.debug) { *(.debug) }
 153   .line           0 : C_PHYS(.line) { *(.line) }
 154   /* GNU DWARF 1 extensions */
 155   .debug_srcinfo  0 : C_PHYS(.debug_srcinfo) { *(.debug_srcinfo) }
 156   .debug_sfnames  0 : C_PHYS(.debug_sfnames) { *(.debug_sfnames) }
 157   /* DWARF 1.1 and DWARF 2 */
 158   .debug_aranges  0 : C_PHYS(.debug_aranges) { *(.debug_aranges) }
 159   .debug_pubnames 0 : C_PHYS(.debug_pubnames) { *(.debug_pubnames) }
 160   /* DWARF 2 */
 161   .debug_info     0 : C_PHYS(.debug_info) { *(.debug_info) }
 162   .debug_abbrev   0 : C_PHYS(.debug_abbrev) { *(.debug_abbrev) }
 163   .debug_line     0 : C_PHYS(.debug_line) { *(.debug_line) }
 164   .debug_frame    0 : C_PHYS(.debug_frame) { *(.debug_frame) }
 165   .debug_str      0 : C_PHYS(.debug_str) { *(.debug_str) }
 166   .debug_loc      0 : C_PHYS(.debug_loc) { *(.debug_loc) }
 167   .debug_macinfo  0 : C_PHYS(.debug_macinfo) { *(.debug_macinfo) }
 168   /* SGI/MIPS DWARF 2 extensions */
 169   .debug_weaknames 0 : C_PHYS(.debug_weaknames) { *(.debug_weaknames) }
 170   .debug_funcnames 0 : C_PHYS(.debug_funcnames) { *(.debug_funcnames) }
 171   .debug_typenames 0 : C_PHYS(.debug_typenames) { *(.debug_typenames) }
 172   .debug_varnames  0 : C_PHYS(.debug_varnames) { *(.debug_varnames) }
 173   /* These must appear regardless of  .  */
 174 }