arch/x86/ia32/ia32entry.S

   1 /*
   2  * Compatibility mode system call entry point for x86-64.
   3  *
   4  * Copyright 2000-2002 Andi Kleen, SuSE Labs.
   5  */
   6
   7 #include <asm/dwarf2.h>
   8 #include <asm/calling.h>
   9 #include <asm/asm-offsets.h>
  10 #include <asm/current.h>
  11 #include <asm/errno.h>
  12 #include <asm/ia32_unistd.h>
  13 #include <asm/thread_info.h>
  14 #include <asm/segment.h>
  15 #include <asm/irqflags.h>
  16 #include <linux/linkage.h>
  17 #include <linux/err.h>
  18
  19 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  20 #include <linux/elf-em.h>
  21 #define AUDIT_ARCH_I386         (EM_386|__AUDIT_ARCH_LE)
  22 #define __AUDIT_ARCH_LE    0x40000000
  23
  24 #ifndef CONFIG_AUDITSYSCALL
  25 #define sysexit_audit ia32_ret_from_sys_call
  26 #define sysretl_audit ia32_ret_from_sys_call
  27 #endif
  28
  29         .section .entry.text, "ax"
  30
  31 #define IA32_NR_syscalls ((ia32_syscall_end - ia32_sys_call_table)/8)
  32
  33         .macro IA32_ARG_FIXUP noebp=0
  34         movl    %edi,%r8d
  35         .if \noebp
  36         .else
  37         movl    %ebp,%r9d
  38         .endif
  39         xchg    %ecx,%esi
  40         movl    %ebx,%edi
  41         movl    %edx,%edx       /* zero extension */
  42         .endm
  43
  44         /* clobbers %eax */
  45         .macro  CLEAR_RREGS offset=0, _r9=rax
  46         xorl    %eax,%eax
  47         movq    %rax,\offset+R11(%rsp)
  48         movq    %rax,\offset+R10(%rsp)
  49         movq    %\_r9,\offset+R9(%rsp)
  50         movq    %rax,\offset+R8(%rsp)
  51         .endm
  52
  53         /*
  54          * Reload arg registers from stack in case ptrace changed them.
  55          * We don't reload %eax because syscall_trace_enter() returned
  56          * the %rax value we should see.  Instead, we just truncate that
  57          * value to 32 bits again as we did on entry from user mode.
  58          * If it's a new value set by user_regset during entry tracing,
  59          * this matches the normal truncation of the user-mode value.
  60          * If it's -1 to make us punt the syscall, then (u32)-1 is still
  61          * an appropriately invalid value.
  62          */
  63         .macro LOAD_ARGS32 offset, _r9=0
  64         .if \_r9
  65         movl \offset+16(%rsp),%r9d
  66         .endif
  67         movl \offset+40(%rsp),%ecx
  68         movl \offset+48(%rsp),%edx
  69         movl \offset+56(%rsp),%esi
  70         movl \offset+64(%rsp),%edi
  71         movl %eax,%eax                  /* zero extension */
  72         .endm
  73
  74         .macro CFI_STARTPROC32 simple
  75         CFI_STARTPROC   \simple
  76         CFI_UNDEFINED   r8
  77         CFI_UNDEFINED   r9
  78         CFI_UNDEFINED   r10
  79         CFI_UNDEFINED   r11
  80         CFI_UNDEFINED   r12
  81         CFI_UNDEFINED   r13
  82         CFI_UNDEFINED   r14
  83         CFI_UNDEFINED   r15
  84         .endm
  85
  86 #ifdef CONFIG_PARAVIRT
  87 ENTRY(native_usergs_sysret32)
  88         swapgs
  89         sysretl
  90 ENDPROC(native_usergs_sysret32)
  91
  92 ENTRY(native_irq_enable_sysexit)
  93         swapgs
  94         sti
  95         sysexit
  96 ENDPROC(native_irq_enable_sysexit)
  97 #endif
  98
  99 /*
 100  * 32bit SYSENTER instruction entry.
 101  *
 102  * Arguments:
 103  * %eax System call number.
 104  * %ebx Arg1
 105  * %ecx Arg2
 106  * %edx Arg3
 107  * %esi Arg4
 108  * %edi Arg5
 109  * %ebp user stack
 110  * 0(%ebp) Arg6
 111  *
 112  * Interrupts off.
 113  *
 114  * This is purely a fast path. For anything complicated we use the int 0x80
 115  * path below.  Set up a complete hardware stack frame to share code
 116  * with the int 0x80 path.
 117  */
 118 ENTRY(ia32_sysenter_target)
 119         CFI_STARTPROC32 simple
 120         CFI_SIGNAL_FRAME
 121         CFI_DEF_CFA     rsp,0
 122         CFI_REGISTER    rsp,rbp
 123         SWAPGS_UNSAFE_STACK
 124         movq    PER_CPU_VAR(kernel_stack), %rsp
 125         addq    $(KERNEL_STACK_OFFSET),%rsp
 126         /*
 127          * No need to follow this irqs on/off section: the syscall
 128          * disabled irqs, here we enable it straight after entry:
 129          */
 130         ENABLE_INTERRUPTS(CLBR_NONE)
 131         movl    %ebp,%ebp               /* zero extension */
 132         pushq_cfi $__USER32_DS
 133         /*CFI_REL_OFFSET ss,0*/
 134         pushq_cfi %rbp
 135         CFI_REL_OFFSET rsp,0
 136         pushfq_cfi
 137         /*CFI_REL_OFFSET rflags,0*/
 138         movl    TI_sysenter_return+THREAD_INFO(%rsp,3*8-KERNEL_STACK_OFFSET),%r10d
 139         CFI_REGISTER rip,r10
 140         pushq_cfi $__USER32_CS
 141         /*CFI_REL_OFFSET cs,0*/
 142         movl    %eax, %eax
 143         pushq_cfi %r10
 144         CFI_REL_OFFSET rip,0
 145         pushq_cfi %rax
 146         cld
 147         SAVE_ARGS 0,1,0
 148         /* no need to do an access_ok check here because rbp has been
 149            32bit zero extended */
 150 1:      movl    (%rbp),%ebp
 151         .section __ex_table,"a"
 152         .quad 1b,ia32_badarg
 153         .previous
 154         orl     $TS_COMPAT,TI_status+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 155         testl   $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 156         CFI_REMEMBER_STATE
 157         jnz  sysenter_tracesys
 158         cmpq    $(IA32_NR_syscalls-1),%rax
 159         ja      ia32_badsys
 160 sysenter_do_call:
 161         IA32_ARG_FIXUP
 162 sysenter_dispatch:
 163         call    *ia32_sys_call_table(,%rax,8)
 164         movq    %rax,RAX-ARGOFFSET(%rsp)
 165         DISABLE_INTERRUPTS(CLBR_NONE)
 166         TRACE_IRQS_OFF
 167         testl   $_TIF_ALLWORK_MASK,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 168         jnz     sysexit_audit
 169 sysexit_from_sys_call:
 170         andl    $~TS_COMPAT,TI_status+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 171         /* clear IF, that popfq doesn't enable interrupts early */
 172         andl  $~0x200,EFLAGS-R11(%rsp)
 173         movl    RIP-R11(%rsp),%edx              /* User %eip */
 174         CFI_REGISTER rip,rdx
 175         RESTORE_ARGS 0,24,0,0,0,0
 176         xorq    %r8,%r8
 177         xorq    %r9,%r9
 178         xorq    %r10,%r10
 179         xorq    %r11,%r11
 180         popfq_cfi
 181         /*CFI_RESTORE rflags*/
 182         popq_cfi %rcx                           /* User %esp */
 183         CFI_REGISTER rsp,rcx
 184         TRACE_IRQS_ON
 185         ENABLE_INTERRUPTS_SYSEXIT32
 186
 187 #ifdef CONFIG_AUDITSYSCALL
 188         .macro auditsys_entry_common
 189         movl %esi,%r9d                  /* 6th arg: 4th syscall arg */
 190         movl %edx,%r8d                  /* 5th arg: 3rd syscall arg */
 191         /* (already in %ecx)               4th arg: 2nd syscall arg */
 192         movl %ebx,%edx                  /* 3rd arg: 1st syscall arg */
 193         movl %eax,%esi                  /* 2nd arg: syscall number */
 194         movl $AUDIT_ARCH_I386,%edi      /* 1st arg: audit arch */
 195         call __audit_syscall_entry
 196         movl RAX-ARGOFFSET(%rsp),%eax   /* reload syscall number */
 197         cmpq $(IA32_NR_syscalls-1),%rax
 198         ja ia32_badsys
 199         movl %ebx,%edi                  /* reload 1st syscall arg */
 200         movl RCX-ARGOFFSET(%rsp),%esi   /* reload 2nd syscall arg */
 201         movl RDX-ARGOFFSET(%rsp),%edx   /* reload 3rd syscall arg */
 202         movl RSI-ARGOFFSET(%rsp),%ecx   /* reload 4th syscall arg */
 203         movl RDI-ARGOFFSET(%rsp),%r8d   /* reload 5th syscall arg */
 204         .endm
 205
 206         .macro auditsys_exit exit
 207         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 208         jnz ia32_ret_from_sys_call
 209         TRACE_IRQS_ON
 210         sti
 211         movl %eax,%esi          /* second arg, syscall return value */
 212         cmpl $-MAX_ERRNO,%eax   /* is it an error ? */
 213         jbe 1f
 214         movslq %eax, %rsi       /* if error sign extend to 64 bits */
 215 1:      setbe %al               /* 1 if error, 0 if not */
 216         movzbl %al,%edi         /* zero-extend that into %edi */
 217         call __audit_syscall_exit
 218         movq RAX-ARGOFFSET(%rsp),%rax   /* reload syscall return value */
 219         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 220         cli
 221         TRACE_IRQS_OFF
 222         testl %edi,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 223         jz \exit
 224         CLEAR_RREGS -ARGOFFSET
 225         jmp int_with_check
 226         .endm
 227
 228 sysenter_auditsys:
 229         CFI_RESTORE_STATE
 230         auditsys_entry_common
 231         movl %ebp,%r9d                  /* reload 6th syscall arg */
 232         jmp sysenter_dispatch
 233
 234 sysexit_audit:
 235         auditsys_exit sysexit_from_sys_call
 236 #endif
 237
 238 sysenter_tracesys:
 239 #ifdef CONFIG_AUDITSYSCALL
 240         testl   $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 241         jz      sysenter_auditsys
 242 #endif
 243         SAVE_REST
 244         CLEAR_RREGS
 245         movq    $-ENOSYS,RAX(%rsp)/* ptrace can change this for a bad syscall */
 246         movq    %rsp,%rdi        /* &pt_regs -> arg1 */
 247         call    syscall_trace_enter
 248         LOAD_ARGS32 ARGOFFSET  /* reload args from stack in case ptrace changed it */
 249         RESTORE_REST
 250         cmpq    $(IA32_NR_syscalls-1),%rax
 251         ja      int_ret_from_sys_call /* sysenter_tracesys has set RAX(%rsp) */
 252         jmp     sysenter_do_call
 253         CFI_ENDPROC
 254 ENDPROC(ia32_sysenter_target)
 255
 256 /*
 257  * 32bit SYSCALL instruction entry.
 258  *
 259  * Arguments:
 260  * %eax System call number.
 261  * %ebx Arg1
 262  * %ecx return EIP
 263  * %edx Arg3
 264  * %esi Arg4
 265  * %edi Arg5
 266  * %ebp Arg2    [note: not saved in the stack frame, should not be touched]
 267  * %esp user stack
 268  * 0(%esp) Arg6
 269  *
 270  * Interrupts off.
 271  *
 272  * This is purely a fast path. For anything complicated we use the int 0x80
 273  * path below.  Set up a complete hardware stack frame to share code
 274  * with the int 0x80 path.
 275  */
 276 ENTRY(ia32_cstar_target)
 277         CFI_STARTPROC32 simple
 278         CFI_SIGNAL_FRAME
 279         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 280         CFI_REGISTER    rip,rcx
 281         /*CFI_REGISTER  rflags,r11*/
 282         SWAPGS_UNSAFE_STACK
 283         movl    %esp,%r8d
 284         CFI_REGISTER    rsp,r8
 285         movq    PER_CPU_VAR(kernel_stack),%rsp
 286         /*
 287          * No need to follow this irqs on/off section: the syscall
 288          * disabled irqs and here we enable it straight after entry:
 289          */
 290         ENABLE_INTERRUPTS(CLBR_NONE)
 291         SAVE_ARGS 8,0,0
 292         movl    %eax,%eax       /* zero extension */
 293         movq    %rax,ORIG_RAX-ARGOFFSET(%rsp)
 294         movq    %rcx,RIP-ARGOFFSET(%rsp)
 295         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 296         movq    %rbp,RCX-ARGOFFSET(%rsp) /* this lies slightly to ptrace */
 297         movl    %ebp,%ecx
 298         movq    $__USER32_CS,CS-ARGOFFSET(%rsp)
 299         movq    $__USER32_DS,SS-ARGOFFSET(%rsp)
 300         movq    %r11,EFLAGS-ARGOFFSET(%rsp)
 301         /*CFI_REL_OFFSET rflags,EFLAGS-ARGOFFSET*/
 302         movq    %r8,RSP-ARGOFFSET(%rsp)
 303         CFI_REL_OFFSET rsp,RSP-ARGOFFSET
 304         /* no need to do an access_ok check here because r8 has been
 305            32bit zero extended */
 306         /* hardware stack frame is complete now */
 307 1:      movl    (%r8),%r9d
 308         .section __ex_table,"a"
 309         .quad 1b,ia32_badarg
 310         .previous
 311         orl     $TS_COMPAT,TI_status+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 312         testl   $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 313         CFI_REMEMBER_STATE
 314         jnz   cstar_tracesys
 315         cmpq $IA32_NR_syscalls-1,%rax
 316         ja  ia32_badsys
 317 cstar_do_call:
 318         IA32_ARG_FIXUP 1
 319 cstar_dispatch:
 320         call *ia32_sys_call_table(,%rax,8)
 321         movq %rax,RAX-ARGOFFSET(%rsp)
 322         DISABLE_INTERRUPTS(CLBR_NONE)
 323         TRACE_IRQS_OFF
 324         testl $_TIF_ALLWORK_MASK,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 325         jnz sysretl_audit
 326 sysretl_from_sys_call:
 327         andl $~TS_COMPAT,TI_status+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 328         RESTORE_ARGS 0,-ARG_SKIP,0,0,0
 329         movl RIP-ARGOFFSET(%rsp),%ecx
 330         CFI_REGISTER rip,rcx
 331         movl EFLAGS-ARGOFFSET(%rsp),%r11d
 332         /*CFI_REGISTER rflags,r11*/
 333         xorq    %r10,%r10
 334         xorq    %r9,%r9
 335         xorq    %r8,%r8
 336         TRACE_IRQS_ON
 337         movl RSP-ARGOFFSET(%rsp),%esp
 338         CFI_RESTORE rsp
 339         USERGS_SYSRET32
 340
 341 #ifdef CONFIG_AUDITSYSCALL
 342 cstar_auditsys:
 343         CFI_RESTORE_STATE
 344         movl %r9d,R9-ARGOFFSET(%rsp)    /* register to be clobbered by call */
 345         auditsys_entry_common
 346         movl R9-ARGOFFSET(%rsp),%r9d    /* reload 6th syscall arg */
 347         jmp cstar_dispatch
 348
 349 sysretl_audit:
 350         auditsys_exit sysretl_from_sys_call
 351 #endif
 352
 353 cstar_tracesys:
 354 #ifdef CONFIG_AUDITSYSCALL
 355         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 356         jz cstar_auditsys
 357 #endif
 358         xchgl %r9d,%ebp
 359         SAVE_REST
 360         CLEAR_RREGS 0, r9
 361         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 362         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 363         call syscall_trace_enter
 364         LOAD_ARGS32 ARGOFFSET, 1  /* reload args from stack in case ptrace changed it */
 365         RESTORE_REST
 366         xchgl %ebp,%r9d
 367         cmpq $(IA32_NR_syscalls-1),%rax
 368         ja int_ret_from_sys_call /* cstar_tracesys has set RAX(%rsp) */
 369         jmp cstar_do_call
 370 END(ia32_cstar_target)
 371
 372 ia32_badarg:
 373         movq $-EFAULT,%rax
 374         jmp ia32_sysret
 375         CFI_ENDPROC
 376
 377 /*
 378  * Emulated IA32 system calls via int 0x80.
 379  *
 380  * Arguments:
 381  * %eax System call number.
 382  * %ebx Arg1
 383  * %ecx Arg2
 384  * %edx Arg3
 385  * %esi Arg4
 386  * %edi Arg5
 387  * %ebp Arg6    [note: not saved in the stack frame, should not be touched]
 388  *
 389  * Notes:
 390  * Uses the same stack frame as the x86-64 version.
 391  * All registers except %eax must be saved (but ptrace may violate that)
 392  * Arguments are zero extended. For system calls that want sign extension and
 393  * take long arguments a wrapper is needed. Most calls can just be called
 394  * directly.
 395  * Assumes it is only called from user space and entered with interrupts off.
 396  */
 397
 398 ENTRY(ia32_syscall)
 399         CFI_STARTPROC32 simple
 400         CFI_SIGNAL_FRAME
 401         CFI_DEF_CFA     rsp,SS+8-RIP
 402         /*CFI_REL_OFFSET        ss,SS-RIP*/
 403         CFI_REL_OFFSET  rsp,RSP-RIP
 404         /*CFI_REL_OFFSET        rflags,EFLAGS-RIP*/
 405         /*CFI_REL_OFFSET        cs,CS-RIP*/
 406         CFI_REL_OFFSET  rip,RIP-RIP
 407         PARAVIRT_ADJUST_EXCEPTION_FRAME
 408         SWAPGS
 409         /*
 410          * No need to follow this irqs on/off section: the syscall
 411          * disabled irqs and here we enable it straight after entry:
 412          */
 413         ENABLE_INTERRUPTS(CLBR_NONE)
 414         movl %eax,%eax
 415         pushq_cfi %rax
 416         cld
 417         /* note the registers are not zero extended to the sf.
 418            this could be a problem. */
 419         SAVE_ARGS 0,1,0
 420         orl $TS_COMPAT,TI_status+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 421         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 422         jnz ia32_tracesys
 423         cmpq $(IA32_NR_syscalls-1),%rax
 424         ja ia32_badsys
 425 ia32_do_call:
 426         IA32_ARG_FIXUP
 427         call *ia32_sys_call_table(,%rax,8) # xxx: rip relative
 428 ia32_sysret:
 429         movq %rax,RAX-ARGOFFSET(%rsp)
 430 ia32_ret_from_sys_call:
 431         CLEAR_RREGS -ARGOFFSET
 432         jmp int_ret_from_sys_call
 433
 434 ia32_tracesys:
 435         SAVE_REST
 436         CLEAR_RREGS
 437         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 438         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 439         call syscall_trace_enter
 440         LOAD_ARGS32 ARGOFFSET  /* reload args from stack in case ptrace changed it */
 441         RESTORE_REST
 442         cmpq $(IA32_NR_syscalls-1),%rax
 443         ja  int_ret_from_sys_call       /* ia32_tracesys has set RAX(%rsp) */
 444         jmp ia32_do_call
 445 END(ia32_syscall)
 446
 447 ia32_badsys:
 448         movq $0,ORIG_RAX-ARGOFFSET(%rsp)
 449         movq $-ENOSYS,%rax
 450         jmp ia32_sysret
 451
 452 quiet_ni_syscall:
 453         movq $-ENOSYS,%rax
 454         ret
 455         CFI_ENDPROC
 456
 457         .macro PTREGSCALL label, func, arg
 458         ALIGN
 459 GLOBAL(\label)
 460         leaq \func(%rip),%rax
 461         leaq -ARGOFFSET+8(%rsp),\arg    /* 8 for return address */
 462         jmp  ia32_ptregs_common
 463         .endm
 464
 465         CFI_STARTPROC32
 466
 467         PTREGSCALL stub32_rt_sigreturn, sys32_rt_sigreturn, %rdi
 468         PTREGSCALL stub32_sigreturn, sys32_sigreturn, %rdi
 469         PTREGSCALL stub32_sigaltstack, sys32_sigaltstack, %rdx
 470         PTREGSCALL stub32_execve, sys32_execve, %rcx
 471         PTREGSCALL stub32_fork, sys_fork, %rdi
 472         PTREGSCALL stub32_clone, sys32_clone, %rdx
 473         PTREGSCALL stub32_vfork, sys_vfork, %rdi
 474         PTREGSCALL stub32_iopl, sys_iopl, %rsi
 475
 476         ALIGN
 477 ia32_ptregs_common:
 478         popq %r11
 479         CFI_ENDPROC
 480         CFI_STARTPROC32 simple
 481         CFI_SIGNAL_FRAME
 482         CFI_DEF_CFA     rsp,SS+8-ARGOFFSET
 483         CFI_REL_OFFSET  rax,RAX-ARGOFFSET
 484         CFI_REL_OFFSET  rcx,RCX-ARGOFFSET
 485         CFI_REL_OFFSET  rdx,RDX-ARGOFFSET
 486         CFI_REL_OFFSET  rsi,RSI-ARGOFFSET
 487         CFI_REL_OFFSET  rdi,RDI-ARGOFFSET
 488         CFI_REL_OFFSET  rip,RIP-ARGOFFSET
 489 /*      CFI_REL_OFFSET  cs,CS-ARGOFFSET*/
 490 /*      CFI_REL_OFFSET  rflags,EFLAGS-ARGOFFSET*/
 491         CFI_REL_OFFSET  rsp,RSP-ARGOFFSET
 492 /*      CFI_REL_OFFSET  ss,SS-ARGOFFSET*/
 493         SAVE_REST
 494         call *%rax
 495         RESTORE_REST
 496         jmp  ia32_sysret        /* misbalances the return cache */
 497         CFI_ENDPROC
 498 END(ia32_ptregs_common)
 499
 500         .section .rodata,"a"
 501         .align 8
 502 ia32_sys_call_table:
 503         .quad sys_restart_syscall
 504         .quad sys_exit
 505         .quad stub32_fork
 506         .quad sys_read
 507         .quad sys_write
 508         .quad compat_sys_open           /* 5 */
 509         .quad sys_close
 510         .quad sys32_waitpid
 511         .quad sys_creat
 512         .quad sys_link
 513         .quad sys_unlink                /* 10 */
 514         .quad stub32_execve
 515         .quad sys_chdir
 516         .quad compat_sys_time
 517         .quad sys_mknod
 518         .quad sys_chmod         /* 15 */
 519         .quad sys_lchown16
 520         .quad quiet_ni_syscall                  /* old break syscall holder */
 521         .quad sys_stat
 522         .quad sys32_lseek
 523         .quad sys_getpid                /* 20 */
 524         .quad compat_sys_mount  /* mount  */
 525         .quad sys_oldumount     /* old_umount  */
 526         .quad sys_setuid16
 527         .quad sys_getuid16
 528         .quad compat_sys_stime  /* stime */             /* 25 */
 529         .quad compat_sys_ptrace /* ptrace */
 530         .quad sys_alarm
 531         .quad sys_fstat /* (old)fstat */
 532         .quad sys_pause
 533         .quad compat_sys_utime  /* 30 */
 534         .quad quiet_ni_syscall  /* old stty syscall holder */
 535         .quad quiet_ni_syscall  /* old gtty syscall holder */
 536         .quad sys_access
 537         .quad sys_nice
 538         .quad quiet_ni_syscall  /* 35 */        /* old ftime syscall holder */
 539         .quad sys_sync
 540         .quad sys32_kill
 541         .quad sys_rename
 542         .quad sys_mkdir
 543         .quad sys_rmdir         /* 40 */
 544         .quad sys_dup
 545         .quad sys_pipe
 546         .quad compat_sys_times
 547         .quad quiet_ni_syscall                  /* old prof syscall holder */
 548         .quad sys_brk           /* 45 */
 549         .quad sys_setgid16
 550         .quad sys_getgid16
 551         .quad sys_signal
 552         .quad sys_geteuid16
 553         .quad sys_getegid16     /* 50 */
 554         .quad sys_acct
 555         .quad sys_umount                        /* new_umount */
 556         .quad quiet_ni_syscall                  /* old lock syscall holder */
 557         .quad compat_sys_ioctl
 558         .quad compat_sys_fcntl64                /* 55 */
 559         .quad quiet_ni_syscall                  /* old mpx syscall holder */
 560         .quad sys_setpgid
 561         .quad quiet_ni_syscall                  /* old ulimit syscall holder */
 562         .quad sys_olduname
 563         .quad sys_umask         /* 60 */
 564         .quad sys_chroot
 565         .quad compat_sys_ustat
 566         .quad sys_dup2
 567         .quad sys_getppid
 568         .quad sys_getpgrp               /* 65 */
 569         .quad sys_setsid
 570         .quad sys32_sigaction
 571         .quad sys_sgetmask
 572         .quad sys_ssetmask
 573         .quad sys_setreuid16    /* 70 */
 574         .quad sys_setregid16
 575         .quad sys32_sigsuspend
 576         .quad compat_sys_sigpending
 577         .quad sys_sethostname
 578         .quad compat_sys_setrlimit      /* 75 */
 579         .quad compat_sys_old_getrlimit  /* old_getrlimit */
 580         .quad compat_sys_getrusage
 581         .quad compat_sys_gettimeofday
 582         .quad compat_sys_settimeofday
 583         .quad sys_getgroups16   /* 80 */
 584         .quad sys_setgroups16
 585         .quad compat_sys_old_select
 586         .quad sys_symlink
 587         .quad sys_lstat
 588         .quad sys_readlink              /* 85 */
 589         .quad sys_uselib
 590         .quad sys_swapon
 591         .quad sys_reboot
 592         .quad compat_sys_old_readdir
 593         .quad sys32_mmap                /* 90 */
 594         .quad sys_munmap
 595         .quad sys_truncate
 596         .quad sys_ftruncate
 597         .quad sys_fchmod
 598         .quad sys_fchown16              /* 95 */
 599         .quad sys_getpriority
 600         .quad sys_setpriority
 601         .quad quiet_ni_syscall                  /* old profil syscall holder */
 602         .quad compat_sys_statfs
 603         .quad compat_sys_fstatfs                /* 100 */
 604         .quad sys_ioperm
 605         .quad compat_sys_socketcall
 606         .quad sys_syslog
 607         .quad compat_sys_setitimer
 608         .quad compat_sys_getitimer      /* 105 */
 609         .quad compat_sys_newstat
 610         .quad compat_sys_newlstat
 611         .quad compat_sys_newfstat
 612         .quad sys_uname
 613         .quad stub32_iopl               /* 110 */
 614         .quad sys_vhangup
 615         .quad quiet_ni_syscall  /* old "idle" system call */
 616         .quad sys32_vm86_warning        /* vm86old */
 617         .quad compat_sys_wait4
 618         .quad sys_swapoff               /* 115 */
 619         .quad compat_sys_sysinfo
 620         .quad sys32_ipc
 621         .quad sys_fsync
 622         .quad stub32_sigreturn
 623         .quad stub32_clone              /* 120 */
 624         .quad sys_setdomainname
 625         .quad sys_newuname
 626         .quad sys_modify_ldt
 627         .quad compat_sys_adjtimex
 628         .quad sys32_mprotect            /* 125 */
 629         .quad compat_sys_sigprocmask
 630         .quad quiet_ni_syscall          /* create_module */
 631         .quad sys_init_module
 632         .quad sys_delete_module
 633         .quad quiet_ni_syscall          /* 130  get_kernel_syms */
 634         .quad sys32_quotactl
 635         .quad sys_getpgid
 636         .quad sys_fchdir
 637         .quad quiet_ni_syscall  /* bdflush */
 638         .quad sys_sysfs         /* 135 */
 639         .quad sys_personality
 640         .quad quiet_ni_syscall  /* for afs_syscall */
 641         .quad sys_setfsuid16
 642         .quad sys_setfsgid16
 643         .quad sys_llseek                /* 140 */
 644         .quad compat_sys_getdents
 645         .quad compat_sys_select
 646         .quad sys_flock
 647         .quad sys_msync
 648         .quad compat_sys_readv          /* 145 */
 649         .quad compat_sys_writev
 650         .quad sys_getsid
 651         .quad sys_fdatasync
 652         .quad compat_sys_sysctl /* sysctl */
 653         .quad sys_mlock         /* 150 */
 654         .quad sys_munlock
 655         .quad sys_mlockall
 656         .quad sys_munlockall
 657         .quad sys_sched_setparam
 658         .quad sys_sched_getparam   /* 155 */
 659         .quad sys_sched_setscheduler
 660         .quad sys_sched_getscheduler
 661         .quad sys_sched_yield
 662         .quad sys_sched_get_priority_max
 663         .quad sys_sched_get_priority_min  /* 160 */
 664         .quad sys32_sched_rr_get_interval
 665         .quad compat_sys_nanosleep
 666         .quad sys_mremap
 667         .quad sys_setresuid16
 668         .quad sys_getresuid16   /* 165 */
 669         .quad sys32_vm86_warning        /* vm86 */
 670         .quad quiet_ni_syscall  /* query_module */
 671         .quad sys_poll
 672         .quad quiet_ni_syscall /* old nfsservctl */
 673         .quad sys_setresgid16   /* 170 */
 674         .quad sys_getresgid16
 675         .quad sys_prctl
 676         .quad stub32_rt_sigreturn
 677         .quad sys32_rt_sigaction
 678         .quad sys32_rt_sigprocmask      /* 175 */
 679         .quad sys32_rt_sigpending
 680         .quad compat_sys_rt_sigtimedwait
 681         .quad sys32_rt_sigqueueinfo
 682         .quad sys_rt_sigsuspend
 683         .quad sys32_pread               /* 180 */
 684         .quad sys32_pwrite
 685         .quad sys_chown16
 686         .quad sys_getcwd
 687         .quad sys_capget
 688         .quad sys_capset
 689         .quad stub32_sigaltstack
 690         .quad sys32_sendfile
 691         .quad quiet_ni_syscall          /* streams1 */
 692         .quad quiet_ni_syscall          /* streams2 */
 693         .quad stub32_vfork            /* 190 */
 694         .quad compat_sys_getrlimit
 695         .quad sys_mmap_pgoff
 696         .quad sys32_truncate64
 697         .quad sys32_ftruncate64
 698         .quad sys32_stat64              /* 195 */
 699         .quad sys32_lstat64
 700         .quad sys32_fstat64
 701         .quad sys_lchown
 702         .quad sys_getuid
 703         .quad sys_getgid                /* 200 */
 704         .quad sys_geteuid
 705         .quad sys_getegid
 706         .quad sys_setreuid
 707         .quad sys_setregid
 708         .quad sys_getgroups     /* 205 */
 709         .quad sys_setgroups
 710         .quad sys_fchown
 711         .quad sys_setresuid
 712         .quad sys_getresuid
 713         .quad sys_setresgid     /* 210 */
 714         .quad sys_getresgid
 715         .quad sys_chown
 716         .quad sys_setuid
 717         .quad sys_setgid
 718         .quad sys_setfsuid              /* 215 */
 719         .quad sys_setfsgid
 720         .quad sys_pivot_root
 721         .quad sys_mincore
 722         .quad sys_madvise
 723         .quad compat_sys_getdents64     /* 220 getdents64 */
 724         .quad compat_sys_fcntl64
 725         .quad quiet_ni_syscall          /* tux */
 726         .quad quiet_ni_syscall          /* security */
 727         .quad sys_gettid
 728         .quad sys32_readahead   /* 225 */
 729         .quad sys_setxattr
 730         .quad sys_lsetxattr
 731         .quad sys_fsetxattr
 732         .quad sys_getxattr
 733         .quad sys_lgetxattr     /* 230 */
 734         .quad sys_fgetxattr
 735         .quad sys_listxattr
 736         .quad sys_llistxattr
 737         .quad sys_flistxattr
 738         .quad sys_removexattr   /* 235 */
 739         .quad sys_lremovexattr
 740         .quad sys_fremovexattr
 741         .quad sys_tkill
 742         .quad sys_sendfile64
 743         .quad compat_sys_futex          /* 240 */
 744         .quad compat_sys_sched_setaffinity
 745         .quad compat_sys_sched_getaffinity
 746         .quad sys_set_thread_area
 747         .quad sys_get_thread_area
 748         .quad compat_sys_io_setup       /* 245 */
 749         .quad sys_io_destroy
 750         .quad compat_sys_io_getevents
 751         .quad compat_sys_io_submit
 752         .quad sys_io_cancel
 753         .quad sys32_fadvise64           /* 250 */
 754         .quad quiet_ni_syscall  /* free_huge_pages */
 755         .quad sys_exit_group
 756         .quad sys32_lookup_dcookie
 757         .quad sys_epoll_create
 758         .quad sys_epoll_ctl             /* 255 */
 759         .quad sys_epoll_wait
 760         .quad sys_remap_file_pages
 761         .quad sys_set_tid_address
 762         .quad compat_sys_timer_create
 763         .quad compat_sys_timer_settime  /* 260 */
 764         .quad compat_sys_timer_gettime
 765         .quad sys_timer_getoverrun
 766         .quad sys_timer_delete
 767         .quad compat_sys_clock_settime
 768         .quad compat_sys_clock_gettime  /* 265 */
 769         .quad compat_sys_clock_getres
 770         .quad compat_sys_clock_nanosleep
 771         .quad compat_sys_statfs64
 772         .quad compat_sys_fstatfs64
 773         .quad sys_tgkill                /* 270 */
 774         .quad compat_sys_utimes
 775         .quad sys32_fadvise64_64
 776         .quad quiet_ni_syscall  /* sys_vserver */
 777         .quad sys_mbind
 778         .quad compat_sys_get_mempolicy  /* 275 */
 779         .quad sys_set_mempolicy
 780         .quad compat_sys_mq_open
 781         .quad sys_mq_unlink
 782         .quad compat_sys_mq_timedsend
 783         .quad compat_sys_mq_timedreceive        /* 280 */
 784         .quad compat_sys_mq_notify
 785         .quad compat_sys_mq_getsetattr
 786         .quad compat_sys_kexec_load     /* reserved for kexec */
 787         .quad compat_sys_waitid
 788         .quad quiet_ni_syscall          /* 285: sys_altroot */
 789         .quad sys_add_key
 790         .quad sys_request_key
 791         .quad sys_keyctl
 792         .quad sys_ioprio_set
 793         .quad sys_ioprio_get            /* 290 */
 794         .quad sys_inotify_init
 795         .quad sys_inotify_add_watch
 796         .quad sys_inotify_rm_watch
 797         .quad sys_migrate_pages
 798         .quad compat_sys_openat         /* 295 */
 799         .quad sys_mkdirat
 800         .quad sys_mknodat
 801         .quad sys_fchownat
 802         .quad compat_sys_futimesat
 803         .quad sys32_fstatat             /* 300 */
 804         .quad sys_unlinkat
 805         .quad sys_renameat
 806         .quad sys_linkat
 807         .quad sys_symlinkat
 808         .quad sys_readlinkat            /* 305 */
 809         .quad sys_fchmodat
 810         .quad sys_faccessat
 811         .quad compat_sys_pselect6
 812         .quad compat_sys_ppoll
 813         .quad sys_unshare               /* 310 */
 814         .quad compat_sys_set_robust_list
 815         .quad compat_sys_get_robust_list
 816         .quad sys_splice
 817         .quad sys32_sync_file_range
 818         .quad sys_tee                   /* 315 */
 819         .quad compat_sys_vmsplice
 820         .quad compat_sys_move_pages
 821         .quad sys_getcpu
 822         .quad sys_epoll_pwait
 823         .quad compat_sys_utimensat      /* 320 */
 824         .quad compat_sys_signalfd
 825         .quad sys_timerfd_create
 826         .quad sys_eventfd
 827         .quad sys32_fallocate
 828         .quad compat_sys_timerfd_settime        /* 325 */
 829         .quad compat_sys_timerfd_gettime
 830         .quad compat_sys_signalfd4
 831         .quad sys_eventfd2
 832         .quad sys_epoll_create1
 833         .quad sys_dup3                          /* 330 */
 834         .quad sys_pipe2
 835         .quad sys_inotify_init1
 836         .quad compat_sys_preadv
 837         .quad compat_sys_pwritev
 838         .quad compat_sys_rt_tgsigqueueinfo      /* 335 */
 839         .quad sys_perf_event_open
 840         .quad compat_sys_recvmmsg
 841         .quad sys_fanotify_init
 842         .quad sys32_fanotify_mark
 843         .quad sys_prlimit64             /* 340 */
 844         .quad sys_name_to_handle_at
 845         .quad compat_sys_open_by_handle_at
 846         .quad compat_sys_clock_adjtime
 847         .quad sys_syncfs
 848         .quad compat_sys_sendmmsg       /* 345 */
 849         .quad sys_setns
 850         .quad compat_sys_process_vm_readv
 851         .quad compat_sys_process_vm_writev
 852 ia32_syscall_end: