configure.ac

   1 AC_PREREQ(2.59)
   2 AC_INIT([userspace-rcu],[0.9.1],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([URCU_LIBRARY_VERSION], [4:0:0])
   7
   8 AC_CONFIG_SRCDIR([urcu.h])
   9 AC_CONFIG_HEADERS([config.h urcu/config.h])
  10 AC_CONFIG_AUX_DIR([config])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  17 AM_MAINTAINER_MODE([enable])
  18
  19 # Enable silent rules if available (Introduced in AM 1.11)
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  21
  22 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  23 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  24 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  25 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  26 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  27 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  28
  29 # Allow overriding storage used for TLS variables.
  30 AC_ARG_ENABLE([compiler-tls],
  31         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  32         [def_compiler_tls=$enableval],
  33         [def_compiler_tls="yes"])
  34
  35 # If not overridden, use ax_tls.m4 to check if TLS is available.
  36 AS_IF([test "x$def_compiler_tls" = "xyes"],
  37         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  38         [:])
  39
  40 AS_IF([test "x$def_tls_detect" = "x"],
  41         [:],
  42         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  43
  44 # Checks for C compiler
  45 AC_USE_SYSTEM_EXTENSIONS
  46 AC_PROG_CC
  47 AC_PROG_CC_STDC
  48
  49 # Checks for programs.
  50 AC_PROG_AWK
  51 AC_PROG_MAKE_SET
  52 AC_CHECK_PROGS(NPROC, [nproc gnproc])
  53 LT_INIT
  54
  55 # Checks for typedefs, structures, and compiler characteristics.
  56 AC_C_INLINE
  57 AC_TYPE_PID_T
  58 AC_TYPE_SIZE_T
  59 AC_TYPE_SSIZE_T
  60 AC_TYPE_UINT16_T
  61 AC_TYPE_INT32_T
  62 AC_TYPE_UINT32_T
  63 AC_TYPE_UINT64_T
  64 AC_TYPE_UINT8_T
  65
  66 AX_C___ATTRIBUTE__
  67 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  68         [:],
  69         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  70
  71 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  72 LIBS="$PTHREAD_LIBS $LIBS"
  73 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  74 CC="$PTHREAD_CC"
  75
  76 # Checks for library functions.
  77 AC_FUNC_MALLOC
  78 AC_FUNC_MMAP
  79 AC_FUNC_FORK
  80 AC_CHECK_FUNCS([ \
  81         atexit \
  82         clock_gettime \
  83         getcpuid \
  84         gettid \
  85         gettimeofday \
  86         memeset \
  87         memset \
  88         munmap \
  89         sched_getcpu \
  90         strerror \
  91         strtoul \
  92         sysconf \
  93 ])
  94
  95 # Check for headers
  96 AC_HEADER_STDBOOL
  97 AC_CHECK_HEADERS([ \
  98         limits.h \
  99         stddef.h \
 100         sys/param.h \
 101         sys/time.h \
 102 ])
 103
 104 # Find arch type
 105 AS_CASE([$host_cpu],
 106         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
 107         [i486], [ARCHTYPE="x86"],
 108         [i586], [ARCHTYPE="x86"],
 109         [i686], [ARCHTYPE="x86"],
 110         [amd64], [ARCHTYPE="x86"],
 111         [x86_64], [ARCHTYPE="x86"],
 112         [powerpc], [ARCHTYPE="ppc"],
 113         [ppc64], [ARCHTYPE="ppc"],
 114         [powerpc64], [ARCHTYPE="ppc"],
 115         [powerpc64le], [ARCHTYPE="ppc"],
 116         [ppc], [ARCHTYPE="ppc"],
 117         [s390], [ARCHTYPE="s390"],
 118         [s390x], [ARCHTYPE="s390"],
 119         [sparc], [ARCHTYPE="sparc64"],
 120         [sparc64], [ARCHTYPE="sparc64"],
 121         [alpha*], [ARCHTYPE="alpha"],
 122         [ia64], [ARCHTYPE="ia64"],
 123         [arm*], [ARCHTYPE="arm"],
 124         [aarch64], [ARCHTYPE="aarch64"],
 125         [mips*], [ARCHTYPE="mips"],
 126         [tile*], [ARCHTYPE="tile"],
 127         [hppa*], [ARCHTYPE="hppa"],
 128         [ARCHTYPE="unknown"]
 129 )
 130
 131 AS_CASE([$host],[*-*-linux-androideabi],
 132         [AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
 133         [AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
 134 )
 135
 136 AC_SUBST(ARCHTYPE)
 137 AC_SUBST(SUBARCHTYPE)
 138
 139 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
 140 ARCHSRC=urcu/arch/$ARCHTYPE.h
 141
 142 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
 143         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 144 ])
 145
 146 AS_IF([test "$host_cpu" = "armv7l"],[
 147         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
 148 ])
 149
 150 # ARM-specific checks
 151 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 152         AC_MSG_CHECKING([for dmb instruction])
 153         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 154                                 int main()
 155                                 {
 156                                         asm volatile("dmb":::"memory");
 157                                         return 0;
 158                                 }
 159                 ]])
 160         ],[
 161                 AC_MSG_RESULT([yes])
 162                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 163         ],[
 164                 AC_MSG_RESULT([no])
 165         ])
 166 ])
 167
 168 # Tile-specific checks
 169 AS_IF([echo "$host_cpu" | grep "^tile"],[
 170         AC_MSG_CHECKING([for Tile architecture type])
 171         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 172                                 #ifndef __tilegx__
 173                                 #error
 174                                 #endif
 175                 ]])
 176         ],[
 177                 AC_MSG_RESULT([ok])
 178         ],[
 179                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 180         ])
 181 ])
 182
 183 # x86-specific checks
 184 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 185         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 186         #For now, using lock; addl compatibility mode even for i686, because the
 187         #Pentium III is seen as a i686, but lacks mfence instruction.
 188         #Only using fence for x86_64.
 189         #
 190         #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
 191         #variant but lacks fence instructions.
 192         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om"],[
 193                 AC_MSG_RESULT([yes])
 194                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 195         ],[
 196                 AC_MSG_RESULT([no])
 197         ])
 198 ])
 199
 200 # Check if sys_futex() is available
 201 AC_MSG_CHECKING([for sys_futex()])
 202 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 203                 #include <sys/syscall.h>
 204                 #ifndef __NR_futex
 205                 #error "futexes not available"
 206                 #endif
 207         ]])
 208 ],[
 209         AC_MSG_RESULT([yes])
 210         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 211         compat_futex_test=0
 212 ],[
 213         AC_MSG_RESULT([no])
 214         compat_futex_test=1
 215 ])
 216
 217 # Check for pthread
 218 AC_CHECK_LIB([pthread], [pthread_create],
 219         [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
 220         [AC_CHECK_LIB([c], [pthread_create],
 221                 [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
 222                 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 223         )]
 224 )
 225
 226 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 227 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 228 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 229
 230 # smp-support configure option
 231 AC_ARG_ENABLE([smp-support],
 232         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 233         [def_smp_support=$enableval],
 234         [def_smp_support="yes"])
 235 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 236
 237
 238 # From the sched_setaffinity(2)'s man page:
 239 # ~~~~
 240 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 241 # The library interfaces were introduced in glibc 2.3.  Initially, the
 242 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 243 # the cpuset size argument was removed, but this argument was
 244 # restored in glibc 2.3.4.
 245 # ~~~~
 246
 247 # In addition to that, some vendors ported the system call to 2.4
 248 # kernels.
 249
 250 # Furthermore, when the function first appeared, the MASK argument was
 251 # an unsigned long pointer, while later it was made into a cpu_set_t
 252 # pointer.  Systems that have the cpu_set_t version also should have
 253 # the CPU_ZERO, CPU_SET, etc. macros.
 254
 255 # All this mess means we have to cater for at least 3 different
 256 # sched_setaffinity prototypes:
 257
 258 # ~~~~
 259 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 260 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 261 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 262 # ~~~~
 263
 264 # Since we define _GNU_SOURCE in the sources, must do so too in the
 265 # autoconf tests, as defining _GNU_SOURCE or not exposes
 266 # sched_setaffinity bits differently.
 267 saved_CFLAGS=$CFLAGS
 268 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 269
 270 AC_CHECK_TYPES([cpu_set_t],
 271         [have_cpu_set_t="yes"],
 272         [have_cpu_set_t="no"],
 273         [#include <sched.h>])
 274
 275 # Confirm that we have CPU_ZERO, and it actually works.
 276 AC_MSG_CHECKING([whether CPU_ZERO works])
 277 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 278 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 279                 #define _GNU_SOURCE
 280                 #include <sched.h>
 281                 int main()
 282                 {
 283                         cpu_set_t foo; CPU_ZERO(&foo);
 284                         return 0;
 285                 }
 286         ]])
 287 ],[
 288         AC_DEFINE(HAVE_CPU_ZERO, 1)
 289         AC_MSG_RESULT([yes])
 290 ],[
 291         AC_MSG_RESULT([no])
 292 ])
 293
 294 # Confirm that we have CPU_SET, and it actually works.
 295 AC_MSG_CHECKING([whether CPU_SET works])
 296 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 297 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 298                 #define _GNU_SOURCE
 299                 #include <sched.h>
 300                 int main()
 301                 {
 302                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 303                         return 0;
 304                 }
 305         ]])
 306 ],[
 307         AC_DEFINE(HAVE_CPU_SET, 1)
 308         AC_MSG_RESULT([yes])
 309 ],[
 310         AC_MSG_RESULT([no])
 311 ])
 312
 313 # First check if the function is available at all.
 314 AC_CHECK_FUNCS([sched_setaffinity],[
 315         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 316         # then we have the first version using unsigned long, and no
 317         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 318         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 319         # should also be present, but we confirm nonetheless.
 320
 321         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 322                 # We do have it.
 323                 # Check how many arguments does sched_setaffinity take.
 324                 # Should be 3 or 2.
 325                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 326                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 327                                 #include <sched.h>
 328                                 int main()
 329                                 {
 330                                         cpu_set_t foo;
 331                                         sched_setaffinity(0, sizeof (foo), &foo);
 332                                         return 0;
 333                                 }
 334                         ]])
 335                 ],
 336                 [sched_set_affinity_args=3],
 337                 [sched_set_affinity_args=2])
 338                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 339                         $sched_set_affinity_args,
 340                         [Defined to sched_setaffinity's number of arguments.])
 341                 AC_MSG_RESULT([$sched_set_affinity_args])
 342         ],[
 343                 # No cpu_set_t, always 3 args.
 344                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 345         ])
 346 ])
 347
 348 CFLAGS=$saved_CFLAGS
 349
 350 AC_CONFIG_LINKS([
 351         urcu/arch.h:$ARCHSRC
 352         urcu/uatomic.h:$UATOMICSRC
 353 ])
 354 AC_CONFIG_FILES([
 355         Makefile
 356         doc/Makefile
 357         doc/examples/Makefile
 358         tests/Makefile
 359         tests/common/Makefile
 360         tests/unit/Makefile
 361         tests/benchmark/Makefile
 362         tests/regression/Makefile
 363         tests/regression/regression_tests
 364         tests/utils/Makefile
 365         liburcu.pc
 366         liburcu-bp.pc
 367         liburcu-cds.pc
 368         liburcu-qsbr.pc
 369         liburcu-mb.pc
 370         liburcu-signal.pc
 371 ])
 372 AC_OUTPUT
 373
 374 # Report on selected configure options
 375 AS_IF([test "x$def_smp_support" = "xyes"],[
 376         AS_ECHO("SMP support enabled.")
 377 ],[
 378         AS_ECHO("SMP support disabled.")
 379 ])
 380
 381 AS_IF([test "x$def_tls_detect" = "x"],[
 382         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 383 ],[
 384         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 385 ])