configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([babeltrace],[1.3.2],[jeremie.galarneau@efficios.com],[],[https://diamon.org/babeltrace])
   3 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [1:0:0])
   4
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 # Checks for C compiler
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AC_SYS_LARGEFILE
  21 AC_PROG_CC
  22 AC_PROG_CC_STDC
  23
  24 # Checks for programs.
  25 AC_PROG_MAKE_SET
  26 LT_INIT
  27 AC_PROG_YACC
  28 AC_PROG_LEX
  29 AC_PROG_MKDIR_P
  30 AC_PROG_LN_S
  31
  32 AX_C___ATTRIBUTE__
  33 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  34         [:],
  35         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  36
  37 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  38 LIBS="$PTHREAD_LIBS $LIBS"
  39 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  40 CC="$PTHREAD_CC"
  41
  42 # Check linker option
  43 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  44 AC_SUBST([LD_NO_AS_NEEDED])
  45
  46 AC_HEADER_STDBOOL
  47 AC_CHECK_HEADERS([ \
  48         fcntl.h \
  49         float.h \
  50         libintl.h \
  51         limits.h \
  52         malloc.h \
  53         netdb.h \
  54         netinet/in.h \
  55         stddef.h \
  56         sys/socket.h \
  57 ])
  58
  59 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  60         if test x"$(basename "$YACC")" != "xbison -y"; then
  61                 AC_MSG_ERROR([[bison not found and is required when building from git.
  62                 Please install bison]])
  63         fi
  64         AC_PATH_PROG([BISON],[bison])
  65         AX_PROG_BISON_VERSION([2.4], [],[
  66                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  67         ])
  68 fi
  69
  70 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  71         if test x"$LEX" != "xflex"; then
  72                 AC_MSG_ERROR([[flex not found and is required when building from git.
  73                 Please install flex]])
  74         fi
  75         AC_PATH_PROG([FLEX],[flex])
  76         AX_PROG_FLEX_VERSION([2.5.35], [],[
  77                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  78         ])
  79 fi
  80
  81 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  82
  83 # Check what libraries are required on this platform to link sockets programs.
  84 AX_LIB_SOCKET_NSL
  85
  86 # Checks for typedefs, structures, and compiler characteristics.
  87 AC_C_INLINE
  88 AC_TYPE_PID_T
  89 AC_TYPE_SIZE_T
  90
  91 # Checks for library functions.
  92 AC_FUNC_ALLOCA
  93 AC_FUNC_FORK
  94 AC_FUNC_MALLOC
  95 AC_FUNC_MKTIME
  96 AC_FUNC_MMAP
  97 AC_FUNC_REALLOC
  98 AC_FUNC_STRERROR_R
  99 AC_CHECK_FUNCS([ \
 100         atexit \
 101         dirfd \
 102         dup2 \
 103         ftruncate \
 104         gethostbyname \
 105         gethostname \
 106         gettimeofday \
 107         localtime_r \
 108         memchr \
 109         memset \
 110         mkdir \
 111         mkdtemp \
 112         munmap \
 113         rmdir \
 114         setenv \
 115         socket \
 116         strchr \
 117         strdup \
 118         strerror \
 119         strndup \
 120         strnlen \
 121         strrchr \
 122         strtoul \
 123         strtoull \
 124         tzset \
 125         uname \
 126 ])
 127
 128 MINGW32=no
 129 DEFAULT_ENABLE_DEBUGINFO=yes
 130 AS_CASE([$host_os],
 131   [solaris*|darwin*],
 132     [
 133         DEFAULT_ENABLE_DEBUGINFO=no
 134     ],
 135   [mingw*],
 136     [
 137         MINGW32=yes
 138     ]
 139 )
 140
 141 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 142
 143 # Check for libuuid
 144 AC_CHECK_LIB([uuid], [uuid_generate],
 145 [
 146         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 147         have_libuuid=yes
 148 ],
 149 [
 150         # libuuid not found, check for uuid_create in libc.
 151         AC_CHECK_LIB([c], [uuid_create],
 152         [
 153                 AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 154                 have_libc_uuid=yes
 155         ],
 156         [
 157                 # for MinGW32 we have our own internal implemenation of uuid using Windows functions.
 158                 if test "x$MINGW32" = xno; then
 159                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 160                 fi
 161         ])
 162 ]
 163 )
 164 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 165 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 166
 167 # Check for fmemopen
 168 AC_CHECK_LIB([c], [fmemopen],
 169 [
 170         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 171 ]
 172 )
 173
 174 # Check for open_memstream
 175 AC_CHECK_LIB([c], [open_memstream],
 176 [
 177         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 178 ]
 179 )
 180
 181 # Check for posix_fallocate
 182 AC_CHECK_LIB([c], [posix_fallocate],
 183 [
 184         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 185 ]
 186 )
 187
 188 # Check for faccessat
 189 AC_CHECK_LIB([c], [faccessat],
 190 [
 191         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
 192 ]
 193 )
 194
 195 AC_CHECK_LIB([popt], [poptGetContext], [],
 196         [AC_MSG_ERROR([Cannot find popt.])]
 197 )
 198
 199 # For Python
 200 # SWIG version needed or newer:
 201 swig_version=2.0.0
 202
 203 AC_ARG_ENABLE([python-bindings],
 204               [AC_HELP_STRING([--enable-python-bindings],
 205                               [generate Python bindings])],
 206               [enable_python=yes], [enable_python=no])
 207
 208 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 209
 210 if test "x${enable_python:-yes}" = xyes; then
 211   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 212   AM_PATH_PYTHON
 213
 214   AM_PATH_PYTHON_MODULES([PYTHON])
 215   # pythondir is the path where extra modules are to be installed
 216   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 217   # pyexecdir is the path that contains shared objects used by the extra modules
 218   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 219   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 220   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 221   AS_IF([test -z "$PYTHON_INCLUDE"], [
 222     AS_IF([test -z "$PYTHON_CONFIG"], [
 223       AC_PATH_PROGS([PYTHON_CONFIG],
 224                     [python$PYTHON_VERSION-config python-config],
 225                     [no],
 226                     [`dirname $PYTHON`])
 227       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 228     ])
 229     AC_MSG_CHECKING([python include flags])
 230     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 231     AC_MSG_RESULT([$PYTHON_INCLUDE])
 232   ])
 233
 234 else
 235     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 236 [if you want Python bindings.])
 237
 238 fi
 239
 240 # Optional debuginfo feature (enabled by default)
 241 AS_IF([test "x$DEFAULT_ENABLE_DEBUGINFO" = xyes],
 242     [AC_ARG_ENABLE([debug-info], [AC_HELP_STRING([--disable-debug-info], [disable the debug-info feature (default on OS X and Solaris)])], [], [enable_debuginfo=yes])],
 243     [AC_ARG_ENABLE([debug-info], [AC_HELP_STRING([--enable-debug-info], [enable the debug-info feature (default on Linux)])], [], [enable_debuginfo=no])]
 244 )
 245
 246 AM_CONDITIONAL([ENABLE_DEBUGINFO], [test "x$enable_debuginfo" = xyes])
 247 AS_IF([test "x$enable_debuginfo" = xyes], [
 248             # Check if libelf and libdw are present
 249             AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug-info. You can disable this feature using --disable-debuginfo.)])
 250             AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug-info. You can disable this feature using --disable-debuginfo.)])
 251             AX_LIB_ELFUTILS([0], [154], [], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug-info feature. You can disable this feature using --disable-debuginfo.)])
 252             AC_DEFINE([ENABLE_DEBUGINFO], [1], [Define to 1 if you enable the 'debug-info' feature])
 253 ], [])
 254
 255 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.0.0])
 256 AC_SUBST(PACKAGE_LIBS)
 257
 258 LIBS="$LIBS $GMODULE_LIBS"
 259 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
 260 AC_SUBST(PACKAGE_CFLAGS)
 261
 262 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
 263 AC_SUBST(DEFAULT_INCLUDES)
 264
 265 babeltraceincludedir="${includedir}/babeltrace"
 266 AC_SUBST(babeltraceincludedir)
 267
 268 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 269 AC_SUBST(babeltracectfincludedir)
 270
 271 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 272 AC_SUBST(babeltracectfwriterincludedir)
 273
 274 AC_CONFIG_FILES([
 275         Makefile
 276         types/Makefile
 277         compat/Makefile
 278         formats/Makefile
 279         formats/ctf/Makefile
 280         formats/ctf/types/Makefile
 281         formats/ctf-text/Makefile
 282         formats/ctf-text/types/Makefile
 283         formats/ctf-metadata/Makefile
 284         formats/bt-dummy/Makefile
 285         formats/lttng-live/Makefile
 286         formats/ctf/metadata/Makefile
 287         formats/ctf/writer/Makefile
 288         converter/Makefile
 289         doc/Makefile
 290         lib/Makefile
 291         lib/prio_heap/Makefile
 292         include/Makefile
 293         bindings/Makefile
 294         bindings/python/Makefile
 295         tests/Makefile
 296         tests/bin/Makefile
 297         tests/lib/Makefile
 298         tests/utils/Makefile
 299         tests/utils/tap/Makefile
 300         extras/Makefile
 301         extras/valgrind/Makefile
 302         babeltrace.pc
 303         babeltrace-ctf.pc
 304 ])
 305
 306 AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
 307 AC_CONFIG_FILES([tests/lib/test_seek_big_trace], [chmod +x tests/lib/test_seek_big_trace])
 308 AC_CONFIG_FILES([tests/lib/test_seek_empty_packet], [chmod +x tests/lib/test_seek_empty_packet])
 309 AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
 310 AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])
 311
 312 AC_CONFIG_FILES([tests/bin/test_trace_read], [chmod +x tests/bin/test_trace_read])
 313 AC_CONFIG_FILES([tests/bin/test_intersection], [chmod +x tests/bin/test_intersection])
 314 AC_CONFIG_FILES([tests/bin/test_packet_seq_num], [chmod +x tests/bin/test_packet_seq_num])
 315
 316 AC_OUTPUT
 317
 318 #
 319 # Mini-report on what will be built.
 320 #
 321
 322 PPRINT_INIT
 323 PPRINT_SET_INDENT(1)
 324 PPRINT_SET_TS(38)
 325
 326 AS_ECHO
 327 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 328 AS_ECHO
 329
 330 PPRINT_SUBTITLE([Features])
 331
 332 # Target architecture we're building for.
 333 target_arch=$host_cpu
 334 [
 335 for f in $CFLAGS; do
 336         if test $f = "-m32"; then
 337                 target_arch="32-bit"
 338         elif test $f = "-m64"; then
 339                 target_arch="64-bit"
 340         fi
 341 done
 342 ]
 343 PPRINT_PROP_STRING([Target architecture], $target_arch)
 344
 345 # python bindings enabled/disabled
 346 test "x$enable_python" = "xyes" && value=1 || value=0
 347 PPRINT_PROP_BOOL([Python bindings], $value)
 348
 349 # python bindings doc enabled/disabled
 350 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 351 PPRINT_PROP_BOOL([Python bindings doc], $value)
 352
 353 # debug-info enabled/disabled
 354 test "x$enable_debuginfo" = "xyes" && value=1 || value=0
 355 PPRINT_PROP_BOOL([Debug information output], $value)
 356
 357
 358 report_bindir="`eval eval echo $bindir`"
 359 report_libdir="`eval eval echo $libdir`"
 360
 361 # Print the bindir and libdir this `make install' will install into.
 362 AS_ECHO
 363 PPRINT_SUBTITLE([Install directories])
 364 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 365 PPRINT_PROP_STRING([Libraries], [$report_libdir])