arch/x86/kernel/vmlinux.lds.S

   1 /*
   2  * ld script for the x86 kernel
   3  *
   4  * Historic 32-bit version written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5  *
   6  * Modernisation, unification and other changes and fixes:
   7  *   Copyright (C) 2007-2009  Sam Ravnborg <sam@ravnborg.org>
   8  *
   9  *
  10  * Don't define absolute symbols until and unless you know that symbol
  11  * value is should remain constant even if kernel image is relocated
  12  * at run time. Absolute symbols are not relocated. If symbol value should
  13  * change if kernel is relocated, make the symbol section relative and
  14  * put it inside the section definition.
  15  */
  16
  17 #ifdef CONFIG_X86_32
  18 #define LOAD_OFFSET __PAGE_OFFSET
  19 #else
  20 #define LOAD_OFFSET __START_KERNEL_map
  21 #endif
  22
  23 #include <asm-generic/vmlinux.lds.h>
  24 #include <asm/asm-offsets.h>
  25 #include <asm/thread_info.h>
  26 #include <asm/page_types.h>
  27 #include <asm/cache.h>
  28 #include <asm/boot.h>
  29
  30 #undef i386     /* in case the preprocessor is a 32bit one */
  31
  32 OUTPUT_FORMAT(CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT)
  33
  34 #ifdef CONFIG_X86_32
  35 OUTPUT_ARCH(i386)
  36 ENTRY(phys_startup_32)
  37 jiffies = jiffies_64;
  38 #else
  39 OUTPUT_ARCH(i386:x86-64)
  40 ENTRY(phys_startup_64)
  41 jiffies_64 = jiffies;
  42 #endif
  43
  44 #if defined(CONFIG_X86_64) && defined(CONFIG_DEBUG_RODATA)
  45 /*
  46  * On 64-bit, align RODATA to 2MB so that even with CONFIG_DEBUG_RODATA
  47  * we retain large page mappings for boundaries spanning kernel text, rodata
  48  * and data sections.
  49  *
  50  * However, kernel identity mappings will have different RWX permissions
  51  * to the pages mapping to text and to the pages padding (which are freed) the
  52  * text section. Hence kernel identity mappings will be broken to smaller
  53  * pages. For 64-bit, kernel text and kernel identity mappings are different,
  54  * so we can enable protection checks that come with CONFIG_DEBUG_RODATA,
  55  * as well as retain 2MB large page mappings for kernel text.
  56  */
  57 #define X64_ALIGN_DEBUG_RODATA_BEGIN    . = ALIGN(HPAGE_SIZE);
  58
  59 #define X64_ALIGN_DEBUG_RODATA_END                              \
  60                 . = ALIGN(HPAGE_SIZE);                          \
  61                 __end_rodata_hpage_align = .;
  62
  63 #else
  64
  65 #define X64_ALIGN_DEBUG_RODATA_BEGIN
  66 #define X64_ALIGN_DEBUG_RODATA_END
  67
  68 #endif
  69
  70 PHDRS {
  71         text PT_LOAD FLAGS(5);          /* R_E */
  72         data PT_LOAD FLAGS(6);          /* RW_ */
  73 #ifdef CONFIG_X86_64
  74 #ifdef CONFIG_SMP
  75         percpu PT_LOAD FLAGS(6);        /* RW_ */
  76 #endif
  77         init PT_LOAD FLAGS(7);          /* RWE */
  78 #endif
  79         note PT_NOTE FLAGS(0);          /* ___ */
  80 }
  81
  82 SECTIONS
  83 {
  84 #ifdef CONFIG_X86_32
  85         . = LOAD_OFFSET + LOAD_PHYSICAL_ADDR;
  86         phys_startup_32 = startup_32 - LOAD_OFFSET;
  87 #else
  88         . = __START_KERNEL;
  89         phys_startup_64 = startup_64 - LOAD_OFFSET;
  90 #endif
  91
  92         /* Text and read-only data */
  93         .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  94                 _text = .;
  95                 /* bootstrapping code */
  96                 HEAD_TEXT
  97                 . = ALIGN(8);
  98                 _stext = .;
  99                 TEXT_TEXT
 100                 SCHED_TEXT
 101                 LOCK_TEXT
 102                 KPROBES_TEXT
 103                 ENTRY_TEXT
 104                 IRQENTRY_TEXT
 105                 *(.fixup)
 106                 *(.gnu.warning)
 107                 /* End of text section */
 108                 _etext = .;
 109         } :text = 0x9090
 110
 111         NOTES :text :note
 112
 113         EXCEPTION_TABLE(16) :text = 0x9090
 114
 115 #if defined(CONFIG_DEBUG_RODATA)
 116         /* .text should occupy whole number of pages */
 117         . = ALIGN(PAGE_SIZE);
 118 #endif
 119         X64_ALIGN_DEBUG_RODATA_BEGIN
 120         RO_DATA(PAGE_SIZE)
 121         X64_ALIGN_DEBUG_RODATA_END
 122
 123         /* Data */
 124         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 125                 /* Start of data section */
 126                 _sdata = .;
 127
 128                 /* init_task */
 129                 INIT_TASK_DATA(THREAD_SIZE)
 130
 131 #ifdef CONFIG_X86_32
 132                 /* 32 bit has nosave before _edata */
 133                 NOSAVE_DATA
 134 #endif
 135
 136                 PAGE_ALIGNED_DATA(PAGE_SIZE)
 137
 138                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 139
 140                 DATA_DATA
 141                 CONSTRUCTORS
 142
 143                 /* rarely changed data like cpu maps */
 144                 READ_MOSTLY_DATA(INTERNODE_CACHE_BYTES)
 145
 146                 /* End of data section */
 147                 _edata = .;
 148         } :data
 149
 150
 151         . = ALIGN(PAGE_SIZE);
 152         __vvar_page = .;
 153
 154         .vvar : AT(ADDR(.vvar) - LOAD_OFFSET) {
 155                 /* work around gold bug 13023 */
 156                 __vvar_beginning_hack = .;
 157
 158                 /* Place all vvars at the offsets in asm/vvar.h. */
 159 #define EMIT_VVAR(name, offset)                         \
 160                 . = __vvar_beginning_hack + offset;     \
 161                 *(.vvar_ ## name)
 162 #define __VVAR_KERNEL_LDS
 163 #include <asm/vvar.h>
 164 #undef __VVAR_KERNEL_LDS
 165 #undef EMIT_VVAR
 166
 167                 /*
 168                  * Pad the rest of the page with zeros.  Otherwise the loader
 169                  * can leave garbage here.
 170                  */
 171                 . = __vvar_beginning_hack + PAGE_SIZE;
 172         } :data
 173
 174        . = ALIGN(__vvar_page + PAGE_SIZE, PAGE_SIZE);
 175
 176         /* Init code and data - will be freed after init */
 177         . = ALIGN(PAGE_SIZE);
 178         .init.begin : AT(ADDR(.init.begin) - LOAD_OFFSET) {
 179                 __init_begin = .; /* paired with __init_end */
 180         }
 181
 182 #if defined(CONFIG_X86_64) && defined(CONFIG_SMP)
 183         /*
 184          * percpu offsets are zero-based on SMP.  PERCPU_VADDR() changes the
 185          * output PHDR, so the next output section - .init.text - should
 186          * start another segment - init.
 187          */
 188         PERCPU_VADDR(INTERNODE_CACHE_BYTES, 0, :percpu)
 189 #endif
 190
 191         INIT_TEXT_SECTION(PAGE_SIZE)
 192 #ifdef CONFIG_X86_64
 193         :init
 194 #endif
 195
 196         INIT_DATA_SECTION(16)
 197
 198         .x86_cpu_dev.init : AT(ADDR(.x86_cpu_dev.init) - LOAD_OFFSET) {
 199                 __x86_cpu_dev_start = .;
 200                 *(.x86_cpu_dev.init)
 201                 __x86_cpu_dev_end = .;
 202         }
 203
 204 #ifdef CONFIG_X86_INTEL_MID
 205         .x86_intel_mid_dev.init : AT(ADDR(.x86_intel_mid_dev.init) - \
 206                                                                 LOAD_OFFSET) {
 207                 __x86_intel_mid_dev_start = .;
 208                 *(.x86_intel_mid_dev.init)
 209                 __x86_intel_mid_dev_end = .;
 210         }
 211 #endif
 212
 213         /*
 214          * start address and size of operations which during runtime
 215          * can be patched with virtualization friendly instructions or
 216          * baremetal native ones. Think page table operations.
 217          * Details in paravirt_types.h
 218          */
 219         . = ALIGN(8);
 220         .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
 221                 __parainstructions = .;
 222                 *(.parainstructions)
 223                 __parainstructions_end = .;
 224         }
 225
 226         /*
 227          * struct alt_inst entries. From the header (alternative.h):
 228          * "Alternative instructions for different CPU types or capabilities"
 229          * Think locking instructions on spinlocks.
 230          */
 231         . = ALIGN(8);
 232         .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 233                 __alt_instructions = .;
 234                 *(.altinstructions)
 235                 __alt_instructions_end = .;
 236         }
 237
 238         /*
 239          * And here are the replacement instructions. The linker sticks
 240          * them as binary blobs. The .altinstructions has enough data to
 241          * get the address and the length of them to patch the kernel safely.
 242          */
 243         .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 244                 *(.altinstr_replacement)
 245         }
 246
 247         /*
 248          * struct iommu_table_entry entries are injected in this section.
 249          * It is an array of IOMMUs which during run time gets sorted depending
 250          * on its dependency order. After rootfs_initcall is complete
 251          * this section can be safely removed.
 252          */
 253         .iommu_table : AT(ADDR(.iommu_table) - LOAD_OFFSET) {
 254                 __iommu_table = .;
 255                 *(.iommu_table)
 256                 __iommu_table_end = .;
 257         }
 258
 259         . = ALIGN(8);
 260         .apicdrivers : AT(ADDR(.apicdrivers) - LOAD_OFFSET) {
 261                 __apicdrivers = .;
 262                 *(.apicdrivers);
 263                 __apicdrivers_end = .;
 264         }
 265
 266         . = ALIGN(8);
 267         /*
 268          * .exit.text is discard at runtime, not link time, to deal with
 269          *  references from .altinstructions and .eh_frame
 270          */
 271         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 272                 EXIT_TEXT
 273         }
 274
 275         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 276                 EXIT_DATA
 277         }
 278
 279 #if !defined(CONFIG_X86_64) || !defined(CONFIG_SMP)
 280         PERCPU_SECTION(INTERNODE_CACHE_BYTES)
 281 #endif
 282
 283         . = ALIGN(PAGE_SIZE);
 284
 285         /* freed after init ends here */
 286         .init.end : AT(ADDR(.init.end) - LOAD_OFFSET) {
 287                 __init_end = .;
 288         }
 289
 290         /*
 291          * smp_locks might be freed after init
 292          * start/end must be page aligned
 293          */
 294         . = ALIGN(PAGE_SIZE);
 295         .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 296                 __smp_locks = .;
 297                 *(.smp_locks)
 298                 . = ALIGN(PAGE_SIZE);
 299                 __smp_locks_end = .;
 300         }
 301
 302 #ifdef CONFIG_X86_64
 303         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 304                 NOSAVE_DATA
 305         }
 306 #endif
 307
 308         /* BSS */
 309         . = ALIGN(PAGE_SIZE);
 310         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 311                 __bss_start = .;
 312                 *(.bss..page_aligned)
 313                 *(.bss)
 314                 . = ALIGN(PAGE_SIZE);
 315                 __bss_stop = .;
 316         }
 317
 318         . = ALIGN(PAGE_SIZE);
 319         .brk : AT(ADDR(.brk) - LOAD_OFFSET) {
 320                 __brk_base = .;
 321                 . += 64 * 1024;         /* 64k alignment slop space */
 322                 *(.brk_reservation)     /* areas brk users have reserved */
 323                 __brk_limit = .;
 324         }
 325
 326         _end = .;
 327
 328         STABS_DEBUG
 329         DWARF_DEBUG
 330
 331         /* Sections to be discarded */
 332         DISCARDS
 333         /DISCARD/ : { *(.eh_frame) }
 334 }
 335
 336
 337 #ifdef CONFIG_X86_32
 338 /*
 339  * The ASSERT() sink to . is intentional, for binutils 2.14 compatibility:
 340  */
 341 . = ASSERT((_end - LOAD_OFFSET <= KERNEL_IMAGE_SIZE),
 342            "kernel image bigger than KERNEL_IMAGE_SIZE");
 343 #else
 344 /*
 345  * Per-cpu symbols which need to be offset from __per_cpu_load
 346  * for the boot processor.
 347  */
 348 #define INIT_PER_CPU(x) init_per_cpu__##x = x + __per_cpu_load
 349 INIT_PER_CPU(gdt_page);
 350 INIT_PER_CPU(irq_stack_union);
 351
 352 /*
 353  * Build-time check on the image size:
 354  */
 355 . = ASSERT((_end - _text <= KERNEL_IMAGE_SIZE),
 356            "kernel image bigger than KERNEL_IMAGE_SIZE");
 357
 358 #ifdef CONFIG_SMP
 359 . = ASSERT((irq_stack_union == 0),
 360            "irq_stack_union is not at start of per-cpu area");
 361 #endif
 362
 363 #endif /* CONFIG_X86_32 */
 364
 365 #ifdef CONFIG_KEXEC
 366 #include <asm/kexec.h>
 367
 368 . = ASSERT(kexec_control_code_size <= KEXEC_CONTROL_CODE_MAX_SIZE,
 369            "kexec control code size is too big");
 370 #endif
 371