arch/x86/boot/header.S

   1 /*
   2  *      header.S
   3  *
   4  *      Copyright (C) 1991, 1992 Linus Torvalds
   5  *
   6  *      Based on bootsect.S and setup.S
   7  *      modified by more people than can be counted
   8  *
   9  *      Rewritten as a common file by H. Peter Anvin (Apr 2007)
  10  *
  11  * BIG FAT NOTE: We're in real mode using 64k segments.  Therefore segment
  12  * addresses must be multiplied by 16 to obtain their respective linear
  13  * addresses. To avoid confusion, linear addresses are written using leading
  14  * hex while segment addresses are written as segment:offset.
  15  *
  16  */
  17
  18 #include <asm/segment.h>
  19 #include <generated/utsrelease.h>
  20 #include <asm/boot.h>
  21 #include <asm/e820.h>
  22 #include <asm/page_types.h>
  23 #include <asm/setup.h>
  24 #include <asm/bootparam.h>
  25 #include "boot.h"
  26 #include "voffset.h"
  27 #include "zoffset.h"
  28
  29 BOOTSEG         = 0x07C0                /* original address of boot-sector */
  30 SYSSEG          = 0x1000                /* historical load address >> 4 */
  31
  32 #ifndef SVGA_MODE
  33 #define SVGA_MODE ASK_VGA
  34 #endif
  35
  36 #ifndef ROOT_RDONLY
  37 #define ROOT_RDONLY 1
  38 #endif
  39
  40         .code16
  41         .section ".bstext", "ax"
  42
  43         .global bootsect_start
  44 bootsect_start:
  45 #ifdef CONFIG_EFI_STUB
  46         # "MZ", MS-DOS header
  47         .byte 0x4d
  48         .byte 0x5a
  49 #endif
  50
  51         # Normalize the start address
  52         ljmp    $BOOTSEG, $start2
  53
  54 start2:
  55         movw    %cs, %ax
  56         movw    %ax, %ds
  57         movw    %ax, %es
  58         movw    %ax, %ss
  59         xorw    %sp, %sp
  60         sti
  61         cld
  62
  63         movw    $bugger_off_msg, %si
  64
  65 msg_loop:
  66         lodsb
  67         andb    %al, %al
  68         jz      bs_die
  69         movb    $0xe, %ah
  70         movw    $7, %bx
  71         int     $0x10
  72         jmp     msg_loop
  73
  74 bs_die:
  75         # Allow the user to press a key, then reboot
  76         xorw    %ax, %ax
  77         int     $0x16
  78         int     $0x19
  79
  80         # int 0x19 should never return.  In case it does anyway,
  81         # invoke the BIOS reset code...
  82         ljmp    $0xf000,$0xfff0
  83
  84 #ifdef CONFIG_EFI_STUB
  85         .org    0x3c
  86         #
  87         # Offset to the PE header.
  88         #
  89         .long   pe_header
  90 #endif /* CONFIG_EFI_STUB */
  91
  92         .section ".bsdata", "a"
  93 bugger_off_msg:
  94         .ascii  "Direct floppy boot is not supported. "
  95         .ascii  "Use a boot loader program instead.\r\n"
  96         .ascii  "\n"
  97         .ascii  "Remove disk and press any key to reboot ...\r\n"
  98         .byte   0
  99
 100 #ifdef CONFIG_EFI_STUB
 101 pe_header:
 102         .ascii  "PE"
 103         .word   0
 104
 105 coff_header:
 106 #ifdef CONFIG_X86_32
 107         .word   0x14c                           # i386
 108 #else
 109         .word   0x8664                          # x86-64
 110 #endif
 111         .word   3                               # nr_sections
 112         .long   0                               # TimeDateStamp
 113         .long   0                               # PointerToSymbolTable
 114         .long   1                               # NumberOfSymbols
 115         .word   section_table - optional_header # SizeOfOptionalHeader
 116 #ifdef CONFIG_X86_32
 117         .word   0x306                           # Characteristics.
 118                                                 # IMAGE_FILE_32BIT_MACHINE |
 119                                                 # IMAGE_FILE_DEBUG_STRIPPED |
 120                                                 # IMAGE_FILE_EXECUTABLE_IMAGE |
 121                                                 # IMAGE_FILE_LINE_NUMS_STRIPPED
 122 #else
 123         .word   0x206                           # Characteristics
 124                                                 # IMAGE_FILE_DEBUG_STRIPPED |
 125                                                 # IMAGE_FILE_EXECUTABLE_IMAGE |
 126                                                 # IMAGE_FILE_LINE_NUMS_STRIPPED
 127 #endif
 128
 129 optional_header:
 130 #ifdef CONFIG_X86_32
 131         .word   0x10b                           # PE32 format
 132 #else
 133         .word   0x20b                           # PE32+ format
 134 #endif
 135         .byte   0x02                            # MajorLinkerVersion
 136         .byte   0x14                            # MinorLinkerVersion
 137
 138         # Filled in by build.c
 139         .long   0                               # SizeOfCode
 140
 141         .long   0                               # SizeOfInitializedData
 142         .long   0                               # SizeOfUninitializedData
 143
 144         # Filled in by build.c
 145         .long   0x0000                          # AddressOfEntryPoint
 146
 147         .long   0x0200                          # BaseOfCode
 148 #ifdef CONFIG_X86_32
 149         .long   0                               # data
 150 #endif
 151
 152 extra_header_fields:
 153 #ifdef CONFIG_X86_32
 154         .long   0                               # ImageBase
 155 #else
 156         .quad   0                               # ImageBase
 157 #endif
 158         .long   0x20                            # SectionAlignment
 159         .long   0x20                            # FileAlignment
 160         .word   0                               # MajorOperatingSystemVersion
 161         .word   0                               # MinorOperatingSystemVersion
 162         .word   0                               # MajorImageVersion
 163         .word   0                               # MinorImageVersion
 164         .word   0                               # MajorSubsystemVersion
 165         .word   0                               # MinorSubsystemVersion
 166         .long   0                               # Win32VersionValue
 167
 168         #
 169         # The size of the bzImage is written in tools/build.c
 170         #
 171         .long   0                               # SizeOfImage
 172
 173         .long   0x200                           # SizeOfHeaders
 174         .long   0                               # CheckSum
 175         .word   0xa                             # Subsystem (EFI application)
 176         .word   0                               # DllCharacteristics
 177 #ifdef CONFIG_X86_32
 178         .long   0                               # SizeOfStackReserve
 179         .long   0                               # SizeOfStackCommit
 180         .long   0                               # SizeOfHeapReserve
 181         .long   0                               # SizeOfHeapCommit
 182 #else
 183         .quad   0                               # SizeOfStackReserve
 184         .quad   0                               # SizeOfStackCommit
 185         .quad   0                               # SizeOfHeapReserve
 186         .quad   0                               # SizeOfHeapCommit
 187 #endif
 188         .long   0                               # LoaderFlags
 189         .long   0x6                             # NumberOfRvaAndSizes
 190
 191         .quad   0                               # ExportTable
 192         .quad   0                               # ImportTable
 193         .quad   0                               # ResourceTable
 194         .quad   0                               # ExceptionTable
 195         .quad   0                               # CertificationTable
 196         .quad   0                               # BaseRelocationTable
 197
 198         # Section table
 199 section_table:
 200         #
 201         # The offset & size fields are filled in by build.c.
 202         #
 203         .ascii  ".setup"
 204         .byte   0
 205         .byte   0
 206         .long   0
 207         .long   0x0                             # startup_{32,64}
 208         .long   0                               # Size of initialized data
 209                                                 # on disk
 210         .long   0x0                             # startup_{32,64}
 211         .long   0                               # PointerToRelocations
 212         .long   0                               # PointerToLineNumbers
 213         .word   0                               # NumberOfRelocations
 214         .word   0                               # NumberOfLineNumbers
 215         .long   0x60500020                      # Characteristics (section flags)
 216
 217         #
 218         # The EFI application loader requires a relocation section
 219         # because EFI applications must be relocatable. The .reloc
 220         # offset & size fields are filled in by build.c.
 221         #
 222         .ascii  ".reloc"
 223         .byte   0
 224         .byte   0
 225         .long   0
 226         .long   0
 227         .long   0                               # SizeOfRawData
 228         .long   0                               # PointerToRawData
 229         .long   0                               # PointerToRelocations
 230         .long   0                               # PointerToLineNumbers
 231         .word   0                               # NumberOfRelocations
 232         .word   0                               # NumberOfLineNumbers
 233         .long   0x42100040                      # Characteristics (section flags)
 234
 235         #
 236         # The offset & size fields are filled in by build.c.
 237         #
 238         .ascii  ".text"
 239         .byte   0
 240         .byte   0
 241         .byte   0
 242         .long   0
 243         .long   0x0                             # startup_{32,64}
 244         .long   0                               # Size of initialized data
 245                                                 # on disk
 246         .long   0x0                             # startup_{32,64}
 247         .long   0                               # PointerToRelocations
 248         .long   0                               # PointerToLineNumbers
 249         .word   0                               # NumberOfRelocations
 250         .word   0                               # NumberOfLineNumbers
 251         .long   0x60500020                      # Characteristics (section flags)
 252
 253 #endif /* CONFIG_EFI_STUB */
 254
 255         # Kernel attributes; used by setup.  This is part 1 of the
 256         # header, from the old boot sector.
 257
 258         .section ".header", "a"
 259         .globl  sentinel
 260 sentinel:       .byte 0xff, 0xff        /* Used to detect broken loaders */
 261
 262         .globl  hdr
 263 hdr:
 264 setup_sects:    .byte 0                 /* Filled in by build.c */
 265 root_flags:     .word ROOT_RDONLY
 266 syssize:        .long 0                 /* Filled in by build.c */
 267 ram_size:       .word 0                 /* Obsolete */
 268 vid_mode:       .word SVGA_MODE
 269 root_dev:       .word 0                 /* Filled in by build.c */
 270 boot_flag:      .word 0xAA55
 271
 272         # offset 512, entry point
 273
 274         .globl  _start
 275 _start:
 276                 # Explicitly enter this as bytes, or the assembler
 277                 # tries to generate a 3-byte jump here, which causes
 278                 # everything else to push off to the wrong offset.
 279                 .byte   0xeb            # short (2-byte) jump
 280                 .byte   start_of_setup-1f
 281 1:
 282
 283         # Part 2 of the header, from the old setup.S
 284
 285                 .ascii  "HdrS"          # header signature
 286                 .word   0x020d          # header version number (>= 0x0105)
 287                                         # or else old loadlin-1.5 will fail)
 288                 .globl realmode_swtch
 289 realmode_swtch: .word   0, 0            # default_switch, SETUPSEG
 290 start_sys_seg:  .word   SYSSEG          # obsolete and meaningless, but just
 291                                         # in case something decided to "use" it
 292                 .word   kernel_version-512 # pointing to kernel version string
 293                                         # above section of header is compatible
 294                                         # with loadlin-1.5 (header v1.5). Don't
 295                                         # change it.
 296
 297 type_of_loader: .byte   0               # 0 means ancient bootloader, newer
 298                                         # bootloaders know to change this.
 299                                         # See Documentation/x86/boot.txt for
 300                                         # assigned ids
 301
 302 # flags, unused bits must be zero (RFU) bit within loadflags
 303 loadflags:
 304                 .byte   LOADED_HIGH     # The kernel is to be loaded high
 305
 306 setup_move_size: .word  0x8000          # size to move, when setup is not
 307                                         # loaded at 0x90000. We will move setup
 308                                         # to 0x90000 then just before jumping
 309                                         # into the kernel. However, only the
 310                                         # loader knows how much data behind
 311                                         # us also needs to be loaded.
 312
 313 code32_start:                           # here loaders can put a different
 314                                         # start address for 32-bit code.
 315                 .long   0x100000        # 0x100000 = default for big kernel
 316
 317 ramdisk_image:  .long   0               # address of loaded ramdisk image
 318                                         # Here the loader puts the 32-bit
 319                                         # address where it loaded the image.
 320                                         # This only will be read by the kernel.
 321
 322 ramdisk_size:   .long   0               # its size in bytes
 323
 324 bootsect_kludge:
 325                 .long   0               # obsolete
 326
 327 heap_end_ptr:   .word   _end+STACK_SIZE-512
 328                                         # (Header version 0x0201 or later)
 329                                         # space from here (exclusive) down to
 330                                         # end of setup code can be used by setup
 331                                         # for local heap purposes.
 332
 333 ext_loader_ver:
 334                 .byte   0               # Extended boot loader version
 335 ext_loader_type:
 336                 .byte   0               # Extended boot loader type
 337
 338 cmd_line_ptr:   .long   0               # (Header version 0x0202 or later)
 339                                         # If nonzero, a 32-bit pointer
 340                                         # to the kernel command line.
 341                                         # The command line should be
 342                                         # located between the start of
 343                                         # setup and the end of low
 344                                         # memory (0xa0000), or it may
 345                                         # get overwritten before it
 346                                         # gets read.  If this field is
 347                                         # used, there is no longer
 348                                         # anything magical about the
 349                                         # 0x90000 segment; the setup
 350                                         # can be located anywhere in
 351                                         # low memory 0x10000 or higher.
 352
 353 initrd_addr_max: .long 0x7fffffff
 354                                         # (Header version 0x0203 or later)
 355                                         # The highest safe address for
 356                                         # the contents of an initrd
 357                                         # The current kernel allows up to 4 GB,
 358                                         # but leave it at 2 GB to avoid
 359                                         # possible bootloader bugs.
 360
 361 kernel_alignment:  .long CONFIG_PHYSICAL_ALIGN  #physical addr alignment
 362                                                 #required for protected mode
 363                                                 #kernel
 364 #ifdef CONFIG_RELOCATABLE
 365 relocatable_kernel:    .byte 1
 366 #else
 367 relocatable_kernel:    .byte 0
 368 #endif
 369 min_alignment:          .byte MIN_KERNEL_ALIGN_LG2      # minimum alignment
 370
 371 xloadflags:
 372 #ifdef CONFIG_X86_64
 373 # define XLF0 XLF_KERNEL_64                     /* 64-bit kernel */
 374 #else
 375 # define XLF0 0
 376 #endif
 377
 378 #if defined(CONFIG_RELOCATABLE) && defined(CONFIG_X86_64) && \
 379         !defined(CONFIG_EFI_MIXED)
 380    /* kernel/boot_param/ramdisk could be loaded above 4g */
 381 # define XLF1 XLF_CAN_BE_LOADED_ABOVE_4G
 382 #else
 383 # define XLF1 0
 384 #endif
 385
 386 #ifdef CONFIG_EFI_STUB
 387 # ifdef CONFIG_EFI_MIXED
 388 #  define XLF23 (XLF_EFI_HANDOVER_32|XLF_EFI_HANDOVER_64)
 389 # else
 390 #  ifdef CONFIG_X86_64
 391 #   define XLF23 XLF_EFI_HANDOVER_64            /* 64-bit EFI handover ok */
 392 #  else
 393 #   define XLF23 XLF_EFI_HANDOVER_32            /* 32-bit EFI handover ok */
 394 #  endif
 395 # endif
 396 #else
 397 # define XLF23 0
 398 #endif
 399
 400 #if defined(CONFIG_X86_64) && defined(CONFIG_EFI) && defined(CONFIG_KEXEC)
 401 # define XLF4 XLF_EFI_KEXEC
 402 #else
 403 # define XLF4 0
 404 #endif
 405
 406                         .word XLF0 | XLF1 | XLF23 | XLF4
 407
 408 cmdline_size:   .long   COMMAND_LINE_SIZE-1     #length of the command line,
 409                                                 #added with boot protocol
 410                                                 #version 2.06
 411
 412 hardware_subarch:       .long 0                 # subarchitecture, added with 2.07
 413                                                 # default to 0 for normal x86 PC
 414
 415 hardware_subarch_data:  .quad 0
 416
 417 payload_offset:         .long ZO_input_data
 418 payload_length:         .long ZO_z_input_len
 419
 420 setup_data:             .quad 0                 # 64-bit physical pointer to
 421                                                 # single linked list of
 422                                                 # struct setup_data
 423
 424 pref_address:           .quad LOAD_PHYSICAL_ADDR        # preferred load addr
 425
 426 #define ZO_INIT_SIZE    (ZO__end - ZO_startup_32 + ZO_z_extract_offset)
 427 #define VO_INIT_SIZE    (VO__end - VO__text)
 428 #if ZO_INIT_SIZE > VO_INIT_SIZE
 429 #define INIT_SIZE ZO_INIT_SIZE
 430 #else
 431 #define INIT_SIZE VO_INIT_SIZE
 432 #endif
 433 init_size:              .long INIT_SIZE         # kernel initialization size
 434 handover_offset:        .long 0                 # Filled in by build.c
 435
 436 # End of setup header #####################################################
 437
 438         .section ".entrytext", "ax"
 439 start_of_setup:
 440 # Force %es = %ds
 441         movw    %ds, %ax
 442         movw    %ax, %es
 443         cld
 444
 445 # Apparently some ancient versions of LILO invoked the kernel with %ss != %ds,
 446 # which happened to work by accident for the old code.  Recalculate the stack
 447 # pointer if %ss is invalid.  Otherwise leave it alone, LOADLIN sets up the
 448 # stack behind its own code, so we can't blindly put it directly past the heap.
 449
 450         movw    %ss, %dx
 451         cmpw    %ax, %dx        # %ds == %ss?
 452         movw    %sp, %dx
 453         je      2f              # -> assume %sp is reasonably set
 454
 455         # Invalid %ss, make up a new stack
 456         movw    $_end, %dx
 457         testb   $CAN_USE_HEAP, loadflags
 458         jz      1f
 459         movw    heap_end_ptr, %dx
 460 1:      addw    $STACK_SIZE, %dx
 461         jnc     2f
 462         xorw    %dx, %dx        # Prevent wraparound
 463
 464 2:      # Now %dx should point to the end of our stack space
 465         andw    $~3, %dx        # dword align (might as well...)
 466         jnz     3f
 467         movw    $0xfffc, %dx    # Make sure we're not zero
 468 3:      movw    %ax, %ss
 469         movzwl  %dx, %esp       # Clear upper half of %esp
 470         sti                     # Now we should have a working stack
 471
 472 # We will have entered with %cs = %ds+0x20, normalize %cs so
 473 # it is on par with the other segments.
 474         pushw   %ds
 475         pushw   $6f
 476         lretw
 477 6:
 478
 479 # Check signature at end of setup
 480         cmpl    $0x5a5aaa55, setup_sig
 481         jne     setup_bad
 482
 483 # Zero the bss
 484         movw    $__bss_start, %di
 485         movw    $_end+3, %cx
 486         xorl    %eax, %eax
 487         subw    %di, %cx
 488         shrw    $2, %cx
 489         rep; stosl
 490
 491 # Jump to C code (should not return)
 492         calll   main
 493
 494 # Setup corrupt somehow...
 495 setup_bad:
 496         movl    $setup_corrupt, %eax
 497         calll   puts
 498         # Fall through...
 499
 500         .globl  die
 501         .type   die, @function
 502 die:
 503         hlt
 504         jmp     die
 505
 506         .size   die, .-die
 507
 508         .section ".initdata", "a"
 509 setup_corrupt:
 510         .byte   7
 511         .string "No setup signature found...\n"