bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.3)
   4 AC_INIT(libbfd.c)
   5
   6 AC_ARG_ENABLE(64-bit-bfd,
   7 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
   8 [case "${enableval}" in
   9   yes)  want64=true  ;;
  10   no)   want64=false ;;
  11   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  12 esac],[want64=false])dnl
  13 AC_ARG_ENABLE(targets,
  14 [  --enable-targets        alternative target configurations],
  15 [case "${enableval}" in
  16   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  17             ;;
  18   no)       enable_targets= ;;
  19   *)        enable_targets=$enableval ;;
  20 esac])dnl
  21 AC_ARG_ENABLE(shared,
  22 [  --enable-shared         build shared BFD library],
  23 [case "${enableval}" in
  24   yes) shared=true ;;
  25   no)  shared=false ;;
  26   *)   AC_MSG_ERROR([bad value ${enableval} for BFD shared option]) ;;
  27 esac])dnl
  28 AC_ARG_ENABLE(commonbfdlib,
  29 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  30 [case "${enableval}" in
  31   yes) commonbfdlib=true ;;
  32   no)  commonbfdlib=false ;;
  33   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  34 esac])dnl
  35 AC_ARG_WITH(mmap,
  36 [  --with-mmap             try using mmap for BFD input files if available],
  37 [case "${withval}" in
  38   yes)  want_mmap=true ;;
  39   no)   want_mmap=false ;;
  40   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  41 esac],[want_mmap=false])dnl
  42
  43 AC_CONFIG_HEADER(config.h:config.in)
  44
  45 AC_CONFIG_AUX_DIR(`cd $srcdir/..;pwd`)
  46 AC_CANONICAL_SYSTEM
  47 if test -z "$target" ; then
  48     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  49 fi
  50 AC_ARG_PROGRAM
  51
  52 host64=false
  53 target64=false
  54
  55 # host stuff:
  56
  57 ALLLIBS='$(TARGETLIB)'
  58 PICFLAG=
  59 SHLIB=unused-shlib
  60 SHLINK=unused-shlink
  61 if test "${shared}" = "true"; then
  62   PICFLAG=-fpic
  63   if test "${commonbfdlib}" = "true"; then
  64     ALLLIBS='$(TARGETLIB)'
  65   else
  66     ALLLIBS='$(TARGETLIB) $(SHLIB) $(SHLINK)'
  67 changequote(,)dnl
  68     SHLIB=libbfd.so.`sed -e 's/[^0-9]*\([0-9.]*\).*/\1/' ${srcdir}/VERSION`
  69 changequote([,])dnl
  70     SHLINK=libbfd.so
  71   fi
  72 fi
  73
  74 AC_PROG_CC
  75
  76 # Permit host specific settings.
  77 . ${srcdir}/configure.host
  78
  79 AC_SUBST(HDEFINES)
  80 AC_CHECK_TOOL(AR, ar)
  81 AC_CHECK_TOOL(RANLIB, ranlib, :)
  82 AC_PROG_INSTALL
  83
  84 if test "${shared}" = "true"; then
  85   if test "${GCC}" != "yes" && test "${shared_non_gcc}" != "yes"; then
  86     AC_MSG_WARN([BFD --enable-shared only supported when using gcc])
  87     shared=false
  88     ALLLIBS='$(TARGETLIB)'
  89     PICFLAG=
  90     SHLIB=unused-shlib
  91   fi
  92 fi
  93
  94 AC_SUBST(ALLLIBS)
  95 AC_SUBST(PICFLAG)
  96 AC_SUBST(SHLIB)
  97 AC_SUBST(SHLIB_CC)
  98 AC_SUBST(SHLIB_CFLAGS)
  99 if test "${commonbfdlib}" = "true"; then
 100   COMMON_SHLIB=yes
 101   PICLIST=piclist
 102 else
 103   COMMON_SHLIB=
 104   PICLIST=
 105 fi
 106 AC_SUBST(COMMON_SHLIB)
 107 AC_SUBST(PICLIST)
 108 AC_SUBST(SHLINK)
 109
 110 HOST_64BIT_LONG=0
 111 if test "x${HOST_64BIT_TYPE}" = "xlong"; then
 112   HOST_64BIT_LONG=1
 113 fi
 114 AC_SUBST(HOST_64BIT_LONG)
 115
 116 BFD_CC_FOR_BUILD
 117
 118 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 119 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 120 AC_HEADER_TIME
 121 AC_CHECK_FUNCS(fcntl getpagesize)
 122
 123 BFD_BINARY_FOPEN
 124
 125 BFD_NEED_DECLARATION(malloc)
 126 BFD_NEED_DECLARATION(free)
 127
 128 # If we are configured native, pick a core file support file.
 129 COREFILE=
 130 COREFLAG=
 131 if test "${target}" = "${host}"; then
 132   case "${host}" in
 133   alpha*-*-linux*)
 134         COREFILE=trad-core.o
 135         AC_DEFINE(TRAD_HEADER,"hosts/alphalinux.h")
 136         ;;
 137   alpha*-*-*)           COREFILE=osf-core.o ;;
 138   arm-*-riscix)         COREFILE=trad-core.o ;;
 139   hppa*-*-hpux*)        COREFILE=hpux-core.o ;;
 140   hppa*-*-hiux*)        COREFILE=hpux-core.o ;;
 141   hppa*-*-bsd*)         COREFILE="hpux-core.o hppabsd-core.o"
 142                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 143 changequote(,)dnl
 144   i[345]86-sequent-bsd*)
 145 changequote([,])dnl
 146         COREFILE=trad-core.o;
 147         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 148         ;;
 149 changequote(,)dnl
 150   i[345]86-sequent-sysv4*) ;;
 151   i[345]86-sequent-sysv*)
 152 changequote([,])dnl
 153         COREFILE=trad-core.o
 154         AC_DEFINE(TRAD_HEADER,"hosts/symmetry.h")
 155         ;;
 156 changequote(,)dnl
 157   i[345]86-*-bsd* | i[345]86-*-freebsd*)
 158 changequote([,])dnl
 159         COREFILE=trad-core.o
 160         AC_DEFINE(TRAD_HEADER,"hosts/i386bsd.h")
 161         ;;
 162 changequote(,)dnl
 163   i[345]86-*-netbsd*)
 164 changequote([,])dnl
 165         COREFILE=netbsd-core.o
 166         ;;
 167 changequote(,)dnl
 168   i[345]86-esix-sysv3*)
 169 changequote([,])dnl
 170         COREFILE=trad-core.o
 171         AC_DEFINE(TRAD_HEADER,"hosts/esix.h")
 172         ;;
 173 changequote(,)dnl
 174   i[345]86-*-sco* | i[345]86-*-isc*)
 175 changequote([,])dnl
 176         COREFILE=trad-core.o
 177         AC_DEFINE(TRAD_HEADER,"hosts/i386sco.h")
 178         ;;
 179 changequote(,)dnl
 180   i[345]86-*-mach3*)
 181 changequote([,])dnl
 182         COREFILE=trad-core.o
 183         AC_DEFINE(TRAD_HEADER,"hosts/i386mach3.h")
 184         ;;
 185 changequote(,)dnl
 186   i[345]86-*-linux*)
 187 changequote([,])dnl
 188         COREFILE=trad-core.o
 189         AC_DEFINE(TRAD_HEADER,"hosts/i386linux.h")
 190         ;;
 191 changequote(,)dnl
 192   i[345]86-*-isc*)      COREFILE=trad-core.o ;;
 193   i[345]86-*-aix*)      COREFILE=aix386-core.o ;;
 194 changequote([,])dnl
 195   i860-*-mach3* | i860-*-osf1*)
 196         COREFILE=trad-core.o
 197         AC_DEFINE(TRAD_HEADER,"hosts/i860mach3.h")
 198         ;;
 199   mips-dec-bsd*)
 200         COREFILE=trad-core.o
 201         AC_DEFINE(TRAD_HEADER,"hosts/mipsbsd.h")
 202         ;;
 203   mips-dec-mach3*)
 204         COREFILE=trad-core.o
 205         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 206         ;;
 207   mips-*-netbsd*)
 208         COREFILE=netbsd-core.o
 209         ;;
 210   mips-dec-*)
 211         COREFILE=trad-core.o
 212         AC_DEFINE(TRAD_HEADER,"hosts/decstation.h")
 213         ;;
 214   mips-sgi-irix4*)      COREFILE=irix-core.o ;;
 215   mips-sgi-irix5*)      COREFILE=irix-core.o ;;
 216   mips-*-mach3*)
 217         COREFILE=trad-core.o
 218         AC_DEFINE(TRAD_HEADER,"hosts/mipsmach3.h")
 219         ;;
 220   mips-*-sysv4*)        ;;
 221   mips-*-sysv* | mips-*-riscos*)
 222         COREFILE=trad-core.o
 223         AC_DEFINE(TRAD_HEADER,"hosts/riscos.h")
 224         ;;
 225   mips-sony-bsd*)
 226         COREFILE=trad-core.o
 227         AC_DEFINE(TRAD_HEADER,"hosts/news-mips.h")
 228         ;;
 229   m68*-bull*-sysv*)
 230         COREFILE=trad-core.o
 231         AC_DEFINE(TRAD_HEADER,"hosts/dpx2.h")
 232         ;;
 233   m68*-hp-hpux*)        COREFILE=hpux-core.o ;;
 234   m68*-hp-bsd*)
 235         COREFILE=trad-core.o
 236         AC_DEFINE(TRAD_HEADER,"hosts/hp300bsd.h")
 237         ;;
 238   m68*-*-linux*)
 239         COREFILE=trad-core.o
 240         AC_DEFINE(TRAD_HEADER,"hosts/m68klinux.h")
 241         ;;
 242   m68*-motorola-sysv*)
 243         COREFILE=trad-core.o
 244         AC_DEFINE(TRAD_HEADER, "hosts/delta68.h")
 245         ;;
 246   m68*-sony-*)
 247         COREFILE=trad-core.o
 248         AC_DEFINE(TRAD_HEADER,"hosts/news.h")
 249         ;;
 250   m68*-*-netbsd*)
 251         COREFILE=netbsd-core.o
 252         ;;
 253   m68*-apple-aux*)
 254         COREFILE=trad-core.o
 255         AC_DEFINE(TRAD_HEADER,"hosts/m68kaux.h")
 256         ;;
 257   m88*-*-sysv4*)        ;;
 258   m88*-motorola-sysv*)  COREFILE=ptrace-core.o ;;
 259   m88*-*-mach3*)
 260         COREFILE=trad-core.o
 261         AC_DEFINE(TRAD_HEADER,"hosts/m88kmach3.h")
 262         ;;
 263   ns32k-pc532-mach)
 264         COREFILE=trad-core.o
 265         AC_DEFINE(TRAD_HEADER,"hosts/pc532mach.h")
 266         ;;
 267   ns32k-*-netbsd*)
 268         COREFILE=netbsd-core.o
 269         ;;
 270   rs6000-*-lynx*)       COREFILE=lynx-core.o ;;
 271   rs6000-*-aix4*)       COREFILE=rs6000-core.o ;;
 272   rs6000-*-*)           COREFILE=rs6000-core.o ;;
 273   powerpc-*-aix4*)      COREFILE=rs6000-core.o ;;
 274   powerpc-*-aix*)       COREFILE=rs6000-core.o ;;
 275   sparc-*-netbsd*)
 276         COREFILE=netbsd-core.o
 277         ;;
 278   tahoe-*-*)
 279         COREFILE=trad-core.o
 280         AC_DEFINE(TRAD_HEADER,"hosts/tahoe.h")
 281         ;;
 282   vax-*-ultrix2*)
 283         COREFILE=trad-core.o
 284         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 285         ;;
 286   vax-*-ultrix*)
 287         COREFILE=trad-core.o
 288         AC_DEFINE(TRAD_HEADER,"hosts/vaxult2.h")
 289         ;;
 290   vax-*-*)
 291         COREFILE=trad-core.o
 292         AC_DEFINE(TRAD_HEADER,"hosts/vaxbsd.h")
 293         ;;
 294   esac
 295
 296   case "$COREFILE" in
 297   aix386-core.o)        COREFLAG=-DAIX386_CORE ;;
 298   hppabsd-core.o)       COREFLAG=-DHPPABSD_CORE ;;
 299   hpux-core.o)          COREFLAG=-DHPUX_CORE ;;
 300   irix-core.o)          COREFLAG=-DIRIX_CORE ;;
 301   lynx-core.o)          COREFLAG=-DLYNX_CORE ;;
 302   osf-core.o)           COREFLAG=-DOSF_CORE ;;
 303   ptrace-core.o)        COREFLAG=-DPTRACE_CORE ;;
 304   rs6000-core.o)        COREFLAG="$COREFLAG -DAIX_CORE" ;;
 305   trad-core.o)          COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 306   esac
 307
 308   # The ELF code uses the native <sys/procfs.h> to handle core files.
 309   # Define HAVE_SYS_PROCFS_H if the file exists and defines
 310   # prstatus_t.
 311   AC_MSG_CHECKING([for sys/procfs.h])
 312   AC_CACHE_VAL(bfd_cv_header_sys_procfs_h,
 313   [AC_TRY_COMPILE([#include <sys/procfs.h>],
 314   [prstatus_t t;],
 315   bfd_cv_header_sys_procfs_h=yes, bfd_cv_header_sys_procfs_h=no)])
 316   AC_MSG_RESULT($bfd_cv_header_sys_procfs_h)
 317   if test $bfd_cv_header_sys_procfs_h = yes; then
 318     AC_DEFINE(HAVE_SYS_PROCFS_H)
 319   fi
 320
 321 fi
 322 AC_SUBST(COREFILE)
 323 AC_SUBST(COREFLAG)
 324
 325 # target stuff:
 326
 327 # Canonicalize the secondary target names.
 328 if test -n "$enable_targets" ; then
 329     for targ in `echo $enable_targets | sed 's/,/ /g'`
 330     do
 331         result=`$ac_config_sub $targ 2>/dev/null`
 332         if test -n "$result" ; then
 333             canon_targets="$canon_targets $result"
 334         else
 335             # Allow targets that config.sub doesn't recognize, like "all".
 336             canon_targets="$canon_targets $targ"
 337         fi
 338     done
 339 fi
 340
 341 all_targets=false
 342 defvec=
 343 selvecs=
 344 selarchs=
 345 TDEFINES=
 346 for targ in $target $canon_targets
 347 do
 348     if test "x$targ" = "xall"; then
 349         all_targets=true
 350     else
 351         . $srcdir/config.bfd
 352         if test "x$targ" = "x$target"; then
 353             defvec=$targ_defvec
 354         fi
 355         selvecs="$selvecs $targ_defvec $targ_selvecs"
 356         selarchs="$selarchs $targ_archs"
 357         TDEFINES="$TDEFINES $targ_cflags"
 358     fi
 359 done
 360 AC_SUBST(TDEFINES)
 361
 362 # This processing still needs to be done if we're to decide properly whether
 363 # 64-bit support needs to be compiled in.  Currently, it will be included if
 364 # the default or any other explicitly requested target requires it; it
 365 # will not be included on a 32-bit host if no 64-bit target is requested, and
 366 # no "--with-64-bit-bfd" option is given, even if "--with-targets=all" is
 367 # used.
 368
 369 # uniq the default and selected vectors in all the configured targets.
 370 f=""
 371 for i in $selvecs ; do
 372     case " $f " in
 373     *" $i "*) ;;
 374     *) f="$f $i" ;;
 375     esac
 376 done
 377 selvecs="$f"
 378
 379 # uniq the architectures in all the configured targets.
 380 f=""
 381 for i in $selarchs ; do
 382     case " $f " in
 383     *" $i "*) ;;
 384     *) f="$f $i" ;;
 385     esac
 386 done
 387 selarchs="$f"
 388
 389 # Target backend .o files.
 390 tb=
 391
 392 elf="elf.o elflink.o"
 393
 394 for vec in $selvecs
 395 do
 396     case "$vec" in
 397     # This list is alphabetized to make it easy to compare
 398     # with the two vector lists in targets.c.
 399     a29kcoff_big_vec)           tb="$tb coff-a29k.o cofflink.o" ;;
 400     a_out_adobe_vec)            tb="$tb aout-adobe.o aout32.o" ;;
 401     armcoff_little_vec)         tb="$tb coff-arm.o cofflink.o " ;;
 402     armcoff_big_vec)            tb="$tb coff-arm.o cofflink.o " ;;
 403     armpe_little_vec)           tb="$tb pe-arm.o cofflink.o " ;;
 404     armpe_big_vec)              tb="$tb pe-arm.o cofflink.o " ;;
 405     armpei_little_vec)          tb="$tb pei-arm.o cofflink.o " ;;
 406     armpei_big_vec)             tb="$tb pei-arm.o cofflink.o " ;;
 407     aout0_big_vec)              tb="$tb aout0.o aout32.o" ;;
 408     aout_arm_big_vec)           tb="$tb aout-arm.o aout32.o" ;;
 409     aout_arm_little_vec)        tb="$tb aout-arm.o aout32.o" ;;
 410     aout_mips_big_vec)          tb="$tb mipsbsd.o aout32.o" ;;
 411     aout_mips_little_vec)       tb="$tb mipsbsd.o aout32.o" ;;
 412     apollocoff_vec)             tb="$tb coff-apollo.o" ;;
 413     b_out_vec_big_host)         tb="$tb bout.o aout32.o" ;;
 414     b_out_vec_little_host)      tb="$tb bout.o aout32.o" ;;
 415 # start-sanitize-arc
 416     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.o elf32.o $elf" ;;
 417     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.o elf32.o $elf" ;;
 418 # end-sanitize-arc
 419     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.o elf32.o $elf" ;;
 420     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.o elf32.o $elf ecofflink.o" ;;
 421     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.o elf32.o $elf" ;;
 422     bfd_elf32_i386_vec)         tb="$tb elf32-i386.o elf32.o $elf" ;;
 423     bfd_elf32_i860_vec)         tb="$tb elf32-i860.o elf32.o $elf" ;;
 424     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.o elf32.o $elf" ;;
 425     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.o elf32.o $elf ecofflink.o" ;;
 426     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.o elf32.o $elf" ;;
 427     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.o elf32.o $elf" ;;
 428     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.o elf32.o $elf" ;;
 429     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.o elf32.o $elf" ;;
 430     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.o elf32.o $elf" ;;
 431     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.o elf64.o $elf"
 432                                 target64=true ;;
 433     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.o elf64.o $elf"
 434                                 target64=true ;;
 435     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.o elf64.o $elf"
 436                                 target64=true ;;
 437     cisco_core_vec)             tb="$tb cisco-core.o" ;;
 438     demo_64_vec)                tb="$tb demo64.o aout64.o"
 439                                 target64=true ;;
 440     ecoff_big_vec)              tb="$tb coff-mips.o ecoff.o ecofflink.o" ;;
 441     ecoff_little_vec)           tb="$tb coff-mips.o ecoff.o ecofflink.o" ;;
 442     ecoffalpha_little_vec)      tb="$tb coff-alpha.o ecoff.o ecofflink.o"
 443                                 target64=true ;;
 444     h8300coff_vec)              tb="$tb coff-h8300.o reloc16.o" ;;
 445     h8500coff_vec)              tb="$tb coff-h8500.o reloc16.o" ;;
 446     host_aout_vec)              tb="$tb host-aout.o aout32.o" ;;
 447     hp300bsd_vec)               tb="$tb hp300bsd.o aout32.o" ;;
 448     hp300hpux_vec)              tb="$tb hp300hpux.o aout32.o" ;;
 449     i386aout_vec)               tb="$tb i386aout.o aout32.o" ;;
 450     i386bsd_vec)                tb="$tb i386bsd.o aout32.o" ;;
 451     i386coff_vec)               tb="$tb coff-i386.o cofflink.o" ;;
 452     i386dynix_vec)              tb="$tb i386dynix.o aout32.o" ;;
 453     i386freebsd_vec)            tb="$tb i386freebsd.o aout32.o" ;;
 454     i386msdos_vec)              tb="$tb i386msdos.o" ;;
 455     i386pe_vec)                 tb="$tb pe-i386.o cofflink.o " ;;
 456     i386pei_vec)                tb="$tb pei-i386.o cofflink.o" ;;
 457     i386linux_vec)              tb="$tb i386linux.o aout32.o" ;;
 458     i386lynx_aout_vec)          tb="$tb i386lynx.o lynx-core.o aout32.o" ;;
 459     i386lynx_coff_vec)          tb="$tb cf-i386lynx.o cofflink.o lynx-core.o" ;;
 460     i386mach3_vec)              tb="$tb i386mach3.o aout32.o" ;;
 461     i386netbsd_vec)             tb="$tb i386netbsd.o aout32.o" ;;
 462     i386os9k_vec)               tb="$tb i386os9k.o aout32.o" ;;
 463     i860coff_vec)               tb="$tb coff-i860.o cofflink.o" ;;
 464     icoff_big_vec)              tb="$tb coff-i960.o cofflink.o" ;;
 465     icoff_little_vec)           tb="$tb coff-i960.o cofflink.o" ;;
 466     ieee_vec)                   tb="$tb ieee.o" ;;
 467     m68kcoff_vec)               tb="$tb coff-m68k.o cofflink.o" ;;
 468     m68kcoffun_vec)             tb="$tb coff-u68k.o coff-m68k.o cofflink.o" ;;
 469     m68klinux_vec)              tb="$tb m68klinux.o aout32.o" ;;
 470     m68klynx_aout_vec)          tb="$tb m68klynx.o lynx-core.o aout32.o" ;;
 471     m68klynx_coff_vec)          tb="$tb cf-m68klynx.o coff-m68k.o cofflink.o lynx-core.o" ;;
 472     m68knetbsd_vec)             tb="$tb m68knetbsd.o aout32.o" ;;
 473     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.o aout32.o" ;;
 474     m68kaux_coff_vec)           tb="$tb coff-aux.o coff-m68k.o cofflink.o" ;;
 475     m88kbcs_vec)                tb="$tb coff-m88k.o" ;;
 476     newsos3_vec)                tb="$tb newsos3.o aout32.o" ;;
 477     nlm32_i386_vec)             tb="$tb nlm32-i386.o nlm32.o nlm.o" ;;
 478     nlm32_sparc_vec)            tb="$tb nlm32-sparc.o nlm32.o nlm.o" ;;
 479     nlm32_alpha_vec)            tb="$tb nlm32-alpha.o nlm32.o nlm.o"
 480                                 target64=true ;;
 481     riscix_vec)                 tb="$tb aout32.o riscix.o" ;;
 482     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.o nlm32.o nlm.o" ;;
 483     pc532netbsd_vec)            tb="$tb ns32knetbsd.o aout-ns32k.o" ;;
 484     pc532machaout_vec)          tb="$tb pc532-mach.o aout-ns32k.o" ;;
 485     pmac_xcoff_vec)             tb="$tb coff-pmac.o xcofflink.o" ;;
 486     rs6000coff_vec)             tb="$tb coff-rs6000.o xcofflink.o" ;;
 487     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.o cofflink.o" ;;
 488     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.o cofflink.o" ;;
 489     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.o cofflink.o" ;;
 490     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.o cofflink.o" ;;
 491     shcoff_vec)                 tb="$tb coff-sh.o cofflink.o" ;;
 492 # start-sanitize-rce
 493     rce_aout_vec)               tb="$tb aout-rce.o aout32.o" ;;
 494 # end-sanitize-rce
 495     shlcoff_vec)                tb="$tb coff-sh.o cofflink.o" ;;
 496     som_vec)                    tb="$tb som.o" ;;
 497     sparclynx_aout_vec)         tb="$tb sparclynx.o lynx-core.o aout32.o" ;;
 498     sparclynx_coff_vec)         tb="$tb cf-sparclynx.o lynx-core.o" ;;
 499     sparcnetbsd_vec)            tb="$tb sparcnetbsd.o aout32.o" ;;
 500     sparccoff_vec)              tb="$tb coff-sparc.o" ;;
 501     srec_vec)                   tb="$tb srec.o" ;;
 502     sunos_big_vec)              tb="$tb sunos.o aout32.o" ;;
 503     symbolsrec_vec)             tb="$tb srec.o" ;;
 504     tekhex_vec)                 tb="$tb tekhex.o" ;;
 505     we32kcoff_vec)              tb="$tb coff-we32k.o" ;;
 506     z8kcoff_vec)                tb="$tb coff-z8k.o reloc16.o" ;;
 507     w65_vec)                    tb="$tb coff-w65.o reloc16.o" ;;
 508     versados_vec)               tb="$tb versados.o" ;;
 509
 510     "")                 ;;
 511     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 512     esac
 513 done
 514
 515 # Target architecture .o files.
 516 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.o/g`
 517
 518 # Weed out duplicate .o files.
 519 f=""
 520 for i in $tb ; do
 521     case " $f " in
 522     *" $i "*) ;;
 523     *) f="$f $i" ;;
 524     esac
 525 done
 526 tb="$f"
 527
 528 f=""
 529 for i in $ta ; do
 530     case " $f " in
 531     *" $i "*) ;;
 532     *) f="$f $i" ;;
 533     esac
 534 done
 535 ta="$f"
 536
 537 bfd_backends="$tb"
 538 bfd_machines="$ta"
 539
 540 if test x${all_targets} = xtrue ; then
 541   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 542   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 543   selvecs=
 544   selarchs=
 545 else    # all_targets is true
 546   # Only set these if they will be nonempty, for the clever echo.
 547   test -n "$selvecs" &&
 548     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 549   test -n "$selarchs" &&
 550     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 551 fi      # all_targets is true
 552
 553 case ${host64}-${target64}-${want64} in
 554   *true*)
 555     wordsize=64
 556     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 557     ;;
 558   false-false-false)
 559     wordsize=32
 560     all_backends='$(BFD32_BACKENDS)'
 561     ;;
 562 esac
 563
 564 AC_SUBST(wordsize)
 565 AC_SUBST(all_backends)
 566 AC_SUBST(bfd_backends)
 567 AC_SUBST(bfd_machines)
 568
 569 tdefaults=""
 570 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 571 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 572 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 573 AC_SUBST(tdefaults)
 574
 575 dnl AC_CHECK_HEADERS(sys/mman.h)
 576 AC_FUNC_MMAP
 577 AC_CHECK_FUNCS(madvise mprotect)
 578 case ${want_mmap}+${ac_cv_func_mmap} in
 579   true+yes )  AC_DEFINE(USE_MMAP) ;;
 580 esac
 581
 582 rm -f doc/config.status
 583 AC_OUTPUT(Makefile doc/Makefile,
 584 [case x$CONFIG_HEADERS in xconfig.h:config.in) echo > stamp-h ;; esac])