bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([libbfd.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 AM_INIT_AUTOMAKE(bfd, 2.16.90)
  12
  13 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  14 dnl to call AC_CHECK_PROG.
  15 AC_CHECK_TOOL(AR, ar)
  16 AC_CHECK_TOOL(RANLIB, ranlib, :)
  17
  18 dnl Default to a non shared library.  This may be overridden by the
  19 dnl configure option --enable-shared.
  20 AM_DISABLE_SHARED
  21
  22 AM_PROG_LIBTOOL
  23
  24 AC_ARG_ENABLE(64-bit-bfd,
  25 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  26 [case "${enableval}" in
  27   yes)  want64=true  ;;
  28   no)   want64=false ;;
  29   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  30 esac],[want64=false])dnl
  31 AC_ARG_ENABLE(targets,
  32 [  --enable-targets        alternative target configurations],
  33 [case "${enableval}" in
  34   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  35             ;;
  36   no)       enable_targets= ;;
  37   *)        enable_targets=$enableval ;;
  38 esac])dnl
  39 AC_ARG_ENABLE(commonbfdlib,
  40 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  41 [case "${enableval}" in
  42   yes) commonbfdlib=true ;;
  43   no)  commonbfdlib=false ;;
  44   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  45 esac])dnl
  46 AC_ARG_WITH(mmap,
  47 [  --with-mmap             try using mmap for BFD input files if available],
  48 [case "${withval}" in
  49   yes)  want_mmap=true ;;
  50   no)   want_mmap=false ;;
  51   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  52 esac],[want_mmap=false])dnl
  53
  54 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  55
  56 AC_ARG_ENABLE(werror,
  57   [  --enable-werror    treat compile warnings as errors],
  58   [case "${enableval}" in
  59      yes | y) ERROR_ON_WARNING="yes" ;;
  60      no | n)  ERROR_ON_WARNING="no" ;;
  61      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
  62    esac])
  63
  64 # Enable -Werror by default, suppressing it only for --disable-werror
  65 # or --disable-build-warnings.
  66 if test "${ERROR_ON_WARNING}" != no
  67 then
  68   build_warnings="$build_warnings -Werror"
  69 fi
  70
  71 AC_ARG_ENABLE(build-warnings,
  72 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  73 [case "${enableval}" in
  74   yes)  ;;
  75   no)   build_warnings="-w";;
  76   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  77         build_warnings="${build_warnings} ${t}";;
  78   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  79         build_warnings="${t} ${build_warnings}";;
  80   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  81 esac
  82 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  83   echo "Setting warning flags = $build_warnings" 6>&1
  84 fi])dnl
  85 WARN_CFLAGS=""
  86 if test "x${build_warnings}" != x && test "x$GCC" = xyes ; then
  87     WARN_CFLAGS="${build_warnings}"
  88 fi
  89 AC_SUBST(WARN_CFLAGS)
  90
  91 AM_CONFIG_HEADER(config.h:config.in)
  92
  93 if test -z "$target" ; then
  94     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  95 fi
  96
  97 AM_MAINTAINER_MODE
  98 AM_INSTALL_LIBBFD
  99 AC_EXEEXT
 100
 101 host64=false
 102 target64=false
 103 bfd_default_target_size=32
 104
 105 # host stuff:
 106
 107 AC_PROG_CC
 108
 109 ALL_LINGUAS="fr tr ja es sv da zh_CN ro rw"
 110 CY_GNU_GETTEXT
 111
 112 # Permit host specific settings.
 113 . ${srcdir}/configure.host
 114
 115 AC_SUBST(HDEFINES)
 116 AC_PROG_INSTALL
 117
 118 BFD_HOST_64BIT_LONG=0
 119 BFD_HOST_LONG_LONG=0
 120 BFD_HOST_64_BIT_DEFINED=0
 121 BFD_HOST_64_BIT=
 122 BFD_HOST_U_64_BIT=
 123
 124 AC_MSG_CHECKING([for long long])
 125 AC_CACHE_VAL(bfd_cv_has_long_long,
 126 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[unsigned long long ll = 18446744073709551615ULL;]])],[bfd_cv_has_long_long=yes],[bfd_cv_has_long_long=no])])
 127 AC_MSG_RESULT($bfd_cv_has_long_long)
 128 if test $bfd_cv_has_long_long = yes; then
 129   BFD_HOST_LONG_LONG=1
 130   AC_COMPILE_CHECK_SIZEOF(long long)
 131 fi
 132
 133 AC_COMPILE_CHECK_SIZEOF(long)
 134 if test "x${ac_cv_sizeof_long}" = "x8"; then
 135   host64=true
 136   BFD_HOST_64BIT_LONG=1
 137   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long"
 138   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long"
 139 elif test "x${ac_cv_sizeof_long_long}" = "x8"; then
 140   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long long"
 141   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long long"
 142 fi
 143
 144 if test -n "${HOST_64BIT_TYPE}" -a -n "${HOST_U_64BIT_TYPE}"; then
 145   BFD_HOST_64_BIT_DEFINED=1
 146   BFD_HOST_64_BIT="${HOST_64BIT_TYPE}"
 147   BFD_HOST_U_64_BIT="${HOST_U_64BIT_TYPE}"
 148 fi
 149
 150 AC_SUBST(BFD_HOST_64BIT_LONG)
 151 AC_SUBST(BFD_HOST_LONG_LONG)
 152 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 153 AC_SUBST(BFD_HOST_64_BIT)
 154 AC_SUBST(BFD_HOST_U_64_BIT)
 155
 156 BFD_CC_FOR_BUILD
 157
 158 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 159 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 160 AC_HEADER_TIME
 161 AC_HEADER_DIRENT
 162 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
 163 AC_CHECK_FUNCS(strtoull)
 164
 165 AC_CHECK_DECLS(basename, , , [#include "sysdep.h"])
 166
 167 BFD_BINARY_FOPEN
 168
 169 BFD_NEED_DECLARATION(ffs)
 170 BFD_NEED_DECLARATION(free)
 171 BFD_NEED_DECLARATION(getenv)
 172 BFD_NEED_DECLARATION(malloc)
 173 BFD_NEED_DECLARATION(realloc)
 174 BFD_NEED_DECLARATION(strstr)
 175
 176 # If we are configured native, pick a core file support file.
 177 COREFILE=
 178 COREFLAG=
 179 TRAD_HEADER=
 180 if test "${target}" = "${host}"; then
 181   case "${host}" in
 182   alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu)
 183         COREFILE=''
 184         ;;
 185   alpha*-*-linux-*)
 186         COREFILE=trad-core.lo
 187         TRAD_HEADER='"hosts/alphalinux.h"'
 188         ;;
 189   alpha*-*-netbsd* | alpha*-*-openbsd*)
 190         COREFILE=netbsd-core.lo
 191         ;;
 192   alpha*-*-*)           COREFILE=osf-core.lo ;;
 193   arm-*-freebsd* | arm-*-kfreebsd*-gnu)
 194                         COREFILE='' ;;
 195   arm-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 196   arm-*-riscix)         COREFILE=trad-core.lo ;;
 197   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 198   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 199   hppa*-*-mpeix*)       COREFILE=hpux-core.lo ;;
 200   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 201                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 202   hppa*-*-netbsd* | hppa*-*-openbsd*)
 203         COREFILE=netbsd-core.lo
 204         ;;
 205
 206   i370-*-*)
 207         COREFILE=trad-core.lo
 208         TRAD_HEADER='"hosts/i370linux.h"'
 209         ;;
 210
 211 changequote(,)dnl
 212   i[3-7]86-sequent-bsd*)
 213 changequote([,])dnl
 214         COREFILE=trad-core.lo
 215         TRAD_HEADER='"hosts/symmetry.h"'
 216         ;;
 217 changequote(,)dnl
 218   i[3-7]86-sequent-sysv4*) ;;
 219   i[3-7]86-sequent-sysv*)
 220 changequote([,])dnl
 221         COREFILE=trad-core.lo
 222         TRAD_HEADER='"hosts/symmetry.h"'
 223         ;;
 224 changequote(,)dnl
 225   i[3-7]86-*-bsdi)
 226 changequote([,])dnl
 227         COREFILE=
 228         ;;
 229 changequote(,)dnl
 230   i[3-7]86-*-bsd* | i[3-7]86-*-freebsd[123] | i[3-7]86-*-freebsd[123]\.* | i[3-7]86-*-freebsd4\.[01234] | i[3-7]86-*-freebsd4\.[01234]\.* | i[3-7]86-*-freebsd*aout*)
 231 changequote([,])dnl
 232         COREFILE=trad-core.lo
 233         TRAD_HEADER='"hosts/i386bsd.h"'
 234         ;;
 235 changequote(,)dnl
 236   i[3-7]86-*-freebsd* | i[3-7]86-*-kfreebsd*-gnu)
 237 changequote([,])dnl
 238         COREFILE=''
 239         TRAD_HEADER='"hosts/i386bsd.h"'
 240         ;;
 241 changequote(,)dnl
 242   i[3-7]86-*-netbsd* | i[3-7]86-*-knetbsd*-gnu | i[3-7]86-*-openbsd*)
 243 changequote([,])dnl
 244         COREFILE=netbsd-core.lo
 245         ;;
 246 changequote(,)dnl
 247   i[3-7]86-esix-sysv3*)
 248 changequote([,])dnl
 249         COREFILE=trad-core.lo
 250         TRAD_HEADER='"hosts/esix.h"'
 251         ;;
 252 changequote(,)dnl
 253   i[3-7]86-*-sco3.2v5*)
 254 changequote([,])dnl
 255         COREFILE=sco5-core.lo
 256         ;;
 257 changequote(,)dnl
 258   i[3-7]86-*-sco* | i[3-7]86-*-isc*)
 259 changequote([,])dnl
 260         COREFILE=trad-core.lo
 261         TRAD_HEADER='"hosts/i386sco.h"'
 262         ;;
 263 changequote(,)dnl
 264   i[3-7]86-*-mach3*)
 265 changequote([,])dnl
 266         COREFILE=trad-core.lo
 267         TRAD_HEADER='"hosts/i386mach3.h"'
 268         ;;
 269 changequote(,)dnl
 270   i[3-7]86-*-linux-*)
 271 changequote([,])dnl
 272         COREFILE=trad-core.lo
 273         TRAD_HEADER='"hosts/i386linux.h"'
 274         ;;
 275 changequote(,)dnl
 276   i[3-7]86-*-isc*)      COREFILE=trad-core.lo ;;
 277   i[3-7]86-*-aix*)      COREFILE=aix386-core.lo ;;
 278 changequote([,])dnl
 279   i860-*-mach3* | i860-*-osf1*)
 280         COREFILE=trad-core.lo
 281         TRAD_HEADER='"hosts/i860mach3.h"'
 282         ;;
 283   mips-*-netbsd* | mips*-*-openbsd*)
 284         COREFILE=netbsd-core.lo
 285         ;;
 286   mips-dec-*)
 287         COREFILE=trad-core.lo
 288         TRAD_HEADER='"hosts/decstation.h"'
 289         ;;
 290   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 291   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 292   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 293   mips-*-sysv4*)        ;;
 294   mips-*-sysv* | mips-*-riscos*)
 295         COREFILE=trad-core.lo
 296         TRAD_HEADER='"hosts/riscos.h"'
 297         ;;
 298   mips-sony-bsd*)
 299         COREFILE=trad-core.lo
 300         TRAD_HEADER='"hosts/news-mips.h"'
 301         ;;
 302   m68*-bull*-sysv*)
 303         COREFILE=trad-core.lo
 304         TRAD_HEADER='"hosts/dpx2.h"'
 305         ;;
 306   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 307   m68*-hp-bsd*)
 308         COREFILE=trad-core.lo
 309         TRAD_HEADER='"hosts/hp300bsd.h"'
 310         ;;
 311   m68*-*-linux-*)
 312         COREFILE=trad-core.lo
 313         TRAD_HEADER='"hosts/m68klinux.h"'
 314         ;;
 315   m68*-motorola-sysv*)
 316         COREFILE=trad-core.lo
 317         TRAD_HEADER='"hosts/delta68.h"'
 318         ;;
 319   m68*-sony-*)
 320         COREFILE=trad-core.lo
 321         TRAD_HEADER='"hosts/news.h"'
 322         ;;
 323   m68*-*-netbsd* | m68*-*-openbsd*)
 324         COREFILE=netbsd-core.lo
 325         ;;
 326   m68*-apple-aux*)
 327         COREFILE=trad-core.lo
 328         TRAD_HEADER='"hosts/m68kaux.h"'
 329         ;;
 330   m88*-*-sysv4*)
 331         ;;
 332   m88*-motorola-sysv*)
 333         COREFILE=ptrace-core.lo
 334         ;;
 335   m88*-*-mach3*)
 336         COREFILE=trad-core.lo
 337         TRAD_HEADER='"hosts/m88kmach3.h"'
 338         ;;
 339   m88*-*-openbsd*)
 340         COREFILE=netbsd-core.lo
 341         ;;
 342   ns32k-pc532-mach)
 343         COREFILE=trad-core.lo
 344         TRAD_HEADER='"hosts/pc532mach.h"'
 345         ;;
 346   ns32k-*-netbsd* | ns32k-*-openbsd*)
 347         COREFILE=netbsd-core.lo
 348         ;;
 349   rs6000-*-lynx*)
 350         COREFILE=lynx-core.lo
 351         ;;
 352   rs6000-*-aix5.* | powerpc-*-aix5.*)
 353         COREFILE=rs6000-core.lo
 354         COREFLAG="$COREFLAG -DAIX_5_CORE -DAIX_CORE_DUMPX_CORE"
 355         ;;
 356 changequote(,)dnl
 357   rs6000-*-aix4.[3-9]* | powerpc-*-aix4.[3-9]*)
 358 changequote([,])dnl
 359         COREFILE=rs6000-core.lo
 360         COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
 361         # Not all versions of AIX with -DAIX_CORE_DUMPX_CORE
 362         # have c_impl as a member of struct core_dumpx
 363         AC_MSG_CHECKING([for c_impl in struct core_dumpx])
 364         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <core.h>]], [[struct core_dumpx c; c.c_impl = 0;]])],[AC_DEFINE(HAVE_ST_C_IMPL, 1,
 365             [Define if struct core_dumpx has member c_impl])
 366           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 367         ;;
 368   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 369   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 370   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 371   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 372   powerpc-*-beos*)      ;;
 373   powerpc-*-freebsd* | powerpc-*-kfreebsd*-gnu)
 374                         COREFILE='' ;;
 375   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 376   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 377   s390*-*-*)            COREFILE=trad-core.lo ;;
 378   sh*-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 379   sparc-*-netbsd* | sparc*-*-openbsd*)
 380         COREFILE=netbsd-core.lo
 381         ;;
 382   tahoe-*-*)
 383         COREFILE=trad-core.lo
 384         TRAD_HEADER='"hosts/tahoe.h"'
 385         ;;
 386   vax-*-netbsd* | vax-*-openbsd*)
 387         COREFILE=netbsd-core.lo
 388         ;;
 389   vax-*-ultrix2*)
 390         COREFILE=trad-core.lo
 391         TRAD_HEADER='"hosts/vaxult2.h"'
 392         ;;
 393   vax-*-ultrix*)
 394         COREFILE=trad-core.lo
 395         TRAD_HEADER='"hosts/vaxult2.h"'
 396         ;;
 397   vax-*-linux-*)
 398         COREFILE=trad-core.lo
 399         TRAD_HEADER='"hosts/vaxlinux.h"'
 400         ;;
 401   vax-*-*)
 402         COREFILE=trad-core.lo
 403         TRAD_HEADER='"hosts/vaxbsd.h"'
 404         ;;
 405   x86_64-*-netbsd* | x86_64-*-openbsd*)
 406         COREFILE=netbsd-core.lo
 407         ;;
 408   esac
 409
 410   case "$COREFILE" in
 411   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 412   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 413   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 414   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 415   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 416   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 417   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 418   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 419   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 420   sco5-core.lo)         COREFLAG="$COREFLAG -DSCO5_CORE" ;;
 421   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 422   esac
 423
 424   # ELF corefile support has several flavors, but all of
 425   # them use something called <sys/procfs.h>
 426   AC_CHECK_HEADERS(sys/procfs.h)
 427   if test "$ac_cv_header_sys_procfs_h" = yes; then
 428     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 429     BFD_HAVE_SYS_PROCFS_TYPE(prstatus32_t)
 430     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 431     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus32_t, pr_who)
 432     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 433     BFD_HAVE_SYS_PROCFS_TYPE(pxstatus_t)
 434     BFD_HAVE_SYS_PROCFS_TYPE(pstatus32_t)
 435     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 436     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo32_t)
 437     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 438     BFD_HAVE_SYS_PROCFS_TYPE(psinfo32_t)
 439     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 440     BFD_HAVE_SYS_PROCFS_TYPE(lwpxstatus_t)
 441     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 442     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 443     BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
 444   fi
 445 fi
 446 AC_SUBST(COREFILE)
 447 AC_SUBST(COREFLAG)
 448 if test -n "$TRAD_HEADER"; then
 449   AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
 450     [Name of host specific header file to include in trad-core.c.])
 451 fi
 452
 453 # Horrible hacks to build DLLs on Windows.
 454 WIN32LDFLAGS=
 455 WIN32LIBADD=
 456 case "${host}" in
 457 *-*-cygwin*)
 458   if test "$enable_shared" = "yes"; then
 459     WIN32LDFLAGS="-no-undefined"
 460     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 461   fi
 462   ;;
 463 *-*-linux*)
 464   # We borrow WIN32LIBADD so that the shared libbfd won't depend on
 465   # libiberty.a.
 466   case "${host}" in
 467   mips*-*-linux*)
 468     # Linux/MIPS uses PIC by default.
 469     if test "$enable_shared" = "yes"; then
 470       WIN32LIBADD="-L../libiberty -liberty"
 471     fi
 472     ;;
 473   *)
 474 changequote(,)dnl
 475     x=`sed -n -e 's/^[  ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 476 changequote([,])dnl
 477     if test -n "$x"; then
 478       WIN32LIBADD="-L../libiberty/pic -liberty"
 479     fi
 480   ;;
 481   esac
 482   ;;
 483 esac
 484 AC_SUBST(WIN32LDFLAGS)
 485 AC_SUBST(WIN32LIBADD)
 486
 487 # target stuff:
 488
 489 # Canonicalize the secondary target names.
 490 if test -n "$enable_targets" ; then
 491     for targ in `echo $enable_targets | sed 's/,/ /g'`
 492     do
 493         result=`$ac_config_sub $targ 2>/dev/null`
 494         if test -n "$result" ; then
 495             canon_targets="$canon_targets $result"
 496         else
 497             # Allow targets that config.sub doesn't recognize, like "all".
 498             canon_targets="$canon_targets $targ"
 499         fi
 500     done
 501 fi
 502
 503 all_targets=false
 504 defvec=
 505 selvecs=
 506 assocvecs=
 507 selarchs=
 508 TDEFINES=
 509 for targ in $target $canon_targets
 510 do
 511     if test "x$targ" = "xall"; then
 512         all_targets=true
 513         assocvecs="$assocvecs $targ_defvec $targ_selvecs"
 514     else
 515         . $srcdir/config.bfd
 516         if test "x$targ" = "x$target"; then
 517             defvec=$targ_defvec
 518         fi
 519         selvecs="$selvecs $targ_defvec $targ_selvecs"
 520         selarchs="$selarchs $targ_archs"
 521         TDEFINES="$TDEFINES $targ_cflags"
 522     fi
 523 done
 524 AC_SUBST(TDEFINES)
 525
 526 # This processing still needs to be done if we're to decide properly whether
 527 # 64-bit support needs to be compiled in.  Currently, it will be included if
 528 # the default or any other explicitly requested target requires it; it
 529 # will not be included on a 32-bit host if no 64-bit target is requested, and
 530 # no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
 531 # used.
 532
 533 # uniq the default and selected vectors in all the configured targets.
 534 f=""
 535 for i in $selvecs ; do
 536     case " $f " in
 537     *" $i "*) ;;
 538     *) f="$f $i" ;;
 539     esac
 540 done
 541 selvecs="$f"
 542
 543
 544 # uniq the associated vectors in all the configured targets.
 545 f=""
 546 for i in $assocvecs ; do
 547     case " $f " in
 548     *" $i "*) ;;
 549     *) f="$f $i" ;;
 550     esac
 551 done
 552 assocvecs="$f"
 553
 554
 555 # uniq the architectures in all the configured targets.
 556 f=""
 557 for i in $selarchs ; do
 558     case " $f " in
 559     *" $i "*) ;;
 560     *) f="$f $i" ;;
 561     esac
 562 done
 563 selarchs="$f"
 564
 565 # Target backend .o files.
 566 tb=
 567
 568 elf="elf.lo elflink.lo elf-strtab.lo elf-eh-frame.lo dwarf1.lo"
 569
 570 for vec in $selvecs
 571 do
 572     target_size=32
 573     case "$vec" in
 574     # This list is alphabetized to make it easy to compare
 575     # with the two vector lists in targets.c.  For the same reason,
 576     # use one entry per line, even though this leads to long lines.
 577     a29kcoff_big_vec)           tb="$tb coff-a29k.lo cofflink.lo" ;;
 578     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 579     aix5coff64_vec)             tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 580     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 581     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 582     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 583     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 584     arm_epoc_pe_big_vec)        tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 585     arm_epoc_pe_little_vec)     tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 586     arm_epoc_pei_big_vec)       tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 587     arm_epoc_pei_little_vec)    tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 588     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 589     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 590     armnetbsd_vec)              tb="$tb armnetbsd.lo aout32.lo" ;;
 591     armpe_big_vec)              tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 592     armpe_little_vec)           tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 593     armpei_big_vec)             tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 594     armpei_little_vec)          tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 595     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 596     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 597     bfd_efi_app_ia32_vec)       tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
 598     bfd_efi_app_ia64_vec)       tb="$tb efi-app-ia64.lo pepigen.lo cofflink.lo"; target_size=64 ;;
 599     bfd_elf32_am33lin_vec)      tb="$tb elf32-am33lin.lo elf32.lo $elf" ;;
 600     bfd_elf32_avr_vec)          tb="$tb elf32-avr.lo elf32.lo $elf" ;;
 601     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 602     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 603     bfd_elf32_bigarm_vec)       tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 604     bfd_elf32_bigarm_symbian_vec)
 605                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 606     bfd_elf32_bigarm_vxworks_vec)
 607                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 608     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 609     bfd_elf32_cr16c_vec)        tb="$tb elf32-cr16c.lo elf32.lo $elf" ;;
 610     bfd_elf32_cris_vec)         tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 611     bfd_elf32_crx_vec)          tb="$tb elf32-crx.lo elf32.lo $elf" ;;
 612     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 613     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 614     bfd_elf32_dlx_big_vec)      tb="$tb elf32-dlx.lo elf32.lo $elf" ;;
 615     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 616     bfd_elf32_frv_vec)          tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 617     bfd_elf32_frvfdpic_vec)     tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 618     bfd_elf32_h8300_vec)        tb="$tb elf32-h8300.lo elf32.lo $elf" ;;
 619     bfd_elf32_hppa_linux_vec)   tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 620     bfd_elf32_hppa_nbsd_vec)    tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 621     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 622     bfd_elf32_i370_vec)         tb="$tb elf32-i370.lo elf32.lo $elf" ;;
 623     bfd_elf32_i386_freebsd_vec) tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 624     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 625     bfd_elf32_i860_little_vec)  tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 626     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 627     bfd_elf32_i960_vec)         tb="$tb elf32-i960.lo elf32.lo $elf" ;;
 628     bfd_elf32_ia64_big_vec)     tb="$tb elf32-ia64.lo elf32.lo $elf" ;;
 629     bfd_elf32_ia64_hpux_big_vec) tb="$tb elf32-ia64.lo elf32.lo $elf";;
 630     bfd_elf32_ip2k_vec)         tb="$tb elf32-ip2k.lo elf32.lo $elf" ;;
 631     bfd_elf32_iq2000_vec)       tb="$tb elf32-iq2000.lo elf32.lo $elf" ;;
 632     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 633     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 634     bfd_elf32_littlearm_symbian_vec)
 635                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 636     bfd_elf32_littlearm_vxworks_vec)
 637                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 638     bfd_elf32_littlearm_vec)    tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 639     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 640     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 641     bfd_elf32_m32rle_vec)       tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 642     bfd_elf32_m32rlin_vec)      tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 643     bfd_elf32_m32rlelin_vec)    tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 644     bfd_elf32_m68hc11_vec)      tb="$tb elf32-m68hc11.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 645     bfd_elf32_m68hc12_vec)      tb="$tb elf32-m68hc12.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 646     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 647     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 648     bfd_elf32_mcore_big_vec)    tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 649     bfd_elf32_mcore_little_vec) tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 650     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 651     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 652     bfd_elf32_msp430_vec)       tb="$tb elf32-msp430.lo elf32.lo $elf" ;;
 653     bfd_elf32_nbigmips_vec)     tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 654     bfd_elf32_nlittlemips_vec)  tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 655     bfd_elf32_ntradbigmips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 656     bfd_elf32_ntradlittlemips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 657     bfd_elf32_openrisc_vec)     tb="$tb elf32-openrisc.lo elf32.lo $elf" ;;
 658     bfd_elf32_or32_big_vec)     tb="$tb elf32-or32.lo elf32.lo $elf" ;;
 659     bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
 660     bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
 661     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 662     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 663     bfd_elf32_s390_vec)         tb="$tb elf32-s390.lo elf32.lo $elf" ;;
 664     # FIXME: We include cofflink.lo not because it's needed for
 665     # bfd_elf32_sh64[l]_vec, but because we include bfd_elf32_sh[l]_vec
 666     # which needs it but does not list it.  Should be fixed in right place.
 667     bfd_elf32_sh64_vec)         tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 668     bfd_elf32_sh64l_vec)        tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 669     bfd_elf32_sh64lin_vec)      tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 670     bfd_elf32_sh64blin_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 671     bfd_elf32_sh64lnbsd_vec)    tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 672     bfd_elf32_sh64nbsd_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 673     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 674     bfd_elf32_shblin_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 675     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 676     bfd_elf32_shl_symbian_vec)  tb="$tb elf32-sh-symbian.lo elf32-sh64-com.lo elf32.lo $elf coff-sh.lo" ;;
 677     bfd_elf32_shlin_vec)        tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 678     bfd_elf32_shlnbsd_vec)      tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 679     bfd_elf32_shnbsd_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 680     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elf32.lo $elf" ;;
 681     bfd_elf32_tradbigmips_vec)  tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 682     bfd_elf32_tradlittlemips_vec) tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 683     bfd_elf32_us_cris_vec)      tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 684     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 685     bfd_elf32_vax_vec)          tb="$tb elf32-vax.lo elf32.lo $elf" ;;
 686     bfd_elf32_xstormy16_vec)    tb="$tb elf32-xstormy16.lo elf32.lo $elf" ;;
 687     bfd_elf32_xtensa_le_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 688     bfd_elf32_xtensa_be_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 689     bfd_elf64_alpha_freebsd_vec) tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 690     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 691     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 692     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 693     bfd_elf64_hppa_linux_vec)   tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 694     bfd_elf64_hppa_vec)         tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 695     bfd_elf64_ia64_big_vec)     tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 696     bfd_elf64_ia64_hpux_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 697     bfd_elf64_ia64_little_vec)  tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 698     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 699     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 700     bfd_elf64_mmix_vec)         tb="$tb elf64-mmix.lo elf64.lo $elf" target_size=64 ;;
 701     bfd_elf64_powerpc_vec)      tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 702     bfd_elf64_powerpcle_vec)    tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf" target_size=64 ;;
 703     bfd_elf64_s390_vec)         tb="$tb elf64-s390.lo elf64.lo $elf"; target_size=64 ;;
 704     bfd_elf64_sh64_vec)         tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 705     bfd_elf64_sh64l_vec)        tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 706     bfd_elf64_sh64lin_vec)      tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 707     bfd_elf64_sh64blin_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 708     bfd_elf64_sh64lnbsd_vec)    tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 709     bfd_elf64_sh64nbsd_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 710     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elf64.lo $elf"; target_size=64 ;;
 711     bfd_elf64_tradbigmips_vec)  tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 712     bfd_elf64_tradlittlemips_vec) tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 713     bfd_elf64_x86_64_vec)       tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
 714     bfd_mmo_vec)                tb="$tb mmo.lo" target_size=64 ;;
 715     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 716     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 717     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 718     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 719     cris_aout_vec)              tb="$tb aout-cris.lo" ;;
 720     demo_64_vec)                tb="$tb demo64.lo aout64.lo"; target_size=64 ;;
 721     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 722     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 723     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 724     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"; target_size=64 ;;
 725     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 726     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 727     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 728     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 729     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 730     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 731     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 732     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 733     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 734     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 735     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 736     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 737     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 738     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 739     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 740     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 741     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 742     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 743     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 744     i386pe_vec)                 tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
 745     i386pei_vec)                tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
 746     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 747     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 748     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 749     ieee_vec)                   tb="$tb ieee.lo" ;;
 750     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 751     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 752     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 753     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 754     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 755     m68klynx_aout_vec)          tb="$tb m68klynx.lo lynx-core.lo aout32.lo" ;;
 756     m68klynx_coff_vec)          tb="$tb cf-m68klynx.lo coff-m68k.lo cofflink.lo lynx-core.lo" ;;
 757     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 758     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 759     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 760     m88kmach3_vec)              tb="$tb m88kmach3.lo aout32.lo" ;;
 761     m88kopenbsd_vec)            tb="$tb m88kopenbsd.lo aout32.lo" ;;
 762     maxqcoff_vec)               tb="$tb coff-maxq.lo" ;;
 763     mach_o_be_vec)              tb="$tb mach-o.lo" ;;
 764     mach_o_le_vec)              tb="$tb mach-o.lo" ;;
 765     mach_o_fat_vec)             tb="$tb mach-o.lo" ;;
 766     mcore_pe_big_vec)           tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 767     mcore_pe_little_vec)        tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 768     mcore_pei_big_vec)          tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 769     mcore_pei_little_vec)       tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 770     mipslpe_vec)                tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
 771     mipslpei_vec)               tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
 772     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 773     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"; target_size=64 ;;
 774     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 775     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 776     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 777     or32coff_big_vec)           tb="$tb coff-or32.lo cofflink.lo" ;;
 778     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 779     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 780     pef_vec)                    tb="$tb pef.lo" ;;
 781     pef_xlib_vec)               tb="$tb pef.lo" ;;
 782     pdp11_aout_vec)             tb="$tb pdp11.lo" ;;
 783     pmac_xcoff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 784     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 785     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 786     rs6000coff64_vec)           tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 787     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 788     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 789     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 790     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 791     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 792     shlpe_vec)                  tb="$tb pe-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 793     shlpei_vec)                 tb="$tb pei-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 794     som_vec)                    tb="$tb som.lo" ;;
 795     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 796     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 797     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 798     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 799     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 800     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 801     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 802     sym_vec)                    tb="$tb xsym.lo" ;;
 803     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 804     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 805     tic4x_coff0_vec)            tb="$tb coff-tic4x.lo" ;;
 806     tic4x_coff0_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 807     tic4x_coff1_vec)            tb="$tb coff-tic4x.lo" ;;
 808     tic4x_coff1_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 809     tic4x_coff2_vec)            tb="$tb coff-tic4x.lo" ;;
 810     tic4x_coff2_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 811     tic54x_coff0_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 812     tic54x_coff0_vec)           tb="$tb coff-tic54x.lo" ;;
 813     tic54x_coff1_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 814     tic54x_coff1_vec)           tb="$tb coff-tic54x.lo" ;;
 815     tic54x_coff2_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 816     tic54x_coff2_vec)           tb="$tb coff-tic54x.lo" ;;
 817     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 818     vaxnetbsd_vec)              tb="$tb vaxnetbsd.lo aout32.lo" ;;
 819     vax1knetbsd_vec)            tb="$tb vax1knetbsd.lo aout32.lo" ;;
 820     vaxbsd_vec)                 tb="$tb vaxbsd.lo aout32.lo" ;;
 821     versados_vec)               tb="$tb versados.lo" ;;
 822     vms_alpha_vec)              tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"; target_size=64 ;;
 823     vms_vax_vec)                tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
 824     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 825     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 826     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo" ;;
 827
 828     # These appear out of order in targets.c
 829     srec_vec)                   tb="$tb srec.lo" ;;
 830     symbolsrec_vec)             tb="$tb srec.lo" ;;
 831     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 832     cisco_core_big_vec)         tb="$tb cisco-core.lo" ;;
 833     cisco_core_little_vec)      tb="$tb cisco-core.lo" ;;
 834
 835     "")                 ;;
 836     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 837     esac
 838
 839     if test ${target_size} = 64; then
 840         target64=true
 841     fi
 842     if test x"${vec}" = x"${defvec}"; then
 843         bfd_default_target_size=${target_size}
 844     fi
 845 done
 846
 847 # Target architecture .o files.
 848 # A couple of CPUs use shorter file names to avoid problems on DOS
 849 # filesystems.
 850 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 851
 852 # Weed out duplicate .o files.
 853 f=""
 854 for i in $tb ; do
 855     case " $f " in
 856     *" $i "*) ;;
 857     *) f="$f $i" ;;
 858     esac
 859 done
 860 tb="$f"
 861
 862 f=""
 863 for i in $ta ; do
 864     case " $f " in
 865     *" $i "*) ;;
 866     *) f="$f $i" ;;
 867     esac
 868 done
 869 ta="$f"
 870
 871 bfd_backends="$tb"
 872 bfd_machines="$ta"
 873
 874 if test x${all_targets} = xtrue ; then
 875   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 876   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 877   selvecs=
 878   havevecs=
 879   selarchs=
 880   test -n "$assocvecs" &&
 881     assocvecs=`echo $assocvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 882 else    # all_targets is true
 883   # Only set these if they will be nonempty, for the clever echo.
 884   havevecs=
 885   assocvecs=
 886   test -n "$selvecs" &&
 887     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 888   test -n "$selvecs" &&
 889     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 890   test -n "$selarchs" &&
 891     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 892 fi      # all_targets is true
 893
 894 case ${host64}-${target64}-${want64} in
 895   *true*)
 896     wordsize=64
 897     bfd_libs='$(BFD64_LIBS) $(BFD32_LIBS)'
 898     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 899     if test $BFD_HOST_64_BIT_DEFINED = 0; then
 900       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 901       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 902     fi
 903     if test -n "$GCC" ; then
 904        bad_64bit_gcc=no;
 905        AC_MSG_CHECKING([for gcc version with buggy 64-bit support])
 906        # Add more tests for gcc versions with non-working 64-bit support here.
 907        AC_EGREP_CPP([: 2 : 91 : 1 :],[:__GNUC__:__GNUC_MINOR__:__i386__:],
 908                     bad_64bit_gcc=yes;
 909                     AC_MSG_RESULT([yes: egcs-1.1.2 on ix86 spotted]),
 910                     AC_MSG_RESULT(no))
 911        if test $bad_64bit_gcc = yes ; then
 912          AC_MSG_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
 913        fi
 914     fi
 915     ;;
 916   false-false-false)
 917     wordsize=32
 918     bfd_libs='$(BFD32_LIBS)'
 919     all_backends='$(BFD32_BACKENDS)'
 920     ;;
 921 esac
 922
 923 AC_SUBST(wordsize)
 924 AC_SUBST(bfd_libs)
 925 AC_SUBST(all_backends)
 926 AC_SUBST(bfd_backends)
 927 AC_SUBST(bfd_machines)
 928 AC_SUBST(bfd_default_target_size)
 929
 930 # Determine the host dependant file_ptr a.k.a. off_t type.  In order
 931 # prefer: off64_t - if ftello64 and fseeko64, off_t - if ftello and
 932 # fseeko, long.  This assumes that sizeof off_t is .ge. sizeof long.
 933 # Hopefully a reasonable assumption since fseeko et.al. should be
 934 # upward compatible.
 935 AC_CHECK_FUNCS(ftello ftello64 fseeko fseeko64)
 936 if test x"$ac_cv_func_ftello" = xyes -a x"$ac_cv_func_fseeko" = xyes; then
 937     AC_COMPILE_CHECK_SIZEOF(off_t)
 938 fi
 939 AC_MSG_CHECKING([file_ptr type])
 940 bfd_file_ptr="long"
 941 bfd_ufile_ptr="unsigned long"
 942 if test x"$ac_cv_func_ftello64" = xyes -a x"$ac_cv_func_fseeko64" = xyes \
 943         -o x"${ac_cv_sizeof_off_t}" = x8; then
 944     bfd_file_ptr=BFD_HOST_64_BIT
 945     bfd_ufile_ptr=BFD_HOST_U_64_BIT
 946 fi
 947 AC_MSG_RESULT($bfd_file_ptr)
 948 AC_SUBST(bfd_file_ptr)
 949 AC_SUBST(bfd_ufile_ptr)
 950
 951
 952 tdefaults=""
 953 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 954 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 955 test -n "${assocvecs}" && tdefaults="${tdefaults} -DASSOCIATED_VECS='${assocvecs}'"
 956 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 957 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 958 AC_SUBST(tdefaults)
 959
 960 dnl AC_CHECK_HEADERS(sys/mman.h)
 961 AC_FUNC_MMAP
 962 AC_CHECK_FUNCS(madvise mprotect)
 963 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 964   true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
 965 esac
 966
 967 rm -f doc/config.status
 968 AC_CONFIG_FILES([Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in])
 969 AC_CONFIG_COMMANDS([default],[[sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' -e '/BLD-POTFILES =/r po/BLD-POTFILES' po/Makefile.in > po/Makefile]],[[]])
 970 AC_OUTPUT
 971