arch/x86/ia32/ia32entry.S

   1 /*
   2  * Compatibility mode system call entry point for x86-64.
   3  *
   4  * Copyright 2000-2002 Andi Kleen, SuSE Labs.
   5  */
   6
   7 #include <asm/dwarf2.h>
   8 #include <asm/calling.h>
   9 #include <asm/asm-offsets.h>
  10 #include <asm/current.h>
  11 #include <asm/errno.h>
  12 #include <asm/ia32_unistd.h>
  13 #include <asm/thread_info.h>
  14 #include <asm/segment.h>
  15 #include <asm/irqflags.h>
  16 #include <asm/asm.h>
  17 #include <asm/smap.h>
  18 #include <linux/linkage.h>
  19 #include <linux/err.h>
  20
  21 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  22 #include <linux/elf-em.h>
  23 #define AUDIT_ARCH_I386         (EM_386|__AUDIT_ARCH_LE)
  24 #define __AUDIT_ARCH_LE    0x40000000
  25
  26 #ifndef CONFIG_AUDITSYSCALL
  27 #define sysexit_audit ia32_ret_from_sys_call
  28 #define sysretl_audit ia32_ret_from_sys_call
  29 #endif
  30
  31         .section .entry.text, "ax"
  32
  33         /* clobbers %rax */
  34         .macro  CLEAR_RREGS _r9=rax
  35         xorl    %eax,%eax
  36         movq    %rax,R11(%rsp)
  37         movq    %rax,R10(%rsp)
  38         movq    %\_r9,R9(%rsp)
  39         movq    %rax,R8(%rsp)
  40         .endm
  41
  42         /*
  43          * Reload arg registers from stack in case ptrace changed them.
  44          * We don't reload %eax because syscall_trace_enter() returned
  45          * the %rax value we should see.  Instead, we just truncate that
  46          * value to 32 bits again as we did on entry from user mode.
  47          * If it's a new value set by user_regset during entry tracing,
  48          * this matches the normal truncation of the user-mode value.
  49          * If it's -1 to make us punt the syscall, then (u32)-1 is still
  50          * an appropriately invalid value.
  51          */
  52         .macro LOAD_ARGS32 _r9=0
  53         .if \_r9
  54         movl R9(%rsp),%r9d
  55         .endif
  56         movl RCX(%rsp),%ecx
  57         movl RDX(%rsp),%edx
  58         movl RSI(%rsp),%esi
  59         movl RDI(%rsp),%edi
  60         movl %eax,%eax                  /* zero extension */
  61         .endm
  62
  63         .macro CFI_STARTPROC32 simple
  64         CFI_STARTPROC   \simple
  65         CFI_UNDEFINED   r8
  66         CFI_UNDEFINED   r9
  67         CFI_UNDEFINED   r10
  68         CFI_UNDEFINED   r11
  69         CFI_UNDEFINED   r12
  70         CFI_UNDEFINED   r13
  71         CFI_UNDEFINED   r14
  72         CFI_UNDEFINED   r15
  73         .endm
  74
  75 #ifdef CONFIG_PARAVIRT
  76 ENTRY(native_usergs_sysret32)
  77         swapgs
  78         sysretl
  79 ENDPROC(native_usergs_sysret32)
  80
  81 ENTRY(native_irq_enable_sysexit)
  82         swapgs
  83         sti
  84         sysexit
  85 ENDPROC(native_irq_enable_sysexit)
  86 #endif
  87
  88 /*
  89  * 32bit SYSENTER instruction entry.
  90  *
  91  * SYSENTER loads ss, rsp, cs, and rip from previously programmed MSRs.
  92  * IF and VM in rflags are cleared (IOW: interrupts are off).
  93  * SYSENTER does not save anything on the stack,
  94  * and does not save old rip (!!!) and rflags.
  95  *
  96  * Arguments:
  97  * eax  system call number
  98  * ebx  arg1
  99  * ecx  arg2
 100  * edx  arg3
 101  * esi  arg4
 102  * edi  arg5
 103  * ebp  user stack
 104  * 0(%ebp) arg6
 105  *
 106  * This is purely a fast path. For anything complicated we use the int 0x80
 107  * path below. We set up a complete hardware stack frame to share code
 108  * with the int 0x80 path.
 109  */
 110 ENTRY(ia32_sysenter_target)
 111         CFI_STARTPROC32 simple
 112         CFI_SIGNAL_FRAME
 113         CFI_DEF_CFA     rsp,0
 114         CFI_REGISTER    rsp,rbp
 115         SWAPGS_UNSAFE_STACK
 116         movq    PER_CPU_VAR(kernel_stack), %rsp
 117         addq    $(KERNEL_STACK_OFFSET),%rsp
 118         /*
 119          * No need to follow this irqs on/off section: the syscall
 120          * disabled irqs, here we enable it straight after entry:
 121          */
 122         ENABLE_INTERRUPTS(CLBR_NONE)
 123         /* Construct iret frame (ss,rsp,rflags,cs,rip) */
 124         movl    %ebp,%ebp               /* zero extension */
 125         pushq_cfi $__USER32_DS
 126         /*CFI_REL_OFFSET ss,0*/
 127         pushq_cfi %rbp
 128         CFI_REL_OFFSET rsp,0
 129         pushfq_cfi
 130         /*CFI_REL_OFFSET rflags,0*/
 131         movl    TI_sysenter_return+THREAD_INFO(%rsp,3*8-KERNEL_STACK_OFFSET),%r10d
 132         CFI_REGISTER rip,r10
 133         pushq_cfi $__USER32_CS
 134         /*CFI_REL_OFFSET cs,0*/
 135         movl    %eax, %eax
 136         /* Store thread_info->sysenter_return in rip stack slot */
 137         pushq_cfi %r10
 138         CFI_REL_OFFSET rip,0
 139         /* Store orig_ax */
 140         pushq_cfi %rax
 141         /* Construct the rest of "struct pt_regs" */
 142         cld
 143         ALLOC_PT_GPREGS_ON_STACK
 144         SAVE_C_REGS_EXCEPT_R891011
 145         /*
 146          * no need to do an access_ok check here because rbp has been
 147          * 32bit zero extended
 148          */
 149         ASM_STAC
 150 1:      movl    (%rbp),%ebp
 151         _ASM_EXTABLE(1b,ia32_badarg)
 152         ASM_CLAC
 153
 154         /*
 155          * Sysenter doesn't filter flags, so we need to clear NT
 156          * ourselves.  To save a few cycles, we can check whether
 157          * NT was set instead of doing an unconditional popfq.
 158          */
 159         testl $X86_EFLAGS_NT,EFLAGS(%rsp)
 160         jnz sysenter_fix_flags
 161 sysenter_flags_fixed:
 162
 163         orl     $TS_COMPAT,TI_status+THREAD_INFO(%rsp,RIP)
 164         testl   $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP)
 165         CFI_REMEMBER_STATE
 166         jnz  sysenter_tracesys
 167         cmpq    $(IA32_NR_syscalls-1),%rax
 168         ja      ia32_badsys
 169 sysenter_do_call:
 170         /* 32bit syscall -> 64bit C ABI argument conversion */
 171         movl    %edi,%r8d       /* arg5 */
 172         movl    %ebp,%r9d       /* arg6 */
 173         xchg    %ecx,%esi       /* rsi:arg2, rcx:arg4 */
 174         movl    %ebx,%edi       /* arg1 */
 175         movl    %edx,%edx       /* arg3 (zero extension) */
 176 sysenter_dispatch:
 177         call    *ia32_sys_call_table(,%rax,8)
 178         movq    %rax,RAX(%rsp)
 179         DISABLE_INTERRUPTS(CLBR_NONE)
 180         TRACE_IRQS_OFF
 181         testl   $_TIF_ALLWORK_MASK,TI_flags+THREAD_INFO(%rsp,RIP)
 182         jnz     sysexit_audit
 183 sysexit_from_sys_call:
 184         andl    $~TS_COMPAT,TI_status+THREAD_INFO(%rsp,RIP)
 185         /* clear IF, that popfq doesn't enable interrupts early */
 186         andl    $~0x200,EFLAGS(%rsp)
 187         movl    RIP(%rsp),%edx          /* User %eip */
 188         CFI_REGISTER rip,rdx
 189         RESTORE_RSI_RDI
 190         /* pop everything except ss,rsp,rflags slots */
 191         REMOVE_PT_GPREGS_FROM_STACK 3*8
 192         xorq    %r8,%r8
 193         xorq    %r9,%r9
 194         xorq    %r10,%r10
 195         xorq    %r11,%r11
 196         popfq_cfi
 197         /*CFI_RESTORE rflags*/
 198         popq_cfi %rcx                           /* User %esp */
 199         CFI_REGISTER rsp,rcx
 200         TRACE_IRQS_ON
 201         /*
 202          * 32bit SYSEXIT restores eip from edx, esp from ecx.
 203          * cs and ss are loaded from MSRs.
 204          */
 205         ENABLE_INTERRUPTS_SYSEXIT32
 206
 207         CFI_RESTORE_STATE
 208
 209 #ifdef CONFIG_AUDITSYSCALL
 210         .macro auditsys_entry_common
 211         movl %esi,%r8d                  /* 5th arg: 4th syscall arg */
 212         movl %ecx,%r9d                  /*swap with edx*/
 213         movl %edx,%ecx                  /* 4th arg: 3rd syscall arg */
 214         movl %r9d,%edx                  /* 3rd arg: 2nd syscall arg */
 215         movl %ebx,%esi                  /* 2nd arg: 1st syscall arg */
 216         movl %eax,%edi                  /* 1st arg: syscall number */
 217         call __audit_syscall_entry
 218         movl RAX(%rsp),%eax     /* reload syscall number */
 219         cmpq $(IA32_NR_syscalls-1),%rax
 220         ja ia32_badsys
 221         movl %ebx,%edi                  /* reload 1st syscall arg */
 222         movl RCX(%rsp),%esi     /* reload 2nd syscall arg */
 223         movl RDX(%rsp),%edx     /* reload 3rd syscall arg */
 224         movl RSI(%rsp),%ecx     /* reload 4th syscall arg */
 225         movl RDI(%rsp),%r8d     /* reload 5th syscall arg */
 226         .endm
 227
 228         .macro auditsys_exit exit
 229         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP)
 230         jnz ia32_ret_from_sys_call
 231         TRACE_IRQS_ON
 232         ENABLE_INTERRUPTS(CLBR_NONE)
 233         movl %eax,%esi          /* second arg, syscall return value */
 234         cmpl $-MAX_ERRNO,%eax   /* is it an error ? */
 235         jbe 1f
 236         movslq %eax, %rsi       /* if error sign extend to 64 bits */
 237 1:      setbe %al               /* 1 if error, 0 if not */
 238         movzbl %al,%edi         /* zero-extend that into %edi */
 239         call __audit_syscall_exit
 240         movq RAX(%rsp),%rax     /* reload syscall return value */
 241         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 242         DISABLE_INTERRUPTS(CLBR_NONE)
 243         TRACE_IRQS_OFF
 244         testl %edi,TI_flags+THREAD_INFO(%rsp,RIP)
 245         jz \exit
 246         CLEAR_RREGS
 247         jmp int_with_check
 248         .endm
 249
 250 sysenter_auditsys:
 251         auditsys_entry_common
 252         movl %ebp,%r9d                  /* reload 6th syscall arg */
 253         jmp sysenter_dispatch
 254
 255 sysexit_audit:
 256         auditsys_exit sysexit_from_sys_call
 257 #endif
 258
 259 sysenter_fix_flags:
 260         pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_FIXED)
 261         popfq_cfi
 262         jmp sysenter_flags_fixed
 263
 264 sysenter_tracesys:
 265 #ifdef CONFIG_AUDITSYSCALL
 266         testl   $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP)
 267         jz      sysenter_auditsys
 268 #endif
 269         SAVE_EXTRA_REGS
 270         CLEAR_RREGS
 271         movq    $-ENOSYS,RAX(%rsp)/* ptrace can change this for a bad syscall */
 272         movq    %rsp,%rdi        /* &pt_regs -> arg1 */
 273         call    syscall_trace_enter
 274         LOAD_ARGS32  /* reload args from stack in case ptrace changed it */
 275         RESTORE_EXTRA_REGS
 276         cmpq    $(IA32_NR_syscalls-1),%rax
 277         ja      int_ret_from_sys_call /* sysenter_tracesys has set RAX(%rsp) */
 278         jmp     sysenter_do_call
 279         CFI_ENDPROC
 280 ENDPROC(ia32_sysenter_target)
 281
 282 /*
 283  * 32bit SYSCALL instruction entry.
 284  *
 285  * 32bit SYSCALL saves rip to rcx, clears rflags.RF, then saves rflags to r11,
 286  * then loads new ss, cs, and rip from previously programmed MSRs.
 287  * rflags gets masked by a value from another MSR (so CLD and CLAC
 288  * are not needed). SYSCALL does not save anything on the stack
 289  * and does not change rsp.
 290  *
 291  * Note: rflags saving+masking-with-MSR happens only in Long mode
 292  * (in legacy 32bit mode, IF, RF and VM bits are cleared and that's it).
 293  * Don't get confused: rflags saving+masking depends on Long Mode Active bit
 294  * (EFER.LMA=1), NOT on bitness of userspace where SYSCALL executes
 295  * or target CS descriptor's L bit (SYSCALL does not read segment descriptors).
 296  *
 297  * Arguments:
 298  * eax  system call number
 299  * ecx  return address
 300  * ebx  arg1
 301  * ebp  arg2    (note: not saved in the stack frame, should not be touched)
 302  * edx  arg3
 303  * esi  arg4
 304  * edi  arg5
 305  * esp  user stack
 306  * 0(%esp) arg6
 307  *
 308  * This is purely a fast path. For anything complicated we use the int 0x80
 309  * path below. We set up a complete hardware stack frame to share code
 310  * with the int 0x80 path.
 311  */
 312 ENTRY(ia32_cstar_target)
 313         CFI_STARTPROC32 simple
 314         CFI_SIGNAL_FRAME
 315         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 316         CFI_REGISTER    rip,rcx
 317         /*CFI_REGISTER  rflags,r11*/
 318         SWAPGS_UNSAFE_STACK
 319         movl    %esp,%r8d
 320         CFI_REGISTER    rsp,r8
 321         movq    PER_CPU_VAR(kernel_stack),%rsp
 322         /*
 323          * No need to follow this irqs on/off section: the syscall
 324          * disabled irqs and here we enable it straight after entry:
 325          */
 326         ENABLE_INTERRUPTS(CLBR_NONE)
 327         ALLOC_PT_GPREGS_ON_STACK 8      /* +8: space for orig_ax */
 328         SAVE_C_REGS_EXCEPT_RCX_R891011
 329         movl    %eax,%eax       /* zero extension */
 330         movq    %rax,ORIG_RAX(%rsp)
 331         movq    %rcx,RIP(%rsp)
 332         CFI_REL_OFFSET rip,RIP
 333         movq    %rbp,RCX(%rsp) /* this lies slightly to ptrace */
 334         movl    %ebp,%ecx
 335         movq    $__USER32_CS,CS(%rsp)
 336         movq    $__USER32_DS,SS(%rsp)
 337         movq    %r11,EFLAGS(%rsp)
 338         /*CFI_REL_OFFSET rflags,EFLAGS*/
 339         movq    %r8,RSP(%rsp)
 340         CFI_REL_OFFSET rsp,RSP
 341         /* iret stack frame is complete now */
 342         /*
 343          * no need to do an access_ok check here because r8 has been
 344          * 32bit zero extended
 345          */
 346         ASM_STAC
 347 1:      movl    (%r8),%r9d
 348         _ASM_EXTABLE(1b,ia32_badarg)
 349         ASM_CLAC
 350         orl     $TS_COMPAT,TI_status+THREAD_INFO(%rsp,RIP)
 351         testl   $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP)
 352         CFI_REMEMBER_STATE
 353         jnz   cstar_tracesys
 354         cmpq $IA32_NR_syscalls-1,%rax
 355         ja  ia32_badsys
 356 cstar_do_call:
 357         /* 32bit syscall -> 64bit C ABI argument conversion */
 358         movl    %edi,%r8d       /* arg5 */
 359         /* r9 already loaded */ /* arg6 */
 360         xchg    %ecx,%esi       /* rsi:arg2, rcx:arg4 */
 361         movl    %ebx,%edi       /* arg1 */
 362         movl    %edx,%edx       /* arg3 (zero extension) */
 363 cstar_dispatch:
 364         call *ia32_sys_call_table(,%rax,8)
 365         movq %rax,RAX(%rsp)
 366         DISABLE_INTERRUPTS(CLBR_NONE)
 367         TRACE_IRQS_OFF
 368         testl $_TIF_ALLWORK_MASK,TI_flags+THREAD_INFO(%rsp,RIP)
 369         jnz sysretl_audit
 370 sysretl_from_sys_call:
 371         andl $~TS_COMPAT,TI_status+THREAD_INFO(%rsp,RIP)
 372         RESTORE_RSI_RDI_RDX
 373         movl RIP(%rsp),%ecx
 374         CFI_REGISTER rip,rcx
 375         movl EFLAGS(%rsp),%r11d
 376         /*CFI_REGISTER rflags,r11*/
 377         xorq    %r10,%r10
 378         xorq    %r9,%r9
 379         xorq    %r8,%r8
 380         TRACE_IRQS_ON
 381         movl RSP(%rsp),%esp
 382         CFI_RESTORE rsp
 383         /*
 384          * 64bit->32bit SYSRET restores eip from ecx,
 385          * eflags from r11 (but RF and VM bits are forced to 0),
 386          * cs and ss are loaded from MSRs.
 387          * (Note: 32bit->32bit SYSRET is different: since r11
 388          * does not exist, it merely sets eflags.IF=1).
 389          */
 390         USERGS_SYSRET32
 391
 392 #ifdef CONFIG_AUDITSYSCALL
 393 cstar_auditsys:
 394         CFI_RESTORE_STATE
 395         movl %r9d,R9(%rsp)      /* register to be clobbered by call */
 396         auditsys_entry_common
 397         movl R9(%rsp),%r9d      /* reload 6th syscall arg */
 398         jmp cstar_dispatch
 399
 400 sysretl_audit:
 401         auditsys_exit sysretl_from_sys_call
 402 #endif
 403
 404 cstar_tracesys:
 405 #ifdef CONFIG_AUDITSYSCALL
 406         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP)
 407         jz cstar_auditsys
 408 #endif
 409         xchgl %r9d,%ebp
 410         SAVE_EXTRA_REGS
 411         CLEAR_RREGS r9
 412         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 413         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 414         call syscall_trace_enter
 415         LOAD_ARGS32 1   /* reload args from stack in case ptrace changed it */
 416         RESTORE_EXTRA_REGS
 417         xchgl %ebp,%r9d
 418         cmpq $(IA32_NR_syscalls-1),%rax
 419         ja int_ret_from_sys_call /* cstar_tracesys has set RAX(%rsp) */
 420         jmp cstar_do_call
 421 END(ia32_cstar_target)
 422
 423 ia32_badarg:
 424         ASM_CLAC
 425         movq $-EFAULT,%rax
 426         jmp ia32_sysret
 427         CFI_ENDPROC
 428
 429 /*
 430  * Emulated IA32 system calls via int 0x80.
 431  *
 432  * Arguments:
 433  * eax  system call number
 434  * ebx  arg1
 435  * ecx  arg2
 436  * edx  arg3
 437  * esi  arg4
 438  * edi  arg5
 439  * ebp  arg6    (note: not saved in the stack frame, should not be touched)
 440  *
 441  * Notes:
 442  * Uses the same stack frame as the x86-64 version.
 443  * All registers except eax must be saved (but ptrace may violate that).
 444  * Arguments are zero extended. For system calls that want sign extension and
 445  * take long arguments a wrapper is needed. Most calls can just be called
 446  * directly.
 447  * Assumes it is only called from user space and entered with interrupts off.
 448  */
 449
 450 ENTRY(ia32_syscall)
 451         CFI_STARTPROC32 simple
 452         CFI_SIGNAL_FRAME
 453         CFI_DEF_CFA     rsp,SS+8-RIP
 454         /*CFI_REL_OFFSET        ss,SS-RIP*/
 455         CFI_REL_OFFSET  rsp,RSP-RIP
 456         /*CFI_REL_OFFSET        rflags,EFLAGS-RIP*/
 457         /*CFI_REL_OFFSET        cs,CS-RIP*/
 458         CFI_REL_OFFSET  rip,RIP-RIP
 459         PARAVIRT_ADJUST_EXCEPTION_FRAME
 460         SWAPGS
 461         /*
 462          * No need to follow this irqs on/off section: the syscall
 463          * disabled irqs and here we enable it straight after entry:
 464          */
 465         ENABLE_INTERRUPTS(CLBR_NONE)
 466         movl %eax,%eax
 467         pushq_cfi %rax          /* store orig_ax */
 468         cld
 469         /* note the registers are not zero extended to the sf.
 470            this could be a problem. */
 471         ALLOC_PT_GPREGS_ON_STACK
 472         SAVE_C_REGS_EXCEPT_R891011
 473         orl $TS_COMPAT,TI_status+THREAD_INFO(%rsp,RIP)
 474         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP)
 475         jnz ia32_tracesys
 476         cmpq $(IA32_NR_syscalls-1),%rax
 477         ja ia32_badsys
 478 ia32_do_call:
 479         /* 32bit syscall -> 64bit C ABI argument conversion */
 480         movl %edi,%r8d  /* arg5 */
 481         movl %ebp,%r9d  /* arg6 */
 482         xchg %ecx,%esi  /* rsi:arg2, rcx:arg4 */
 483         movl %ebx,%edi  /* arg1 */
 484         movl %edx,%edx  /* arg3 (zero extension) */
 485         call *ia32_sys_call_table(,%rax,8) # xxx: rip relative
 486 ia32_sysret:
 487         movq %rax,RAX(%rsp)
 488 ia32_ret_from_sys_call:
 489         CLEAR_RREGS
 490         jmp int_ret_from_sys_call
 491
 492 ia32_tracesys:
 493         SAVE_EXTRA_REGS
 494         CLEAR_RREGS
 495         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 496         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 497         call syscall_trace_enter
 498         LOAD_ARGS32     /* reload args from stack in case ptrace changed it */
 499         RESTORE_EXTRA_REGS
 500         cmpq $(IA32_NR_syscalls-1),%rax
 501         ja  int_ret_from_sys_call       /* ia32_tracesys has set RAX(%rsp) */
 502         jmp ia32_do_call
 503 END(ia32_syscall)
 504
 505 ia32_badsys:
 506         movq $0,ORIG_RAX(%rsp)
 507         movq $-ENOSYS,%rax
 508         jmp ia32_sysret
 509
 510         CFI_ENDPROC
 511
 512         .macro PTREGSCALL label, func
 513         ALIGN
 514 GLOBAL(\label)
 515         leaq \func(%rip),%rax
 516         jmp  ia32_ptregs_common
 517         .endm
 518
 519         CFI_STARTPROC32
 520
 521         PTREGSCALL stub32_rt_sigreturn, sys32_rt_sigreturn
 522         PTREGSCALL stub32_sigreturn, sys32_sigreturn
 523         PTREGSCALL stub32_execve, compat_sys_execve
 524         PTREGSCALL stub32_execveat, compat_sys_execveat
 525         PTREGSCALL stub32_fork, sys_fork
 526         PTREGSCALL stub32_vfork, sys_vfork
 527
 528         ALIGN
 529 GLOBAL(stub32_clone)
 530         leaq sys_clone(%rip),%rax
 531         mov     %r8, %rcx
 532         jmp  ia32_ptregs_common
 533
 534         ALIGN
 535 ia32_ptregs_common:
 536         CFI_ENDPROC
 537         CFI_STARTPROC32 simple
 538         CFI_SIGNAL_FRAME
 539         CFI_DEF_CFA     rsp,SS+8
 540         CFI_REL_OFFSET  rax,RAX
 541         CFI_REL_OFFSET  rcx,RCX
 542         CFI_REL_OFFSET  rdx,RDX
 543         CFI_REL_OFFSET  rsi,RSI
 544         CFI_REL_OFFSET  rdi,RDI
 545         CFI_REL_OFFSET  rip,RIP
 546 /*      CFI_REL_OFFSET  cs,CS*/
 547 /*      CFI_REL_OFFSET  rflags,EFLAGS*/
 548         CFI_REL_OFFSET  rsp,RSP
 549 /*      CFI_REL_OFFSET  ss,SS*/
 550         SAVE_EXTRA_REGS 8
 551         call *%rax
 552         RESTORE_EXTRA_REGS 8
 553         ret
 554         CFI_ENDPROC
 555 END(ia32_ptregs_common)