configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([babeltrace],[2.0.0-pre],[jeremie dot galarneau at efficios dot com])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [2:0:0])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar])
  16 AM_MAINTAINER_MODE([enable])
  17
  18 # Enable silent rules if available (Introduced in AM 1.11)
  19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  20
  21 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  22
  23 # Checks for C compiler
  24 AC_USE_SYSTEM_EXTENSIONS
  25 AC_SYS_LARGEFILE
  26 AC_PROG_CC
  27 AC_PROG_CC_STDC
  28
  29 # Checks for programs.
  30 AC_PROG_MAKE_SET
  31 LT_INIT
  32 AC_PROG_YACC
  33 AC_PROG_LEX
  34 AC_PROG_MKDIR_P
  35 AC_PROG_LN_S
  36
  37 AX_C___ATTRIBUTE__
  38 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  39         [:],
  40         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  41
  42 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  43 LIBS="$PTHREAD_LIBS $LIBS"
  44 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  45 CC="$PTHREAD_CC"
  46
  47 # Check linker option
  48 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  49 AC_SUBST([LD_NO_AS_NEEDED])
  50
  51 AC_HEADER_STDBOOL
  52 AC_CHECK_HEADERS([ \
  53         fcntl.h \
  54         float.h \
  55         libintl.h \
  56         limits.h \
  57         malloc.h \
  58         netdb.h \
  59         netinet/in.h \
  60         stddef.h \
  61         sys/socket.h \
  62 ])
  63
  64 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  65         if test x"$(basename "$YACC")" != "xbison -y"; then
  66                 AC_MSG_ERROR([[bison not found and is required when building from git.
  67                 Please install bison]])
  68         fi
  69         AC_PATH_PROG([BISON],[bison])
  70         AX_PROG_BISON_VERSION([2.4], [],[
  71                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  72         ])
  73 fi
  74
  75 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  76         if test x"$LEX" != "xflex"; then
  77                 AC_MSG_ERROR([[flex not found and is required when building from git.
  78                 Please install flex]])
  79         fi
  80         AC_PATH_PROG([FLEX],[flex])
  81         AX_PROG_FLEX_VERSION([2.5.35], [],[
  82                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  83         ])
  84 fi
  85
  86
  87 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  88
  89 # Check what libraries are required on this platform to link sockets programs.
  90 AX_LIB_SOCKET_NSL
  91
  92 # Checks for typedefs, structures, and compiler characteristics.
  93 AC_C_INLINE
  94 AC_TYPE_PID_T
  95 AC_TYPE_SIZE_T
  96 AC_TYPE_INT16_T
  97 AC_TYPE_INT32_T
  98 AC_TYPE_INT64_T
  99 AC_TYPE_INT8_T
 100 AC_TYPE_OFF_T
 101 AC_TYPE_SSIZE_T
 102 AC_TYPE_UINT16_T
 103 AC_TYPE_UINT32_T
 104 AC_TYPE_UINT64_T
 105 AC_TYPE_UINT8_T
 106
 107 # Checks for library functions.
 108 AC_FUNC_ALLOCA
 109 AC_FUNC_FORK
 110 AC_FUNC_MALLOC
 111 AC_FUNC_MKTIME
 112 AC_FUNC_MMAP
 113 AC_FUNC_REALLOC
 114 AC_FUNC_STRERROR_R
 115 AC_CHECK_FUNCS([ \
 116         atexit \
 117         dirfd \
 118         dup2 \
 119         ftruncate \
 120         gethostbyname \
 121         gethostname \
 122         gettimeofday \
 123         localtime_r \
 124         memchr \
 125         memset \
 126         mkdir \
 127         mkdtemp \
 128         munmap \
 129         rmdir \
 130         setenv \
 131         socket \
 132         strchr \
 133         strdup \
 134         strerror \
 135         strndup \
 136         strnlen \
 137         strrchr \
 138         strtoul \
 139         strtoull \
 140         tzset \
 141         uname \
 142 ])
 143
 144 MINGW32=no
 145 DEFAULT_ENABLE_DEBUG_INFO=yes
 146 AS_CASE([$host_os],
 147   [solaris*|darwin*],
 148     [
 149         DEFAULT_ENABLE_DEBUG_INFO=no
 150     ],
 151   [mingw*],
 152     [
 153         MINGW32=yes
 154     ]
 155 )
 156
 157 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 158
 159 # Check for uuid in system libs
 160 AC_CHECK_FUNCS([uuid_generate],
 161 [
 162   AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 163   link_with_libuuid=no
 164 ],
 165 [
 166   # First, check the pkg-config module is available, otherwise explicitly check
 167   # for libuuid, or uuid support in the C-library.
 168   PKG_CHECK_MODULES([UUID], [uuid],
 169   [
 170     LIBS="${UUID_LIBS} ${LIBS}"
 171     CFLAGS="${CFLAGS} ${UUID_CFLAGS}"
 172     AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 173     link_with_libuuid=yes
 174   ],
 175   [
 176     # Check for libuuid
 177     AC_CHECK_LIB([uuid], [uuid_generate],
 178     [
 179       AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 180       link_with_libuuid=yes
 181     ],
 182     [
 183       # libuuid not found, check for uuid_create in libc.
 184       AC_CHECK_LIB([c], [uuid_create],
 185       [
 186         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 187         link_with_libc_uuid=yes
 188       ],
 189       [
 190         # for MinGW32 we have our own internal implementation of uuid using Windows functions.
 191         if test "x$MINGW32" = xno; then
 192           AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 193         fi
 194       ])
 195     ])
 196   ])
 197 ])
 198
 199 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 200 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 201
 202 # Check for fmemopen
 203 AC_CHECK_LIB([c], [fmemopen],
 204 [
 205         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 206 ]
 207 )
 208
 209 # Check for open_memstream
 210 AC_CHECK_LIB([c], [open_memstream],
 211 [
 212         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 213 ]
 214 )
 215
 216 # Check for posix_fallocate
 217 AC_CHECK_LIB([c], [posix_fallocate],
 218 [
 219         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 220 ]
 221 )
 222
 223 # Check for faccessat
 224 AC_CHECK_LIB([c], [faccessat],
 225 [
 226         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
 227 ]
 228 )
 229
 230 AC_CHECK_LIB([popt], [poptGetContext], [],
 231         [AC_MSG_ERROR([Cannot find popt.])]
 232 )
 233
 234 # Plugins
 235 AC_ARG_VAR([PLUGINSDIR], [built-in plugins install directory [LIBDIR/babeltrace/plugins]])
 236 AS_IF([test "x$PLUGINSDIR" = x], [PLUGINSDIR='$(libdir)/babeltrace/plugins'])
 237
 238 # For Python
 239 # SWIG version needed or newer:
 240 swig_version=2.0.0
 241
 242 AC_ARG_ENABLE([python-bindings],
 243               [AC_HELP_STRING([--enable-python-bindings],
 244                               [generate Python bindings])],
 245               [enable_python=yes], [enable_python=no])
 246
 247 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 248
 249 AC_ARG_ENABLE([python-bindings-doc],
 250               [AC_HELP_STRING([--enable-python-bindings-doc],
 251                               [generate Python bindings documentation])],
 252               [enable_python_bindings_doc=yes], [enable_python_bindings_doc=no])
 253
 254 if test "x${enable_python:-no}" = xno && test "x${enable_python_bindings_doc:-yes}" = xyes; then
 255   AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 256 fi
 257
 258 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 259
 260 if test "x${enable_python:-yes}" = xyes; then
 261   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 262   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 263
 264   AM_PATH_PYTHON_MODULES([PYTHON])
 265   # pythondir is the path where extra modules are to be installed
 266   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 267   # pyexecdir is the path that contains shared objects used by the extra modules
 268   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 269   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 270   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 271   AS_IF([test -z "$PYTHON_INCLUDE"], [
 272     AS_IF([test -z "$PYTHON_CONFIG"], [
 273       AC_PATH_PROGS([PYTHON_CONFIG],
 274                     [python$PYTHON_VERSION-config python-config],
 275                     [no],
 276                     [`dirname $PYTHON`])
 277       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 278     ])
 279     AC_MSG_CHECKING([python include flags])
 280     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 281     AC_MSG_RESULT([$PYTHON_INCLUDE])
 282   ])
 283 else
 284     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 285 [if you want Python bindings.])
 286
 287 fi
 288
 289 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 290     AM_CHECK_PYTHON_SPHINX([PYTHON])
 291     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 292       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 293     )
 294 fi
 295
 296 # Set default enable state for debug info.
 297 # The _enable_debug_info variable is prepended with an underscore to
 298 # avoid clashing with the one generated by AC_ARG_ENABLE.
 299 AS_IF([test "x$DEFAULT_ENABLE_DEBUG_INFO" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])
 300
 301 # Optional debug info feature
 302 # Do _not_ indent the help string below (appears in the configure --help
 303 # output).
 304 AC_ARG_ENABLE([debug-info],
 305 [AC_HELP_STRING([--enable-debug-info], [enable the debug info feature (default on Linux)])]
 306 [AC_HELP_STRING([--disable-debug-info], [disable the debug info feature (default on OS X and Solaris)])],
 307         [AS_IF([test "x$enableval" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])], [])
 308
 309 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$_enable_debug_info" = xyes])
 310 AS_IF([test "x$_enable_debug_info" = xyes], [
 311             # Check if libelf and libdw are present
 312             AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 313             AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 314             BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 315             AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])
 316 ], [])
 317
 318 AC_ARG_VAR([BUILT_IN_PLUGINS], [Statically-link in-tree plug-ins into the babeltrace binary])
 319 AS_IF([test "x$BUILT_IN_PLUGINS" != x], [
 320 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 321         AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace executable)])
 322         AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace executable)])
 323         built_in_plugins=yes
 324         AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])
 325 ])
 326 AM_CONDITIONAL([BUILT_IN_PLUGINS], [test "x$built_in_plugins" = "xyes"])
 327
 328 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.0.0])
 329
 330 LIBS="$LIBS $GMODULE_LIBS"
 331 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
 332 AC_SUBST(PACKAGE_CFLAGS)
 333
 334 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
 335 AC_SUBST(DEFAULT_INCLUDES)
 336
 337 babeltraceincludedir="${includedir}/babeltrace"
 338 AC_SUBST(babeltraceincludedir)
 339
 340 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 341 AC_SUBST(babeltracectfincludedir)
 342
 343 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 344 AC_SUBST(babeltracectfwriterincludedir)
 345
 346 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 347 AC_SUBST(babeltracectfirincludedir)
 348
 349 babeltracepluginincludedir="${includedir}/babeltrace/plugin"
 350 AC_SUBST(babeltracepluginincludedir)
 351
 352 program_transform_name='s/babeltrace[\].bin/babeltrace/g'
 353 AC_SUBST(program_transform_name)
 354
 355 # check for Doxygen
 356 AC_ARG_ENABLE(
 357   [api-doc],
 358   [AC_HELP_STRING(
 359     [--enable-api-doc],
 360     [generate and install HTML API documentation]
 361   )],
 362   [enable_api_doc=$enableval],
 363   [enable_api_doc=no]
 364 )
 365 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = "xyes"])
 366
 367 AS_IF([test "x$enable_api_doc" = "xyes"], [
 368   DX_DOXYGEN_FEATURE(ON)
 369   DX_DOT_FEATURE(OFF)
 370   DX_HTML_FEATURE(ON)
 371   DX_CHM_FEATURE(OFF)
 372   DX_CHI_FEATURE(OFF)
 373   DX_MAN_FEATURE(OFF)
 374   DX_RTF_FEATURE(OFF)
 375   DX_XML_FEATURE(OFF)
 376   DX_PDF_FEATURE(OFF)
 377   DX_PS_FEATURE(OFF)
 378   DX_INIT_DOXYGEN([Babeltrace], [$(srcdir)/Doxyfile], [output])
 379 ])
 380
 381 AC_CONFIG_FILES([
 382         Makefile
 383         types/Makefile
 384         compat/Makefile
 385         formats/Makefile
 386         formats/ctf/Makefile
 387         formats/ctf/types/Makefile
 388         formats/ctf-text/Makefile
 389         formats/ctf-text/types/Makefile
 390         formats/ctf-metadata/Makefile
 391         formats/bt-dummy/Makefile
 392         formats/lttng-live/Makefile
 393         formats/ctf/metadata/Makefile
 394         formats/ctf/writer/Makefile
 395         formats/ctf/ir/Makefile
 396         converter/Makefile
 397         doc/Makefile
 398         doc/api/Makefile
 399         doc/api/Doxyfile
 400         doc/bindings/Makefile
 401         doc/bindings/python/Makefile
 402         doc/images/Makefile
 403         lib/Makefile
 404         lib/prio_heap/Makefile
 405         lib/plugin-system/Makefile
 406         lib/plugin-system/notification/Makefile
 407         include/Makefile
 408         bindings/Makefile
 409         bindings/python/Makefile
 410         bindings/python/babeltrace/Makefile
 411         tests/Makefile
 412         tests/bin/Makefile
 413         tests/bin/intersection/Makefile
 414         tests/lib/Makefile
 415         tests/utils/Makefile
 416         tests/utils/tap/Makefile
 417         extras/Makefile
 418         extras/valgrind/Makefile
 419         plugins/Makefile
 420         plugins/ctf/Makefile
 421         plugins/ctf/common/Makefile
 422         plugins/ctf/common/btr/Makefile
 423         plugins/ctf/common/metadata/Makefile
 424         plugins/ctf/common/notif-iter/Makefile
 425         plugins/ctf/fs/Makefile
 426         plugins/ctf/lttng-live/Makefile
 427         plugins/muxer/Makefile
 428         plugins/text/Makefile
 429         plugins/trimmer/Makefile
 430         plugins/writer/Makefile
 431         babeltrace.pc
 432         babeltrace-ctf.pc
 433 ])
 434
 435 AC_CONFIG_FILES([converter/babeltrace], [chmod +x converter/babeltrace])
 436 AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
 437 AC_CONFIG_FILES([tests/lib/test_seek_big_trace], [chmod +x tests/lib/test_seek_big_trace])
 438 AC_CONFIG_FILES([tests/lib/test_seek_empty_packet], [chmod +x tests/lib/test_seek_empty_packet])
 439 AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
 440 AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])
 441
 442 AC_CONFIG_FILES([tests/bin/test_trace_read], [chmod +x tests/bin/test_trace_read])
 443 AC_CONFIG_FILES([tests/bin/intersection/test_intersection], [chmod +x tests/bin/intersection/test_intersection])
 444 AC_CONFIG_FILES([tests/bin/intersection/bt_python_helper.py])
 445 AC_CONFIG_FILES([tests/bin/test_packet_seq_num], [chmod +x tests/bin/test_packet_seq_num])
 446 AC_CONFIG_FILES([tests/bin/test_formats], [chmod +x tests/bin/test_formats])
 447
 448 AC_OUTPUT
 449
 450 #
 451 # Mini-report on what will be built.
 452 #
 453
 454 PPRINT_INIT
 455 PPRINT_SET_INDENT(1)
 456 PPRINT_SET_TS(38)
 457
 458 AS_ECHO
 459 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 460 AS_ECHO
 461
 462 PPRINT_SUBTITLE([Features])
 463
 464 # Target architecture we're building for.
 465 target_arch=$host_cpu
 466 [
 467 for f in $CFLAGS; do
 468         if test $f = "-m32"; then
 469                 target_arch="32-bit"
 470         elif test $f = "-m64"; then
 471                 target_arch="64-bit"
 472         fi
 473 done
 474 ]
 475 PPRINT_PROP_STRING([Target architecture], $target_arch)
 476
 477 # API doc
 478 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 479 PPRINT_PROP_BOOL([HTML API documentation], $value)
 480
 481 # python bindings enabled/disabled
 482 test "x$enable_python" = "xyes" && value=1 || value=0
 483 PPRINT_PROP_BOOL([Python bindings], $value)
 484
 485 # python bindings doc enabled/disabled
 486 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 487 PPRINT_PROP_BOOL([Python bindings doc], $value)
 488
 489 # debug info enabled/disabled
 490 test "x$_enable_debug_info" = "xyes" && value=1 || value=0
 491 PPRINT_PROP_BOOL([Debug information output], $value)
 492
 493 # built-in plug-ins enabled/disabled
 494 test "x$built_in_plugins" = "xyes" && value=1 || value=0
 495 PPRINT_PROP_BOOL([Built-in plug-ins], $value)
 496
 497 report_bindir="`eval eval echo $bindir`"
 498 report_libdir="`eval eval echo $libdir`"
 499
 500 # Print the bindir and libdir this `make install' will install into.
 501 AS_ECHO
 502 PPRINT_SUBTITLE([Install directories])
 503 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 504 PPRINT_PROP_STRING([Libraries], [$report_libdir])