arch/sparc/kernel/sys32.S

   1 /*
   2  * sys32.S: I-cache tricks for 32-bit compatibility layer simple
   3  *          conversions.
   4  *
   5  * Copyright (C) 1997 David S. Miller (davem@caip.rutgers.edu)
   6  * Copyright (C) 1998 Jakub Jelinek   (jj@ultra.linux.cz)
   7  */
   8
   9 #include <asm/errno.h>
  10
  11 /* NOTE: call as jump breaks return stack, we have to avoid that */
  12
  13         .text
  14
  15 #define SIGN1(STUB,SYSCALL,REG1) \
  16         .align  32; \
  17         .globl  STUB; \
  18 STUB:   sethi   %hi(SYSCALL), %g1; \
  19         jmpl    %g1 + %lo(SYSCALL), %g0; \
  20         sra     REG1, 0, REG1
  21
  22 #define SIGN2(STUB,SYSCALL,REG1,REG2) \
  23         .align  32; \
  24         .globl  STUB; \
  25 STUB:   sethi   %hi(SYSCALL), %g1; \
  26         sra     REG1, 0, REG1; \
  27         jmpl    %g1 + %lo(SYSCALL), %g0; \
  28         sra     REG2, 0, REG2
  29
  30 #define SIGN3(STUB,SYSCALL,REG1,REG2,REG3) \
  31         .align  32; \
  32         .globl  STUB; \
  33 STUB:   sra     REG1, 0, REG1; \
  34         sethi   %hi(SYSCALL), %g1; \
  35         sra     REG2, 0, REG2; \
  36         jmpl    %g1 + %lo(SYSCALL), %g0; \
  37         sra     REG3, 0, REG3
  38
  39 SIGN1(sys32_readahead, compat_sys_readahead, %o0)
  40 SIGN2(sys32_fadvise64, compat_sys_fadvise64, %o0, %o4)
  41 SIGN2(sys32_fadvise64_64, compat_sys_fadvise64_64, %o0, %o5)
  42 SIGN1(sys32_clock_nanosleep, compat_sys_clock_nanosleep, %o1)
  43 SIGN1(sys32_timer_settime, compat_sys_timer_settime, %o1)
  44 SIGN1(sys32_io_submit, compat_sys_io_submit, %o1)
  45 SIGN1(sys32_mq_open, compat_sys_mq_open, %o1)
  46 SIGN1(sys32_select, compat_sys_select, %o0)
  47 SIGN3(sys32_futex, compat_sys_futex, %o1, %o2, %o5)
  48 SIGN1(sys32_recvfrom, compat_sys_recvfrom, %o0)
  49 SIGN1(sys32_recvmsg, compat_sys_recvmsg, %o0)
  50 SIGN1(sys32_sendmsg, compat_sys_sendmsg, %o0)
  51
  52         .globl          sys32_mmap2
  53 sys32_mmap2:
  54         sethi           %hi(sys_mmap), %g1
  55         jmpl            %g1 + %lo(sys_mmap), %g0
  56          sllx           %o5, 12, %o5
  57
  58         .align          32
  59         .globl          sys32_socketcall
  60 sys32_socketcall:       /* %o0=call, %o1=args */
  61         cmp             %o0, 1
  62         bl,pn           %xcc, do_einval
  63          cmp            %o0, 18
  64         bg,pn           %xcc, do_einval
  65          sub            %o0, 1, %o0
  66         sllx            %o0, 5, %o0
  67         sethi           %hi(__socketcall_table_begin), %g2
  68         or              %g2, %lo(__socketcall_table_begin), %g2
  69         jmpl            %g2 + %o0, %g0
  70          nop
  71 do_einval:
  72         retl
  73          mov            -EINVAL, %o0
  74
  75         .align          32
  76 __socketcall_table_begin:
  77
  78         /* Each entry is exactly 32 bytes. */
  79 do_sys_socket: /* sys_socket(int, int, int) */
  80 1:      ldswa           [%o1 + 0x0] %asi, %o0
  81         sethi           %hi(sys_socket), %g1
  82 2:      ldswa           [%o1 + 0x8] %asi, %o2
  83         jmpl            %g1 + %lo(sys_socket), %g0
  84 3:       ldswa          [%o1 + 0x4] %asi, %o1
  85         nop
  86         nop
  87         nop
  88 do_sys_bind: /* sys_bind(int fd, struct sockaddr *, int) */
  89 4:      ldswa           [%o1 + 0x0] %asi, %o0
  90         sethi           %hi(sys_bind), %g1
  91 5:      ldswa           [%o1 + 0x8] %asi, %o2
  92         jmpl            %g1 + %lo(sys_bind), %g0
  93 6:       lduwa          [%o1 + 0x4] %asi, %o1
  94         nop
  95         nop
  96         nop
  97 do_sys_connect: /* sys_connect(int, struct sockaddr *, int) */
  98 7:      ldswa           [%o1 + 0x0] %asi, %o0
  99         sethi           %hi(sys_connect), %g1
 100 8:      ldswa           [%o1 + 0x8] %asi, %o2
 101         jmpl            %g1 + %lo(sys_connect), %g0
 102 9:       lduwa          [%o1 + 0x4] %asi, %o1
 103         nop
 104         nop
 105         nop
 106 do_sys_listen: /* sys_listen(int, int) */
 107 10:     ldswa           [%o1 + 0x0] %asi, %o0
 108         sethi           %hi(sys_listen), %g1
 109         jmpl            %g1 + %lo(sys_listen), %g0
 110 11:      ldswa          [%o1 + 0x4] %asi, %o1
 111         nop
 112         nop
 113         nop
 114         nop
 115 do_sys_accept: /* sys_accept(int, struct sockaddr *, int *) */
 116 12:     ldswa           [%o1 + 0x0] %asi, %o0
 117         sethi           %hi(sys_accept), %g1
 118 13:     lduwa           [%o1 + 0x8] %asi, %o2
 119         jmpl            %g1 + %lo(sys_accept), %g0
 120 14:      lduwa          [%o1 + 0x4] %asi, %o1
 121         nop
 122         nop
 123         nop
 124 do_sys_getsockname: /* sys_getsockname(int, struct sockaddr *, int *) */
 125 15:     ldswa           [%o1 + 0x0] %asi, %o0
 126         sethi           %hi(sys_getsockname), %g1
 127 16:     lduwa           [%o1 + 0x8] %asi, %o2
 128         jmpl            %g1 + %lo(sys_getsockname), %g0
 129 17:      lduwa          [%o1 + 0x4] %asi, %o1
 130         nop
 131         nop
 132         nop
 133 do_sys_getpeername: /* sys_getpeername(int, struct sockaddr *, int *) */
 134 18:     ldswa           [%o1 + 0x0] %asi, %o0
 135         sethi           %hi(sys_getpeername), %g1
 136 19:     lduwa           [%o1 + 0x8] %asi, %o2
 137         jmpl            %g1 + %lo(sys_getpeername), %g0
 138 20:      lduwa          [%o1 + 0x4] %asi, %o1
 139         nop
 140         nop
 141         nop
 142 do_sys_socketpair: /* sys_socketpair(int, int, int, int *) */
 143 21:     ldswa           [%o1 + 0x0] %asi, %o0
 144         sethi           %hi(sys_socketpair), %g1
 145 22:     ldswa           [%o1 + 0x8] %asi, %o2
 146 23:     lduwa           [%o1 + 0xc] %asi, %o3
 147         jmpl            %g1 + %lo(sys_socketpair), %g0
 148 24:      ldswa          [%o1 + 0x4] %asi, %o1
 149         nop
 150         nop
 151 do_sys_send: /* sys_send(int, void *, size_t, unsigned int) */
 152 25:     ldswa           [%o1 + 0x0] %asi, %o0
 153         sethi           %hi(sys_send), %g1
 154 26:     lduwa           [%o1 + 0x8] %asi, %o2
 155 27:     lduwa           [%o1 + 0xc] %asi, %o3
 156         jmpl            %g1 + %lo(sys_send), %g0
 157 28:      lduwa          [%o1 + 0x4] %asi, %o1
 158         nop
 159         nop
 160 do_sys_recv: /* sys_recv(int, void *, size_t, unsigned int) */
 161 29:     ldswa           [%o1 + 0x0] %asi, %o0
 162         sethi           %hi(sys_recv), %g1
 163 30:     lduwa           [%o1 + 0x8] %asi, %o2
 164 31:     lduwa           [%o1 + 0xc] %asi, %o3
 165         jmpl            %g1 + %lo(sys_recv), %g0
 166 32:      lduwa          [%o1 + 0x4] %asi, %o1
 167         nop
 168         nop
 169 do_sys_sendto: /* sys_sendto(int, u32, compat_size_t, unsigned int, u32, int) */
 170 33:     ldswa           [%o1 + 0x0] %asi, %o0
 171         sethi           %hi(sys_sendto), %g1
 172 34:     lduwa           [%o1 + 0x8] %asi, %o2
 173 35:     lduwa           [%o1 + 0xc] %asi, %o3
 174 36:     lduwa           [%o1 + 0x10] %asi, %o4
 175 37:     ldswa           [%o1 + 0x14] %asi, %o5
 176         jmpl            %g1 + %lo(sys_sendto), %g0
 177 38:      lduwa          [%o1 + 0x4] %asi, %o1
 178 do_sys_recvfrom: /* sys_recvfrom(int, u32, compat_size_t, unsigned int, u32, u32) */
 179 39:     ldswa           [%o1 + 0x0] %asi, %o0
 180         sethi           %hi(sys_recvfrom), %g1
 181 40:     lduwa           [%o1 + 0x8] %asi, %o2
 182 41:     lduwa           [%o1 + 0xc] %asi, %o3
 183 42:     lduwa           [%o1 + 0x10] %asi, %o4
 184 43:     lduwa           [%o1 + 0x14] %asi, %o5
 185         jmpl            %g1 + %lo(sys_recvfrom), %g0
 186 44:      lduwa          [%o1 + 0x4] %asi, %o1
 187 do_sys_shutdown: /* sys_shutdown(int, int) */
 188 45:     ldswa           [%o1 + 0x0] %asi, %o0
 189         sethi           %hi(sys_shutdown), %g1
 190         jmpl            %g1 + %lo(sys_shutdown), %g0
 191 46:      ldswa          [%o1 + 0x4] %asi, %o1
 192         nop
 193         nop
 194         nop
 195         nop
 196 do_sys_setsockopt: /* compat_sys_setsockopt(int, int, int, char *, int) */
 197 47:     ldswa           [%o1 + 0x0] %asi, %o0
 198         sethi           %hi(compat_sys_setsockopt), %g1
 199 48:     ldswa           [%o1 + 0x8] %asi, %o2
 200 49:     lduwa           [%o1 + 0xc] %asi, %o3
 201 50:     ldswa           [%o1 + 0x10] %asi, %o4
 202         jmpl            %g1 + %lo(compat_sys_setsockopt), %g0
 203 51:      ldswa          [%o1 + 0x4] %asi, %o1
 204         nop
 205 do_sys_getsockopt: /* compat_sys_getsockopt(int, int, int, u32, u32) */
 206 52:     ldswa           [%o1 + 0x0] %asi, %o0
 207         sethi           %hi(compat_sys_getsockopt), %g1
 208 53:     ldswa           [%o1 + 0x8] %asi, %o2
 209 54:     lduwa           [%o1 + 0xc] %asi, %o3
 210 55:     lduwa           [%o1 + 0x10] %asi, %o4
 211         jmpl            %g1 + %lo(compat_sys_getsockopt), %g0
 212 56:      ldswa          [%o1 + 0x4] %asi, %o1
 213         nop
 214 do_sys_sendmsg: /* compat_sys_sendmsg(int, struct compat_msghdr *, unsigned int) */
 215 57:     ldswa           [%o1 + 0x0] %asi, %o0
 216         sethi           %hi(compat_sys_sendmsg), %g1
 217 58:     lduwa           [%o1 + 0x8] %asi, %o2
 218         jmpl            %g1 + %lo(compat_sys_sendmsg), %g0
 219 59:      lduwa          [%o1 + 0x4] %asi, %o1
 220         nop
 221         nop
 222         nop
 223 do_sys_recvmsg: /* compat_sys_recvmsg(int, struct compat_msghdr *, unsigned int) */
 224 60:     ldswa           [%o1 + 0x0] %asi, %o0
 225         sethi           %hi(compat_sys_recvmsg), %g1
 226 61:     lduwa           [%o1 + 0x8] %asi, %o2
 227         jmpl            %g1 + %lo(compat_sys_recvmsg), %g0
 228 62:      lduwa          [%o1 + 0x4] %asi, %o1
 229         nop
 230         nop
 231         nop
 232 do_sys_accept4: /* sys_accept4(int, struct sockaddr *, int *, int) */
 233 63:     ldswa           [%o1 + 0x0] %asi, %o0
 234         sethi           %hi(sys_accept4), %g1
 235 64:     lduwa           [%o1 + 0x8] %asi, %o2
 236 65:     ldswa           [%o1 + 0xc] %asi, %o3
 237         jmpl            %g1 + %lo(sys_accept4), %g0
 238 66:      lduwa          [%o1 + 0x4] %asi, %o1
 239         nop
 240         nop
 241
 242         .section        __ex_table,"a"
 243         .align          4
 244         .word           1b, __retl_efault, 2b, __retl_efault
 245         .word           3b, __retl_efault, 4b, __retl_efault
 246         .word           5b, __retl_efault, 6b, __retl_efault
 247         .word           7b, __retl_efault, 8b, __retl_efault
 248         .word           9b, __retl_efault, 10b, __retl_efault
 249         .word           11b, __retl_efault, 12b, __retl_efault
 250         .word           13b, __retl_efault, 14b, __retl_efault
 251         .word           15b, __retl_efault, 16b, __retl_efault
 252         .word           17b, __retl_efault, 18b, __retl_efault
 253         .word           19b, __retl_efault, 20b, __retl_efault
 254         .word           21b, __retl_efault, 22b, __retl_efault
 255         .word           23b, __retl_efault, 24b, __retl_efault
 256         .word           25b, __retl_efault, 26b, __retl_efault
 257         .word           27b, __retl_efault, 28b, __retl_efault
 258         .word           29b, __retl_efault, 30b, __retl_efault
 259         .word           31b, __retl_efault, 32b, __retl_efault
 260         .word           33b, __retl_efault, 34b, __retl_efault
 261         .word           35b, __retl_efault, 36b, __retl_efault
 262         .word           37b, __retl_efault, 38b, __retl_efault
 263         .word           39b, __retl_efault, 40b, __retl_efault
 264         .word           41b, __retl_efault, 42b, __retl_efault
 265         .word           43b, __retl_efault, 44b, __retl_efault
 266         .word           45b, __retl_efault, 46b, __retl_efault
 267         .word           47b, __retl_efault, 48b, __retl_efault
 268         .word           49b, __retl_efault, 50b, __retl_efault
 269         .word           51b, __retl_efault, 52b, __retl_efault
 270         .word           53b, __retl_efault, 54b, __retl_efault
 271         .word           55b, __retl_efault, 56b, __retl_efault
 272         .word           57b, __retl_efault, 58b, __retl_efault
 273         .word           59b, __retl_efault, 60b, __retl_efault
 274         .word           61b, __retl_efault, 62b, __retl_efault
 275         .word           63b, __retl_efault, 64b, __retl_efault
 276         .word           65b, __retl_efault, 66b, __retl_efault
 277         .previous