arch/x86/include/asm/calling.h

   1 /*
   2
   3  x86 function call convention, 64-bit:
   4  -------------------------------------
   5   arguments           |  callee-saved      | extra caller-saved | return
   6  [callee-clobbered]   |                    | [callee-clobbered] |
   7  ---------------------------------------------------------------------------
   8  rdi rsi rdx rcx r8-9 | rbx rbp [*] r12-15 | r10-11             | rax, rdx [**]
   9
  10  ( rsp is obviously invariant across normal function calls. (gcc can 'merge'
  11    functions when it sees tail-call optimization possibilities) rflags is
  12    clobbered. Leftover arguments are passed over the stack frame.)
  13
  14  [*]  In the frame-pointers case rbp is fixed to the stack frame.
  15
  16  [**] for struct return values wider than 64 bits the return convention is a
  17       bit more complex: up to 128 bits width we return small structures
  18       straight in rax, rdx. For structures larger than that (3 words or
  19       larger) the caller puts a pointer to an on-stack return struct
  20       [allocated in the caller's stack frame] into the first argument - i.e.
  21       into rdi. All other arguments shift up by one in this case.
  22       Fortunately this case is rare in the kernel.
  23
  24 For 32-bit we have the following conventions - kernel is built with
  25 -mregparm=3 and -freg-struct-return:
  26
  27  x86 function calling convention, 32-bit:
  28  ----------------------------------------
  29   arguments         | callee-saved        | extra caller-saved | return
  30  [callee-clobbered] |                     | [callee-clobbered] |
  31  -------------------------------------------------------------------------
  32  eax edx ecx        | ebx edi esi ebp [*] | <none>             | eax, edx [**]
  33
  34  ( here too esp is obviously invariant across normal function calls. eflags
  35    is clobbered. Leftover arguments are passed over the stack frame. )
  36
  37  [*]  In the frame-pointers case ebp is fixed to the stack frame.
  38
  39  [**] We build with -freg-struct-return, which on 32-bit means similar
  40       semantics as on 64-bit: edx can be used for a second return value
  41       (i.e. covering integer and structure sizes up to 64 bits) - after that
  42       it gets more complex and more expensive: 3-word or larger struct returns
  43       get done in the caller's frame and the pointer to the return struct goes
  44       into regparm0, i.e. eax - the other arguments shift up and the
  45       function's register parameters degenerate to regparm=2 in essence.
  46
  47 */
  48
  49 #include <asm/dwarf2.h>
  50
  51 #ifdef CONFIG_X86_64
  52
  53 /*
  54  * 64-bit system call stack frame layout defines and helpers,
  55  * for assembly code:
  56  */
  57
  58 /* The layout forms the "struct pt_regs" on the stack: */
  59 /*
  60  * C ABI says these regs are callee-preserved. They aren't saved on kernel entry
  61  * unless syscall needs a complete, fully filled "struct pt_regs".
  62  */
  63 #define R15             0*8
  64 #define R14             1*8
  65 #define R13             2*8
  66 #define R12             3*8
  67 #define RBP             4*8
  68 #define RBX             5*8
  69 /* These regs are callee-clobbered. Always saved on kernel entry. */
  70 #define R11             6*8
  71 #define R10             7*8
  72 #define R9              8*8
  73 #define R8              9*8
  74 #define RAX             10*8
  75 #define RCX             11*8
  76 #define RDX             12*8
  77 #define RSI             13*8
  78 #define RDI             14*8
  79 /*
  80  * On syscall entry, this is syscall#. On CPU exception, this is error code.
  81  * On hw interrupt, it's IRQ number:
  82  */
  83 #define ORIG_RAX        15*8
  84 /* Return frame for iretq */
  85 #define RIP             16*8
  86 #define CS              17*8
  87 #define EFLAGS          18*8
  88 #define RSP             19*8
  89 #define SS              20*8
  90
  91         .macro ALLOC_PT_GPREGS_ON_STACK addskip=0
  92         subq    $15*8+\addskip, %rsp
  93         CFI_ADJUST_CFA_OFFSET 15*8+\addskip
  94         .endm
  95
  96         .macro SAVE_C_REGS_HELPER offset=0 rax=1 rcx=1 r8plus=1
  97         .if \r8plus
  98         movq_cfi r11, 6*8+\offset
  99         movq_cfi r10, 7*8+\offset
 100         movq_cfi r9,  8*8+\offset
 101         movq_cfi r8,  9*8+\offset
 102         .endif
 103         .if \rax
 104         movq_cfi rax, 10*8+\offset
 105         .endif
 106         .if \rcx
 107         movq_cfi rcx, 11*8+\offset
 108         .endif
 109         movq_cfi rdx, 12*8+\offset
 110         movq_cfi rsi, 13*8+\offset
 111         movq_cfi rdi, 14*8+\offset
 112         .endm
 113         .macro SAVE_C_REGS offset=0
 114         SAVE_C_REGS_HELPER \offset, 1, 1, 1
 115         .endm
 116         .macro SAVE_C_REGS_EXCEPT_RAX_RCX offset=0
 117         SAVE_C_REGS_HELPER \offset, 0, 0, 1
 118         .endm
 119         .macro SAVE_C_REGS_EXCEPT_R891011
 120         SAVE_C_REGS_HELPER 0, 1, 1, 0
 121         .endm
 122         .macro SAVE_C_REGS_EXCEPT_RCX_R891011
 123         SAVE_C_REGS_HELPER 0, 1, 0, 0
 124         .endm
 125
 126         .macro SAVE_EXTRA_REGS offset=0
 127         movq_cfi r15, 0*8+\offset
 128         movq_cfi r14, 1*8+\offset
 129         movq_cfi r13, 2*8+\offset
 130         movq_cfi r12, 3*8+\offset
 131         movq_cfi rbp, 4*8+\offset
 132         movq_cfi rbx, 5*8+\offset
 133         .endm
 134         .macro SAVE_EXTRA_REGS_RBP offset=0
 135         movq_cfi rbp, 4*8+\offset
 136         .endm
 137
 138         .macro RESTORE_EXTRA_REGS offset=0
 139         movq_cfi_restore 0*8+\offset, r15
 140         movq_cfi_restore 1*8+\offset, r14
 141         movq_cfi_restore 2*8+\offset, r13
 142         movq_cfi_restore 3*8+\offset, r12
 143         movq_cfi_restore 4*8+\offset, rbp
 144         movq_cfi_restore 5*8+\offset, rbx
 145         .endm
 146
 147         .macro RESTORE_C_REGS_HELPER rstor_rax=1, rstor_rcx=1, rstor_r11=1, rstor_r8910=1, rstor_rdx=1
 148         .if \rstor_r11
 149         movq_cfi_restore 6*8, r11
 150         .endif
 151         .if \rstor_r8910
 152         movq_cfi_restore 7*8, r10
 153         movq_cfi_restore 8*8, r9
 154         movq_cfi_restore 9*8, r8
 155         .endif
 156         .if \rstor_rax
 157         movq_cfi_restore 10*8, rax
 158         .endif
 159         .if \rstor_rcx
 160         movq_cfi_restore 11*8, rcx
 161         .endif
 162         .if \rstor_rdx
 163         movq_cfi_restore 12*8, rdx
 164         .endif
 165         movq_cfi_restore 13*8, rsi
 166         movq_cfi_restore 14*8, rdi
 167         .endm
 168         .macro RESTORE_C_REGS
 169         RESTORE_C_REGS_HELPER 1,1,1,1,1
 170         .endm
 171         .macro RESTORE_C_REGS_EXCEPT_RAX
 172         RESTORE_C_REGS_HELPER 0,1,1,1,1
 173         .endm
 174         .macro RESTORE_C_REGS_EXCEPT_RCX
 175         RESTORE_C_REGS_HELPER 1,0,1,1,1
 176         .endm
 177         .macro RESTORE_RSI_RDI
 178         RESTORE_C_REGS_HELPER 0,0,0,0,0
 179         .endm
 180         .macro RESTORE_RSI_RDI_RDX
 181         RESTORE_C_REGS_HELPER 0,0,0,0,1
 182         .endm
 183
 184         .macro REMOVE_PT_GPREGS_FROM_STACK addskip=0
 185         addq $15*8+\addskip, %rsp
 186         CFI_ADJUST_CFA_OFFSET -(15*8+\addskip)
 187         .endm
 188
 189         .macro icebp
 190         .byte 0xf1
 191         .endm
 192
 193 #else /* CONFIG_X86_64 */
 194
 195 /*
 196  * For 32bit only simplified versions of SAVE_ALL/RESTORE_ALL. These
 197  * are different from the entry_32.S versions in not changing the segment
 198  * registers. So only suitable for in kernel use, not when transitioning
 199  * from or to user space. The resulting stack frame is not a standard
 200  * pt_regs frame. The main use case is calling C code from assembler
 201  * when all the registers need to be preserved.
 202  */
 203
 204         .macro SAVE_ALL
 205         pushl_cfi_reg eax
 206         pushl_cfi_reg ebp
 207         pushl_cfi_reg edi
 208         pushl_cfi_reg esi
 209         pushl_cfi_reg edx
 210         pushl_cfi_reg ecx
 211         pushl_cfi_reg ebx
 212         .endm
 213
 214         .macro RESTORE_ALL
 215         popl_cfi_reg ebx
 216         popl_cfi_reg ecx
 217         popl_cfi_reg edx
 218         popl_cfi_reg esi
 219         popl_cfi_reg edi
 220         popl_cfi_reg ebp
 221         popl_cfi_reg eax
 222         .endm
 223
 224 #endif /* CONFIG_X86_64 */
 225