arch/um/kernel/dyn.lds.S

   1 #include <asm-generic/vmlinux.lds.h>
   2
   3 OUTPUT_FORMAT(ELF_FORMAT)
   4 OUTPUT_ARCH(ELF_ARCH)
   5 ENTRY(_start)
   6 jiffies = jiffies_64;
   7
   8 SECTIONS
   9 {
  10   PROVIDE (__executable_start = START);
  11   . = START + SIZEOF_HEADERS;
  12   .interp         : { *(.interp) }
  13   /* Used in arch/um/kernel/mem.c. Any memory between START and __binary_start
  14    * is remapped.*/
  15   __binary_start = .;
  16   . = ALIGN(4096);              /* Init code and data */
  17   _stext = .;
  18   __init_begin = .;
  19   .init.text : {
  20         _sinittext = .;
  21         *(.init.text)
  22         _einittext = .;
  23   }
  24
  25   . = ALIGN(4096);
  26
  27   /* Read-only sections, merged into text segment: */
  28   .hash           : { *(.hash) }
  29   .gnu.hash       : { *(.gnu.hash) }
  30   .dynsym         : { *(.dynsym) }
  31   .dynstr         : { *(.dynstr) }
  32   .gnu.version    : { *(.gnu.version) }
  33   .gnu.version_d  : { *(.gnu.version_d) }
  34   .gnu.version_r  : { *(.gnu.version_r) }
  35   .rel.init       : { *(.rel.init) }
  36   .rela.init      : { *(.rela.init) }
  37   .rel.text       : { *(.rel.text .rel.text.* .rel.gnu.linkonce.t.*) }
  38   .rela.text      : { *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*) }
  39   .rel.fini       : { *(.rel.fini) }
  40   .rela.fini      : { *(.rela.fini) }
  41   .rel.rodata     : { *(.rel.rodata .rel.rodata.* .rel.gnu.linkonce.r.*) }
  42   .rela.rodata    : { *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*) }
  43   .rel.data       : { *(.rel.data .rel.data.* .rel.gnu.linkonce.d.*) }
  44   .rela.data      : { *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*) }
  45   .rel.tdata      : { *(.rel.tdata .rel.tdata.* .rel.gnu.linkonce.td.*) }
  46   .rela.tdata     : { *(.rela.tdata .rela.tdata.* .rela.gnu.linkonce.td.*) }
  47   .rel.tbss       : { *(.rel.tbss .rel.tbss.* .rel.gnu.linkonce.tb.*) }
  48   .rela.tbss      : { *(.rela.tbss .rela.tbss.* .rela.gnu.linkonce.tb.*) }
  49   .rel.ctors      : { *(.rel.ctors) }
  50   .rela.ctors     : { *(.rela.ctors) }
  51   .rel.dtors      : { *(.rel.dtors) }
  52   .rela.dtors     : { *(.rela.dtors) }
  53   .rel.got        : { *(.rel.got) }
  54   .rela.got       : { *(.rela.got) }
  55   .rel.bss        : { *(.rel.bss .rel.bss.* .rel.gnu.linkonce.b.*) }
  56   .rela.bss       : { *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*) }
  57   .rel.plt        : { *(.rel.plt) }
  58   .rela.plt       : { *(.rela.plt) }
  59   .init           : {
  60     KEEP (*(.init))
  61   } =0x90909090
  62   .plt            : { *(.plt) }
  63   .text           : {
  64     *(.text)
  65     SCHED_TEXT
  66     LOCK_TEXT
  67     *(.fixup)
  68     *(.stub .text.* .gnu.linkonce.t.*)
  69     /* .gnu.warning sections are handled specially by elf32.em.  */
  70     *(.gnu.warning)
  71
  72     . = ALIGN(4096);
  73     __syscall_stub_start = .;
  74     *(.__syscall_stub*)
  75     __syscall_stub_end = .;
  76     . = ALIGN(4096);
  77   } =0x90909090
  78   .fini           : {
  79     KEEP (*(.fini))
  80   } =0x90909090
  81
  82   .kstrtab : { *(.kstrtab) }
  83
  84   #include "asm/common.lds.S"
  85
  86   init.data : { *(.init.data) }
  87
  88   /* Ensure the __preinit_array_start label is properly aligned.  We
  89      could instead move the label definition inside the section, but
  90      the linker would then create the section even if it turns out to
  91      be empty, which isn't pretty.  */
  92   . = ALIGN(32 / 8);
  93   .preinit_array     : { *(.preinit_array) }
  94   .init_array     : { *(.init_array) }
  95   .fini_array     : { *(.fini_array) }
  96   .data           : {
  97     . = ALIGN(KERNEL_STACK_SIZE);               /* init_task */
  98     *(.data.init_task)
  99     *(.data .data.* .gnu.linkonce.d.*)
 100     SORT(CONSTRUCTORS)
 101   }
 102   .data1          : { *(.data1) }
 103   .tdata          : { *(.tdata .tdata.* .gnu.linkonce.td.*) }
 104   .tbss           : { *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon) }
 105   .eh_frame       : { KEEP (*(.eh_frame)) }
 106   .gcc_except_table   : { *(.gcc_except_table) }
 107   .dynamic        : { *(.dynamic) }
 108   .ctors          : {
 109     /* gcc uses crtbegin.o to find the start of
 110        the constructors, so we make sure it is
 111        first.  Because this is a wildcard, it
 112        doesn't matter if the user does not
 113        actually link against crtbegin.o; the
 114        linker won't look for a file to match a
 115        wildcard.  The wildcard also means that it
 116        doesn't matter which directory crtbegin.o
 117        is in.  */
 118     KEEP (*crtbegin.o(.ctors))
 119     /* We don't want to include the .ctor section from
 120        from the crtend.o file until after the sorted ctors.
 121        The .ctor section from the crtend file contains the
 122        end of ctors marker and it must be last */
 123     KEEP (*(EXCLUDE_FILE (*crtend.o ) .ctors))
 124     KEEP (*(SORT(.ctors.*)))
 125     KEEP (*(.ctors))
 126   }
 127   .dtors          : {
 128     KEEP (*crtbegin.o(.dtors))
 129     KEEP (*(EXCLUDE_FILE (*crtend.o ) .dtors))
 130     KEEP (*(SORT(.dtors.*)))
 131     KEEP (*(.dtors))
 132   }
 133   .jcr            : { KEEP (*(.jcr)) }
 134   .got            : { *(.got.plt) *(.got) }
 135   _edata = .;
 136   PROVIDE (edata = .);
 137   __bss_start = .;
 138   .bss            : {
 139    *(.dynbss)
 140    *(.bss .bss.* .gnu.linkonce.b.*)
 141    *(COMMON)
 142    /* Align here to ensure that the .bss section occupies space up to
 143       _end.  Align after .bss to ensure correct alignment even if the
 144       .bss section disappears because there are no input sections.  */
 145    . = ALIGN(32 / 8);
 146   . = ALIGN(32 / 8);
 147   }
 148   _end = .;
 149   PROVIDE (end = .);
 150
 151   STABS_DEBUG
 152
 153   DWARF_DEBUG
 154 }