arch/x86_64/kernel/vmlinux.lds.S

   1 /* ld script to make x86-64 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __START_KERNEL_map
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/page.h>
   9
  10 #undef i386     /* in case the preprocessor is a 32bit one */
  11
  12 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
  13 OUTPUT_ARCH(i386:x86-64)
  14 ENTRY(phys_startup_64)
  15 jiffies_64 = jiffies;
  16 _proxy_pda = 0;
  17 PHDRS {
  18         text PT_LOAD FLAGS(5);  /* R_E */
  19         data PT_LOAD FLAGS(7);  /* RWE */
  20         user PT_LOAD FLAGS(7);  /* RWE */
  21         data.init PT_LOAD FLAGS(7);     /* RWE */
  22         note PT_NOTE FLAGS(4);  /* R__ */
  23 }
  24 SECTIONS
  25 {
  26   . = __START_KERNEL;
  27   phys_startup_64 = startup_64 - LOAD_OFFSET;
  28   _text = .;                    /* Text and read-only data */
  29   .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  30         /* First the code that has to be first for bootstrapping */
  31         *(.bootstrap.text)
  32         /* Then all the functions that are "hot" in profiles, to group them
  33            onto the same hugetlb entry */
  34         #include "functionlist"
  35         /* Then the rest */
  36         *(.text)
  37         SCHED_TEXT
  38         LOCK_TEXT
  39         KPROBES_TEXT
  40         *(.fixup)
  41         *(.gnu.warning)
  42         } :text = 0x9090
  43                                 /* out-of-line lock text */
  44   .text.lock : AT(ADDR(.text.lock) - LOAD_OFFSET) { *(.text.lock) }
  45
  46   _etext = .;                   /* End of text section */
  47
  48   . = ALIGN(16);                /* Exception table */
  49   __start___ex_table = .;
  50   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  51   __stop___ex_table = .;
  52
  53   RODATA
  54
  55   BUG_TABLE
  56
  57   . = ALIGN(PAGE_SIZE);        /* Align data segment to page size boundary */
  58                                 /* Data */
  59   .data : AT(ADDR(.data) - LOAD_OFFSET) {
  60         *(.data)
  61         CONSTRUCTORS
  62         } :data
  63
  64   _edata = .;                   /* End of data section */
  65
  66   . = ALIGN(PAGE_SIZE);
  67   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  68   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  69         *(.data.cacheline_aligned)
  70   }
  71   . = ALIGN(CONFIG_X86_INTERNODE_CACHE_BYTES);
  72   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
  73         *(.data.read_mostly)
  74   }
  75
  76 #define VSYSCALL_ADDR (-10*1024*1024)
  77 #define VSYSCALL_PHYS_ADDR ((LOADADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  78 #define VSYSCALL_VIRT_ADDR ((ADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  79
  80 #define VLOAD_OFFSET (VSYSCALL_ADDR - VSYSCALL_PHYS_ADDR)
  81 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
  82
  83 #define VVIRT_OFFSET (VSYSCALL_ADDR - VSYSCALL_VIRT_ADDR)
  84 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
  85
  86   . = VSYSCALL_ADDR;
  87   .vsyscall_0 :  AT(VSYSCALL_PHYS_ADDR) { *(.vsyscall_0) } :user
  88   __vsyscall_0 = VSYSCALL_VIRT_ADDR;
  89
  90   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  91   .vsyscall_fn : AT(VLOAD(.vsyscall_fn)) { *(.vsyscall_fn) }
  92   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  93   .vsyscall_gtod_data : AT(VLOAD(.vsyscall_gtod_data))
  94                 { *(.vsyscall_gtod_data) }
  95   vsyscall_gtod_data = VVIRT(.vsyscall_gtod_data);
  96
  97   .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) { *(.vgetcpu_mode) }
  98   vgetcpu_mode = VVIRT(.vgetcpu_mode);
  99
 100   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 101   .jiffies : AT(VLOAD(.jiffies)) { *(.jiffies) }
 102   jiffies = VVIRT(.jiffies);
 103
 104   .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1))
 105                 { *(.vsyscall_1) }
 106   .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2))
 107                 { *(.vsyscall_2) }
 108   .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3))
 109                 { *(.vsyscall_3) }
 110
 111   . = VSYSCALL_VIRT_ADDR + 4096;
 112
 113 #undef VSYSCALL_ADDR
 114 #undef VSYSCALL_PHYS_ADDR
 115 #undef VSYSCALL_VIRT_ADDR
 116 #undef VLOAD_OFFSET
 117 #undef VLOAD
 118 #undef VVIRT_OFFSET
 119 #undef VVIRT
 120
 121   . = ALIGN(8192);              /* init_task */
 122   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 123         *(.data.init_task)
 124   }:data.init
 125
 126   . = ALIGN(4096);
 127   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
 128         *(.data.page_aligned)
 129   }
 130
 131   /* might get freed after init */
 132   . = ALIGN(4096);
 133   __smp_alt_begin = .;
 134   __smp_alt_instructions = .;
 135   .smp_altinstructions : AT(ADDR(.smp_altinstructions) - LOAD_OFFSET) {
 136         *(.smp_altinstructions)
 137   }
 138   __smp_alt_instructions_end = .;
 139   . = ALIGN(8);
 140   __smp_locks = .;
 141   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 142         *(.smp_locks)
 143   }
 144   __smp_locks_end = .;
 145   .smp_altinstr_replacement : AT(ADDR(.smp_altinstr_replacement) - LOAD_OFFSET) {
 146         *(.smp_altinstr_replacement)
 147   }
 148   . = ALIGN(4096);
 149   __smp_alt_end = .;
 150
 151   . = ALIGN(4096);              /* Init code and data */
 152   __init_begin = .;
 153   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 154         _sinittext = .;
 155         *(.init.text)
 156         _einittext = .;
 157   }
 158   __initdata_begin = .;
 159   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
 160   __initdata_end = .;
 161   . = ALIGN(16);
 162   __setup_start = .;
 163   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 164   __setup_end = .;
 165   __initcall_start = .;
 166   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 167         INITCALLS
 168   }
 169   __initcall_end = .;
 170   __con_initcall_start = .;
 171   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 172         *(.con_initcall.init)
 173   }
 174   __con_initcall_end = .;
 175   SECURITY_INIT
 176   . = ALIGN(8);
 177   __alt_instructions = .;
 178   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 179         *(.altinstructions)
 180   }
 181   __alt_instructions_end = .;
 182   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 183         *(.altinstr_replacement)
 184   }
 185   /* .exit.text is discard at runtime, not link time, to deal with references
 186      from .altinstructions and .eh_frame */
 187   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 188   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 189
 190 #ifdef CONFIG_BLK_DEV_INITRD
 191   . = ALIGN(4096);
 192   __initramfs_start = .;
 193   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 194   __initramfs_end = .;
 195 #endif
 196
 197     . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 198   __per_cpu_start = .;
 199   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
 200   __per_cpu_end = .;
 201   . = ALIGN(4096);
 202   __init_end = .;
 203
 204   . = ALIGN(4096);
 205   __nosave_begin = .;
 206   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
 207   . = ALIGN(4096);
 208   __nosave_end = .;
 209
 210   __bss_start = .;              /* BSS */
 211   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 212         *(.bss.page_aligned)
 213         *(.bss)
 214         }
 215   __bss_stop = .;
 216
 217   _end = . ;
 218
 219   /* Sections to be discarded */
 220   /DISCARD/ : {
 221         *(.exitcall.exit)
 222         *(.eh_frame)
 223         }
 224
 225   STABS_DEBUG
 226
 227   DWARF_DEBUG
 228 }