arch/x86/xen/xen-asm_64.S

   1 /*
   2  * Asm versions of Xen pv-ops, suitable for either direct use or
   3  * inlining.  The inline versions are the same as the direct-use
   4  * versions, with the pre- and post-amble chopped off.
   5  *
   6  * This code is encoded for size rather than absolute efficiency, with
   7  * a view to being able to inline as much as possible.
   8  *
   9  * We only bother with direct forms (ie, vcpu in pda) of the
  10  * operations here; the indirect forms are better handled in C, since
  11  * they're generally too large to inline anyway.
  12  */
  13
  14 #include <asm/errno.h>
  15 #include <asm/percpu.h>
  16 #include <asm/processor-flags.h>
  17 #include <asm/segment.h>
  18
  19 #include <xen/interface/xen.h>
  20
  21 #include "xen-asm.h"
  22
  23 ENTRY(xen_adjust_exception_frame)
  24         mov 8+0(%rsp), %rcx
  25         mov 8+8(%rsp), %r11
  26         ret $16
  27
  28 hypercall_iret = hypercall_page + __HYPERVISOR_iret * 32
  29 /*
  30  * Xen64 iret frame:
  31  *
  32  *      ss
  33  *      rsp
  34  *      rflags
  35  *      cs
  36  *      rip             <-- standard iret frame
  37  *
  38  *      flags
  39  *
  40  *      rcx             }
  41  *      r11             }<-- pushed by hypercall page
  42  * rsp->rax             }
  43  */
  44 ENTRY(xen_iret)
  45         pushq $0
  46 1:      jmp hypercall_iret
  47 ENDPATCH(xen_iret)
  48 RELOC(xen_iret, 1b+1)
  49
  50 ENTRY(xen_sysret64)
  51         /*
  52          * We're already on the usermode stack at this point, but
  53          * still with the kernel gs, so we can easily switch back
  54          */
  55         movq %rsp, PER_CPU_VAR(rsp_scratch)
  56         movq PER_CPU_VAR(kernel_stack), %rsp
  57
  58         pushq $__USER_DS
  59         pushq PER_CPU_VAR(rsp_scratch)
  60         pushq %r11
  61         pushq $__USER_CS
  62         pushq %rcx
  63
  64         pushq $VGCF_in_syscall
  65 1:      jmp hypercall_iret
  66 ENDPATCH(xen_sysret64)
  67 RELOC(xen_sysret64, 1b+1)
  68
  69 ENTRY(xen_sysret32)
  70         /*
  71          * We're already on the usermode stack at this point, but
  72          * still with the kernel gs, so we can easily switch back
  73          */
  74         movq %rsp, PER_CPU_VAR(rsp_scratch)
  75         movq PER_CPU_VAR(kernel_stack), %rsp
  76
  77         pushq $__USER32_DS
  78         pushq PER_CPU_VAR(rsp_scratch)
  79         pushq %r11
  80         pushq $__USER32_CS
  81         pushq %rcx
  82
  83         pushq $0
  84 1:      jmp hypercall_iret
  85 ENDPATCH(xen_sysret32)
  86 RELOC(xen_sysret32, 1b+1)
  87
  88 /*
  89  * Xen handles syscall callbacks much like ordinary exceptions, which
  90  * means we have:
  91  * - kernel gs
  92  * - kernel rsp
  93  * - an iret-like stack frame on the stack (including rcx and r11):
  94  *      ss
  95  *      rsp
  96  *      rflags
  97  *      cs
  98  *      rip
  99  *      r11
 100  * rsp->rcx
 101  *
 102  * In all the entrypoints, we undo all that to make it look like a
 103  * CPU-generated syscall/sysenter and jump to the normal entrypoint.
 104  */
 105
 106 .macro undo_xen_syscall
 107         mov 0*8(%rsp), %rcx
 108         mov 1*8(%rsp), %r11
 109         mov 5*8(%rsp), %rsp
 110 .endm
 111
 112 /* Normal 64-bit system call target */
 113 ENTRY(xen_syscall_target)
 114         undo_xen_syscall
 115         jmp system_call_after_swapgs
 116 ENDPROC(xen_syscall_target)
 117
 118 #ifdef CONFIG_IA32_EMULATION
 119
 120 /* 32-bit compat syscall target */
 121 ENTRY(xen_syscall32_target)
 122         undo_xen_syscall
 123         jmp ia32_cstar_target
 124 ENDPROC(xen_syscall32_target)
 125
 126 /* 32-bit compat sysenter target */
 127 ENTRY(xen_sysenter_target)
 128         undo_xen_syscall
 129         jmp ia32_sysenter_target
 130 ENDPROC(xen_sysenter_target)
 131
 132 #else /* !CONFIG_IA32_EMULATION */
 133
 134 ENTRY(xen_syscall32_target)
 135 ENTRY(xen_sysenter_target)
 136         lea 16(%rsp), %rsp      /* strip %rcx, %r11 */
 137         mov $-ENOSYS, %rax
 138         pushq $0
 139         jmp hypercall_iret
 140 ENDPROC(xen_syscall32_target)
 141 ENDPROC(xen_sysenter_target)
 142
 143 #endif  /* CONFIG_IA32_EMULATION */