arch/x86/kernel/vmlinux.lds.S

   1 /*
   2  * ld script for the x86 kernel
   3  *
   4  * Historic 32-bit version written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5  *
   6  * Modernisation, unification and other changes and fixes:
   7  *   Copyright (C) 2007-2009  Sam Ravnborg <sam@ravnborg.org>
   8  *
   9  *
  10  * Don't define absolute symbols until and unless you know that symbol
  11  * value is should remain constant even if kernel image is relocated
  12  * at run time. Absolute symbols are not relocated. If symbol value should
  13  * change if kernel is relocated, make the symbol section relative and
  14  * put it inside the section definition.
  15  */
  16
  17 #ifdef CONFIG_X86_32
  18 #define LOAD_OFFSET __PAGE_OFFSET
  19 #else
  20 #define LOAD_OFFSET __START_KERNEL_map
  21 #endif
  22
  23 #include <asm-generic/vmlinux.lds.h>
  24 #include <asm/asm-offsets.h>
  25 #include <asm/thread_info.h>
  26 #include <asm/page_types.h>
  27 #include <asm/cache.h>
  28 #include <asm/boot.h>
  29
  30 #undef i386     /* in case the preprocessor is a 32bit one */
  31
  32 OUTPUT_FORMAT(CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT)
  33
  34 #ifdef CONFIG_X86_32
  35 OUTPUT_ARCH(i386)
  36 ENTRY(phys_startup_32)
  37 jiffies = jiffies_64;
  38 #else
  39 OUTPUT_ARCH(i386:x86-64)
  40 ENTRY(phys_startup_64)
  41 jiffies_64 = jiffies;
  42 #endif
  43
  44 #if defined(CONFIG_X86_64) && defined(CONFIG_DEBUG_RODATA)
  45 /*
  46  * On 64-bit, align RODATA to 2MB so that even with CONFIG_DEBUG_RODATA
  47  * we retain large page mappings for boundaries spanning kernel text, rodata
  48  * and data sections.
  49  *
  50  * However, kernel identity mappings will have different RWX permissions
  51  * to the pages mapping to text and to the pages padding (which are freed) the
  52  * text section. Hence kernel identity mappings will be broken to smaller
  53  * pages. For 64-bit, kernel text and kernel identity mappings are different,
  54  * so we can enable protection checks that come with CONFIG_DEBUG_RODATA,
  55  * as well as retain 2MB large page mappings for kernel text.
  56  */
  57 #define X64_ALIGN_DEBUG_RODATA_BEGIN    . = ALIGN(HPAGE_SIZE);
  58
  59 #define X64_ALIGN_DEBUG_RODATA_END                              \
  60                 . = ALIGN(HPAGE_SIZE);                          \
  61                 __end_rodata_hpage_align = .;
  62
  63 #else
  64
  65 #define X64_ALIGN_DEBUG_RODATA_BEGIN
  66 #define X64_ALIGN_DEBUG_RODATA_END
  67
  68 #endif
  69
  70 PHDRS {
  71         text PT_LOAD FLAGS(5);          /* R_E */
  72         data PT_LOAD FLAGS(7);          /* RWE */
  73 #ifdef CONFIG_X86_64
  74         user PT_LOAD FLAGS(5);          /* R_E */
  75 #ifdef CONFIG_SMP
  76         percpu PT_LOAD FLAGS(6);        /* RW_ */
  77 #endif
  78         init PT_LOAD FLAGS(7);          /* RWE */
  79 #endif
  80         note PT_NOTE FLAGS(0);          /* ___ */
  81 }
  82
  83 SECTIONS
  84 {
  85 #ifdef CONFIG_X86_32
  86         . = LOAD_OFFSET + LOAD_PHYSICAL_ADDR;
  87         phys_startup_32 = startup_32 - LOAD_OFFSET;
  88 #else
  89         . = __START_KERNEL;
  90         phys_startup_64 = startup_64 - LOAD_OFFSET;
  91 #endif
  92
  93         /* Text and read-only data */
  94         .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  95                 _text = .;
  96                 /* bootstrapping code */
  97                 HEAD_TEXT
  98 #ifdef CONFIG_X86_32
  99                 . = ALIGN(PAGE_SIZE);
 100                 *(.text..page_aligned)
 101 #endif
 102                 . = ALIGN(8);
 103                 _stext = .;
 104                 TEXT_TEXT
 105                 SCHED_TEXT
 106                 LOCK_TEXT
 107                 KPROBES_TEXT
 108                 IRQENTRY_TEXT
 109                 *(.fixup)
 110                 *(.gnu.warning)
 111                 /* End of text section */
 112                 _etext = .;
 113         } :text = 0x9090
 114
 115         NOTES :text :note
 116
 117         EXCEPTION_TABLE(16) :text = 0x9090
 118
 119         X64_ALIGN_DEBUG_RODATA_BEGIN
 120         RO_DATA(PAGE_SIZE)
 121         X64_ALIGN_DEBUG_RODATA_END
 122
 123         /* Data */
 124         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 125                 /* Start of data section */
 126                 _sdata = .;
 127
 128                 /* init_task */
 129                 INIT_TASK_DATA(THREAD_SIZE)
 130
 131 #ifdef CONFIG_X86_32
 132                 /* 32 bit has nosave before _edata */
 133                 NOSAVE_DATA
 134 #endif
 135
 136                 PAGE_ALIGNED_DATA(PAGE_SIZE)
 137
 138                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 139
 140                 DATA_DATA
 141                 CONSTRUCTORS
 142
 143                 /* rarely changed data like cpu maps */
 144                 READ_MOSTLY_DATA(INTERNODE_CACHE_BYTES)
 145
 146                 /* End of data section */
 147                 _edata = .;
 148         } :data
 149
 150 #ifdef CONFIG_X86_64
 151
 152 #define VSYSCALL_ADDR (-10*1024*1024)
 153
 154 #define VLOAD_OFFSET (VSYSCALL_ADDR - __vsyscall_0 + LOAD_OFFSET)
 155 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
 156
 157 #define VVIRT_OFFSET (VSYSCALL_ADDR - __vsyscall_0)
 158 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
 159
 160         . = ALIGN(4096);
 161         __vsyscall_0 = .;
 162
 163         . = VSYSCALL_ADDR;
 164         .vsyscall_0 : AT(VLOAD(.vsyscall_0)) {
 165                 *(.vsyscall_0)
 166         } :user
 167
 168         . = ALIGN(L1_CACHE_BYTES);
 169         .vsyscall_fn : AT(VLOAD(.vsyscall_fn)) {
 170                 *(.vsyscall_fn)
 171         }
 172
 173         . = ALIGN(L1_CACHE_BYTES);
 174         .vsyscall_gtod_data : AT(VLOAD(.vsyscall_gtod_data)) {
 175                 *(.vsyscall_gtod_data)
 176         }
 177
 178         vsyscall_gtod_data = VVIRT(.vsyscall_gtod_data);
 179         .vsyscall_clock : AT(VLOAD(.vsyscall_clock)) {
 180                 *(.vsyscall_clock)
 181         }
 182         vsyscall_clock = VVIRT(.vsyscall_clock);
 183
 184
 185         .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1)) {
 186                 *(.vsyscall_1)
 187         }
 188         .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2)) {
 189                 *(.vsyscall_2)
 190         }
 191
 192         .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) {
 193                 *(.vgetcpu_mode)
 194         }
 195         vgetcpu_mode = VVIRT(.vgetcpu_mode);
 196
 197         . = ALIGN(L1_CACHE_BYTES);
 198         .jiffies : AT(VLOAD(.jiffies)) {
 199                 *(.jiffies)
 200         }
 201         jiffies = VVIRT(.jiffies);
 202
 203         .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3)) {
 204                 *(.vsyscall_3)
 205         }
 206
 207         . = __vsyscall_0 + PAGE_SIZE;
 208
 209 #undef VSYSCALL_ADDR
 210 #undef VLOAD_OFFSET
 211 #undef VLOAD
 212 #undef VVIRT_OFFSET
 213 #undef VVIRT
 214
 215 #endif /* CONFIG_X86_64 */
 216
 217         /* Init code and data - will be freed after init */
 218         . = ALIGN(PAGE_SIZE);
 219         .init.begin : AT(ADDR(.init.begin) - LOAD_OFFSET) {
 220                 __init_begin = .; /* paired with __init_end */
 221         }
 222
 223 #if defined(CONFIG_X86_64) && defined(CONFIG_SMP)
 224         /*
 225          * percpu offsets are zero-based on SMP.  PERCPU_VADDR() changes the
 226          * output PHDR, so the next output section - .init.text - should
 227          * start another segment - init.
 228          */
 229         PERCPU_VADDR(0, :percpu)
 230 #endif
 231
 232         INIT_TEXT_SECTION(PAGE_SIZE)
 233 #ifdef CONFIG_X86_64
 234         :init
 235 #endif
 236
 237         INIT_DATA_SECTION(16)
 238
 239         .x86_cpu_dev.init : AT(ADDR(.x86_cpu_dev.init) - LOAD_OFFSET) {
 240                 __x86_cpu_dev_start = .;
 241                 *(.x86_cpu_dev.init)
 242                 __x86_cpu_dev_end = .;
 243         }
 244
 245         /*
 246          * start address and size of operations which during runtime
 247          * can be patched with virtualization friendly instructions or
 248          * baremetal native ones. Think page table operations.
 249          * Details in paravirt_types.h
 250          */
 251         . = ALIGN(8);
 252         .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
 253                 __parainstructions = .;
 254                 *(.parainstructions)
 255                 __parainstructions_end = .;
 256         }
 257
 258         /*
 259          * struct alt_inst entries. From the header (alternative.h):
 260          * "Alternative instructions for different CPU types or capabilities"
 261          * Think locking instructions on spinlocks.
 262          */
 263         . = ALIGN(8);
 264         .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 265                 __alt_instructions = .;
 266                 *(.altinstructions)
 267                 __alt_instructions_end = .;
 268         }
 269
 270         /*
 271          * And here are the replacement instructions. The linker sticks
 272          * them as binary blobs. The .altinstructions has enough data to
 273          * get the address and the length of them to patch the kernel safely.
 274          */
 275         .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 276                 *(.altinstr_replacement)
 277         }
 278
 279         /*
 280          * struct iommu_table_entry entries are injected in this section.
 281          * It is an array of IOMMUs which during run time gets sorted depending
 282          * on its dependency order. After rootfs_initcall is complete
 283          * this section can be safely removed.
 284          */
 285         .iommu_table : AT(ADDR(.iommu_table) - LOAD_OFFSET) {
 286                 __iommu_table = .;
 287                 *(.iommu_table)
 288                 __iommu_table_end = .;
 289         }
 290         . = ALIGN(8);
 291         /*
 292          * .exit.text is discard at runtime, not link time, to deal with
 293          *  references from .altinstructions and .eh_frame
 294          */
 295         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 296                 EXIT_TEXT
 297         }
 298
 299         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 300                 EXIT_DATA
 301         }
 302
 303 #if !defined(CONFIG_X86_64) || !defined(CONFIG_SMP)
 304         PERCPU(THREAD_SIZE)
 305 #endif
 306
 307         . = ALIGN(PAGE_SIZE);
 308
 309         /* freed after init ends here */
 310         .init.end : AT(ADDR(.init.end) - LOAD_OFFSET) {
 311                 __init_end = .;
 312         }
 313
 314         /*
 315          * smp_locks might be freed after init
 316          * start/end must be page aligned
 317          */
 318         . = ALIGN(PAGE_SIZE);
 319         .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 320                 __smp_locks = .;
 321                 *(.smp_locks)
 322                 . = ALIGN(PAGE_SIZE);
 323                 __smp_locks_end = .;
 324         }
 325
 326 #ifdef CONFIG_X86_64
 327         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 328                 NOSAVE_DATA
 329         }
 330 #endif
 331
 332         /* BSS */
 333         . = ALIGN(PAGE_SIZE);
 334         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 335                 __bss_start = .;
 336                 *(.bss..page_aligned)
 337                 *(.bss)
 338                 . = ALIGN(4);
 339                 __bss_stop = .;
 340         }
 341
 342         . = ALIGN(PAGE_SIZE);
 343         .brk : AT(ADDR(.brk) - LOAD_OFFSET) {
 344                 __brk_base = .;
 345                 . += 64 * 1024;         /* 64k alignment slop space */
 346                 *(.brk_reservation)     /* areas brk users have reserved */
 347                 __brk_limit = .;
 348         }
 349
 350         _end = .;
 351
 352         STABS_DEBUG
 353         DWARF_DEBUG
 354
 355         /* Sections to be discarded */
 356         DISCARDS
 357         /DISCARD/ : { *(.eh_frame) }
 358 }
 359
 360
 361 #ifdef CONFIG_X86_32
 362 /*
 363  * The ASSERT() sink to . is intentional, for binutils 2.14 compatibility:
 364  */
 365 . = ASSERT((_end - LOAD_OFFSET <= KERNEL_IMAGE_SIZE),
 366            "kernel image bigger than KERNEL_IMAGE_SIZE");
 367 #else
 368 /*
 369  * Per-cpu symbols which need to be offset from __per_cpu_load
 370  * for the boot processor.
 371  */
 372 #define INIT_PER_CPU(x) init_per_cpu__##x = x + __per_cpu_load
 373 INIT_PER_CPU(gdt_page);
 374 INIT_PER_CPU(irq_stack_union);
 375
 376 /*
 377  * Build-time check on the image size:
 378  */
 379 . = ASSERT((_end - _text <= KERNEL_IMAGE_SIZE),
 380            "kernel image bigger than KERNEL_IMAGE_SIZE");
 381
 382 #ifdef CONFIG_SMP
 383 . = ASSERT((irq_stack_union == 0),
 384            "irq_stack_union is not at start of per-cpu area");
 385 #endif
 386
 387 #endif /* CONFIG_X86_32 */
 388
 389 #ifdef CONFIG_KEXEC
 390 #include <asm/kexec.h>
 391
 392 . = ASSERT(kexec_control_code_size <= KEXEC_CONTROL_CODE_MAX_SIZE,
 393            "kexec control code size is too big");
 394 #endif
 395