arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after an interrupt and after each system call.
  14  *
  15  * Normal syscalls and interrupts don't save a full stack frame, this is
  16  * only done for syscall tracing, signals or fork/exec et.al.
  17  *
  18  * A note on terminology:
  19  * - top of stack: Architecture defined interrupt frame from SS to RIP
  20  * at the top of the kernel process stack.
  21  * - partial stack frame: partially saved registers upto R11.
  22  * - full stack frame: Like partial stack frame, but all register saved.
  23  *
  24  * Some macro usage:
  25  * - CFI macros are used to generate dwarf2 unwind information for better
  26  * backtraces. They don't change any code.
  27  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  28  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  29  * There are unfortunately lots of special cases where some registers
  30  * not touched. The macro is a big mess that should be cleaned up.
  31  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  32  * Gives a full stack frame.
  33  * - ENTRY/END Define functions in the symbol table.
  34  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  35  * frame that is otherwise undefined after a SYSCALL
  36  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  37  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  38  */
  39
  40 #include <linux/linkage.h>
  41 #include <asm/segment.h>
  42 #include <asm/cache.h>
  43 #include <asm/errno.h>
  44 #include <asm/dwarf2.h>
  45 #include <asm/calling.h>
  46 #include <asm/asm-offsets.h>
  47 #include <asm/msr.h>
  48 #include <asm/unistd.h>
  49 #include <asm/thread_info.h>
  50 #include <asm/hw_irq.h>
  51 #include <asm/page.h>
  52 #include <asm/irqflags.h>
  53 #include <asm/paravirt.h>
  54 #include <asm/ftrace.h>
  55
  56 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  57 #include <linux/elf-em.h>
  58 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  59 #define __AUDIT_ARCH_64BIT 0x80000000
  60 #define __AUDIT_ARCH_LE    0x40000000
  61
  62         .code64
  63 #ifdef CONFIG_FUNCTION_TRACER
  64 #ifdef CONFIG_DYNAMIC_FTRACE
  65 ENTRY(mcount)
  66         retq
  67 END(mcount)
  68
  69 ENTRY(ftrace_caller)
  70         cmpl $0, function_trace_stop
  71         jne  ftrace_stub
  72
  73         MCOUNT_SAVE_FRAME
  74
  75         movq 0x38(%rsp), %rdi
  76         movq 8(%rbp), %rsi
  77         subq $MCOUNT_INSN_SIZE, %rdi
  78
  79 .globl ftrace_call
  80 ftrace_call:
  81         call ftrace_stub
  82
  83         MCOUNT_RESTORE_FRAME
  84
  85 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  86 .globl ftrace_graph_call
  87 ftrace_graph_call:
  88         jmp ftrace_stub
  89 #endif
  90
  91 .globl ftrace_stub
  92 ftrace_stub:
  93         retq
  94 END(ftrace_caller)
  95
  96 #else /* ! CONFIG_DYNAMIC_FTRACE */
  97 ENTRY(mcount)
  98         cmpl $0, function_trace_stop
  99         jne  ftrace_stub
 100
 101         cmpq $ftrace_stub, ftrace_trace_function
 102         jnz trace
 103
 104 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 105         cmpq $ftrace_stub, ftrace_graph_return
 106         jnz ftrace_graph_caller
 107
 108         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 109         jnz ftrace_graph_caller
 110 #endif
 111
 112 .globl ftrace_stub
 113 ftrace_stub:
 114         retq
 115
 116 trace:
 117         MCOUNT_SAVE_FRAME
 118
 119         movq 0x38(%rsp), %rdi
 120         movq 8(%rbp), %rsi
 121         subq $MCOUNT_INSN_SIZE, %rdi
 122
 123         call   *ftrace_trace_function
 124
 125         MCOUNT_RESTORE_FRAME
 126
 127         jmp ftrace_stub
 128 END(mcount)
 129 #endif /* CONFIG_DYNAMIC_FTRACE */
 130 #endif /* CONFIG_FUNCTION_TRACER */
 131
 132 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 133 ENTRY(ftrace_graph_caller)
 134         cmpl $0, function_trace_stop
 135         jne ftrace_stub
 136
 137         MCOUNT_SAVE_FRAME
 138
 139         leaq 8(%rbp), %rdi
 140         movq 0x38(%rsp), %rsi
 141         subq $MCOUNT_INSN_SIZE, %rsi
 142
 143         call    prepare_ftrace_return
 144
 145         MCOUNT_RESTORE_FRAME
 146
 147         retq
 148 END(ftrace_graph_caller)
 149
 150
 151 .globl return_to_handler
 152 return_to_handler:
 153         subq  $80, %rsp
 154
 155         movq %rax, (%rsp)
 156         movq %rcx, 8(%rsp)
 157         movq %rdx, 16(%rsp)
 158         movq %rsi, 24(%rsp)
 159         movq %rdi, 32(%rsp)
 160         movq %r8, 40(%rsp)
 161         movq %r9, 48(%rsp)
 162         movq %r10, 56(%rsp)
 163         movq %r11, 64(%rsp)
 164
 165         call ftrace_return_to_handler
 166
 167         movq %rax, 72(%rsp)
 168         movq 64(%rsp), %r11
 169         movq 56(%rsp), %r10
 170         movq 48(%rsp), %r9
 171         movq 40(%rsp), %r8
 172         movq 32(%rsp), %rdi
 173         movq 24(%rsp), %rsi
 174         movq 16(%rsp), %rdx
 175         movq 8(%rsp), %rcx
 176         movq (%rsp), %rax
 177         addq $72, %rsp
 178         retq
 179 #endif
 180
 181
 182 #ifndef CONFIG_PREEMPT
 183 #define retint_kernel retint_restore_args
 184 #endif
 185
 186 #ifdef CONFIG_PARAVIRT
 187 ENTRY(native_usergs_sysret64)
 188         swapgs
 189         sysretq
 190 #endif /* CONFIG_PARAVIRT */
 191
 192
 193 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 194 #ifdef CONFIG_TRACE_IRQFLAGS
 195         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 196         jnc  1f
 197         TRACE_IRQS_ON
 198 1:
 199 #endif
 200 .endm
 201
 202 /*
 203  * C code is not supposed to know about undefined top of stack. Every time
 204  * a C function with an pt_regs argument is called from the SYSCALL based
 205  * fast path FIXUP_TOP_OF_STACK is needed.
 206  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 207  * manipulation.
 208  */
 209
 210         /* %rsp:at FRAMEEND */
 211         .macro FIXUP_TOP_OF_STACK tmp offset=0
 212         movq %gs:pda_oldrsp,\tmp
 213         movq \tmp,RSP+\offset(%rsp)
 214         movq $__USER_DS,SS+\offset(%rsp)
 215         movq $__USER_CS,CS+\offset(%rsp)
 216         movq $-1,RCX+\offset(%rsp)
 217         movq R11+\offset(%rsp),\tmp  /* get eflags */
 218         movq \tmp,EFLAGS+\offset(%rsp)
 219         .endm
 220
 221         .macro RESTORE_TOP_OF_STACK tmp offset=0
 222         movq RSP+\offset(%rsp),\tmp
 223         movq \tmp,%gs:pda_oldrsp
 224         movq EFLAGS+\offset(%rsp),\tmp
 225         movq \tmp,R11+\offset(%rsp)
 226         .endm
 227
 228         .macro FAKE_STACK_FRAME child_rip
 229         /* push in order ss, rsp, eflags, cs, rip */
 230         xorl %eax, %eax
 231         pushq $__KERNEL_DS /* ss */
 232         CFI_ADJUST_CFA_OFFSET   8
 233         /*CFI_REL_OFFSET        ss,0*/
 234         pushq %rax /* rsp */
 235         CFI_ADJUST_CFA_OFFSET   8
 236         CFI_REL_OFFSET  rsp,0
 237         pushq $X86_EFLAGS_IF /* eflags - interrupts on */
 238         CFI_ADJUST_CFA_OFFSET   8
 239         /*CFI_REL_OFFSET        rflags,0*/
 240         pushq $__KERNEL_CS /* cs */
 241         CFI_ADJUST_CFA_OFFSET   8
 242         /*CFI_REL_OFFSET        cs,0*/
 243         pushq \child_rip /* rip */
 244         CFI_ADJUST_CFA_OFFSET   8
 245         CFI_REL_OFFSET  rip,0
 246         pushq   %rax /* orig rax */
 247         CFI_ADJUST_CFA_OFFSET   8
 248         .endm
 249
 250         .macro UNFAKE_STACK_FRAME
 251         addq $8*6, %rsp
 252         CFI_ADJUST_CFA_OFFSET   -(6*8)
 253         .endm
 254
 255 /*
 256  * initial frame state for interrupts (and exceptions without error code)
 257  */
 258         .macro EMPTY_FRAME start=1 offset=0
 259         .if \start
 260         CFI_STARTPROC simple
 261         CFI_SIGNAL_FRAME
 262         CFI_DEF_CFA rsp,8+\offset
 263         .else
 264         CFI_DEF_CFA_OFFSET 8+\offset
 265         .endif
 266         .endm
 267
 268 /*
 269  * initial frame state for interrupts (and exceptions without error code)
 270  */
 271         .macro INTR_FRAME start=1 offset=0
 272         EMPTY_FRAME \start, SS+8+\offset-RIP
 273         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 274         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 275         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 276         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 277         CFI_REL_OFFSET rip, RIP+\offset-RIP
 278         .endm
 279
 280 /*
 281  * initial frame state for exceptions with error code (and interrupts
 282  * with vector already pushed)
 283  */
 284         .macro XCPT_FRAME start=1 offset=0
 285         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 286         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 287         .endm
 288
 289 /*
 290  * frame that enables calling into C.
 291  */
 292         .macro PARTIAL_FRAME start=1 offset=0
 293         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 294         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 295         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 296         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 297         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 298         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 299         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 300         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 301         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 302         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 303         .endm
 304
 305 /*
 306  * frame that enables passing a complete pt_regs to a C function.
 307  */
 308         .macro DEFAULT_FRAME start=1 offset=0
 309         PARTIAL_FRAME \start, R11+\offset-R15
 310         CFI_REL_OFFSET rbx, RBX+\offset
 311         CFI_REL_OFFSET rbp, RBP+\offset
 312         CFI_REL_OFFSET r12, R12+\offset
 313         CFI_REL_OFFSET r13, R13+\offset
 314         CFI_REL_OFFSET r14, R14+\offset
 315         CFI_REL_OFFSET r15, R15+\offset
 316         .endm
 317
 318 /* save partial stack frame */
 319 ENTRY(save_args)
 320         XCPT_FRAME
 321         cld
 322         movq_cfi rdi, RDI+16-ARGOFFSET
 323         movq_cfi rsi, RSI+16-ARGOFFSET
 324         movq_cfi rdx, RDX+16-ARGOFFSET
 325         movq_cfi rcx, RCX+16-ARGOFFSET
 326         movq_cfi rax, RAX+16-ARGOFFSET
 327         movq_cfi  r8,  R8+16-ARGOFFSET
 328         movq_cfi  r9,  R9+16-ARGOFFSET
 329         movq_cfi r10, R10+16-ARGOFFSET
 330         movq_cfi r11, R11+16-ARGOFFSET
 331
 332         leaq -ARGOFFSET+16(%rsp),%rdi   /* arg1 for handler */
 333         movq_cfi rbp, 8         /* push %rbp */
 334         leaq 8(%rsp), %rbp              /* mov %rsp, %ebp */
 335         testl $3, CS(%rdi)
 336         je 1f
 337         SWAPGS
 338         /*
 339          * irqcount is used to check if a CPU is already on an interrupt stack
 340          * or not. While this is essentially redundant with preempt_count it is
 341          * a little cheaper to use a separate counter in the PDA (short of
 342          * moving irq_enter into assembly, which would be too much work)
 343          */
 344 1:      incl %gs:pda_irqcount
 345         jne 2f
 346         popq_cfi %rax                   /* move return address... */
 347         mov %gs:pda_irqstackptr,%rsp
 348         EMPTY_FRAME 0
 349         pushq_cfi %rax                  /* ... to the new stack */
 350         /*
 351          * We entered an interrupt context - irqs are off:
 352          */
 353 2:      TRACE_IRQS_OFF
 354         ret
 355         CFI_ENDPROC
 356 END(save_args)
 357
 358 ENTRY(save_rest)
 359         PARTIAL_FRAME 1 REST_SKIP+8
 360         movq 5*8+16(%rsp), %r11 /* save return address */
 361         movq_cfi rbx, RBX+16
 362         movq_cfi rbp, RBP+16
 363         movq_cfi r12, R12+16
 364         movq_cfi r13, R13+16
 365         movq_cfi r14, R14+16
 366         movq_cfi r15, R15+16
 367         movq %r11, 8(%rsp)      /* return address */
 368         FIXUP_TOP_OF_STACK %r11, 16
 369         ret
 370         CFI_ENDPROC
 371 END(save_rest)
 372
 373 /* save complete stack frame */
 374 ENTRY(save_paranoid)
 375         XCPT_FRAME 1 RDI+8
 376         cld
 377         movq_cfi rdi, RDI+8
 378         movq_cfi rsi, RSI+8
 379         movq_cfi rdx, RDX+8
 380         movq_cfi rcx, RCX+8
 381         movq_cfi rax, RAX+8
 382         movq_cfi r8, R8+8
 383         movq_cfi r9, R9+8
 384         movq_cfi r10, R10+8
 385         movq_cfi r11, R11+8
 386         movq_cfi rbx, RBX+8
 387         movq_cfi rbp, RBP+8
 388         movq_cfi r12, R12+8
 389         movq_cfi r13, R13+8
 390         movq_cfi r14, R14+8
 391         movq_cfi r15, R15+8
 392         movl $1,%ebx
 393         movl $MSR_GS_BASE,%ecx
 394         rdmsr
 395         testl %edx,%edx
 396         js 1f   /* negative -> in kernel */
 397         SWAPGS
 398         xorl %ebx,%ebx
 399 1:      ret
 400         CFI_ENDPROC
 401 END(save_paranoid)
 402
 403 /*
 404  * A newly forked process directly context switches into this address.
 405  *
 406  * rdi: prev task we switched from
 407  */
 408 ENTRY(ret_from_fork)
 409         DEFAULT_FRAME
 410
 411         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 412
 413         push kernel_eflags(%rip)
 414         CFI_ADJUST_CFA_OFFSET 8
 415         popf                                    # reset kernel eflags
 416         CFI_ADJUST_CFA_OFFSET -8
 417
 418         call schedule_tail                      # rdi: 'prev' task parameter
 419
 420         GET_THREAD_INFO(%rcx)
 421
 422         CFI_REMEMBER_STATE
 423         RESTORE_REST
 424
 425         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 426         je   int_ret_from_sys_call
 427
 428         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 429         jnz  int_ret_from_sys_call
 430
 431         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 432         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 433
 434         CFI_RESTORE_STATE
 435         CFI_ENDPROC
 436 END(ret_from_fork)
 437
 438 /*
 439  * System call entry. Upto 6 arguments in registers are supported.
 440  *
 441  * SYSCALL does not save anything on the stack and does not change the
 442  * stack pointer.
 443  */
 444
 445 /*
 446  * Register setup:
 447  * rax  system call number
 448  * rdi  arg0
 449  * rcx  return address for syscall/sysret, C arg3
 450  * rsi  arg1
 451  * rdx  arg2
 452  * r10  arg3    (--> moved to rcx for C)
 453  * r8   arg4
 454  * r9   arg5
 455  * r11  eflags for syscall/sysret, temporary for C
 456  * r12-r15,rbp,rbx saved by C code, not touched.
 457  *
 458  * Interrupts are off on entry.
 459  * Only called from user space.
 460  *
 461  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 462  *      and report it properly in ps. Unfortunately we haven't.
 463  *
 464  * When user can change the frames always force IRET. That is because
 465  * it deals with uncanonical addresses better. SYSRET has trouble
 466  * with them due to bugs in both AMD and Intel CPUs.
 467  */
 468
 469 ENTRY(system_call)
 470         CFI_STARTPROC   simple
 471         CFI_SIGNAL_FRAME
 472         CFI_DEF_CFA     rsp,PDA_STACKOFFSET
 473         CFI_REGISTER    rip,rcx
 474         /*CFI_REGISTER  rflags,r11*/
 475         SWAPGS_UNSAFE_STACK
 476         /*
 477          * A hypervisor implementation might want to use a label
 478          * after the swapgs, so that it can do the swapgs
 479          * for the guest and jump here on syscall.
 480          */
 481 ENTRY(system_call_after_swapgs)
 482
 483         movq    %rsp,%gs:pda_oldrsp
 484         movq    %gs:pda_kernelstack,%rsp
 485         /*
 486          * No need to follow this irqs off/on section - it's straight
 487          * and short:
 488          */
 489         ENABLE_INTERRUPTS(CLBR_NONE)
 490         SAVE_ARGS 8,1
 491         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 492         movq  %rcx,RIP-ARGOFFSET(%rsp)
 493         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 494         GET_THREAD_INFO(%rcx)
 495         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 496         jnz tracesys
 497 system_call_fastpath:
 498         cmpq $__NR_syscall_max,%rax
 499         ja badsys
 500         movq %r10,%rcx
 501         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 502         movq %rax,RAX-ARGOFFSET(%rsp)
 503 /*
 504  * Syscall return path ending with SYSRET (fast path)
 505  * Has incomplete stack frame and undefined top of stack.
 506  */
 507 ret_from_sys_call:
 508         movl $_TIF_ALLWORK_MASK,%edi
 509         /* edi: flagmask */
 510 sysret_check:
 511         LOCKDEP_SYS_EXIT
 512         GET_THREAD_INFO(%rcx)
 513         DISABLE_INTERRUPTS(CLBR_NONE)
 514         TRACE_IRQS_OFF
 515         movl TI_flags(%rcx),%edx
 516         andl %edi,%edx
 517         jnz  sysret_careful
 518         CFI_REMEMBER_STATE
 519         /*
 520          * sysretq will re-enable interrupts:
 521          */
 522         TRACE_IRQS_ON
 523         movq RIP-ARGOFFSET(%rsp),%rcx
 524         CFI_REGISTER    rip,rcx
 525         RESTORE_ARGS 0,-ARG_SKIP,1
 526         /*CFI_REGISTER  rflags,r11*/
 527         movq    %gs:pda_oldrsp, %rsp
 528         USERGS_SYSRET64
 529
 530         CFI_RESTORE_STATE
 531         /* Handle reschedules */
 532         /* edx: work, edi: workmask */
 533 sysret_careful:
 534         bt $TIF_NEED_RESCHED,%edx
 535         jnc sysret_signal
 536         TRACE_IRQS_ON
 537         ENABLE_INTERRUPTS(CLBR_NONE)
 538         pushq %rdi
 539         CFI_ADJUST_CFA_OFFSET 8
 540         call schedule
 541         popq  %rdi
 542         CFI_ADJUST_CFA_OFFSET -8
 543         jmp sysret_check
 544
 545         /* Handle a signal */
 546 sysret_signal:
 547         TRACE_IRQS_ON
 548         ENABLE_INTERRUPTS(CLBR_NONE)
 549 #ifdef CONFIG_AUDITSYSCALL
 550         bt $TIF_SYSCALL_AUDIT,%edx
 551         jc sysret_audit
 552 #endif
 553         /* edx: work flags (arg3) */
 554         leaq -ARGOFFSET(%rsp),%rdi # &pt_regs -> arg1
 555         xorl %esi,%esi # oldset -> arg2
 556         SAVE_REST
 557         FIXUP_TOP_OF_STACK %r11
 558         call do_notify_resume
 559         RESTORE_TOP_OF_STACK %r11
 560         RESTORE_REST
 561         movl $_TIF_WORK_MASK,%edi
 562         /* Use IRET because user could have changed frame. This
 563            works because ptregscall_common has called FIXUP_TOP_OF_STACK. */
 564         DISABLE_INTERRUPTS(CLBR_NONE)
 565         TRACE_IRQS_OFF
 566         jmp int_with_check
 567
 568 badsys:
 569         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 570         jmp ret_from_sys_call
 571
 572 #ifdef CONFIG_AUDITSYSCALL
 573         /*
 574          * Fast path for syscall audit without full syscall trace.
 575          * We just call audit_syscall_entry() directly, and then
 576          * jump back to the normal fast path.
 577          */
 578 auditsys:
 579         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 580         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 581         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 582         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 583         movq %rax,%rsi                  /* 2nd arg: syscall number */
 584         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 585         call audit_syscall_entry
 586         LOAD_ARGS 0             /* reload call-clobbered registers */
 587         jmp system_call_fastpath
 588
 589         /*
 590          * Return fast path for syscall audit.  Call audit_syscall_exit()
 591          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 592          * masked off.
 593          */
 594 sysret_audit:
 595         movq %rax,%rsi          /* second arg, syscall return value */
 596         cmpq $0,%rax            /* is it < 0? */
 597         setl %al                /* 1 if so, 0 if not */
 598         movzbl %al,%edi         /* zero-extend that into %edi */
 599         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 600         call audit_syscall_exit
 601         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 602         jmp sysret_check
 603 #endif  /* CONFIG_AUDITSYSCALL */
 604
 605         /* Do syscall tracing */
 606 tracesys:
 607 #ifdef CONFIG_AUDITSYSCALL
 608         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 609         jz auditsys
 610 #endif
 611         SAVE_REST
 612         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 613         FIXUP_TOP_OF_STACK %rdi
 614         movq %rsp,%rdi
 615         call syscall_trace_enter
 616         /*
 617          * Reload arg registers from stack in case ptrace changed them.
 618          * We don't reload %rax because syscall_trace_enter() returned
 619          * the value it wants us to use in the table lookup.
 620          */
 621         LOAD_ARGS ARGOFFSET, 1
 622         RESTORE_REST
 623         cmpq $__NR_syscall_max,%rax
 624         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 625         movq %r10,%rcx  /* fixup for C */
 626         call *sys_call_table(,%rax,8)
 627         movq %rax,RAX-ARGOFFSET(%rsp)
 628         /* Use IRET because user could have changed frame */
 629
 630 /*
 631  * Syscall return path ending with IRET.
 632  * Has correct top of stack, but partial stack frame.
 633  */
 634         .globl int_ret_from_sys_call
 635         .globl int_with_check
 636 int_ret_from_sys_call:
 637         DISABLE_INTERRUPTS(CLBR_NONE)
 638         TRACE_IRQS_OFF
 639         testl $3,CS-ARGOFFSET(%rsp)
 640         je retint_restore_args
 641         movl $_TIF_ALLWORK_MASK,%edi
 642         /* edi: mask to check */
 643 int_with_check:
 644         LOCKDEP_SYS_EXIT_IRQ
 645         GET_THREAD_INFO(%rcx)
 646         movl TI_flags(%rcx),%edx
 647         andl %edi,%edx
 648         jnz   int_careful
 649         andl    $~TS_COMPAT,TI_status(%rcx)
 650         jmp   retint_swapgs
 651
 652         /* Either reschedule or signal or syscall exit tracking needed. */
 653         /* First do a reschedule test. */
 654         /* edx: work, edi: workmask */
 655 int_careful:
 656         bt $TIF_NEED_RESCHED,%edx
 657         jnc  int_very_careful
 658         TRACE_IRQS_ON
 659         ENABLE_INTERRUPTS(CLBR_NONE)
 660         pushq %rdi
 661         CFI_ADJUST_CFA_OFFSET 8
 662         call schedule
 663         popq %rdi
 664         CFI_ADJUST_CFA_OFFSET -8
 665         DISABLE_INTERRUPTS(CLBR_NONE)
 666         TRACE_IRQS_OFF
 667         jmp int_with_check
 668
 669         /* handle signals and tracing -- both require a full stack frame */
 670 int_very_careful:
 671         TRACE_IRQS_ON
 672         ENABLE_INTERRUPTS(CLBR_NONE)
 673         SAVE_REST
 674         /* Check for syscall exit trace */
 675         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 676         jz int_signal
 677         pushq %rdi
 678         CFI_ADJUST_CFA_OFFSET 8
 679         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 680         call syscall_trace_leave
 681         popq %rdi
 682         CFI_ADJUST_CFA_OFFSET -8
 683         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 684         jmp int_restore_rest
 685
 686 int_signal:
 687         testl $_TIF_DO_NOTIFY_MASK,%edx
 688         jz 1f
 689         movq %rsp,%rdi          # &ptregs -> arg1
 690         xorl %esi,%esi          # oldset -> arg2
 691         call do_notify_resume
 692 1:      movl $_TIF_WORK_MASK,%edi
 693 int_restore_rest:
 694         RESTORE_REST
 695         DISABLE_INTERRUPTS(CLBR_NONE)
 696         TRACE_IRQS_OFF
 697         jmp int_with_check
 698         CFI_ENDPROC
 699 END(system_call)
 700
 701 /*
 702  * Certain special system calls that need to save a complete full stack frame.
 703  */
 704         .macro PTREGSCALL label,func,arg
 705 ENTRY(\label)
 706         PARTIAL_FRAME 1 8               /* offset 8: return address */
 707         subq $REST_SKIP, %rsp
 708         CFI_ADJUST_CFA_OFFSET REST_SKIP
 709         call save_rest
 710         DEFAULT_FRAME 0 8               /* offset 8: return address */
 711         leaq 8(%rsp), \arg      /* pt_regs pointer */
 712         call \func
 713         jmp ptregscall_common
 714         CFI_ENDPROC
 715 END(\label)
 716         .endm
 717
 718         PTREGSCALL stub_clone, sys_clone, %r8
 719         PTREGSCALL stub_fork, sys_fork, %rdi
 720         PTREGSCALL stub_vfork, sys_vfork, %rdi
 721         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 722         PTREGSCALL stub_iopl, sys_iopl, %rsi
 723
 724 ENTRY(ptregscall_common)
 725         DEFAULT_FRAME 1 8       /* offset 8: return address */
 726         RESTORE_TOP_OF_STACK %r11, 8
 727         movq_cfi_restore R15+8, r15
 728         movq_cfi_restore R14+8, r14
 729         movq_cfi_restore R13+8, r13
 730         movq_cfi_restore R12+8, r12
 731         movq_cfi_restore RBP+8, rbp
 732         movq_cfi_restore RBX+8, rbx
 733         ret $REST_SKIP          /* pop extended registers */
 734         CFI_ENDPROC
 735 END(ptregscall_common)
 736
 737 ENTRY(stub_execve)
 738         CFI_STARTPROC
 739         popq %r11
 740         CFI_ADJUST_CFA_OFFSET -8
 741         CFI_REGISTER rip, r11
 742         SAVE_REST
 743         FIXUP_TOP_OF_STACK %r11
 744         movq %rsp, %rcx
 745         call sys_execve
 746         RESTORE_TOP_OF_STACK %r11
 747         movq %rax,RAX(%rsp)
 748         RESTORE_REST
 749         jmp int_ret_from_sys_call
 750         CFI_ENDPROC
 751 END(stub_execve)
 752
 753 /*
 754  * sigreturn is special because it needs to restore all registers on return.
 755  * This cannot be done with SYSRET, so use the IRET return path instead.
 756  */
 757 ENTRY(stub_rt_sigreturn)
 758         CFI_STARTPROC
 759         addq $8, %rsp
 760         CFI_ADJUST_CFA_OFFSET   -8
 761         SAVE_REST
 762         movq %rsp,%rdi
 763         FIXUP_TOP_OF_STACK %r11
 764         call sys_rt_sigreturn
 765         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 766         RESTORE_REST
 767         jmp int_ret_from_sys_call
 768         CFI_ENDPROC
 769 END(stub_rt_sigreturn)
 770
 771 /*
 772  * Build the entry stubs and pointer table with some assembler magic.
 773  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 774  * single cache line on all modern x86 implementations.
 775  */
 776         .section .init.rodata,"a"
 777 ENTRY(interrupt)
 778         .text
 779         .p2align 5
 780         .p2align CONFIG_X86_L1_CACHE_SHIFT
 781 ENTRY(irq_entries_start)
 782         INTR_FRAME
 783 vector=FIRST_EXTERNAL_VECTOR
 784 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 785         .balign 32
 786   .rept 7
 787     .if vector < NR_VECTORS
 788       .if vector <> FIRST_EXTERNAL_VECTOR
 789         CFI_ADJUST_CFA_OFFSET -8
 790       .endif
 791 1:      pushq $(~vector+0x80)   /* Note: always in signed byte range */
 792         CFI_ADJUST_CFA_OFFSET 8
 793       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 794         jmp 2f
 795       .endif
 796       .previous
 797         .quad 1b
 798       .text
 799 vector=vector+1
 800     .endif
 801   .endr
 802 2:      jmp common_interrupt
 803 .endr
 804         CFI_ENDPROC
 805 END(irq_entries_start)
 806
 807 .previous
 808 END(interrupt)
 809 .previous
 810
 811 /*
 812  * Interrupt entry/exit.
 813  *
 814  * Interrupt entry points save only callee clobbered registers in fast path.
 815  *
 816  * Entry runs with interrupts off.
 817  */
 818
 819 /* 0(%rsp): ~(interrupt number) */
 820         .macro interrupt func
 821         subq $10*8, %rsp
 822         CFI_ADJUST_CFA_OFFSET 10*8
 823         call save_args
 824         PARTIAL_FRAME 0
 825         call \func
 826         .endm
 827
 828         /*
 829          * The interrupt stubs push (~vector+0x80) onto the stack and
 830          * then jump to common_interrupt.
 831          */
 832         .p2align CONFIG_X86_L1_CACHE_SHIFT
 833 common_interrupt:
 834         XCPT_FRAME
 835         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 836         interrupt do_IRQ
 837         /* 0(%rsp): oldrsp-ARGOFFSET */
 838 ret_from_intr:
 839         DISABLE_INTERRUPTS(CLBR_NONE)
 840         TRACE_IRQS_OFF
 841         decl %gs:pda_irqcount
 842         leaveq
 843         CFI_DEF_CFA_REGISTER    rsp
 844         CFI_ADJUST_CFA_OFFSET   -8
 845 exit_intr:
 846         GET_THREAD_INFO(%rcx)
 847         testl $3,CS-ARGOFFSET(%rsp)
 848         je retint_kernel
 849
 850         /* Interrupt came from user space */
 851         /*
 852          * Has a correct top of stack, but a partial stack frame
 853          * %rcx: thread info. Interrupts off.
 854          */
 855 retint_with_reschedule:
 856         movl $_TIF_WORK_MASK,%edi
 857 retint_check:
 858         LOCKDEP_SYS_EXIT_IRQ
 859         movl TI_flags(%rcx),%edx
 860         andl %edi,%edx
 861         CFI_REMEMBER_STATE
 862         jnz  retint_careful
 863
 864 retint_swapgs:          /* return to user-space */
 865         /*
 866          * The iretq could re-enable interrupts:
 867          */
 868         DISABLE_INTERRUPTS(CLBR_ANY)
 869         TRACE_IRQS_IRETQ
 870         SWAPGS
 871         jmp restore_args
 872
 873 retint_restore_args:    /* return to kernel space */
 874         DISABLE_INTERRUPTS(CLBR_ANY)
 875         /*
 876          * The iretq could re-enable interrupts:
 877          */
 878         TRACE_IRQS_IRETQ
 879 restore_args:
 880         RESTORE_ARGS 0,8,0
 881
 882 irq_return:
 883         INTERRUPT_RETURN
 884
 885         .section __ex_table, "a"
 886         .quad irq_return, bad_iret
 887         .previous
 888
 889 #ifdef CONFIG_PARAVIRT
 890 ENTRY(native_iret)
 891         iretq
 892
 893         .section __ex_table,"a"
 894         .quad native_iret, bad_iret
 895         .previous
 896 #endif
 897
 898         .section .fixup,"ax"
 899 bad_iret:
 900         /*
 901          * The iret traps when the %cs or %ss being restored is bogus.
 902          * We've lost the original trap vector and error code.
 903          * #GPF is the most likely one to get for an invalid selector.
 904          * So pretend we completed the iret and took the #GPF in user mode.
 905          *
 906          * We are now running with the kernel GS after exception recovery.
 907          * But error_entry expects us to have user GS to match the user %cs,
 908          * so swap back.
 909          */
 910         pushq $0
 911
 912         SWAPGS
 913         jmp general_protection
 914
 915         .previous
 916
 917         /* edi: workmask, edx: work */
 918 retint_careful:
 919         CFI_RESTORE_STATE
 920         bt    $TIF_NEED_RESCHED,%edx
 921         jnc   retint_signal
 922         TRACE_IRQS_ON
 923         ENABLE_INTERRUPTS(CLBR_NONE)
 924         pushq %rdi
 925         CFI_ADJUST_CFA_OFFSET   8
 926         call  schedule
 927         popq %rdi
 928         CFI_ADJUST_CFA_OFFSET   -8
 929         GET_THREAD_INFO(%rcx)
 930         DISABLE_INTERRUPTS(CLBR_NONE)
 931         TRACE_IRQS_OFF
 932         jmp retint_check
 933
 934 retint_signal:
 935         testl $_TIF_DO_NOTIFY_MASK,%edx
 936         jz    retint_swapgs
 937         TRACE_IRQS_ON
 938         ENABLE_INTERRUPTS(CLBR_NONE)
 939         SAVE_REST
 940         movq $-1,ORIG_RAX(%rsp)
 941         xorl %esi,%esi          # oldset
 942         movq %rsp,%rdi          # &pt_regs
 943         call do_notify_resume
 944         RESTORE_REST
 945         DISABLE_INTERRUPTS(CLBR_NONE)
 946         TRACE_IRQS_OFF
 947         GET_THREAD_INFO(%rcx)
 948         jmp retint_with_reschedule
 949
 950 #ifdef CONFIG_PREEMPT
 951         /* Returning to kernel space. Check if we need preemption */
 952         /* rcx:  threadinfo. interrupts off. */
 953 ENTRY(retint_kernel)
 954         cmpl $0,TI_preempt_count(%rcx)
 955         jnz  retint_restore_args
 956         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 957         jnc  retint_restore_args
 958         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 959         jnc  retint_restore_args
 960         call preempt_schedule_irq
 961         jmp exit_intr
 962 #endif
 963
 964         CFI_ENDPROC
 965 END(common_interrupt)
 966
 967 /*
 968  * APIC interrupts.
 969  */
 970 .macro apicinterrupt num sym do_sym
 971 ENTRY(\sym)
 972         INTR_FRAME
 973         pushq $~(\num)
 974         CFI_ADJUST_CFA_OFFSET 8
 975         interrupt \do_sym
 976         jmp ret_from_intr
 977         CFI_ENDPROC
 978 END(\sym)
 979 .endm
 980
 981 #ifdef CONFIG_SMP
 982 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 983         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 984 #endif
 985
 986 apicinterrupt UV_BAU_MESSAGE \
 987         uv_bau_message_intr1 uv_bau_message_interrupt
 988 apicinterrupt LOCAL_TIMER_VECTOR \
 989         apic_timer_interrupt smp_apic_timer_interrupt
 990
 991 #ifdef CONFIG_SMP
 992 apicinterrupt INVALIDATE_TLB_VECTOR_START+0 \
 993         invalidate_interrupt0 smp_invalidate_interrupt
 994 apicinterrupt INVALIDATE_TLB_VECTOR_START+1 \
 995         invalidate_interrupt1 smp_invalidate_interrupt
 996 apicinterrupt INVALIDATE_TLB_VECTOR_START+2 \
 997         invalidate_interrupt2 smp_invalidate_interrupt
 998 apicinterrupt INVALIDATE_TLB_VECTOR_START+3 \
 999         invalidate_interrupt3 smp_invalidate_interrupt
