bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.13)
   5 AC_INIT(libbfd.c)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_ISC_POSIX
   9
  10 AM_INIT_AUTOMAKE(bfd, 2.11.90)
  11
  12 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  13 dnl to call AC_CHECK_PROG.
  14 AC_CHECK_TOOL(AR, ar)
  15 AC_CHECK_TOOL(RANLIB, ranlib, :)
  16
  17 dnl Default to a non shared library.  This may be overridden by the
  18 dnl configure option --enable-shared.
  19 AM_DISABLE_SHARED
  20
  21 AM_PROG_LIBTOOL
  22
  23 AC_ARG_ENABLE(64-bit-bfd,
  24 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  25 [case "${enableval}" in
  26   yes)  want64=true  ;;
  27   no)   want64=false ;;
  28   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  29 esac],[want64=false])dnl
  30 AC_ARG_ENABLE(targets,
  31 [  --enable-targets        alternative target configurations],
  32 [case "${enableval}" in
  33   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  34             ;;
  35   no)       enable_targets= ;;
  36   *)        enable_targets=$enableval ;;
  37 esac])dnl
  38 AC_ARG_ENABLE(commonbfdlib,
  39 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  40 [case "${enableval}" in
  41   yes) commonbfdlib=true ;;
  42   no)  commonbfdlib=false ;;
  43   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  44 esac])dnl
  45 AC_ARG_WITH(mmap,
  46 [  --with-mmap             try using mmap for BFD input files if available],
  47 [case "${withval}" in
  48   yes)  want_mmap=true ;;
  49   no)   want_mmap=false ;;
  50   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  51 esac],[want_mmap=false])dnl
  52
  53 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  54 AC_ARG_ENABLE(build-warnings,
  55 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  56 [case "${enableval}" in
  57   yes)  ;;
  58   no)   build_warnings="-w";;
  59   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  60         build_warnings="${build_warnings} ${t}";;
  61   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  62         build_warnings="${t} ${build_warnings}";;
  63   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  64 esac
  65 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  66   echo "Setting warning flags = $build_warnings" 6>&1
  67 fi])dnl
  68 WARN_CFLAGS=""
  69 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  70     WARN_CFLAGS="${build_warnings}"
  71 fi
  72 AC_SUBST(WARN_CFLAGS)
  73
  74 AM_CONFIG_HEADER(config.h:config.in)
  75
  76 if test -z "$target" ; then
  77     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  78 fi
  79
  80 AM_MAINTAINER_MODE
  81 AC_EXEEXT
  82
  83 host64=false
  84 target64=false
  85 bfd_default_target_size=32
  86
  87 # host stuff:
  88
  89 AC_PROG_CC
  90
  91 ALL_LINGUAS=
  92 CY_GNU_GETTEXT
  93
  94 # Permit host specific settings.
  95 . ${srcdir}/configure.host
  96
  97 AC_SUBST(HDEFINES)
  98 AC_PROG_INSTALL
  99
 100 BFD_HOST_64BIT_LONG=0
 101 BFD_HOST_64_BIT_DEFINED=0
 102 BFD_HOST_64_BIT=
 103 BFD_HOST_U_64_BIT=
 104 if test "x${HOST_64BIT_TYPE}" = "xlong"; then
 105   BFD_HOST_64BIT_LONG=1
 106 elif test "x${HOST_64BIT_TYPE}" != "x"; then
 107   BFD_HOST_64_BIT_DEFINED=1
 108   BFD_HOST_64_BIT=${HOST_64BIT_TYPE}
 109   BFD_HOST_U_64_BIT=${HOST_U_64BIT_TYPE}
 110 fi
 111 AC_SUBST(BFD_HOST_64BIT_LONG)
 112 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 113 AC_SUBST(BFD_HOST_64_BIT)
 114 AC_SUBST(BFD_HOST_U_64_BIT)
 115
 116 BFD_CC_FOR_BUILD
 117
 118 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 119 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 120 AC_HEADER_TIME
 121 AC_HEADER_DIRENT
 122 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
 123
 124 BFD_BINARY_FOPEN
 125
 126 BFD_NEED_DECLARATION(strstr)
 127 BFD_NEED_DECLARATION(malloc)
 128 BFD_NEED_DECLARATION(realloc)
 129 BFD_NEED_DECLARATION(free)
 130 BFD_NEED_DECLARATION(getenv)
 131
 132 # If we are configured native, pick a core file support file.
 133 COREFILE=
 134 COREFLAG=
 135 TRAD_HEADER=
 136 if test "${target}" = "${host}"; then
 137   case "${host}" in
 138   alpha*-*-freebsd*)
 139         COREFILE=''
 140         ;;
 141   alpha*-*-linux-gnu*)
 142         COREFILE=trad-core.lo
 143         TRAD_HEADER='"hosts/alphalinux.h"'
 144         ;;
 145   alpha*-*-netbsd*)     COREFILE=netbsd-core.lo ;;
 146   alpha*-*-*)           COREFILE=osf-core.lo ;;
 147   arm-*-freebsd*)       COREFILE='' ;;
 148   arm-*-riscix)         COREFILE=trad-core.lo ;;
 149   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 150   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 151   hppa*-*-mpeix*)       COREFILE=hpux-core.lo ;;
 152   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 153                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 154   i370-*-*)
 155         COREFILE=trad-core.lo
 156         TRAD_HEADER='"hosts/i370linux.h"'
 157         ;;
 158
 159 changequote(,)dnl
 160   i[3456]86-sequent-bsd*)
 161 changequote([,])dnl
 162         COREFILE=trad-core.lo
 163         TRAD_HEADER='"hosts/symmetry.h"'
 164         ;;
 165 changequote(,)dnl
 166   i[3456]86-sequent-sysv4*) ;;
 167   i[3456]86-sequent-sysv*)
 168 changequote([,])dnl
 169         COREFILE=trad-core.lo
 170         TRAD_HEADER='"hosts/symmetry.h"'
 171         ;;
 172 changequote(,)dnl
 173   i[3456]86-*-bsdi)
 174 changequote([,])dnl
 175         COREFILE=
 176         ;;
 177 changequote(,)dnl
 178   i[3456]86-*-bsd* | i[34567]86-*-freebsd[1234] | i[34567]86-*-freebsd[1234]\.* | i[34567]86-*-freebsd*aout*)
 179 changequote([,])dnl
 180         COREFILE=trad-core.lo
 181         TRAD_HEADER='"hosts/i386bsd.h"'
 182         ;;
 183 changequote(,)dnl
 184   i[3456]86-*-freebsd*)
 185 changequote([,])dnl
 186         COREFILE=''
 187         TRAD_HEADER='"hosts/i386bsd.h"'
 188         ;;
 189 changequote(,)dnl
 190   i[3456]86-*-netbsd* | i[3456]86-*-openbsd*)
 191 changequote([,])dnl
 192         COREFILE=netbsd-core.lo
 193         ;;
 194 changequote(,)dnl
 195   i[3456]86-esix-sysv3*)
 196 changequote([,])dnl
 197         COREFILE=trad-core.lo
 198         TRAD_HEADER='"hosts/esix.h"'
 199         ;;
 200 changequote(,)dnl
 201   i[3456]86-*-sco3.2v5*)
 202 changequote([,])dnl
 203         COREFILE=sco5-core.lo
 204         ;;
 205 changequote(,)dnl
 206   i[3456]86-*-sco* | i[3456]86-*-isc*)
 207 changequote([,])dnl
 208         COREFILE=trad-core.lo
 209         TRAD_HEADER='"hosts/i386sco.h"'
 210         ;;
 211 changequote(,)dnl
 212   i[3456]86-*-mach3*)
 213 changequote([,])dnl
 214         COREFILE=trad-core.lo
 215         TRAD_HEADER='"hosts/i386mach3.h"'
 216         ;;
 217 changequote(,)dnl
 218   i[3456]86-*-linux-gnu*)
 219 changequote([,])dnl
 220         COREFILE=trad-core.lo
 221         TRAD_HEADER='"hosts/i386linux.h"'
 222         ;;
 223 changequote(,)dnl
 224   i[3456]86-*-isc*)     COREFILE=trad-core.lo ;;
 225   i[3456]86-*-aix*)     COREFILE=aix386-core.lo ;;
 226 changequote([,])dnl
 227   i860-*-mach3* | i860-*-osf1*)
 228         COREFILE=trad-core.lo
 229         TRAD_HEADER='"hosts/i860mach3.h"'
 230         ;;
 231   mips-dec-bsd*)
 232         COREFILE=trad-core.lo
 233         TRAD_HEADER='"hosts/mipsbsd.h"'
 234         ;;
 235   mips-dec-mach3*)
 236         COREFILE=trad-core.lo
 237         TRAD_HEADER='"hosts/mipsmach3.h"'
 238         ;;
 239   mips-*-netbsd* | mips*-*-openbsd*)
 240         COREFILE=netbsd-core.lo
 241         ;;
 242   mips-dec-*)
 243         COREFILE=trad-core.lo
 244         TRAD_HEADER='"hosts/decstation.h"'
 245         ;;
 246   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 247   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 248   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 249   mips-*-mach3*)
 250         COREFILE=trad-core.lo
 251         TRAD_HEADER='"hosts/mipsmach3.h"'
 252         ;;
 253   mips-*-sysv4*)        ;;
 254   mips-*-sysv* | mips-*-riscos*)
 255         COREFILE=trad-core.lo
 256         TRAD_HEADER='"hosts/riscos.h"'
 257         ;;
 258   mips-sony-bsd*)
 259         COREFILE=trad-core.lo
 260         TRAD_HEADER='"hosts/news-mips.h"'
 261         ;;
 262   m68*-bull*-sysv*)
 263         COREFILE=trad-core.lo
 264         TRAD_HEADER='"hosts/dpx2.h"'
 265         ;;
 266   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 267   m68*-hp-bsd*)
 268         COREFILE=trad-core.lo
 269         TRAD_HEADER='"hosts/hp300bsd.h"'
 270         ;;
 271   m68*-*-linux-gnu*)
 272         COREFILE=trad-core.lo
 273         TRAD_HEADER='"hosts/m68klinux.h"'
 274         ;;
 275   m68*-motorola-sysv*)
 276         COREFILE=trad-core.lo
 277         TRAD_HEADER='"hosts/delta68.h"'
 278         ;;
 279   m68*-sony-*)
 280         COREFILE=trad-core.lo
 281         TRAD_HEADER='"hosts/news.h"'
 282         ;;
 283   m68*-*-netbsd* | m68*-*-openbsd*)
 284         COREFILE=netbsd-core.lo
 285         ;;
 286   m68*-apple-aux*)
 287         COREFILE=trad-core.lo
 288         TRAD_HEADER='"hosts/m68kaux.h"'
 289         ;;
 290   m88*-*-sysv4*)        ;;
 291   m88*-motorola-sysv*)  COREFILE=ptrace-core.lo ;;
 292   m88*-*-mach3*)
 293         COREFILE=trad-core.lo
 294         TRAD_HEADER='"hosts/m88kmach3.h"'
 295         ;;
 296   ns32k-pc532-mach)
 297         COREFILE=trad-core.lo
 298         TRAD_HEADER='"hosts/pc532mach.h"'
 299         ;;
 300   ns32k-*-netbsd* | ns32k-*-openbsd*)
 301         COREFILE=netbsd-core.lo
 302         ;;
 303   rs6000-*-lynx*)       COREFILE=lynx-core.lo ;;
 304 changequote(,)dnl
 305   rs6000-*-aix4.[3-9]* | powerpc-*-aix4.[3-9]*)
 306 changequote([,])dnl
 307         COREFILE=rs6000-core.lo
 308         COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
 309         ;;
 310   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 311   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 312   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 313   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 314   powerpc-*-beos*)      ;;
 315   powerpc-*-freebsd*)   COREFILE='' ;;
 316   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 317   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 318   s390*-*-*)            COREFILE=trad-core.lo ;;
 319   sparc-*-netbsd* | sparc-*-openbsd*)
 320         COREFILE=netbsd-core.lo
 321         ;;
 322   tahoe-*-*)
 323         COREFILE=trad-core.lo
 324         TRAD_HEADER='"hosts/tahoe.h"'
 325         ;;
 326   vax-*-ultrix2*)
 327         COREFILE=trad-core.lo
 328         TRAD_HEADER='"hosts/vaxult2.h"'
 329         ;;
 330   vax-*-ultrix*)
 331         COREFILE=trad-core.lo
 332         TRAD_HEADER='"hosts/vaxult2.h"'
 333         ;;
 334   vax-*-*)
 335         COREFILE=trad-core.lo
 336         TRAD_HEADER='"hosts/vaxbsd.h"'
 337         ;;
 338   esac
 339
 340   case "$COREFILE" in
 341   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 342   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 343   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 344   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 345   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 346   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 347   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 348   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 349   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 350   sco5-core.lo)         COREFLAG="$COREFLAG -DSCO5_CORE" ;;
 351   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 352   esac
 353
 354   # ELF corefile support has several flavors, but all of
 355   # them use something called <sys/procfs.h>
 356   AC_CHECK_HEADERS(sys/procfs.h)
 357   if test "$ac_cv_header_sys_procfs_h" = yes; then
 358     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 359     BFD_HAVE_SYS_PROCFS_TYPE(prstatus32_t)
 360     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 361     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus32_t, pr_who)
 362     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 363     BFD_HAVE_SYS_PROCFS_TYPE(pxstatus_t)
 364     BFD_HAVE_SYS_PROCFS_TYPE(pstatus32_t)
 365     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 366     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo32_t)
 367     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 368     BFD_HAVE_SYS_PROCFS_TYPE(psinfo32_t)
 369     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 370     BFD_HAVE_SYS_PROCFS_TYPE(lwpxstatus_t)
 371     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 372     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 373     BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
 374   fi
 375 fi
 376 AC_SUBST(COREFILE)
 377 AC_SUBST(COREFLAG)
 378 if test -n "$TRAD_HEADER"; then
 379   AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
 380     [Name of host specific header file to include in trad-core.c.])
 381 fi
 382
 383 # Horrible hacks to build DLLs on Windows.
 384 WIN32LDFLAGS=
 385 WIN32LIBADD=
 386 case "${host}" in
 387 *-*-cygwin*)
 388   if test "$enable_shared" = "yes"; then
 389     WIN32LDFLAGS="-no-undefined"
 390     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 391   fi
 392   ;;
 393 esac
 394 AC_SUBST(WIN32LDFLAGS)
 395 AC_SUBST(WIN32LIBADD)
 396
 397 # target stuff:
 398
 399 # Canonicalize the secondary target names.
 400 if test -n "$enable_targets" ; then
 401     for targ in `echo $enable_targets | sed 's/,/ /g'`
 402     do
 403         result=`$ac_config_sub $targ 2>/dev/null`
 404         if test -n "$result" ; then
 405             canon_targets="$canon_targets $result"
 406         else
 407             # Allow targets that config.sub doesn't recognize, like "all".
 408             canon_targets="$canon_targets $targ"
 409         fi
 410     done
 411 fi
 412
 413 all_targets=false
 414 defvec=
 415 selvecs=
 416 selarchs=
 417 TDEFINES=
 418 for targ in $target $canon_targets
 419 do
 420     if test "x$targ" = "xall"; then
 421         all_targets=true
 422     else
 423         . $srcdir/config.bfd
 424         if test "x$targ" = "x$target"; then
 425             defvec=$targ_defvec
 426         fi
 427         selvecs="$selvecs $targ_defvec $targ_selvecs"
 428         selarchs="$selarchs $targ_archs"
 429         TDEFINES="$TDEFINES $targ_cflags"
 430     fi
 431 done
 432 AC_SUBST(TDEFINES)
 433
 434 # This processing still needs to be done if we're to decide properly whether
 435 # 64-bit support needs to be compiled in.  Currently, it will be included if
 436 # the default or any other explicitly requested target requires it; it
 437 # will not be included on a 32-bit host if no 64-bit target is requested, and
 438 # no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
 439 # used.
 440
 441 # uniq the default and selected vectors in all the configured targets.
 442 f=""
 443 for i in $selvecs ; do
 444     case " $f " in
 445     *" $i "*) ;;
 446     *) f="$f $i" ;;
 447     esac
 448 done
 449 selvecs="$f"
 450
 451
 452 # uniq the architectures in all the configured targets.
 453 f=""
 454 for i in $selarchs ; do
 455     case " $f " in
 456     *" $i "*) ;;
 457     *) f="$f $i" ;;
 458     esac
 459 done
 460 selarchs="$f"
 461
 462 # Target backend .o files.
 463 tb=
 464
 465 elf="elf.lo elflink.lo dwarf1.lo"
 466
 467 for vec in $selvecs
 468 do
 469     target_size=32
 470     case "$vec" in
 471     # This list is alphabetized to make it easy to compare
 472     # with the two vector lists in targets.c.
 473     a29kcoff_big_vec)           tb="$tb coff-a29k.lo cofflink.lo" ;;
 474     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 475     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 476     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 477     armnetbsd_vec)              tb="$tb armnetbsd.lo aout32.lo" ;;
 478     armpe_little_vec)           tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 479     armpe_big_vec)              tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 480     armpei_little_vec)          tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 481     armpei_big_vec)             tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 482     arm_epoc_pe_little_vec)     tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 483     arm_epoc_pe_big_vec)        tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 484     arm_epoc_pei_little_vec)    tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 485     arm_epoc_pei_big_vec)       tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 486     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 487     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 488     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 489     aout_mips_big_vec)          tb="$tb mipsbsd.lo aout32.lo" ;;
 490     aout_mips_little_vec)       tb="$tb mipsbsd.lo aout32.lo" ;;
 491     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 492     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 493     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 494     bfd_efi_app_ia32_vec)       tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
 495     bfd_efi_app_ia64_vec)       tb="$tb efi-app-ia64.lo pepigen.lo cofflink.lo"
 496                                 target_size=64 ;;
 497     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"
 498                                 target_size=64 ;;
 499     bfd_elf64_hppa_vec | bfd_elf64_hppa_linux_vec)
 500                                 tb="$tb elf64-hppa.lo elf64.lo $elf"
 501                                 target_size=64 ;;
 502     bfd_elf64_ia64_little_vec)  tb="$tb elf64-ia64.lo elf64.lo $elf"
 503                                 target_size=64 ;;
 504     bfd_elf64_ia64_big_vec)     tb="$tb elf64-ia64.lo elf64.lo $elf"
 505                                 target_size=64 ;;
 506     bfd_elf64_ia64_aix_little_vec)
 507                                 tb="$tb elf64-ia64.lo elf64.lo $elf"
 508                                 target_size=64 ;;
 509     bfd_elf64_ia64_aix_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"
 510                                 target_size=64 ;;
 511     bfd_elf32_ia64_big_vec)     tb="$tb elf32-ia64.lo elf32.lo $elf" ;;
 512     bfd_elf32_avr_vec)          tb="$tb elf32-avr.lo elf32.lo $elf" ;;
 513     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 514     bfd_elf32_littlearm_vec)    tb="$tb elfarm-nabi.lo elf32.lo $elf" ;;
 515     bfd_elf32_littlearm_oabi_vec) tb="$tb elfarm-oabi.lo elf32.lo $elf" ;;
 516     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 517     bfd_elf32_bigarm_vec)       tb="$tb elfarm-nabi.lo elf32.lo $elf" ;;
 518     bfd_elf32_bigarm_oabi_vec)  tb="$tb elfarm-oabi.lo elf32.lo $elf" ;;
 519     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 520     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elf32.lo $elf ecofflink.lo" ;;
 521     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elf32-mips.lo elf32.lo $elf ecofflink.lo"
 522                                 target_size=64 ;;
 523     bfd_elf32_cris_vec)         tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 524     bfd_elf32_us_cris_vec)      tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 525     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 526     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 527     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 528     bfd_elf32_hppa_vec | bfd_elf32_hppa_linux_vec)
 529                                 tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 530     bfd_elf32_i370_vec)         tb="$tb elf32-i370.lo elf32.lo $elf" ;;
 531     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 532     bfd_elf64_x86_64_vec)       tb="$tb elf64-x86-64.lo elf64.lo $elf"
 533                                 target_size=64 ;;
 534     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 535     bfd_elf32_i860_little_vec)  tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 536     bfd_elf32_i960_vec)         tb="$tb elf32-i960.lo elf32.lo $elf" ;;
 537     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 538     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elf32.lo $elf ecofflink.lo" ;;
 539     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elf32-mips.lo elf32.lo $elf ecofflink.lo"
 540                                 target_size=64 ;;
 541     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 542     bfd_elf32_m68hc11_vec)      tb="$tb elf32-m68hc11.lo elf32.lo $elf" ;;
 543     bfd_elf32_m68hc12_vec)      tb="$tb elf32-m68hc12.lo elf32.lo $elf" ;;
 544     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 545     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 546     bfd_elf32_mcore_big_vec)    tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 547     bfd_elf32_mcore_little_vec) tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 548     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 549     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 550     bfd_elf32_openrisc_vec)     tb="$tb elf32-openrisc.lo elf32.lo $elf" ;;
 551     bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
 552     bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
 553     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 554     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 555     bfd_elf64_powerpc_vec)      tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"
 556                                 target_size=64 ;;
 557     bfd_elf64_powerpcle_vec)    tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"
 558                                 target_size=64 ;;
 559     bfd_elf32_s390_vec)         tb="$tb elf32-s390.lo elf32.lo $elf" ;;
 560     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 561     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 562     bfd_elf32_shlin_vec)        tb="$tb elf32-sh-lin.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 563     bfd_elf32_shblin_vec)       tb="$tb elf32-sh-lin.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 564     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elf32.lo $elf" ;;
 565     bfd_elf32_tradbigmips_vec)  tb="$tb elf32-mips.lo elf32.lo $elf ecofflink.lo" ;;
 566     bfd_elf32_tradlittlemips_vec) tb="$tb elf32-mips.lo elf32.lo $elf ecofflink.lo" ;;
 567     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 568     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"
 569                                 target_size=64 ;;
 570     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"
 571                                 target_size=64 ;;
 572     bfd_elf64_s390_vec)         tb="$tb elf64-s390.lo elf64.lo $elf"
 573                                 target_size=64 ;;
 574     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elf64.lo $elf"
 575                                 target_size=64 ;;
 576     bfd_elf64_tradbigmips_vec)  tb="$tb elf64-mips.lo elf64.lo $elf ecofflink.lo"
 577                                 target_size=64 ;;
 578     bfd_elf64_tradlittlemips_vec) tb="$tb elf64-mips.lo elf64.lo $elf ecofflink.lo"
 579                                 target_size=64 ;;
 580     cisco_core_big_vec)         tb="$tb cisco-core.lo" ;;
 581     cisco_core_little_vec)      tb="$tb cisco-core.lo" ;;
 582     cris_aout_vec)              tb="$tb aout-cris.lo" ;;
 583     demo_64_vec)                tb="$tb demo64.lo aout64.lo"
 584                                 target_size=64 ;;
 585     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 586     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 587     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 588     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"
 589                                 target_size=64 ;;
 590     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 591     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 592     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 593     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 594     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 595     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 596     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 597     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 598     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 599     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 600     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 601     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 602     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 603     i386pe_vec)                 tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
 604     i386pei_vec)                tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
 605     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 606     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 607     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 608     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 609     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 610     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 611     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 612     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 613     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 614     ieee_vec)                   tb="$tb ieee.lo" ;;
 615     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 616     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 617     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 618     m68klynx_aout_vec)          tb="$tb m68klynx.lo lynx-core.lo aout32.lo" ;;
 619     m68klynx_coff_vec)          tb="$tb cf-m68klynx.lo coff-m68k.lo cofflink.lo lynx-core.lo" ;;
 620     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 621     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 622     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 623     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 624     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 625     mipslpe_vec)                tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
 626     mipslpei_vec)               tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
 627     mcore_pe_big_vec)           tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 628     mcore_pe_little_vec)        tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 629     mcore_pei_big_vec)          tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 630     mcore_pei_little_vec)       tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 631     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 632     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 633     rs6000coff64_vec)           tb="$tb coff64-rs6000.lo xcofflink.lo"
 634                                 target_size=64 ;;
 635     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 636     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"
 637                                 target_size=64 ;;
 638     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 639     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 640     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 641     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 642     pdp11_aout_vec)             tb="$tb pdp11.lo" ;;
 643     pmac_xcoff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 644     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 645     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 646     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 647     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 648     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 649     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 650     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 651     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 652     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 653     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 654     shlpe_vec)                  tb="$tb pe-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 655     shlpei_vec)                 tb="$tb pei-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 656     som_vec)                    tb="$tb som.lo" ;;
 657     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 658     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 659     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 660     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 661     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 662     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 663     srec_vec)                   tb="$tb srec.lo" ;;
 664     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 665     symbolsrec_vec)             tb="$tb srec.lo" ;;
 666     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 667     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 668     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 669     tic54x_coff0_vec)           tb="$tb coff-tic54x.lo" ;;
 670     tic54x_coff0_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 671     tic54x_coff1_vec)           tb="$tb coff-tic54x.lo" ;;
 672     tic54x_coff1_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 673     tic54x_coff2_vec)           tb="$tb coff-tic54x.lo" ;;
 674     tic54x_coff2_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 675     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 676     versados_vec)               tb="$tb versados.lo" ;;
 677     vms_alpha_vec)              tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"
 678                                 target_size=64 ;;
 679     vms_vax_vec)                tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
 680     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 681     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 682     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo" ;;
 683
 684     "")                 ;;
 685     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 686     esac
 687
 688     if test ${target_size} = 64; then
 689         target64=true
 690     fi
 691     if test x"${vec}" = x"${defvec}"; then
 692         bfd_default_target_size=${target_size}
 693     fi
 694 done
 695
 696 # Target architecture .o files.
 697 # A couple of CPUs use shorter file names to avoid problems on DOS
 698 # filesystems.
 699 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 700
 701 # Weed out duplicate .o files.
 702 f=""
 703 for i in $tb ; do
 704     case " $f " in
 705     *" $i "*) ;;
 706     *) f="$f $i" ;;
 707     esac
 708 done
 709 tb="$f"
 710
 711 f=""
 712 for i in $ta ; do
 713     case " $f " in
 714     *" $i "*) ;;
 715     *) f="$f $i" ;;
 716     esac
 717 done
 718 ta="$f"
 719
 720 bfd_backends="$tb"
 721 bfd_machines="$ta"
 722
 723 if test x${all_targets} = xtrue ; then
 724   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 725   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 726   selvecs=
 727   havevecs=
 728   selarchs=
 729 else    # all_targets is true
 730   # Only set these if they will be nonempty, for the clever echo.
 731   havevecs=
 732   test -n "$selvecs" &&
 733     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 734   test -n "$selvecs" &&
 735     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 736   test -n "$selarchs" &&
 737     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 738 fi      # all_targets is true
 739
 740 case ${host64}-${target64}-${want64} in
 741   *true*)
 742     wordsize=64
 743     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 744     if test -z "$GCC" && test "$BFD_HOST_64BIT_LONG" = "0" && test "$BFD_HOST_64_BIT_DEFINED" = "0"; then
 745       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 746       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 747     fi
 748     ;;
 749   false-false-false)
 750     wordsize=32
 751     all_backends='$(BFD32_BACKENDS)'
 752     ;;
 753 esac
 754
 755 AC_SUBST(wordsize)
 756 AC_SUBST(all_backends)
 757 AC_SUBST(bfd_backends)
 758 AC_SUBST(bfd_machines)
 759 AC_SUBST(bfd_default_target_size)
 760
 761 tdefaults=""
 762 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 763 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 764 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 765 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 766 AC_SUBST(tdefaults)
 767
 768 dnl AC_CHECK_HEADERS(sys/mman.h)
 769 AC_FUNC_MMAP
 770 AC_CHECK_FUNCS(madvise mprotect)
 771 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 772   true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
 773 esac
 774
 775 rm -f doc/config.status
 776 AC_OUTPUT(Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in,
 777 [sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' -e '/BLD-POTFILES =/r po/BLD-POTFILES' po/Makefile.in > po/Makefile])
 778