arch/sparc/kernel/sys32.S

   1 /*
   2  * sys32.S: I-cache tricks for 32-bit compatibility layer simple
   3  *          conversions.
   4  *
   5  * Copyright (C) 1997 David S. Miller (davem@caip.rutgers.edu)
   6  * Copyright (C) 1998 Jakub Jelinek   (jj@ultra.linux.cz)
   7  */
   8
   9 #include <asm/errno.h>
  10
  11 /* NOTE: call as jump breaks return stack, we have to avoid that */
  12
  13         .text
  14
  15 #define SIGN1(STUB,SYSCALL,REG1) \
  16         .align  32; \
  17         .globl  STUB; \
  18 STUB:   sethi   %hi(SYSCALL), %g1; \
  19         jmpl    %g1 + %lo(SYSCALL), %g0; \
  20         sra     REG1, 0, REG1
  21
  22 #define SIGN2(STUB,SYSCALL,REG1,REG2) \
  23         .align  32; \
  24         .globl  STUB; \
  25 STUB:   sethi   %hi(SYSCALL), %g1; \
  26         sra     REG1, 0, REG1; \
  27         jmpl    %g1 + %lo(SYSCALL), %g0; \
  28         sra     REG2, 0, REG2
  29
  30 #define SIGN3(STUB,SYSCALL,REG1,REG2,REG3) \
  31         .align  32; \
  32         .globl  STUB; \
  33 STUB:   sra     REG1, 0, REG1; \
  34         sethi   %hi(SYSCALL), %g1; \
  35         sra     REG2, 0, REG2; \
  36         jmpl    %g1 + %lo(SYSCALL), %g0; \
  37         sra     REG3, 0, REG3
  38
  39 SIGN1(sys32_readahead, compat_sys_readahead, %o0)
  40 SIGN2(sys32_fadvise64, compat_sys_fadvise64, %o0, %o4)
  41 SIGN2(sys32_fadvise64_64, compat_sys_fadvise64_64, %o0, %o5)
  42 SIGN1(sys32_clock_nanosleep, compat_sys_clock_nanosleep, %o1)
  43 SIGN1(sys32_timer_settime, compat_sys_timer_settime, %o1)
  44 SIGN1(sys32_io_submit, compat_sys_io_submit, %o1)
  45 SIGN1(sys32_mq_open, compat_sys_mq_open, %o1)
  46 SIGN1(sys32_select, compat_sys_select, %o0)
  47 SIGN1(sys32_futex, compat_sys_futex, %o1)
  48 SIGN1(sys32_recvfrom, compat_sys_recvfrom, %o0)
  49 SIGN1(sys32_recvmsg, compat_sys_recvmsg, %o0)
  50 SIGN1(sys32_sendmsg, compat_sys_sendmsg, %o0)
  51 SIGN2(sys32_renameat2, sys_renameat2, %o0, %o2)
  52
  53         .globl          sys32_mmap2
  54 sys32_mmap2:
  55         sethi           %hi(sys_mmap), %g1
  56         jmpl            %g1 + %lo(sys_mmap), %g0
  57          sllx           %o5, 12, %o5
  58
  59         .align          32
  60         .globl          sys32_socketcall
  61 sys32_socketcall:       /* %o0=call, %o1=args */
  62         cmp             %o0, 1
  63         bl,pn           %xcc, do_einval
  64          cmp            %o0, 18
  65         bg,pn           %xcc, do_einval
  66          sub            %o0, 1, %o0
  67         sllx            %o0, 5, %o0
  68         sethi           %hi(__socketcall_table_begin), %g2
  69         or              %g2, %lo(__socketcall_table_begin), %g2
  70         jmpl            %g2 + %o0, %g0
  71          nop
  72 do_einval:
  73         retl
  74          mov            -EINVAL, %o0
  75
  76         .align          32
  77 __socketcall_table_begin:
  78
  79         /* Each entry is exactly 32 bytes. */
  80 do_sys_socket: /* sys_socket(int, int, int) */
  81 1:      ldswa           [%o1 + 0x0] %asi, %o0
  82         sethi           %hi(sys_socket), %g1
  83 2:      ldswa           [%o1 + 0x8] %asi, %o2
  84         jmpl            %g1 + %lo(sys_socket), %g0
  85 3:       ldswa          [%o1 + 0x4] %asi, %o1
  86         nop
  87         nop
  88         nop
  89 do_sys_bind: /* sys_bind(int fd, struct sockaddr *, int) */
  90 4:      ldswa           [%o1 + 0x0] %asi, %o0
  91         sethi           %hi(sys_bind), %g1
  92 5:      ldswa           [%o1 + 0x8] %asi, %o2
  93         jmpl            %g1 + %lo(sys_bind), %g0
  94 6:       lduwa          [%o1 + 0x4] %asi, %o1
  95         nop
  96         nop
  97         nop
  98 do_sys_connect: /* sys_connect(int, struct sockaddr *, int) */
  99 7:      ldswa           [%o1 + 0x0] %asi, %o0
 100         sethi           %hi(sys_connect), %g1
 101 8:      ldswa           [%o1 + 0x8] %asi, %o2
 102         jmpl            %g1 + %lo(sys_connect), %g0
 103 9:       lduwa          [%o1 + 0x4] %asi, %o1
 104         nop
 105         nop
 106         nop
 107 do_sys_listen: /* sys_listen(int, int) */
 108 10:     ldswa           [%o1 + 0x0] %asi, %o0
 109         sethi           %hi(sys_listen), %g1
 110         jmpl            %g1 + %lo(sys_listen), %g0
 111 11:      ldswa          [%o1 + 0x4] %asi, %o1
 112         nop
 113         nop
 114         nop
 115         nop
 116 do_sys_accept: /* sys_accept(int, struct sockaddr *, int *) */
 117 12:     ldswa           [%o1 + 0x0] %asi, %o0
 118         sethi           %hi(sys_accept), %g1
 119 13:     lduwa           [%o1 + 0x8] %asi, %o2
 120         jmpl            %g1 + %lo(sys_accept), %g0
 121 14:      lduwa          [%o1 + 0x4] %asi, %o1
 122         nop
 123         nop
 124         nop
 125 do_sys_getsockname: /* sys_getsockname(int, struct sockaddr *, int *) */
 126 15:     ldswa           [%o1 + 0x0] %asi, %o0
 127         sethi           %hi(sys_getsockname), %g1
 128 16:     lduwa           [%o1 + 0x8] %asi, %o2
 129         jmpl            %g1 + %lo(sys_getsockname), %g0
 130 17:      lduwa          [%o1 + 0x4] %asi, %o1
 131         nop
 132         nop
 133         nop
 134 do_sys_getpeername: /* sys_getpeername(int, struct sockaddr *, int *) */
 135 18:     ldswa           [%o1 + 0x0] %asi, %o0
 136         sethi           %hi(sys_getpeername), %g1
 137 19:     lduwa           [%o1 + 0x8] %asi, %o2
 138         jmpl            %g1 + %lo(sys_getpeername), %g0
 139 20:      lduwa          [%o1 + 0x4] %asi, %o1
 140         nop
 141         nop
 142         nop
 143 do_sys_socketpair: /* sys_socketpair(int, int, int, int *) */
 144 21:     ldswa           [%o1 + 0x0] %asi, %o0
 145         sethi           %hi(sys_socketpair), %g1
 146 22:     ldswa           [%o1 + 0x8] %asi, %o2
 147 23:     lduwa           [%o1 + 0xc] %asi, %o3
 148         jmpl            %g1 + %lo(sys_socketpair), %g0
 149 24:      ldswa          [%o1 + 0x4] %asi, %o1
 150         nop
 151         nop
 152 do_sys_send: /* sys_send(int, void *, size_t, unsigned int) */
 153 25:     ldswa           [%o1 + 0x0] %asi, %o0
 154         sethi           %hi(sys_send), %g1
 155 26:     lduwa           [%o1 + 0x8] %asi, %o2
 156 27:     lduwa           [%o1 + 0xc] %asi, %o3
 157         jmpl            %g1 + %lo(sys_send), %g0
 158 28:      lduwa          [%o1 + 0x4] %asi, %o1
 159         nop
 160         nop
 161 do_sys_recv: /* sys_recv(int, void *, size_t, unsigned int) */
 162 29:     ldswa           [%o1 + 0x0] %asi, %o0
 163         sethi           %hi(sys_recv), %g1
 164 30:     lduwa           [%o1 + 0x8] %asi, %o2
 165 31:     lduwa           [%o1 + 0xc] %asi, %o3
 166         jmpl            %g1 + %lo(sys_recv), %g0
 167 32:      lduwa          [%o1 + 0x4] %asi, %o1
 168         nop
 169         nop
 170 do_sys_sendto: /* sys_sendto(int, u32, compat_size_t, unsigned int, u32, int) */
 171 33:     ldswa           [%o1 + 0x0] %asi, %o0
 172         sethi           %hi(sys_sendto), %g1
 173 34:     lduwa           [%o1 + 0x8] %asi, %o2
 174 35:     lduwa           [%o1 + 0xc] %asi, %o3
 175 36:     lduwa           [%o1 + 0x10] %asi, %o4
 176 37:     ldswa           [%o1 + 0x14] %asi, %o5
 177         jmpl            %g1 + %lo(sys_sendto), %g0
 178 38:      lduwa          [%o1 + 0x4] %asi, %o1
 179 do_sys_recvfrom: /* sys_recvfrom(int, u32, compat_size_t, unsigned int, u32, u32) */
 180 39:     ldswa           [%o1 + 0x0] %asi, %o0
 181         sethi           %hi(sys_recvfrom), %g1
 182 40:     lduwa           [%o1 + 0x8] %asi, %o2
 183 41:     lduwa           [%o1 + 0xc] %asi, %o3
 184 42:     lduwa           [%o1 + 0x10] %asi, %o4
 185 43:     lduwa           [%o1 + 0x14] %asi, %o5
 186         jmpl            %g1 + %lo(sys_recvfrom), %g0
 187 44:      lduwa          [%o1 + 0x4] %asi, %o1
 188 do_sys_shutdown: /* sys_shutdown(int, int) */
 189 45:     ldswa           [%o1 + 0x0] %asi, %o0
 190         sethi           %hi(sys_shutdown), %g1
 191         jmpl            %g1 + %lo(sys_shutdown), %g0
 192 46:      ldswa          [%o1 + 0x4] %asi, %o1
 193         nop
 194         nop
 195         nop
 196         nop
 197 do_sys_setsockopt: /* compat_sys_setsockopt(int, int, int, char *, int) */
 198 47:     ldswa           [%o1 + 0x0] %asi, %o0
 199         sethi           %hi(compat_sys_setsockopt), %g1
 200 48:     ldswa           [%o1 + 0x8] %asi, %o2
 201 49:     lduwa           [%o1 + 0xc] %asi, %o3
 202 50:     ldswa           [%o1 + 0x10] %asi, %o4
 203         jmpl            %g1 + %lo(compat_sys_setsockopt), %g0
 204 51:      ldswa          [%o1 + 0x4] %asi, %o1
 205         nop
 206 do_sys_getsockopt: /* compat_sys_getsockopt(int, int, int, u32, u32) */
 207 52:     ldswa           [%o1 + 0x0] %asi, %o0
 208         sethi           %hi(compat_sys_getsockopt), %g1
 209 53:     ldswa           [%o1 + 0x8] %asi, %o2
 210 54:     lduwa           [%o1 + 0xc] %asi, %o3
 211 55:     lduwa           [%o1 + 0x10] %asi, %o4
 212         jmpl            %g1 + %lo(compat_sys_getsockopt), %g0
 213 56:      ldswa          [%o1 + 0x4] %asi, %o1
 214         nop
 215 do_sys_sendmsg: /* compat_sys_sendmsg(int, struct compat_msghdr *, unsigned int) */
 216 57:     ldswa           [%o1 + 0x0] %asi, %o0
 217         sethi           %hi(compat_sys_sendmsg), %g1
 218 58:     lduwa           [%o1 + 0x8] %asi, %o2
 219         jmpl            %g1 + %lo(compat_sys_sendmsg), %g0
 220 59:      lduwa          [%o1 + 0x4] %asi, %o1
 221         nop
 222         nop
 223         nop
 224 do_sys_recvmsg: /* compat_sys_recvmsg(int, struct compat_msghdr *, unsigned int) */
 225 60:     ldswa           [%o1 + 0x0] %asi, %o0
 226         sethi           %hi(compat_sys_recvmsg), %g1
 227 61:     lduwa           [%o1 + 0x8] %asi, %o2
 228         jmpl            %g1 + %lo(compat_sys_recvmsg), %g0
 229 62:      lduwa          [%o1 + 0x4] %asi, %o1
 230         nop
 231         nop
 232         nop
 233 do_sys_accept4: /* sys_accept4(int, struct sockaddr *, int *, int) */
 234 63:     ldswa           [%o1 + 0x0] %asi, %o0
 235         sethi           %hi(sys_accept4), %g1
 236 64:     lduwa           [%o1 + 0x8] %asi, %o2
 237 65:     ldswa           [%o1 + 0xc] %asi, %o3
 238         jmpl            %g1 + %lo(sys_accept4), %g0
 239 66:      lduwa          [%o1 + 0x4] %asi, %o1
 240         nop
 241         nop
 242
 243         .section        __ex_table,"a"
 244         .align          4
 245         .word           1b, __retl_efault, 2b, __retl_efault
 246         .word           3b, __retl_efault, 4b, __retl_efault
 247         .word           5b, __retl_efault, 6b, __retl_efault
 248         .word           7b, __retl_efault, 8b, __retl_efault
 249         .word           9b, __retl_efault, 10b, __retl_efault
 250         .word           11b, __retl_efault, 12b, __retl_efault
 251         .word           13b, __retl_efault, 14b, __retl_efault
 252         .word           15b, __retl_efault, 16b, __retl_efault
 253         .word           17b, __retl_efault, 18b, __retl_efault
 254         .word           19b, __retl_efault, 20b, __retl_efault
 255         .word           21b, __retl_efault, 22b, __retl_efault
 256         .word           23b, __retl_efault, 24b, __retl_efault
 257         .word           25b, __retl_efault, 26b, __retl_efault
 258         .word           27b, __retl_efault, 28b, __retl_efault
 259         .word           29b, __retl_efault, 30b, __retl_efault
 260         .word           31b, __retl_efault, 32b, __retl_efault
 261         .word           33b, __retl_efault, 34b, __retl_efault
 262         .word           35b, __retl_efault, 36b, __retl_efault
 263         .word           37b, __retl_efault, 38b, __retl_efault
 264         .word           39b, __retl_efault, 40b, __retl_efault
 265         .word           41b, __retl_efault, 42b, __retl_efault
 266         .word           43b, __retl_efault, 44b, __retl_efault
 267         .word           45b, __retl_efault, 46b, __retl_efault
 268         .word           47b, __retl_efault, 48b, __retl_efault
 269         .word           49b, __retl_efault, 50b, __retl_efault
 270         .word           51b, __retl_efault, 52b, __retl_efault
 271         .word           53b, __retl_efault, 54b, __retl_efault
 272         .word           55b, __retl_efault, 56b, __retl_efault
 273         .word           57b, __retl_efault, 58b, __retl_efault
 274         .word           59b, __retl_efault, 60b, __retl_efault
 275         .word           61b, __retl_efault, 62b, __retl_efault
 276         .word           63b, __retl_efault, 64b, __retl_efault
 277         .word           65b, __retl_efault, 66b, __retl_efault
 278         .previous