1000 apicinterrupt INVALIDATE_TLB_VECTOR_START+4 \
1001         invalidate_interrupt4 smp_invalidate_interrupt
1002 apicinterrupt INVALIDATE_TLB_VECTOR_START+5 \
1003         invalidate_interrupt5 smp_invalidate_interrupt
1004 apicinterrupt INVALIDATE_TLB_VECTOR_START+6 \
1005         invalidate_interrupt6 smp_invalidate_interrupt
1006 apicinterrupt INVALIDATE_TLB_VECTOR_START+7 \
1007         invalidate_interrupt7 smp_invalidate_interrupt
1008 #endif
1009
1010 apicinterrupt THRESHOLD_APIC_VECTOR \
1011         threshold_interrupt mce_threshold_interrupt
1012 apicinterrupt THERMAL_APIC_VECTOR \
1013         thermal_interrupt smp_thermal_interrupt
1014
1015 #ifdef CONFIG_SMP
1016 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1017         call_function_single_interrupt smp_call_function_single_interrupt
1018 apicinterrupt CALL_FUNCTION_VECTOR \
1019         call_function_interrupt smp_call_function_interrupt
1020 apicinterrupt RESCHEDULE_VECTOR \
1021         reschedule_interrupt smp_reschedule_interrupt
1022 #endif
1023
1024 apicinterrupt ERROR_APIC_VECTOR \
1025         error_interrupt smp_error_interrupt
1026 apicinterrupt SPURIOUS_APIC_VECTOR \
1027         spurious_interrupt smp_spurious_interrupt
1028
1029 /*
1030  * Exception entry points.
1031  */
1032 .macro zeroentry sym do_sym
1033 ENTRY(\sym)
1034         INTR_FRAME
1035         PARAVIRT_ADJUST_EXCEPTION_FRAME
1036         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1037         subq $15*8,%rsp
1038         CFI_ADJUST_CFA_OFFSET 15*8
1039         call error_entry
1040         DEFAULT_FRAME 0
1041         movq %rsp,%rdi          /* pt_regs pointer */
1042         xorl %esi,%esi          /* no error code */
1043         call \do_sym
1044         jmp error_exit          /* %ebx: no swapgs flag */
1045         CFI_ENDPROC
1046 END(\sym)
1047 .endm
1048
1049 .macro paranoidzeroentry sym do_sym
1050 ENTRY(\sym)
1051         INTR_FRAME
1052         PARAVIRT_ADJUST_EXCEPTION_FRAME
1053         pushq $-1               /* ORIG_RAX: no syscall to restart */
1054         CFI_ADJUST_CFA_OFFSET 8
1055         subq $15*8, %rsp
1056         call save_paranoid
1057         TRACE_IRQS_OFF
1058         movq %rsp,%rdi          /* pt_regs pointer */
1059         xorl %esi,%esi          /* no error code */
1060         call \do_sym
1061         jmp paranoid_exit       /* %ebx: no swapgs flag */
1062         CFI_ENDPROC
1063 END(\sym)
1064 .endm
1065
1066 .macro paranoidzeroentry_ist sym do_sym ist
1067 ENTRY(\sym)
1068         INTR_FRAME
1069         PARAVIRT_ADJUST_EXCEPTION_FRAME
1070         pushq $-1               /* ORIG_RAX: no syscall to restart */
1071         CFI_ADJUST_CFA_OFFSET 8
1072         subq $15*8, %rsp
1073         call save_paranoid
1074         TRACE_IRQS_OFF
1075         movq %rsp,%rdi          /* pt_regs pointer */
1076         xorl %esi,%esi          /* no error code */
1077         movq %gs:pda_data_offset, %rbp
1078         subq $EXCEPTION_STKSZ, per_cpu__init_tss + TSS_ist + (\ist - 1) * 8(%rbp)
1079         call \do_sym
1080         addq $EXCEPTION_STKSZ, per_cpu__init_tss + TSS_ist + (\ist - 1) * 8(%rbp)
1081         jmp paranoid_exit       /* %ebx: no swapgs flag */
1082         CFI_ENDPROC
1083 END(\sym)
1084 .endm
1085
1086 .macro errorentry sym do_sym
1087 ENTRY(\sym)
1088         XCPT_FRAME
1089         PARAVIRT_ADJUST_EXCEPTION_FRAME
1090         subq $15*8,%rsp
1091         CFI_ADJUST_CFA_OFFSET 15*8
1092         call error_entry
1093         DEFAULT_FRAME 0
1094         movq %rsp,%rdi                  /* pt_regs pointer */
1095         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1096         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1097         call \do_sym
1098         jmp error_exit                  /* %ebx: no swapgs flag */
1099         CFI_ENDPROC
1100 END(\sym)
1101 .endm
1102
1103         /* error code is on the stack already */
1104 .macro paranoiderrorentry sym do_sym
1105 ENTRY(\sym)
1106         XCPT_FRAME
1107         PARAVIRT_ADJUST_EXCEPTION_FRAME
1108         subq $15*8,%rsp
1109         CFI_ADJUST_CFA_OFFSET 15*8
1110         call save_paranoid
1111         DEFAULT_FRAME 0
1112         TRACE_IRQS_OFF
1113         movq %rsp,%rdi                  /* pt_regs pointer */
1114         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1115         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1116         call \do_sym
1117         jmp paranoid_exit               /* %ebx: no swapgs flag */
1118         CFI_ENDPROC
1119 END(\sym)
1120 .endm
1121
1122 zeroentry divide_error do_divide_error
1123 zeroentry overflow do_overflow
1124 zeroentry bounds do_bounds
1125 zeroentry invalid_op do_invalid_op
1126 zeroentry device_not_available do_device_not_available
1127 paranoiderrorentry double_fault do_double_fault
1128 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1129 errorentry invalid_TSS do_invalid_TSS
1130 errorentry segment_not_present do_segment_not_present
1131 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1132 zeroentry coprocessor_error do_coprocessor_error
1133 errorentry alignment_check do_alignment_check
1134 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1135
1136         /* Reload gs selector with exception handling */
1137         /* edi:  new selector */
1138 ENTRY(native_load_gs_index)
1139         CFI_STARTPROC
1140         pushf
1141         CFI_ADJUST_CFA_OFFSET 8
1142         DISABLE_INTERRUPTS(CLBR_ANY | ~(CLBR_RDI))
1143         SWAPGS
1144 gs_change:
1145         movl %edi,%gs
1146 2:      mfence          /* workaround */
1147         SWAPGS
1148         popf
1149         CFI_ADJUST_CFA_OFFSET -8
1150         ret
1151         CFI_ENDPROC
1152 END(native_load_gs_index)
1153
1154         .section __ex_table,"a"
1155         .align 8
1156         .quad gs_change,bad_gs
1157         .previous
1158         .section .fixup,"ax"
1159         /* running with kernelgs */
1160 bad_gs:
1161         SWAPGS                  /* switch back to user gs */
1162         xorl %eax,%eax
1163         movl %eax,%gs
1164         jmp  2b
1165         .previous
1166
1167 /*
1168  * Create a kernel thread.
1169  *
1170  * C extern interface:
1171  *      extern long kernel_thread(int (*fn)(void *), void * arg, unsigned long flags)
1172  *
1173  * asm input arguments:
1174  *      rdi: fn, rsi: arg, rdx: flags
1175  */
1176 ENTRY(kernel_thread)
1177         CFI_STARTPROC
1178         FAKE_STACK_FRAME $child_rip
1179         SAVE_ALL
1180
1181         # rdi: flags, rsi: usp, rdx: will be &pt_regs
1182         movq %rdx,%rdi
1183         orq  kernel_thread_flags(%rip),%rdi
1184         movq $-1, %rsi
1185         movq %rsp, %rdx
1186
1187         xorl %r8d,%r8d
1188         xorl %r9d,%r9d
1189
1190         # clone now
1191         call do_fork
1192         movq %rax,RAX(%rsp)
1193         xorl %edi,%edi
1194
1195         /*
1196          * It isn't worth to check for reschedule here,
1197          * so internally to the x86_64 port you can rely on kernel_thread()
1198          * not to reschedule the child before returning, this avoids the need
1199          * of hacks for example to fork off the per-CPU idle tasks.
1200          * [Hopefully no generic code relies on the reschedule -AK]
1201          */
1202         RESTORE_ALL
1203         UNFAKE_STACK_FRAME
1204         ret
1205         CFI_ENDPROC
1206 END(kernel_thread)
1207
1208 ENTRY(child_rip)
1209         pushq $0                # fake return address
1210         CFI_STARTPROC
1211         /*
1212          * Here we are in the child and the registers are set as they were
1213          * at kernel_thread() invocation in the parent.
1214          */
1215         movq %rdi, %rax
1216         movq %rsi, %rdi
1217         call *%rax
1218         # exit
1219         mov %eax, %edi
1220         call do_exit
1221         ud2                     # padding for call trace
1222         CFI_ENDPROC
1223 END(child_rip)
1224
1225 /*
1226  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1227  *
1228  * C extern interface:
1229  *       extern long execve(char *name, char **argv, char **envp)
1230  *
1231  * asm input arguments:
1232  *      rdi: name, rsi: argv, rdx: envp
1233  *
1234  * We want to fallback into:
1235  *      extern long sys_execve(char *name, char **argv,char **envp, struct pt_regs *regs)
1236  *
1237  * do_sys_execve asm fallback arguments:
1238  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1239  */
1240 ENTRY(kernel_execve)
1241         CFI_STARTPROC
1242         FAKE_STACK_FRAME $0
1243         SAVE_ALL
1244         movq %rsp,%rcx
1245         call sys_execve
1246         movq %rax, RAX(%rsp)
1247         RESTORE_REST
1248         testq %rax,%rax
1249         je int_ret_from_sys_call
1250         RESTORE_ARGS
1251         UNFAKE_STACK_FRAME
1252         ret
1253         CFI_ENDPROC
1254 END(kernel_execve)
1255
1256 /* Call softirq on interrupt stack. Interrupts are off. */
1257 ENTRY(call_softirq)
1258         CFI_STARTPROC
1259         push %rbp
1260         CFI_ADJUST_CFA_OFFSET   8
1261         CFI_REL_OFFSET rbp,0
1262         mov  %rsp,%rbp
1263         CFI_DEF_CFA_REGISTER rbp
1264         incl %gs:pda_irqcount
1265         cmove %gs:pda_irqstackptr,%rsp
1266         push  %rbp                      # backlink for old unwinder
1267         call __do_softirq
1268         leaveq
1269         CFI_DEF_CFA_REGISTER    rsp
1270         CFI_ADJUST_CFA_OFFSET   -8
1271         decl %gs:pda_irqcount
1272         ret
1273         CFI_ENDPROC
1274 END(call_softirq)
1275
1276 #ifdef CONFIG_XEN
1277 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1278
1279 /*
1280  * A note on the "critical region" in our callback handler.
1281  * We want to avoid stacking callback handlers due to events occurring
1282  * during handling of the last event. To do this, we keep events disabled
1283  * until we've done all processing. HOWEVER, we must enable events before
1284  * popping the stack frame (can't be done atomically) and so it would still
1285  * be possible to get enough handler activations to overflow the stack.
1286  * Although unlikely, bugs of that kind are hard to track down, so we'd
1287  * like to avoid the possibility.
1288  * So, on entry to the handler we detect whether we interrupted an
1289  * existing activation in its critical region -- if so, we pop the current
1290  * activation and restart the handler using the previous one.
1291  */
1292 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1293         CFI_STARTPROC
1294 /*
1295  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1296  * see the correct pointer to the pt_regs
1297  */
1298         movq %rdi, %rsp            # we don't return, adjust the stack frame
1299         CFI_ENDPROC
1300         DEFAULT_FRAME
1301 11:     incl %gs:pda_irqcount
1302         movq %rsp,%rbp
1303         CFI_DEF_CFA_REGISTER rbp
1304         cmovzq %gs:pda_irqstackptr,%rsp
1305         pushq %rbp                      # backlink for old unwinder
1306         call xen_evtchn_do_upcall
1307         popq %rsp
1308         CFI_DEF_CFA_REGISTER rsp
1309         decl %gs:pda_irqcount
1310         jmp  error_exit
1311         CFI_ENDPROC
1312 END(do_hypervisor_callback)
1313
1314 /*
1315  * Hypervisor uses this for application faults while it executes.
1316  * We get here for two reasons:
1317  *  1. Fault while reloading DS, ES, FS or GS
1318  *  2. Fault while executing IRET
1319  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1320  * registers that could be reloaded and zeroed the others.
1321  * Category 2 we fix up by killing the current process. We cannot use the
1322  * normal Linux return path in this case because if we use the IRET hypercall
1323  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1324  * We distinguish between categories by comparing each saved segment register
1325  * with its current contents: any discrepancy means we in category 1.
1326  */
1327 ENTRY(xen_failsafe_callback)
1328         INTR_FRAME 1 (6*8)
1329         /*CFI_REL_OFFSET gs,GS*/
1330         /*CFI_REL_OFFSET fs,FS*/
1331         /*CFI_REL_OFFSET es,ES*/
1332         /*CFI_REL_OFFSET ds,DS*/
1333         CFI_REL_OFFSET r11,8
1334         CFI_REL_OFFSET rcx,0
1335         movw %ds,%cx
1336         cmpw %cx,0x10(%rsp)
1337         CFI_REMEMBER_STATE
1338         jne 1f
1339         movw %es,%cx
1340         cmpw %cx,0x18(%rsp)
1341         jne 1f
1342         movw %fs,%cx
1343         cmpw %cx,0x20(%rsp)
1344         jne 1f
1345         movw %gs,%cx
1346         cmpw %cx,0x28(%rsp)
1347         jne 1f
1348         /* All segments match their saved values => Category 2 (Bad IRET). */
1349         movq (%rsp),%rcx
1350         CFI_RESTORE rcx
1351         movq 8(%rsp),%r11
1352         CFI_RESTORE r11
1353         addq $0x30,%rsp
1354         CFI_ADJUST_CFA_OFFSET -0x30
1355         pushq_cfi $0    /* RIP */
1356         pushq_cfi %r11
1357         pushq_cfi %rcx
1358         jmp general_protection
1359         CFI_RESTORE_STATE
1360 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1361         movq (%rsp),%rcx
1362         CFI_RESTORE rcx
1363         movq 8(%rsp),%r11
1364         CFI_RESTORE r11
1365         addq $0x30,%rsp
1366         CFI_ADJUST_CFA_OFFSET -0x30
1367         pushq_cfi $0
1368         SAVE_ALL
1369         jmp error_exit
1370         CFI_ENDPROC
1371 END(xen_failsafe_callback)
1372
1373 #endif /* CONFIG_XEN */
1374
1375 /*
1376  * Some functions should be protected against kprobes
1377  */
1378         .pushsection .kprobes.text, "ax"
1379
1380 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1381 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1382 paranoiderrorentry stack_segment do_stack_segment
1383 errorentry general_protection do_general_protection
1384 errorentry page_fault do_page_fault
1385 #ifdef CONFIG_X86_MCE
1386 paranoidzeroentry machine_check do_machine_check
1387 #endif
1388
1389         /*
1390          * "Paranoid" exit path from exception stack.
1391          * Paranoid because this is used by NMIs and cannot take
1392          * any kernel state for granted.
1393          * We don't do kernel preemption checks here, because only
1394          * NMI should be common and it does not enable IRQs and
1395          * cannot get reschedule ticks.
1396          *
1397          * "trace" is 0 for the NMI handler only, because irq-tracing
1398          * is fundamentally NMI-unsafe. (we cannot change the soft and
1399          * hard flags at once, atomically)
1400          */
1401
1402         /* ebx: no swapgs flag */
1403 ENTRY(paranoid_exit)
1404         INTR_FRAME
1405         DISABLE_INTERRUPTS(CLBR_NONE)
1406         TRACE_IRQS_OFF
1407         testl %ebx,%ebx                         /* swapgs needed? */
1408         jnz paranoid_restore
1409         testl $3,CS(%rsp)
1410         jnz   paranoid_userspace
1411 paranoid_swapgs:
1412         TRACE_IRQS_IRETQ 0
1413         SWAPGS_UNSAFE_STACK
1414 paranoid_restore:
1415         RESTORE_ALL 8
1416         jmp irq_return
1417 paranoid_userspace:
1418         GET_THREAD_INFO(%rcx)
1419         movl TI_flags(%rcx),%ebx
1420         andl $_TIF_WORK_MASK,%ebx
1421         jz paranoid_swapgs
1422         movq %rsp,%rdi                  /* &pt_regs */
1423         call sync_regs
1424         movq %rax,%rsp                  /* switch stack for scheduling */
1425         testl $_TIF_NEED_RESCHED,%ebx
1426         jnz paranoid_schedule
1427         movl %ebx,%edx                  /* arg3: thread flags */
1428         TRACE_IRQS_ON
1429         ENABLE_INTERRUPTS(CLBR_NONE)
1430         xorl %esi,%esi                  /* arg2: oldset */
1431         movq %rsp,%rdi                  /* arg1: &pt_regs */
1432         call do_notify_resume
1433         DISABLE_INTERRUPTS(CLBR_NONE)
1434         TRACE_IRQS_OFF
1435         jmp paranoid_userspace
1436 paranoid_schedule:
1437         TRACE_IRQS_ON
1438         ENABLE_INTERRUPTS(CLBR_ANY)
1439         call schedule
1440         DISABLE_INTERRUPTS(CLBR_ANY)
1441         TRACE_IRQS_OFF
1442         jmp paranoid_userspace
1443         CFI_ENDPROC
1444 END(paranoid_exit)
1445
1446 /*
1447  * Exception entry point. This expects an error code/orig_rax on the stack.
1448  * returns in "no swapgs flag" in %ebx.
1449  */
1450 ENTRY(error_entry)
1451         XCPT_FRAME
1452         CFI_ADJUST_CFA_OFFSET 15*8
1453         /* oldrax contains error code */
1454         cld
1455         movq_cfi rdi, RDI+8
1456         movq_cfi rsi, RSI+8
1457         movq_cfi rdx, RDX+8
1458         movq_cfi rcx, RCX+8
1459         movq_cfi rax, RAX+8
1460         movq_cfi  r8,  R8+8
1461         movq_cfi  r9,  R9+8
1462         movq_cfi r10, R10+8
1463         movq_cfi r11, R11+8
1464         movq_cfi rbx, RBX+8
1465         movq_cfi rbp, RBP+8
1466         movq_cfi r12, R12+8
1467         movq_cfi r13, R13+8
1468         movq_cfi r14, R14+8
1469         movq_cfi r15, R15+8
1470         xorl %ebx,%ebx
1471         testl $3,CS+8(%rsp)
1472         je error_kernelspace
1473 error_swapgs:
1474         SWAPGS
1475 error_sti:
1476         TRACE_IRQS_OFF
1477         ret
1478         CFI_ENDPROC
1479
1480 /*
1481  * There are two places in the kernel that can potentially fault with
1482  * usergs. Handle them here. The exception handlers after iret run with
1483  * kernel gs again, so don't set the user space flag. B stepping K8s
1484  * sometimes report an truncated RIP for IRET exceptions returning to
1485  * compat mode. Check for these here too.
1486  */
1487 error_kernelspace:
1488         incl %ebx
1489         leaq irq_return(%rip),%rcx
1490         cmpq %rcx,RIP+8(%rsp)
1491         je error_swapgs
1492         movl %ecx,%ecx  /* zero extend */
1493         cmpq %rcx,RIP+8(%rsp)
1494         je error_swapgs
1495         cmpq $gs_change,RIP+8(%rsp)
1496         je error_swapgs
1497         jmp error_sti
1498 END(error_entry)
1499
1500
1501 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1502 ENTRY(error_exit)
1503         DEFAULT_FRAME
1504         movl %ebx,%eax
1505         RESTORE_REST
1506         DISABLE_INTERRUPTS(CLBR_NONE)
1507         TRACE_IRQS_OFF
1508         GET_THREAD_INFO(%rcx)
1509         testl %eax,%eax
1510         jne retint_kernel
1511         LOCKDEP_SYS_EXIT_IRQ
1512         movl TI_flags(%rcx),%edx
1513         movl $_TIF_WORK_MASK,%edi
1514         andl %edi,%edx
1515         jnz retint_careful
1516         jmp retint_swapgs
1517         CFI_ENDPROC
1518 END(error_exit)
1519
1520
1521         /* runs on exception stack */
1522 ENTRY(nmi)
1523         INTR_FRAME
1524         PARAVIRT_ADJUST_EXCEPTION_FRAME
1525         pushq_cfi $-1
1526         subq $15*8, %rsp
1527         CFI_ADJUST_CFA_OFFSET 15*8
1528         call save_paranoid
1529         DEFAULT_FRAME 0
1530         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1531         movq %rsp,%rdi
1532         movq $-1,%rsi
1533         call do_nmi
1534 #ifdef CONFIG_TRACE_IRQFLAGS
1535         /* paranoidexit; without TRACE_IRQS_OFF */
1536         /* ebx: no swapgs flag */
1537         DISABLE_INTERRUPTS(CLBR_NONE)
1538         testl %ebx,%ebx                         /* swapgs needed? */
1539         jnz nmi_restore
1540         testl $3,CS(%rsp)
1541         jnz nmi_userspace
1542 nmi_swapgs:
1543         SWAPGS_UNSAFE_STACK
1544 nmi_restore:
1545         RESTORE_ALL 8
1546         jmp irq_return
1547 nmi_userspace:
1548         GET_THREAD_INFO(%rcx)
1549         movl TI_flags(%rcx),%ebx
1550         andl $_TIF_WORK_MASK,%ebx
1551         jz nmi_swapgs
1552         movq %rsp,%rdi                  /* &pt_regs */
1553         call sync_regs
1554         movq %rax,%rsp                  /* switch stack for scheduling */
1555         testl $_TIF_NEED_RESCHED,%ebx
1556         jnz nmi_schedule
1557         movl %ebx,%edx                  /* arg3: thread flags */
1558         ENABLE_INTERRUPTS(CLBR_NONE)
1559         xorl %esi,%esi                  /* arg2: oldset */
1560         movq %rsp,%rdi                  /* arg1: &pt_regs */
1561         call do_notify_resume
1562         DISABLE_INTERRUPTS(CLBR_NONE)
1563         jmp nmi_userspace
1564 nmi_schedule:
1565         ENABLE_INTERRUPTS(CLBR_ANY)
1566         call schedule
1567         DISABLE_INTERRUPTS(CLBR_ANY)
1568         jmp nmi_userspace
1569         CFI_ENDPROC
1570 #else
1571         jmp paranoid_exit
1572         CFI_ENDPROC
1573 #endif
1574 END(nmi)
1575
1576 ENTRY(ignore_sysret)
1577         CFI_STARTPROC
1578         mov $-ENOSYS,%eax
1579         sysret
1580         CFI_ENDPROC
1581 END(ignore_sysret)
1582
1583 /*
1584  * End of kprobes section
1585  */
1586         .popsection