projects / deliverable / linux.git / blob
? search:


848f73f09549e3d8701f2080ccaddfb15b0d5363
[deliverable/linux.git] / arch / x86 / kernel / entry_32.S
1 /*
2 *
3 * Copyright (C) 1991, 1992 Linus Torvalds
4 */
5
6 /*
7 * entry.S contains the system-call and fault low-level handling routines.
8 * This also contains the timer-interrupt handler, as well as all interrupts
9 * and faults that can result in a task-switch.
10 *
11 * NOTE: This code handles signal-recognition, which happens every time
12 * after a timer-interrupt and after each system call.
13 *
14 * I changed all the .align's to 4 (16 byte alignment), as that's faster
15 * on a 486.
16 *
17 * Stack layout in 'syscall_exit':
18 * ptrace needs to have all regs on the stack.
19 * if the order here is changed, it needs to be
20 * updated in fork.c:copy_process, signal.c:do_signal,
21 * ptrace.c and ptrace.h
22 *
23 * 0(%esp) - %ebx
24 * 4(%esp) - %ecx
25 * 8(%esp) - %edx
26 * C(%esp) - %esi
27 * 10(%esp) - %edi
28 * 14(%esp) - %ebp
29 * 18(%esp) - %eax
30 * 1C(%esp) - %ds
31 * 20(%esp) - %es
32 * 24(%esp) - %fs
33 * 28(%esp) - %gs saved iff !CONFIG_X86_32_LAZY_GS
34 * 2C(%esp) - orig_eax
35 * 30(%esp) - %eip
36 * 34(%esp) - %cs
37 * 38(%esp) - %eflags
38 * 3C(%esp) - %oldesp
39 * 40(%esp) - %oldss
40 *
41 * "current" is in register %ebx during any slow entries.
42 */
43
44 #include <linux/linkage.h>
45 #include <asm/thread_info.h>
46 #include <asm/irqflags.h>
47 #include <asm/errno.h>
48 #include <asm/segment.h>
49 #include <asm/smp.h>
50 #include <asm/page_types.h>
51 #include <asm/desc.h>
52 #include <asm/percpu.h>
53 #include <asm/dwarf2.h>
54 #include <asm/processor-flags.h>
55 #include <asm/ftrace.h>
56 #include <asm/irq_vectors.h>
57
58 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this. */
59 #include <linux/elf-em.h>
60 #define AUDIT_ARCH_I386 (EM_386|__AUDIT_ARCH_LE)
61 #define __AUDIT_ARCH_LE 0x40000000
62
63 #ifndef CONFIG_AUDITSYSCALL
64 #define sysenter_audit syscall_trace_entry
65 #define sysexit_audit syscall_exit_work
66 #endif
67
68 /*
69 * We use macros for low-level operations which need to be overridden
70 * for paravirtualization. The following will never clobber any registers:
71 * INTERRUPT_RETURN (aka. "iret")
72 * GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
73 * ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
74 *
75 * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
76 * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
77 * Allowing a register to be clobbered can shrink the paravirt replacement
78 * enough to patch inline, increasing performance.
79 */
80
81 #define nr_syscalls ((syscall_table_size)/4)
82
83 #ifdef CONFIG_PREEMPT
84 #define preempt_stop(clobbers) DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
85 #else
86 #define preempt_stop(clobbers)
87 #define resume_kernel restore_all
88 #endif
89
90 .macro TRACE_IRQS_IRET
91 #ifdef CONFIG_TRACE_IRQFLAGS
92 testl $X86_EFLAGS_IF,PT_EFLAGS(%esp) # interrupts off?
93 jz 1f
94 TRACE_IRQS_ON
95 1:
96 #endif
97 .endm
98
99 #ifdef CONFIG_VM86
100 #define resume_userspace_sig check_userspace
101 #else
102 #define resume_userspace_sig resume_userspace
103 #endif
104
105 /*
106 * User gs save/restore
107 *
108 * %gs is used for userland TLS and kernel only uses it for stack
109 * canary which is required to be at %gs:20 by gcc. Read the comment
110 * at the top of stackprotector.h for more info.
111 *
112 * Local labels 98 and 99 are used.
113 */
114 #ifdef CONFIG_X86_32_LAZY_GS
115
116 /* unfortunately push/pop can't be no-op */
117 .macro PUSH_GS
118 pushl $0
119 CFI_ADJUST_CFA_OFFSET 4
120 .endm
121 .macro POP_GS pop=0
122 addl $(4 + \pop), %esp
123 CFI_ADJUST_CFA_OFFSET -(4 + \pop)
124 .endm
125 .macro POP_GS_EX
126 .endm
127
128 /* all the rest are no-op */
129 .macro PTGS_TO_GS
130 .endm
131 .macro PTGS_TO_GS_EX
132 .endm
133 .macro GS_TO_REG reg
134 .endm
135 .macro REG_TO_PTGS reg
136 .endm
137 .macro SET_KERNEL_GS reg
138 .endm
139
140 #else /* CONFIG_X86_32_LAZY_GS */
141
142 .macro PUSH_GS
143 pushl %gs
144 CFI_ADJUST_CFA_OFFSET 4
145 /*CFI_REL_OFFSET gs, 0*/
146 .endm
147
148 .macro POP_GS pop=0
149 98: popl %gs
150 CFI_ADJUST_CFA_OFFSET -4
151 /*CFI_RESTORE gs*/
152 .if \pop <> 0
153 add $\pop, %esp
154 CFI_ADJUST_CFA_OFFSET -\pop
155 .endif
156 .endm
157 .macro POP_GS_EX
158 .pushsection .fixup, "ax"
159 99: movl $0, (%esp)
160 jmp 98b
161 .section __ex_table, "a"
162 .align 4
163 .long 98b, 99b
164 .popsection
165 .endm
166
167 .macro PTGS_TO_GS
168 98: mov PT_GS(%esp), %gs
169 .endm
170 .macro PTGS_TO_GS_EX
171 .pushsection .fixup, "ax"
172 99: movl $0, PT_GS(%esp)
173 jmp 98b
174 .section __ex_table, "a"
175 .align 4
176 .long 98b, 99b
177 .popsection
178 .endm
179
180 .macro GS_TO_REG reg
181 movl %gs, \reg
182 /*CFI_REGISTER gs, \reg*/
183 .endm
184 .macro REG_TO_PTGS reg
185 movl \reg, PT_GS(%esp)
186 /*CFI_REL_OFFSET gs, PT_GS*/
187 .endm
188 .macro SET_KERNEL_GS reg
189 movl $(__KERNEL_STACK_CANARY), \reg
190 movl \reg, %gs
191 .endm
192
193 #endif /* CONFIG_X86_32_LAZY_GS */
194
195 .macro SAVE_ALL
196 cld
197 PUSH_GS
198 pushl %fs
199 CFI_ADJUST_CFA_OFFSET 4
200 /*CFI_REL_OFFSET fs, 0;*/
201 pushl %es
202 CFI_ADJUST_CFA_OFFSET 4
203 /*CFI_REL_OFFSET es, 0;*/
204 pushl %ds
205 CFI_ADJUST_CFA_OFFSET 4
206 /*CFI_REL_OFFSET ds, 0;*/
207 pushl %eax
208 CFI_ADJUST_CFA_OFFSET 4
209 CFI_REL_OFFSET eax, 0
210 pushl %ebp
211 CFI_ADJUST_CFA_OFFSET 4
212 CFI_REL_OFFSET ebp, 0
213 pushl %edi
214 CFI_ADJUST_CFA_OFFSET 4
215 CFI_REL_OFFSET edi, 0
216 pushl %esi
217 CFI_ADJUST_CFA_OFFSET 4
218 CFI_REL_OFFSET esi, 0
219 pushl %edx
220 CFI_ADJUST_CFA_OFFSET 4
221 CFI_REL_OFFSET edx, 0
222 pushl %ecx
223 CFI_ADJUST_CFA_OFFSET 4
224 CFI_REL_OFFSET ecx, 0
225 pushl %ebx
226 CFI_ADJUST_CFA_OFFSET 4
227 CFI_REL_OFFSET ebx, 0
228 movl $(__USER_DS), %edx
229 movl %edx, %ds
230 movl %edx, %es
231 movl $(__KERNEL_PERCPU), %edx
232 movl %edx, %fs
233 SET_KERNEL_GS %edx
234 .endm
235
236 .macro RESTORE_INT_REGS
237 popl %ebx
238 CFI_ADJUST_CFA_OFFSET -4
239 CFI_RESTORE ebx
240 popl %ecx
241 CFI_ADJUST_CFA_OFFSET -4
242 CFI_RESTORE ecx
243 popl %edx
244 CFI_ADJUST_CFA_OFFSET -4
245 CFI_RESTORE edx
246 popl %esi
247 CFI_ADJUST_CFA_OFFSET -4
248 CFI_RESTORE esi
249 popl %edi
250 CFI_ADJUST_CFA_OFFSET -4
251 CFI_RESTORE edi
252 popl %ebp
253 CFI_ADJUST_CFA_OFFSET -4
254 CFI_RESTORE ebp
255 popl %eax
256 CFI_ADJUST_CFA_OFFSET -4
257 CFI_RESTORE eax
258 .endm
259
260 .macro RESTORE_REGS pop=0
261 RESTORE_INT_REGS
262 1: popl %ds
263 CFI_ADJUST_CFA_OFFSET -4
264 /*CFI_RESTORE ds;*/
265 2: popl %es
266 CFI_ADJUST_CFA_OFFSET -4
267 /*CFI_RESTORE es;*/
268 3: popl %fs
269 CFI_ADJUST_CFA_OFFSET -4
270 /*CFI_RESTORE fs;*/
271 POP_GS \pop
272 .pushsection .fixup, "ax"
273 4: movl $0, (%esp)
274 jmp 1b
275 5: movl $0, (%esp)
276 jmp 2b
277 6: movl $0, (%esp)
278 jmp 3b
279 .section __ex_table, "a"
280 .align 4
281 .long 1b, 4b
282 .long 2b, 5b
283 .long 3b, 6b
284 .popsection
285 POP_GS_EX
286 .endm
287
288 .macro RING0_INT_FRAME
289 CFI_STARTPROC simple
290 CFI_SIGNAL_FRAME
291 CFI_DEF_CFA esp, 3*4
292 /*CFI_OFFSET cs, -2*4;*/
293 CFI_OFFSET eip, -3*4
294 .endm
295
296 .macro RING0_EC_FRAME
297 CFI_STARTPROC simple
298 CFI_SIGNAL_FRAME
299 CFI_DEF_CFA esp, 4*4
300 /*CFI_OFFSET cs, -2*4;*/
301 CFI_OFFSET eip, -3*4
302 .endm
303
304 .macro RING0_PTREGS_FRAME
305 CFI_STARTPROC simple
306 CFI_SIGNAL_FRAME
307 CFI_DEF_CFA esp, PT_OLDESP-PT_EBX
308 /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/
309 CFI_OFFSET eip, PT_EIP-PT_OLDESP
310 /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/
311 /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/
312 CFI_OFFSET eax, PT_EAX-PT_OLDESP
313 CFI_OFFSET ebp, PT_EBP-PT_OLDESP
314 CFI_OFFSET edi, PT_EDI-PT_OLDESP
315 CFI_OFFSET esi, PT_ESI-PT_OLDESP
316 CFI_OFFSET edx, PT_EDX-PT_OLDESP
317 CFI_OFFSET ecx, PT_ECX-PT_OLDESP
318 CFI_OFFSET ebx, PT_EBX-PT_OLDESP
319 .endm
320
321 ENTRY(ret_from_fork)
322 CFI_STARTPROC
323 pushl %eax
324 CFI_ADJUST_CFA_OFFSET 4
325 call schedule_tail
326 GET_THREAD_INFO(%ebp)
327 popl %eax
328 CFI_ADJUST_CFA_OFFSET -4
329 pushl $0x0202 # Reset kernel eflags
330 CFI_ADJUST_CFA_OFFSET 4
331 popfl
332 CFI_ADJUST_CFA_OFFSET -4
333 jmp syscall_exit
334 CFI_ENDPROC
335 END(ret_from_fork)
336
337 /*
338 * Return to user mode is not as complex as all this looks,
339 * but we want the default path for a system call return to
340 * go as quickly as possible which is why some of this is
341 * less clear than it otherwise should be.
342 */
343
344 # userspace resumption stub bypassing syscall exit tracing
345 ALIGN
346 RING0_PTREGS_FRAME
347 ret_from_exception:
348 preempt_stop(CLBR_ANY)
349 ret_from_intr:
350 GET_THREAD_INFO(%ebp)
351 check_userspace:
352 movl PT_EFLAGS(%esp), %eax # mix EFLAGS and CS
353 movb PT_CS(%esp), %al
354 andl $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
355 cmpl $USER_RPL, %eax
356 jb resume_kernel # not returning to v8086 or userspace
357
358 ENTRY(resume_userspace)
359 LOCKDEP_SYS_EXIT
360 DISABLE_INTERRUPTS(CLBR_ANY) # make sure we don't miss an interrupt
361 # setting need_resched or sigpending
362 # between sampling and the iret
363 TRACE_IRQS_OFF
364 movl TI_flags(%ebp), %ecx
365 andl $_TIF_WORK_MASK, %ecx # is there any work to be done on
366 # int/exception return?
367 jne work_pending
368 jmp restore_all
369 END(ret_from_exception)
370
371 #ifdef CONFIG_PREEMPT
372 ENTRY(resume_kernel)
373 DISABLE_INTERRUPTS(CLBR_ANY)
374 cmpl $0,TI_preempt_count(%ebp) # non-zero preempt_count ?
375 jnz restore_all
376 need_resched:
377 movl TI_flags(%ebp), %ecx # need_resched set ?
378 testb $_TIF_NEED_RESCHED, %cl
379 jz restore_all
380 testl $X86_EFLAGS_IF,PT_EFLAGS(%esp) # interrupts off (exception path) ?
381 jz restore_all
382 call preempt_schedule_irq
383 jmp need_resched
384 END(resume_kernel)
385 #endif
386 CFI_ENDPROC
387
388 /* SYSENTER_RETURN points to after the "sysenter" instruction in
389 the vsyscall page. See vsyscall-sysentry.S, which defines the symbol. */
390
391 # sysenter call handler stub
392 ENTRY(ia32_sysenter_target)
393 CFI_STARTPROC simple
394 CFI_SIGNAL_FRAME
395 CFI_DEF_CFA esp, 0
396 CFI_REGISTER esp, ebp
397 movl TSS_sysenter_sp0(%esp),%esp
398 sysenter_past_esp:
399 /*
400 * Interrupts are disabled here, but we can't trace it until
401 * enough kernel state to call TRACE_IRQS_OFF can be called - but
402 * we immediately enable interrupts at that point anyway.
403 */
404 pushl $(__USER_DS)
405 CFI_ADJUST_CFA_OFFSET 4
406 /*CFI_REL_OFFSET ss, 0*/
407 pushl %ebp
408 CFI_ADJUST_CFA_OFFSET 4
409 CFI_REL_OFFSET esp, 0
410 pushfl
411 orl $X86_EFLAGS_IF, (%esp)
412 CFI_ADJUST_CFA_OFFSET 4
413 pushl $(__USER_CS)
414 CFI_ADJUST_CFA_OFFSET 4
415 /*CFI_REL_OFFSET cs, 0*/
416 /*
417 * Push current_thread_info()->sysenter_return to the stack.
418 * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
419 * pushed above; +8 corresponds to copy_thread's esp0 setting.
420 */
421 pushl (TI_sysenter_return-THREAD_SIZE+8+4*4)(%esp)
422 CFI_ADJUST_CFA_OFFSET 4
423 CFI_REL_OFFSET eip, 0
424
425 pushl %eax
426 CFI_ADJUST_CFA_OFFSET 4
427 SAVE_ALL
428 ENABLE_INTERRUPTS(CLBR_NONE)
429
430 /*
431 * Load the potential sixth argument from user stack.
432 * Careful about security.
433 */
434 cmpl $__PAGE_OFFSET-3,%ebp
435 jae syscall_fault
436 1: movl (%ebp),%ebp
437 movl %ebp,PT_EBP(%esp)
438 .section __ex_table,"a"
439 .align 4
440 .long 1b,syscall_fault
441 .previous
442
443 GET_THREAD_INFO(%ebp)
444
445 testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
446 jnz sysenter_audit
447 sysenter_do_call:
448 cmpl $(nr_syscalls), %eax
449 jae syscall_badsys
450 call *sys_call_table(,%eax,4)
451 movl %eax,PT_EAX(%esp)
452 LOCKDEP_SYS_EXIT
453 DISABLE_INTERRUPTS(CLBR_ANY)
454 TRACE_IRQS_OFF
455 movl TI_flags(%ebp), %ecx
456 testl $_TIF_ALLWORK_MASK, %ecx
457 jne sysexit_audit
458 sysenter_exit:
459 /* if something modifies registers it must also disable sysexit */
460 movl PT_EIP(%esp), %edx
461 movl PT_OLDESP(%esp), %ecx
462 xorl %ebp,%ebp
463 TRACE_IRQS_ON
464 1: mov PT_FS(%esp), %fs
465 PTGS_TO_GS
466 ENABLE_INTERRUPTS_SYSEXIT
467
468 #ifdef CONFIG_AUDITSYSCALL
469 sysenter_audit:
470 testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
471 jnz syscall_trace_entry
472 addl $4,%esp
473 CFI_ADJUST_CFA_OFFSET -4
474 /* %esi already in 8(%esp) 6th arg: 4th syscall arg */
475 /* %edx already in 4(%esp) 5th arg: 3rd syscall arg */
476 /* %ecx already in 0(%esp) 4th arg: 2nd syscall arg */
477 movl %ebx,%ecx /* 3rd arg: 1st syscall arg */
478 movl %eax,%edx /* 2nd arg: syscall number */
479 movl $AUDIT_ARCH_I386,%eax /* 1st arg: audit arch */
480 call audit_syscall_entry
481 pushl %ebx
482 CFI_ADJUST_CFA_OFFSET 4
483 movl PT_EAX(%esp),%eax /* reload syscall number */
484 jmp sysenter_do_call
485
486 sysexit_audit:
487 testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
488 jne syscall_exit_work
489 TRACE_IRQS_ON
490 ENABLE_INTERRUPTS(CLBR_ANY)
491 movl %eax,%edx /* second arg, syscall return value */
492 cmpl $0,%eax /* is it < 0? */
493 setl %al /* 1 if so, 0 if not */
494 movzbl %al,%eax /* zero-extend that */
495 inc %eax /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
496 call audit_syscall_exit
497 DISABLE_INTERRUPTS(CLBR_ANY)
498 TRACE_IRQS_OFF
499 movl TI_flags(%ebp), %ecx
500 testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
501 jne syscall_exit_work
502 movl PT_EAX(%esp),%eax /* reload syscall return value */
503 jmp sysenter_exit
504 #endif
505
506 CFI_ENDPROC
507 .pushsection .fixup,"ax"
508 2: movl $0,PT_FS(%esp)
509 jmp 1b
510 .section __ex_table,"a"
511 .align 4
512 .long 1b,2b
513 .popsection
514 PTGS_TO_GS_EX
515 ENDPROC(ia32_sysenter_target)
516
517 # system call handler stub
518 ENTRY(system_call)
519 RING0_INT_FRAME # can't unwind into user space anyway
520 pushl %eax # save orig_eax
521 CFI_ADJUST_CFA_OFFSET 4
522 SAVE_ALL
523 GET_THREAD_INFO(%ebp)
524 # system call tracing in operation / emulation
525 testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
526 jnz syscall_trace_entry
527 cmpl $(nr_syscalls), %eax
528 jae syscall_badsys
529 syscall_call:
530 call *sys_call_table(,%eax,4)
531 movl %eax,PT_EAX(%esp) # store the return value
532 syscall_exit:
533 LOCKDEP_SYS_EXIT
534 DISABLE_INTERRUPTS(CLBR_ANY) # make sure we don't miss an interrupt
535 # setting need_resched or sigpending
536 # between sampling and the iret
537 TRACE_IRQS_OFF
538 movl TI_flags(%ebp), %ecx
539 testl $_TIF_ALLWORK_MASK, %ecx # current->work
540 jne syscall_exit_work
541
542 restore_all:
543 TRACE_IRQS_IRET
544 restore_all_notrace:
545 movl PT_EFLAGS(%esp), %eax # mix EFLAGS, SS and CS
546 # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
547 # are returning to the kernel.
548 # See comments in process.c:copy_thread() for details.
549 movb PT_OLDSS(%esp), %ah
550 movb PT_CS(%esp), %al
551 andl $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
552 cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
553 CFI_REMEMBER_STATE
554 je ldt_ss # returning to user-space with LDT SS
555 restore_nocheck:
556 RESTORE_REGS 4 # skip orig_eax/error_code
557 CFI_ADJUST_CFA_OFFSET -4
558 irq_return:
559 INTERRUPT_RETURN
560 .section .fixup,"ax"
561 ENTRY(iret_exc)
562 pushl $0 # no error code
563 pushl $do_iret_error
564 jmp error_code
565 .previous
566 .section __ex_table,"a"
567 .align 4
568 .long irq_return,iret_exc
569 .previous
570
571 CFI_RESTORE_STATE
572 ldt_ss:
573 larl PT_OLDSS(%esp), %eax
574 jnz restore_nocheck
575 testl $0x00400000, %eax # returning to 32bit stack?
576 jnz restore_nocheck # allright, normal return
577
578 #ifdef CONFIG_PARAVIRT
579 /*
580 * The kernel can't run on a non-flat stack if paravirt mode
581 * is active. Rather than try to fixup the high bits of
582 * ESP, bypass this code entirely. This may break DOSemu
583 * and/or Wine support in a paravirt VM, although the option
584 * is still available to implement the setting of the high
585 * 16-bits in the INTERRUPT_RETURN paravirt-op.
586 */
587 cmpl $0, pv_info+PARAVIRT_enabled
588 jne restore_nocheck
589 #endif
590
591 /*
592 * Setup and switch to ESPFIX stack
593 *
594 * We're returning to userspace with a 16 bit stack. The CPU will not
595 * restore the high word of ESP for us on executing iret... This is an
596 * "official" bug of all the x86-compatible CPUs, which we can work
597 * around to make dosemu and wine happy. We do this by preloading the
598 * high word of ESP with the high word of the userspace ESP while
599 * compensating for the offset by changing to the ESPFIX segment with
600 * a base address that matches for the difference.
601 */
602 mov %esp, %edx /* load kernel esp */
603 mov PT_OLDESP(%esp), %eax /* load userspace esp */
604 mov %dx, %ax /* eax: new kernel esp */
605 sub %eax, %edx /* offset (low word is 0) */
606 PER_CPU(gdt_page, %ebx)
607 shr $16, %edx
608 mov %dl, GDT_ENTRY_ESPFIX_SS * 8 + 4(%ebx) /* bits 16..23 */
609 mov %dh, GDT_ENTRY_ESPFIX_SS * 8 + 7(%ebx) /* bits 24..31 */
610 pushl $__ESPFIX_SS
611 CFI_ADJUST_CFA_OFFSET 4
612 push %eax /* new kernel esp */
613 CFI_ADJUST_CFA_OFFSET 4
614 /* Disable interrupts, but do not irqtrace this section: we
615 * will soon execute iret and the tracer was already set to
616 * the irqstate after the iret */
617 DISABLE_INTERRUPTS(CLBR_EAX)
618 lss (%esp), %esp /* switch to espfix segment */
619 CFI_ADJUST_CFA_OFFSET -8
620 jmp restore_nocheck
621 CFI_ENDPROC
622 ENDPROC(system_call)
623
624 # perform work that needs to be done immediately before resumption
625 ALIGN
626 RING0_PTREGS_FRAME # can't unwind into user space anyway
627 work_pending:
628 testb $_TIF_NEED_RESCHED, %cl
629 jz work_notifysig
630 work_resched:
631 call schedule
632 LOCKDEP_SYS_EXIT
633 DISABLE_INTERRUPTS(CLBR_ANY) # make sure we don't miss an interrupt
634 # setting need_resched or sigpending
635 # between sampling and the iret
636 TRACE_IRQS_OFF
637 movl TI_flags(%ebp), %ecx
638 andl $_TIF_WORK_MASK, %ecx # is there any work to be done other
639 # than syscall tracing?
640 jz restore_all
641 testb $_TIF_NEED_RESCHED, %cl
642 jnz work_resched
643
644 work_notifysig: # deal with pending signals and
645 # notify-resume requests
646 #ifdef CONFIG_VM86
647 testl $X86_EFLAGS_VM, PT_EFLAGS(%esp)
648 movl %esp, %eax
649 jne work_notifysig_v86 # returning to kernel-space or
650 # vm86-space
651 xorl %edx, %edx
652 call do_notify_resume
653 jmp resume_userspace_sig
654
655 ALIGN
656 work_notifysig_v86:
657 pushl %ecx # save ti_flags for do_notify_resume
658 CFI_ADJUST_CFA_OFFSET 4
659 call save_v86_state # %eax contains pt_regs pointer
660 popl %ecx
661 CFI_ADJUST_CFA_OFFSET -4
662 movl %eax, %esp
663 #else
664 movl %esp, %eax
665 #endif
666 xorl %edx, %edx
667 call do_notify_resume
668 jmp resume_userspace_sig
669 END(work_pending)
670
671 # perform syscall exit tracing
672 ALIGN
673 syscall_trace_entry:
674 movl $-ENOSYS,PT_EAX(%esp)
675 movl %esp, %eax
676 call syscall_trace_enter
677 /* What it returned is what we'll actually use. */
678 cmpl $(nr_syscalls), %eax
679 jnae syscall_call
680 jmp syscall_exit
681 END(syscall_trace_entry)
682
683 # perform syscall exit tracing
684 ALIGN
685 syscall_exit_work:
686 testl $_TIF_WORK_SYSCALL_EXIT, %ecx
687 jz work_pending
688 TRACE_IRQS_ON
689 ENABLE_INTERRUPTS(CLBR_ANY) # could let syscall_trace_leave() call
690 # schedule() instead
691 movl %esp, %eax
692 call syscall_trace_leave
693 jmp resume_userspace
694 END(syscall_exit_work)
695 CFI_ENDPROC
696
697 RING0_INT_FRAME # can't unwind into user space anyway
698 syscall_fault:
699 GET_THREAD_INFO(%ebp)
700 movl $-EFAULT,PT_EAX(%esp)
701 jmp resume_userspace
702 END(syscall_fault)
703
704 syscall_badsys:
705 movl $-ENOSYS,PT_EAX(%esp)
706 jmp resume_userspace
707 END(syscall_badsys)
708 CFI_ENDPROC
709
710 /*
711 * System calls that need a pt_regs pointer.
712 */
713 #define PTREGSCALL(name) \
714 ALIGN; \
715 ptregs_##name: \
716 leal 4(%esp),%eax; \
717 jmp sys_##name;
718
719 PTREGSCALL(iopl)
720 PTREGSCALL(fork)
721 PTREGSCALL(clone)
722 PTREGSCALL(vfork)
723 PTREGSCALL(execve)
724 PTREGSCALL(sigaltstack)
725 PTREGSCALL(sigreturn)
726 PTREGSCALL(rt_sigreturn)
727 PTREGSCALL(vm86)
728 PTREGSCALL(vm86old)
729
730 .macro FIXUP_ESPFIX_STACK
731 /*
732 * Switch back for ESPFIX stack to the normal zerobased stack
733 *
734 * We can't call C functions using the ESPFIX stack. This code reads
735 * the high word of the segment base from the GDT and swiches to the
736 * normal stack and adjusts ESP with the matching offset.
737 */
738 /* fixup the stack */
739 PER_CPU(gdt_page, %ebx)
740 mov GDT_ENTRY_ESPFIX_SS * 8 + 4(%ebx), %al /* bits 16..23 */
741 mov GDT_ENTRY_ESPFIX_SS * 8 + 7(%ebx), %ah /* bits 24..31 */
742 shl $16, %eax
743 addl %esp, %eax /* the adjusted stack pointer */
744 pushl $__KERNEL_DS
745 CFI_ADJUST_CFA_OFFSET 4
746 pushl %eax
747 CFI_ADJUST_CFA_OFFSET 4
748 lss (%esp), %esp /* switch to the normal stack segment */
749 CFI_ADJUST_CFA_OFFSET -8
750 .endm
751 .macro UNWIND_ESPFIX_STACK
752 movl %ss, %eax
753 /* see if on espfix stack */
754 cmpw $__ESPFIX_SS, %ax
755 jne 27f
756 movl $__KERNEL_DS, %eax
757 movl %eax, %ds
758 movl %eax, %es
759 /* switch to normal stack */
760 FIXUP_ESPFIX_STACK
761 27:
762 .endm
763
764 /*
765 * Build the entry stubs and pointer table with some assembler magic.
766 * We pack 7 stubs into a single 32-byte chunk, which will fit in a
767 * single cache line on all modern x86 implementations.
768 */
769 .section .init.rodata,"a"
770 ENTRY(interrupt)
771 .text
772 .p2align 5
773 .p2align CONFIG_X86_L1_CACHE_SHIFT
774 ENTRY(irq_entries_start)
775 RING0_INT_FRAME
776 vector=FIRST_EXTERNAL_VECTOR
777 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
778 .balign 32
779 .rept 7
780 .if vector < NR_VECTORS
781 .if vector <> FIRST_EXTERNAL_VECTOR
782 CFI_ADJUST_CFA_OFFSET -4
783 .endif
784 1: pushl $(~vector+0x80) /* Note: always in signed byte range */
785 CFI_ADJUST_CFA_OFFSET 4
786 .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
787 jmp 2f
788 .endif
789 .previous
790 .long 1b
791 .text
792 vector=vector+1
793 .endif
794 .endr
795 2: jmp common_interrupt
796 .endr
797 END(irq_entries_start)
798
799 .previous
800 END(interrupt)
801 .previous
802
803 /*
804 * the CPU automatically disables interrupts when executing an IRQ vector,
805 * so IRQ-flags tracing has to follow that:
806 */
807 .p2align CONFIG_X86_L1_CACHE_SHIFT
808 common_interrupt:
809 addl $-0x80,(%esp) /* Adjust vector into the [-256,-1] range */
810 SAVE_ALL
811 TRACE_IRQS_OFF
812 movl %esp,%eax
813 call do_IRQ
814 jmp ret_from_intr
815 ENDPROC(common_interrupt)
816 CFI_ENDPROC
817
818 #define BUILD_INTERRUPT3(name, nr, fn) \
819 ENTRY(name) \
820 RING0_INT_FRAME; \
821 pushl $~(nr); \
822 CFI_ADJUST_CFA_OFFSET 4; \
823 SAVE_ALL; \
824 TRACE_IRQS_OFF \
825 movl %esp,%eax; \
826 call fn; \
827 jmp ret_from_intr; \
828 CFI_ENDPROC; \
829 ENDPROC(name)
830
831 #define BUILD_INTERRUPT(name, nr) BUILD_INTERRUPT3(name, nr, smp_##name)
832
833 /* The include is where all of the SMP etc. interrupts come from */
834 #include <asm/entry_arch.h>
835
836 ENTRY(coprocessor_error)
837 RING0_INT_FRAME
838 pushl $0
839 CFI_ADJUST_CFA_OFFSET 4
840 pushl $do_coprocessor_error
841 CFI_ADJUST_CFA_OFFSET 4
842 jmp error_code
843 CFI_ENDPROC
844 END(coprocessor_error)
845
846 ENTRY(simd_coprocessor_error)
847 RING0_INT_FRAME
848 pushl $0
849 CFI_ADJUST_CFA_OFFSET 4
850 pushl $do_simd_coprocessor_error
851 CFI_ADJUST_CFA_OFFSET 4
852 jmp error_code
853 CFI_ENDPROC
854 END(simd_coprocessor_error)
855
856 ENTRY(device_not_available)
857 RING0_INT_FRAME
858 pushl $-1 # mark this as an int
859 CFI_ADJUST_CFA_OFFSET 4
860 pushl $do_device_not_available
861 CFI_ADJUST_CFA_OFFSET 4
862 jmp error_code
863 CFI_ENDPROC
864 END(device_not_available)
865
866 #ifdef CONFIG_PARAVIRT
867 ENTRY(native_iret)
868 iret
869 .section __ex_table,"a"
870 .align 4
871 .long native_iret, iret_exc
872 .previous
873 END(native_iret)
874
875 ENTRY(native_irq_enable_sysexit)
876 sti
877 sysexit
878 END(native_irq_enable_sysexit)
879 #endif
880
881 ENTRY(overflow)
882 RING0_INT_FRAME
883 pushl $0
884 CFI_ADJUST_CFA_OFFSET 4
885 pushl $do_overflow
886 CFI_ADJUST_CFA_OFFSET 4
887 jmp error_code
888 CFI_ENDPROC
889 END(overflow)
890
891 ENTRY(bounds)
892 RING0_INT_FRAME
893 pushl $0
894 CFI_ADJUST_CFA_OFFSET 4
895 pushl $do_bounds
896 CFI_ADJUST_CFA_OFFSET 4
897 jmp error_code
898 CFI_ENDPROC
899 END(bounds)
900
901 ENTRY(invalid_op)
902 RING0_INT_FRAME
903 pushl $0
904 CFI_ADJUST_CFA_OFFSET 4
905 pushl $do_invalid_op
906 CFI_ADJUST_CFA_OFFSET 4
907 jmp error_code
908 CFI_ENDPROC
909 END(invalid_op)
910
911 ENTRY(coprocessor_segment_overrun)
912 RING0_INT_FRAME
913 pushl $0
914 CFI_ADJUST_CFA_OFFSET 4
915 pushl $do_coprocessor_segment_overrun
916 CFI_ADJUST_CFA_OFFSET 4
917 jmp error_code
918 CFI_ENDPROC
919 END(coprocessor_segment_overrun)
920
921 ENTRY(invalid_TSS)
922 RING0_EC_FRAME
923 pushl $do_invalid_TSS
924 CFI_ADJUST_CFA_OFFSET 4
925 jmp error_code
926 CFI_ENDPROC
927 END(invalid_TSS)
928
929 ENTRY(segment_not_present)
930 RING0_EC_FRAME
931 pushl $do_segment_not_present
932 CFI_ADJUST_CFA_OFFSET 4
933 jmp error_code
934 CFI_ENDPROC
935 END(segment_not_present)
936
937 ENTRY(stack_segment)
938 RING0_EC_FRAME
939 pushl $do_stack_segment
940 CFI_ADJUST_CFA_OFFSET 4
941 jmp error_code
942 CFI_ENDPROC
943 END(stack_segment)
944
945 ENTRY(alignment_check)
946 RING0_EC_FRAME
947 pushl $do_alignment_check
948 CFI_ADJUST_CFA_OFFSET 4
949 jmp error_code
950 CFI_ENDPROC
951 END(alignment_check)
952
953 ENTRY(divide_error)
954 RING0_INT_FRAME
955 pushl $0 # no error code
956 CFI_ADJUST_CFA_OFFSET 4
957 pushl $do_divide_error
958 CFI_ADJUST_CFA_OFFSET 4
959 jmp error_code
960 CFI_ENDPROC
961 END(divide_error)
962
963 #ifdef CONFIG_X86_MCE
964 ENTRY(machine_check)
965 RING0_INT_FRAME
966 pushl $0
967 CFI_ADJUST_CFA_OFFSET 4
968 pushl machine_check_vector
969 CFI_ADJUST_CFA_OFFSET 4
970 jmp error_code
971 CFI_ENDPROC
972 END(machine_check)
973 #endif
974
975 ENTRY(spurious_interrupt_bug)
976 RING0_INT_FRAME
977 pushl $0
978 CFI_ADJUST_CFA_OFFSET 4
979 pushl $do_spurious_interrupt_bug
980 CFI_ADJUST_CFA_OFFSET 4
981 jmp error_code
982 CFI_ENDPROC
983 END(spurious_interrupt_bug)
984
985 ENTRY(kernel_thread_helper)
986 pushl $0 # fake return address for unwinder
987 CFI_STARTPROC
988 movl %edx,%eax
989 push %edx
990 CFI_ADJUST_CFA_OFFSET 4
991 call *%ebx
992 push %eax
993 CFI_ADJUST_CFA_OFFSET 4
994 call do_exit
995 ud2 # padding for call trace
996 CFI_ENDPROC
997 ENDPROC(kernel_thread_helper)
998
999 #ifdef CONFIG_XEN
1000 /* Xen doesn't set %esp to be precisely what the normal sysenter
1001 entrypoint expects, so fix it up before using the normal path. */
1002 ENTRY(xen_sysenter_target)
1003 RING0_INT_FRAME
1004 addl $5*4, %esp /* remove xen-provided frame */
1005 CFI_ADJUST_CFA_OFFSET -5*4
1006 jmp sysenter_past_esp
1007 CFI_ENDPROC
1008
1009 ENTRY(xen_hypervisor_callback)
1010 CFI_STARTPROC
1011 pushl $0
1012 CFI_ADJUST_CFA_OFFSET 4
1013 SAVE_ALL
1014 TRACE_IRQS_OFF
1015
1016 /* Check to see if we got the event in the critical
1017 region in xen_iret_direct, after we've reenabled
1018 events and checked for pending events. This simulates
1019 iret instruction's behaviour where it delivers a
1020 pending interrupt when enabling interrupts. */
1021 movl PT_EIP(%esp),%eax
1022 cmpl $xen_iret_start_crit,%eax
1023 jb 1f
1024 cmpl $xen_iret_end_crit,%eax
1025 jae 1f
1026
1027 jmp xen_iret_crit_fixup
1028
1029 ENTRY(xen_do_upcall)
1030 1: mov %esp, %eax
1031 call xen_evtchn_do_upcall
1032 jmp ret_from_intr
1033 CFI_ENDPROC
1034 ENDPROC(xen_hypervisor_callback)
1035
1036 # Hypervisor uses this for application faults while it executes.
1037 # We get here for two reasons:
1038 # 1. Fault while reloading DS, ES, FS or GS
1039 # 2. Fault while executing IRET
1040 # Category 1 we fix up by reattempting the load, and zeroing the segment
1041 # register if the load fails.
1042 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
1043 # normal Linux return path in this case because if we use the IRET hypercall
1044 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1045 # We distinguish between categories by maintaining a status value in EAX.
1046 ENTRY(xen_failsafe_callback)
1047 CFI_STARTPROC
1048 pushl %eax
1049 CFI_ADJUST_CFA_OFFSET 4
1050 movl $1,%eax
1051 1: mov 4(%esp),%ds
1052 2: mov 8(%esp),%es
1053 3: mov 12(%esp),%fs
1054 4: mov 16(%esp),%gs
1055 testl %eax,%eax
1056 popl %eax
1057 CFI_ADJUST_CFA_OFFSET -4
1058 lea 16(%esp),%esp
1059 CFI_ADJUST_CFA_OFFSET -16
1060 jz 5f
1061 addl $16,%esp
1062 jmp iret_exc # EAX != 0 => Category 2 (Bad IRET)
1063 5: pushl $0 # EAX == 0 => Category 1 (Bad segment)
1064 CFI_ADJUST_CFA_OFFSET 4
1065 SAVE_ALL
1066 jmp ret_from_exception
1067 CFI_ENDPROC
1068
1069 .section .fixup,"ax"
1070 6: xorl %eax,%eax
1071 movl %eax,4(%esp)
1072 jmp 1b
1073 7: xorl %eax,%eax
1074 movl %eax,8(%esp)
1075 jmp 2b
1076 8: xorl %eax,%eax
1077 movl %eax,12(%esp)
1078 jmp 3b
1079 9: xorl %eax,%eax
1080 movl %eax,16(%esp)
1081 jmp 4b
1082 .previous
1083 .section __ex_table,"a"
1084 .align 4
1085 .long 1b,6b
1086 .long 2b,7b
1087 .long 3b,8b
1088 .long 4b,9b
1089 .previous
1090 ENDPROC(xen_failsafe_callback)
1091
1092 #endif /* CONFIG_XEN */
1093
1094 #ifdef CONFIG_FUNCTION_TRACER
1095 #ifdef CONFIG_DYNAMIC_FTRACE
1096
1097 ENTRY(mcount)
1098 ret
1099 END(mcount)
1100
1101 ENTRY(ftrace_caller)
1102 cmpl $0, function_trace_stop
1103 jne ftrace_stub
1104
1105 pushl %eax
1106 pushl %ecx
1107 pushl %edx
1108 movl 0xc(%esp), %eax
1109 movl 0x4(%ebp), %edx
1110 subl $MCOUNT_INSN_SIZE, %eax
1111
1112 .globl ftrace_call
1113 ftrace_call:
1114 call ftrace_stub
1115
1116 popl %edx
1117 popl %ecx
1118 popl %eax
1119 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1120 .globl ftrace_graph_call
1121 ftrace_graph_call:
1122 jmp ftrace_stub
1123 #endif
1124
1125 .globl ftrace_stub
1126 ftrace_stub:
1127 ret
1128 END(ftrace_caller)
1129
1130 #else /* ! CONFIG_DYNAMIC_FTRACE */
1131
1132 ENTRY(mcount)
1133 cmpl $0, function_trace_stop
1134 jne ftrace_stub
1135
1136 cmpl $ftrace_stub, ftrace_trace_function
1137 jnz trace
1138 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1139 cmpl $ftrace_stub, ftrace_graph_return
1140 jnz ftrace_graph_caller
1141
1142 cmpl $ftrace_graph_entry_stub, ftrace_graph_entry
1143 jnz ftrace_graph_caller
1144 #endif
1145 .globl ftrace_stub
1146 ftrace_stub:
1147 ret
1148
1149 /* taken from glibc */
1150 trace:
1151 pushl %eax
1152 pushl %ecx
1153 pushl %edx
1154 movl 0xc(%esp), %eax
1155 movl 0x4(%ebp), %edx
1156 subl $MCOUNT_INSN_SIZE, %eax
1157
1158 call *ftrace_trace_function
1159
1160 popl %edx
1161 popl %ecx
1162 popl %eax
1163 jmp ftrace_stub
1164 END(mcount)
1165 #endif /* CONFIG_DYNAMIC_FTRACE */
1166 #endif /* CONFIG_FUNCTION_TRACER */
1167
1168 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1169 ENTRY(ftrace_graph_caller)
1170 cmpl $0, function_trace_stop
1171 jne ftrace_stub
1172
1173 pushl %eax
1174 pushl %ecx
1175 pushl %edx
1176 movl 0xc(%esp), %edx
1177 lea 0x4(%ebp), %eax
1178 subl $MCOUNT_INSN_SIZE, %edx
1179 call prepare_ftrace_return
1180 popl %edx
1181 popl %ecx
1182 popl %eax
1183 ret
1184 END(ftrace_graph_caller)
1185
1186 .globl return_to_handler
1187 return_to_handler:
1188 pushl $0
1189 pushl %eax
1190 pushl %ecx
1191 pushl %edx
1192 call ftrace_return_to_handler
1193 movl %eax, 0xc(%esp)
1194 popl %edx
1195 popl %ecx
1196 popl %eax
1197 ret
1198 #endif
1199
1200 .section .rodata,"a"
1201 #include "syscall_table_32.S"
1202
1203 syscall_table_size=(.-sys_call_table)
1204
1205 /*
1206 * Some functions should be protected against kprobes
1207 */
1208 .pushsection .kprobes.text, "ax"
1209
1210 ENTRY(page_fault)
1211 RING0_EC_FRAME
1212 pushl $do_page_fault
1213 CFI_ADJUST_CFA_OFFSET 4
1214 ALIGN
1215 error_code:
1216 /* the function address is in %gs's slot on the stack */
1217 pushl %fs
1218 CFI_ADJUST_CFA_OFFSET 4
1219 /*CFI_REL_OFFSET fs, 0*/
1220 pushl %es
1221 CFI_ADJUST_CFA_OFFSET 4
1222 /*CFI_REL_OFFSET es, 0*/
1223 pushl %ds
1224 CFI_ADJUST_CFA_OFFSET 4
1225 /*CFI_REL_OFFSET ds, 0*/
1226 pushl %eax
1227 CFI_ADJUST_CFA_OFFSET 4
1228 CFI_REL_OFFSET eax, 0
1229 pushl %ebp
1230 CFI_ADJUST_CFA_OFFSET 4
1231 CFI_REL_OFFSET ebp, 0
1232 pushl %edi
1233 CFI_ADJUST_CFA_OFFSET 4
1234 CFI_REL_OFFSET edi, 0
1235 pushl %esi
1236 CFI_ADJUST_CFA_OFFSET 4
1237 CFI_REL_OFFSET esi, 0
1238 pushl %edx
1239 CFI_ADJUST_CFA_OFFSET 4
1240 CFI_REL_OFFSET edx, 0
1241 pushl %ecx
1242 CFI_ADJUST_CFA_OFFSET 4
1243 CFI_REL_OFFSET ecx, 0
1244 pushl %ebx
1245 CFI_ADJUST_CFA_OFFSET 4
1246 CFI_REL_OFFSET ebx, 0
1247 cld
1248 movl $(__KERNEL_PERCPU), %ecx
1249 movl %ecx, %fs
1250 UNWIND_ESPFIX_STACK
1251 GS_TO_REG %ecx
1252 movl PT_GS(%esp), %edi # get the function address
1253 movl PT_ORIG_EAX(%esp), %edx # get the error code
1254 movl $-1, PT_ORIG_EAX(%esp) # no syscall to restart
1255 REG_TO_PTGS %ecx
1256 SET_KERNEL_GS %ecx
1257 movl $(__USER_DS), %ecx
1258 movl %ecx, %ds
1259 movl %ecx, %es
1260 TRACE_IRQS_OFF
1261 movl %esp,%eax # pt_regs pointer
1262 call *%edi
1263 jmp ret_from_exception
1264 CFI_ENDPROC
1265 END(page_fault)
1266
1267 /*
1268 * Debug traps and NMI can happen at the one SYSENTER instruction
1269 * that sets up the real kernel stack. Check here, since we can't
1270 * allow the wrong stack to be used.
1271 *
1272 * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
1273 * already pushed 3 words if it hits on the sysenter instruction:
1274 * eflags, cs and eip.
1275 *
1276 * We just load the right stack, and push the three (known) values
1277 * by hand onto the new stack - while updating the return eip past
1278 * the instruction that would have done it for sysenter.
1279 */
1280 .macro FIX_STACK offset ok label
1281 cmpw $__KERNEL_CS, 4(%esp)
1282 jne \ok
1283 \label:
1284 movl TSS_sysenter_sp0 + \offset(%esp), %esp
1285 CFI_DEF_CFA esp, 0
1286 CFI_UNDEFINED eip
1287 pushfl
1288 CFI_ADJUST_CFA_OFFSET 4
1289 pushl $__KERNEL_CS
1290 CFI_ADJUST_CFA_OFFSET 4
1291 pushl $sysenter_past_esp
1292 CFI_ADJUST_CFA_OFFSET 4
1293 CFI_REL_OFFSET eip, 0
1294 .endm
1295
1296 ENTRY(debug)
1297 RING0_INT_FRAME
1298 cmpl $ia32_sysenter_target,(%esp)
1299 jne debug_stack_correct
1300 FIX_STACK 12, debug_stack_correct, debug_esp_fix_insn
1301 debug_stack_correct:
1302 pushl $-1 # mark this as an int
1303 CFI_ADJUST_CFA_OFFSET 4
1304 SAVE_ALL
1305 TRACE_IRQS_OFF
1306 xorl %edx,%edx # error code 0
1307 movl %esp,%eax # pt_regs pointer
1308 call do_debug
1309 jmp ret_from_exception
1310 CFI_ENDPROC
1311 END(debug)
1312
1313 /*
1314 * NMI is doubly nasty. It can happen _while_ we're handling
1315 * a debug fault, and the debug fault hasn't yet been able to
1316 * clear up the stack. So we first check whether we got an
1317 * NMI on the sysenter entry path, but after that we need to
1318 * check whether we got an NMI on the debug path where the debug
1319 * fault happened on the sysenter path.
1320 */
1321 ENTRY(nmi)
1322 RING0_INT_FRAME
1323 pushl %eax
1324 CFI_ADJUST_CFA_OFFSET 4
1325 movl %ss, %eax
1326 cmpw $__ESPFIX_SS, %ax
1327 popl %eax
1328 CFI_ADJUST_CFA_OFFSET -4
1329 je nmi_espfix_stack
1330 cmpl $ia32_sysenter_target,(%esp)
1331 je nmi_stack_fixup
1332 pushl %eax
1333 CFI_ADJUST_CFA_OFFSET 4
1334 movl %esp,%eax
1335 /* Do not access memory above the end of our stack page,
1336 * it might not exist.
1337 */
1338 andl $(THREAD_SIZE-1),%eax
1339 cmpl $(THREAD_SIZE-20),%eax
1340 popl %eax
1341 CFI_ADJUST_CFA_OFFSET -4
1342 jae nmi_stack_correct
1343 cmpl $ia32_sysenter_target,12(%esp)
1344 je nmi_debug_stack_check
1345 nmi_stack_correct:
1346 /* We have a RING0_INT_FRAME here */
1347 pushl %eax
1348 CFI_ADJUST_CFA_OFFSET 4
1349 SAVE_ALL
1350 xorl %edx,%edx # zero error code
1351 movl %esp,%eax # pt_regs pointer
1352 call do_nmi
1353 jmp restore_all_notrace
1354 CFI_ENDPROC
1355
1356 nmi_stack_fixup:
1357 RING0_INT_FRAME
1358 FIX_STACK 12, nmi_stack_correct, 1
1359 jmp nmi_stack_correct
1360
1361 nmi_debug_stack_check:
1362 /* We have a RING0_INT_FRAME here */
1363 cmpw $__KERNEL_CS,16(%esp)
1364 jne nmi_stack_correct
1365 cmpl $debug,(%esp)
1366 jb nmi_stack_correct
1367 cmpl $debug_esp_fix_insn,(%esp)
1368 ja nmi_stack_correct
1369 FIX_STACK 24, nmi_stack_correct, 1
1370 jmp nmi_stack_correct
1371
1372 nmi_espfix_stack:
1373 /* We have a RING0_INT_FRAME here.
1374 *
1375 * create the pointer to lss back
1376 */
1377 pushl %ss
1378 CFI_ADJUST_CFA_OFFSET 4
1379 pushl %esp
1380 CFI_ADJUST_CFA_OFFSET 4
1381 addl $4, (%esp)
1382 /* copy the iret frame of 12 bytes */
1383 .rept 3
1384 pushl 16(%esp)
1385 CFI_ADJUST_CFA_OFFSET 4
1386 .endr
1387 pushl %eax
1388 CFI_ADJUST_CFA_OFFSET 4
1389 SAVE_ALL
1390 FIXUP_ESPFIX_STACK # %eax == %esp
1391 xorl %edx,%edx # zero error code
1392 call do_nmi
1393 RESTORE_REGS
1394 lss 12+4(%esp), %esp # back to espfix stack
1395 CFI_ADJUST_CFA_OFFSET -24
1396 jmp irq_return
1397 CFI_ENDPROC
1398 END(nmi)
1399
1400 ENTRY(int3)
1401 RING0_INT_FRAME
1402 pushl $-1 # mark this as an int
1403 CFI_ADJUST_CFA_OFFSET 4
1404 SAVE_ALL
1405 TRACE_IRQS_OFF
1406 xorl %edx,%edx # zero error code
1407 movl %esp,%eax # pt_regs pointer
1408 call do_int3
1409 jmp ret_from_exception
1410 CFI_ENDPROC
1411 END(int3)
1412
1413 ENTRY(general_protection)
1414 RING0_EC_FRAME
1415 pushl $do_general_protection
1416 CFI_ADJUST_CFA_OFFSET 4
1417 jmp error_code
1418 CFI_ENDPROC
1419 END(general_protection)
1420
1421 /*
1422 * End of kprobes section
1423 */
1424 .popsection
Linux kernel - Deliverables
This page took 0.062189 seconds and 4 git commands to generate.