arch/x86_64/kernel/vmlinux.lds.S

   1 /* ld script to make x86-64 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __START_KERNEL_map
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/page.h>
   9
  10 #undef i386     /* in case the preprocessor is a 32bit one */
  11
  12 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
  13 OUTPUT_ARCH(i386:x86-64)
  14 ENTRY(phys_startup_64)
  15 jiffies_64 = jiffies;
  16 _proxy_pda = 0;
  17 PHDRS {
  18         text PT_LOAD FLAGS(5);  /* R_E */
  19         data PT_LOAD FLAGS(7);  /* RWE */
  20         user PT_LOAD FLAGS(7);  /* RWE */
  21         data.init PT_LOAD FLAGS(7);     /* RWE */
  22         note PT_NOTE FLAGS(4);  /* R__ */
  23 }
  24 SECTIONS
  25 {
  26   . = __START_KERNEL;
  27   phys_startup_64 = startup_64 - LOAD_OFFSET;
  28   _text = .;                    /* Text and read-only data */
  29   .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  30         /* First the code that has to be first for bootstrapping */
  31         *(.bootstrap.text)
  32         /* Then all the functions that are "hot" in profiles, to group them
  33            onto the same hugetlb entry */
  34         #include "functionlist"
  35         /* Then the rest */
  36         *(.text)
  37         SCHED_TEXT
  38         LOCK_TEXT
  39         KPROBES_TEXT
  40         *(.fixup)
  41         *(.gnu.warning)
  42         } :text = 0x9090
  43                                 /* out-of-line lock text */
  44   .text.lock : AT(ADDR(.text.lock) - LOAD_OFFSET) { *(.text.lock) }
  45
  46   _etext = .;                   /* End of text section */
  47
  48   . = ALIGN(16);                /* Exception table */
  49   __start___ex_table = .;
  50   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  51   __stop___ex_table = .;
  52
  53   RODATA
  54
  55   BUG_TABLE
  56
  57   . = ALIGN(PAGE_SIZE);        /* Align data segment to page size boundary */
  58                                 /* Data */
  59   .data : AT(ADDR(.data) - LOAD_OFFSET) {
  60         *(.data)
  61         CONSTRUCTORS
  62         } :data
  63
  64   _edata = .;                   /* End of data section */
  65
  66   . = ALIGN(PAGE_SIZE);
  67   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  68   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  69         *(.data.cacheline_aligned)
  70   }
  71   . = ALIGN(CONFIG_X86_INTERNODE_CACHE_BYTES);
  72   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
  73         *(.data.read_mostly)
  74   }
  75
  76 #define VSYSCALL_ADDR (-10*1024*1024)
  77 #define VSYSCALL_PHYS_ADDR ((LOADADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  78 #define VSYSCALL_VIRT_ADDR ((ADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  79
  80 #define VLOAD_OFFSET (VSYSCALL_ADDR - VSYSCALL_PHYS_ADDR)
  81 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
  82
  83 #define VVIRT_OFFSET (VSYSCALL_ADDR - VSYSCALL_VIRT_ADDR)
  84 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
  85
  86   . = VSYSCALL_ADDR;
  87   .vsyscall_0 :  AT(VSYSCALL_PHYS_ADDR) { *(.vsyscall_0) } :user
  88   __vsyscall_0 = VSYSCALL_VIRT_ADDR;
  89
  90   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  91   .xtime_lock : AT(VLOAD(.xtime_lock)) { *(.xtime_lock) }
  92   xtime_lock = VVIRT(.xtime_lock);
  93
  94   .vxtime : AT(VLOAD(.vxtime)) { *(.vxtime) }
  95   vxtime = VVIRT(.vxtime);
  96
  97   .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) { *(.vgetcpu_mode) }
  98   vgetcpu_mode = VVIRT(.vgetcpu_mode);
  99
 100   .sys_tz : AT(VLOAD(.sys_tz)) { *(.sys_tz) }
 101   sys_tz = VVIRT(.sys_tz);
 102
 103   .sysctl_vsyscall : AT(VLOAD(.sysctl_vsyscall)) { *(.sysctl_vsyscall) }
 104   sysctl_vsyscall = VVIRT(.sysctl_vsyscall);
 105
 106   .xtime : AT(VLOAD(.xtime)) { *(.xtime) }
 107   xtime = VVIRT(.xtime);
 108
 109   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 110   .jiffies : AT(VLOAD(.jiffies)) { *(.jiffies) }
 111   jiffies = VVIRT(.jiffies);
 112
 113   .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1)) { *(.vsyscall_1) }
 114   .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2)) { *(.vsyscall_2) }
 115   .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3)) { *(.vsyscall_3) }
 116
 117   . = VSYSCALL_VIRT_ADDR + 4096;
 118
 119 #undef VSYSCALL_ADDR
 120 #undef VSYSCALL_PHYS_ADDR
 121 #undef VSYSCALL_VIRT_ADDR
 122 #undef VLOAD_OFFSET
 123 #undef VLOAD
 124 #undef VVIRT_OFFSET
 125 #undef VVIRT
 126
 127   . = ALIGN(8192);              /* init_task */
 128   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 129         *(.data.init_task)
 130   }:data.init
 131
 132   . = ALIGN(4096);
 133   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
 134         *(.data.page_aligned)
 135   }
 136
 137   /* might get freed after init */
 138   . = ALIGN(4096);
 139   __smp_alt_begin = .;
 140   __smp_alt_instructions = .;
 141   .smp_altinstructions : AT(ADDR(.smp_altinstructions) - LOAD_OFFSET) {
 142         *(.smp_altinstructions)
 143   }
 144   __smp_alt_instructions_end = .;
 145   . = ALIGN(8);
 146   __smp_locks = .;
 147   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 148         *(.smp_locks)
 149   }
 150   __smp_locks_end = .;
 151   .smp_altinstr_replacement : AT(ADDR(.smp_altinstr_replacement) - LOAD_OFFSET) {
 152         *(.smp_altinstr_replacement)
 153   }
 154   . = ALIGN(4096);
 155   __smp_alt_end = .;
 156
 157   . = ALIGN(4096);              /* Init code and data */
 158   __init_begin = .;
 159   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 160         _sinittext = .;
 161         *(.init.text)
 162         _einittext = .;
 163   }
 164   __initdata_begin = .;
 165   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
 166   __initdata_end = .;
 167   . = ALIGN(16);
 168   __setup_start = .;
 169   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 170   __setup_end = .;
 171   __initcall_start = .;
 172   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 173         INITCALLS
 174   }
 175   __initcall_end = .;
 176   __con_initcall_start = .;
 177   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 178         *(.con_initcall.init)
 179   }
 180   __con_initcall_end = .;
 181   SECURITY_INIT
 182   . = ALIGN(8);
 183   __alt_instructions = .;
 184   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 185         *(.altinstructions)
 186   }
 187   __alt_instructions_end = .;
 188   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 189         *(.altinstr_replacement)
 190   }
 191   /* .exit.text is discard at runtime, not link time, to deal with references
 192      from .altinstructions and .eh_frame */
 193   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 194   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 195   . = ALIGN(4096);
 196   __initramfs_start = .;
 197   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 198   __initramfs_end = .;
 199     . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 200   __per_cpu_start = .;
 201   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
 202   __per_cpu_end = .;
 203   . = ALIGN(4096);
 204   __init_end = .;
 205
 206   . = ALIGN(4096);
 207   __nosave_begin = .;
 208   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
 209   . = ALIGN(4096);
 210   __nosave_end = .;
 211
 212   __bss_start = .;              /* BSS */
 213   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 214         *(.bss.page_aligned)
 215         *(.bss)
 216         }
 217   __bss_stop = .;
 218
 219   _end = . ;
 220
 221   /* Sections to be discarded */
 222   /DISCARD/ : {
 223         *(.exitcall.exit)
 224         *(.eh_frame)
 225         }
 226
 227   STABS_DEBUG
 228
 229   DWARF_DEBUG
 230 }