arch/x86/vdso/vdso.lds.S

   1 /*
   2  * Linker script for vsyscall DSO.  The vsyscall page is an ELF shared
   3  * object prelinked to its virtual address, and with only one read-only
   4  * segment (that fits in one page).  This script controls its layout.
   5  */
   6 #include <asm/asm-offsets.h>
   7 #include "voffset.h"
   8
   9 #define VDSO_PRELINK 0xffffffffff700000
  10
  11 SECTIONS
  12 {
  13   . = VDSO_PRELINK + SIZEOF_HEADERS;
  14
  15   .hash           : { *(.hash) }                :text
  16   .gnu.hash       : { *(.gnu.hash) }
  17   .dynsym         : { *(.dynsym) }
  18   .dynstr         : { *(.dynstr) }
  19   .gnu.version    : { *(.gnu.version) }
  20   .gnu.version_d  : { *(.gnu.version_d) }
  21   .gnu.version_r  : { *(.gnu.version_r) }
  22
  23   /* This linker script is used both with -r and with -shared.
  24      For the layouts to match, we need to skip more than enough
  25      space for the dynamic symbol table et al.  If this amount
  26      is insufficient, ld -shared will barf.  Just increase it here.  */
  27   . = VDSO_PRELINK + VDSO_TEXT_OFFSET;
  28
  29   .text           : { *(.text*) }               :text
  30   .rodata         : { *(.rodata*) }             :text
  31   .data           : {
  32         *(.data*)
  33         *(.sdata*)
  34         *(.bss*)
  35         *(.dynbss*)
  36   }                                             :text
  37
  38   .altinstructions : { *(.altinstructions) }            :text
  39   .altinstr_replacement  : { *(.altinstr_replacement) } :text
  40
  41   .note           : { *(.note.*) }              :text :note
  42   .eh_frame_hdr   : { *(.eh_frame_hdr) }        :text :eh_frame_hdr
  43   .eh_frame       : { KEEP (*(.eh_frame)) }     :text
  44   .dynamic        : { *(.dynamic) }             :text :dynamic
  45   .useless        : {
  46         *(.got.plt) *(.got)
  47         *(.gnu.linkonce.d.*)
  48         *(.gnu.linkonce.b.*)
  49   }                                             :text
  50 }
  51
  52 /*
  53  * We must supply the ELF program headers explicitly to get just one
  54  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
  55  */
  56 PHDRS
  57 {
  58   text PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
  59   dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
  60   note PT_NOTE FLAGS(4); /* PF_R */
  61   eh_frame_hdr 0x6474e550; /* PT_GNU_EH_FRAME, but ld doesn't match the name */
  62 }
  63
  64 /*
  65  * This controls what symbols we export from the DSO.
  66  */
  67 VERSION
  68 {
  69   LINUX_2.6 {
  70     global:
  71         clock_gettime;
  72         __vdso_clock_gettime;
  73         gettimeofday;
  74         __vdso_gettimeofday;
  75         getcpu;
  76         __vdso_getcpu;
  77     local: *;
  78   };
  79 }