configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([babeltrace],[2.0.0-pre],[jeremie dot galarneau at efficios dot com])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([BABELTRACE_LIBRARY_VERSION], [2:0:0])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-ustar])
  16 AM_MAINTAINER_MODE([enable])
  17
  18 # Enable silent rules if available (Introduced in AM 1.11)
  19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  20
  21 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  22
  23 # Checks for C compiler
  24 AC_USE_SYSTEM_EXTENSIONS
  25 AC_SYS_LARGEFILE
  26 AC_PROG_CC
  27 AC_PROG_CC_STDC
  28
  29 # Checks for programs.
  30 AC_PROG_MAKE_SET
  31 LT_INIT
  32 AC_PROG_YACC
  33 AC_PROG_LEX
  34 AC_PROG_MKDIR_P
  35 AC_PROG_LN_S
  36
  37 AX_C___ATTRIBUTE__
  38 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  39         [:],
  40         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  41
  42 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  43 LIBS="$PTHREAD_LIBS $LIBS"
  44 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  45 CC="$PTHREAD_CC"
  46
  47 # Check linker option
  48 AX_APPEND_LINK_FLAGS([-Wl,--no-as-needed], [LD_NO_AS_NEEDED])
  49 AC_SUBST([LD_NO_AS_NEEDED])
  50
  51 AC_HEADER_STDBOOL
  52 AC_CHECK_HEADERS([ \
  53         fcntl.h \
  54         float.h \
  55         libintl.h \
  56         limits.h \
  57         malloc.h \
  58         netdb.h \
  59         netinet/in.h \
  60         stddef.h \
  61         sys/socket.h \
  62 ])
  63
  64 if test ! -f "$srcdir/formats/ctf/metadata/ctf-parser.h"; then
  65         if test x"$(basename "$YACC")" != "xbison -y"; then
  66                 AC_MSG_ERROR([[bison not found and is required when building from git.
  67                 Please install bison]])
  68         fi
  69         AC_PATH_PROG([BISON],[bison])
  70         AX_PROG_BISON_VERSION([2.4], [],[
  71                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
  72         ])
  73 fi
  74
  75 if test ! -f "$srcdir/formats/ctf/metadata/ctf-lexer.c"; then
  76         if test x"$LEX" != "xflex"; then
  77                 AC_MSG_ERROR([[flex not found and is required when building from git.
  78                 Please install flex]])
  79         fi
  80         AC_PATH_PROG([FLEX],[flex])
  81         AX_PROG_FLEX_VERSION([2.5.35], [],[
  82                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
  83         ])
  84 fi
  85
  86
  87 AM_PATH_GLIB_2_0(2.22.0, ,AC_MSG_ERROR([glib is required in order to compile BabelTrace - download it from ftp://ftp.gtk.org/pub/gtk]) , gmodule)
  88
  89 # Check what libraries are required on this platform to link sockets programs.
  90 AX_LIB_SOCKET_NSL
  91
  92 # Checks for typedefs, structures, and compiler characteristics.
  93 AC_C_INLINE
  94 AC_TYPE_PID_T
  95 AC_TYPE_SIZE_T
  96 AC_TYPE_INT16_T
  97 AC_TYPE_INT32_T
  98 AC_TYPE_INT64_T
  99 AC_TYPE_INT8_T
 100 AC_TYPE_OFF_T
 101 AC_TYPE_SSIZE_T
 102 AC_TYPE_UINT16_T
 103 AC_TYPE_UINT32_T
 104 AC_TYPE_UINT64_T
 105 AC_TYPE_UINT8_T
 106
 107 # Checks for library functions.
 108 AC_FUNC_ALLOCA
 109 AC_FUNC_FORK
 110 AC_FUNC_MALLOC
 111 AC_FUNC_MKTIME
 112 AC_FUNC_MMAP
 113 AC_FUNC_REALLOC
 114 AC_FUNC_STRERROR_R
 115 AC_CHECK_FUNCS([ \
 116         atexit \
 117         dirfd \
 118         dup2 \
 119         ftruncate \
 120         gethostbyname \
 121         gethostname \
 122         gettimeofday \
 123         localtime_r \
 124         memchr \
 125         memset \
 126         mkdir \
 127         mkdtemp \
 128         munmap \
 129         rmdir \
 130         setenv \
 131         socket \
 132         strchr \
 133         strdup \
 134         strerror \
 135         strndup \
 136         strnlen \
 137         strrchr \
 138         strtoul \
 139         strtoull \
 140         tzset \
 141         uname \
 142 ])
 143
 144 MINGW32=no
 145 DEFAULT_ENABLE_DEBUG_INFO=yes
 146 AS_CASE([$host_os],
 147   [solaris*|darwin*],
 148     [
 149         DEFAULT_ENABLE_DEBUG_INFO=no
 150     ],
 151   [mingw*],
 152     [
 153         MINGW32=yes
 154     ]
 155 )
 156
 157 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_MINGW], [test "x$MINGW32" = "xyes"])
 158
 159 # Check for uuid in system libs
 160 AC_CHECK_FUNCS([uuid_generate],
 161 [
 162   AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 163   link_with_libuuid=no
 164 ],
 165 [
 166   # First, check the pkg-config module is available, otherwise explicitly check
 167   # for libuuid, or uuid support in the C-library.
 168   PKG_CHECK_MODULES([UUID], [uuid],
 169   [
 170     LIBS="${UUID_LIBS} ${LIBS}"
 171     CFLAGS="${CFLAGS} ${UUID_CFLAGS}"
 172     AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 173     link_with_libuuid=yes
 174   ],
 175   [
 176     # Check for libuuid
 177     AC_CHECK_LIB([uuid], [uuid_generate],
 178     [
 179       AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBUUID], 1, [Has libuuid support.])
 180       link_with_libuuid=yes
 181     ],
 182     [
 183       # libuuid not found, check for uuid_create in libc.
 184       AC_CHECK_LIB([c], [uuid_create],
 185       [
 186         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 187         link_with_libc_uuid=yes
 188       ],
 189       [
 190         # for MinGW32 we have our own internal implementation of uuid using Windows functions.
 191         if test "x$MINGW32" = xno; then
 192           AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 193         fi
 194       ])
 195     ])
 196   ])
 197 ])
 198
 199 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 200 AM_CONDITIONAL([BABELTRACE_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 201
 202 # Check for fmemopen
 203 AC_CHECK_LIB([c], [fmemopen],
 204 [
 205         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 206 ]
 207 )
 208
 209 # Check for open_memstream
 210 AC_CHECK_LIB([c], [open_memstream],
 211 [
 212         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 213 ]
 214 )
 215
 216 # Check for posix_fallocate
 217 AC_CHECK_LIB([c], [posix_fallocate],
 218 [
 219         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_POSIX_FALLOCATE], 1, [Has posix_fallocate support.])
 220 ]
 221 )
 222
 223 # Check for faccessat
 224 AC_CHECK_LIB([c], [faccessat],
 225 [
 226         AC_DEFINE_UNQUOTED([BABELTRACE_HAVE_FACCESSAT], 1, [Has faccessat support.])
 227 ]
 228 )
 229
 230 AC_CHECK_LIB([popt], [poptGetContext], [],
 231         [AC_MSG_ERROR([Cannot find popt.])]
 232 )
 233
 234 # Plugins
 235 AC_ARG_VAR([PLUGINSDIR], [built-in plugins install directory [LIBDIR/babeltrace/plugins]])
 236 AS_IF([test "x$PLUGINSDIR" = x], [PLUGINSDIR='$(libdir)/babeltrace/plugins'])
 237
 238 # For Python
 239 # SWIG version needed or newer:
 240 swig_version=2.0.0
 241
 242 AC_ARG_ENABLE([python-bindings],
 243               [AC_HELP_STRING([--enable-python-bindings],
 244                               [generate Python bindings])],
 245               [enable_python=yes], [enable_python=no])
 246
 247 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 248
 249 AC_ARG_ENABLE([python-bindings-doc],
 250               [AC_HELP_STRING([--enable-python-bindings-doc],
 251                               [generate Python bindings documentation])],
 252               [enable_python_bindings_doc=yes], [enable_python_bindings_doc=no])
 253
 254 if test "x${enable_python:-no}" = xno && test "x${enable_python_bindings_doc:-yes}" = xyes; then
 255   AC_MSG_ERROR([--enable-python-bindings-doc was specified without --enable-python-bindings])
 256 fi
 257
 258 AM_CONDITIONAL([BUILD_PYTHON_BINDINGS_DOC], [test "x${enable_python_bindings_doc:-yes}" = xyes])
 259
 260 if test "x${enable_python:-yes}" = xyes; then
 261   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 262   AM_PATH_PYTHON([3.0], , [AC_MSG_ERROR(Python3 is not available or is not the default Python interpreter on your system. See the README file to learn how to override your distribution's default Python interpreter.)])
 263
 264   AM_PATH_PYTHON_MODULES([PYTHON])
 265   # pythondir is the path where extra modules are to be installed
 266   pythondir=$PYTHON_PREFIX/$PYTHON_MODULES_PATH
 267   # pyexecdir is the path that contains shared objects used by the extra modules
 268   pyexecdir=$PYTHON_EXEC_PREFIX/$PYTHON_MODULES_PATH
 269   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 270   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 271   AS_IF([test -z "$PYTHON_INCLUDE"], [
 272     AS_IF([test -z "$PYTHON_CONFIG"], [
 273       AC_PATH_PROGS([PYTHON_CONFIG],
 274                     [python$PYTHON_VERSION-config python-config],
 275                     [no],
 276                     [`dirname $PYTHON`])
 277       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 278     ])
 279     AC_MSG_CHECKING([python include flags])
 280     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 281     AC_MSG_RESULT([$PYTHON_INCLUDE])
 282   ])
 283 else
 284     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 285 [if you want Python bindings.])
 286
 287 fi
 288
 289 if test "x${enable_python_bindings_doc:-yes}" = xyes; then
 290     AM_CHECK_PYTHON_SPHINX([PYTHON])
 291     AS_IF([test "x$PYTHON_SPHINX_EXISTS" = xno],
 292       AC_MSG_ERROR([The Sphinx package for Python 3 is required to build Python bindings documentation])
 293     )
 294 fi
 295
 296 # Set default enable state for debug info.
 297 # The _enable_debug_info variable is prepended with an underscore to
 298 # avoid clashing with the one generated by AC_ARG_ENABLE.
 299 AS_IF([test "x$DEFAULT_ENABLE_DEBUG_INFO" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])
 300
 301 # Optional debug info feature
 302 # Do _not_ indent the help string below (appears in the configure --help
 303 # output).
 304 AC_ARG_ENABLE([debug-info],
 305 [AC_HELP_STRING([--enable-debug-info], [enable the debug info feature (default on Linux)])]
 306 [AC_HELP_STRING([--disable-debug-info], [disable the debug info feature (default on OS X and Solaris)])],
 307         [AS_IF([test "x$enableval" = xyes], [_enable_debug_info=yes], [_enable_debug_info=no])], [])
 308
 309 AM_CONDITIONAL([ENABLE_DEBUG_INFO], [test "x$_enable_debug_info" = xyes])
 310 AS_IF([test "x$_enable_debug_info" = xyes], [
 311             # Check if libelf and libdw are present
 312             AC_CHECK_LIB([elf], [elf_version], [], [AC_MSG_ERROR(Missing libelf (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 313             AC_CHECK_LIB([dw], [dwarf_begin], [], [AC_MSG_ERROR(Missing libdw (from elfutils >= 0.154) which is required by debug info. You can disable this feature using --disable-debug-info.)])
 314             BT_LIB_ELFUTILS([0], [154], [:], [AC_MSG_ERROR(elfutils >= 0.154 is required to use the debug info feature. You can disable this feature using --disable-debug-info.)])
 315             AC_DEFINE([ENABLE_DEBUG_INFO], [1], [Define to 1 if you enable the 'debug info' feature])
 316 ], [])
 317
 318 AC_ARG_VAR([BUILT_IN_PLUGINS], [Statically-link in-tree plug-ins into the babeltrace binary])
 319 AS_IF([test "x$BUILT_IN_PLUGINS" != x], [
 320 # Built-in plug-ins are only available when the --disable-shared --enable-static options are used.
 321         AS_IF([test "x$enable_static" != "xyes"], [AC_MSG_ERROR(--enable-static must be used to bundle plug-ins in the babeltrace executable)])
 322         AS_IF([test "x$enable_shared" = "xyes"], [AC_MSG_ERROR(--disable-shared must be used to bundle plug-ins in the babeltrace executable)])
 323         built_in_plugins=yes
 324         AC_DEFINE([BT_BUILT_IN_PLUGINS], [1], [Define to 1 to register plug-in attributes in static executable sections])
 325 ])
 326 AM_CONDITIONAL([BUILT_IN_PLUGINS], [test "x$built_in_plugins" = "xyes"])
 327
 328 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.0.0])
 329
 330 LIBS="$LIBS $GMODULE_LIBS"
 331 PACKAGE_CFLAGS="$GMODULE_CFLAGS -Wall -Wformat"
 332 AC_SUBST(PACKAGE_CFLAGS)
 333
 334 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/include -include config.h"
 335 AC_SUBST(DEFAULT_INCLUDES)
 336
 337 babeltraceincludedir="${includedir}/babeltrace"
 338 AC_SUBST(babeltraceincludedir)
 339
 340 babeltracectfincludedir="${includedir}/babeltrace/ctf"
 341 AC_SUBST(babeltracectfincludedir)
 342
 343 babeltracectfwriterincludedir="${includedir}/babeltrace/ctf-writer"
 344 AC_SUBST(babeltracectfwriterincludedir)
 345
 346 babeltracectfirincludedir="${includedir}/babeltrace/ctf-ir"
 347 AC_SUBST(babeltracectfirincludedir)
 348
 349 babeltracepluginincludedir="${includedir}/babeltrace/plugin"
 350 AC_SUBST(babeltracepluginincludedir)
 351
 352 babeltracecomponentincludedir="${includedir}/babeltrace/component"
 353 AC_SUBST(babeltracecomponentincludedir)
 354
 355 program_transform_name="s&babeltrace\.bin&babeltrace&;$program_transform_name"
 356 AC_SUBST(program_transform_name)
 357
 358 # check for Doxygen
 359 AC_ARG_ENABLE(
 360   [api-doc],
 361   [AC_HELP_STRING(
 362     [--enable-api-doc],
 363     [generate and install HTML API documentation]
 364   )],
 365   [enable_api_doc=$enableval],
 366   [enable_api_doc=no]
 367 )
 368 AM_CONDITIONAL([ENABLE_API_DOC], [test "x$enable_api_doc" = "xyes"])
 369
 370 AS_IF([test "x$enable_api_doc" = "xyes"], [
 371   DX_DOXYGEN_FEATURE(ON)
 372   DX_DOT_FEATURE(OFF)
 373   DX_HTML_FEATURE(ON)
 374   DX_CHM_FEATURE(OFF)
 375   DX_CHI_FEATURE(OFF)
 376   DX_MAN_FEATURE(OFF)
 377   DX_RTF_FEATURE(OFF)
 378   DX_XML_FEATURE(OFF)
 379   DX_PDF_FEATURE(OFF)
 380   DX_PS_FEATURE(OFF)
 381   DX_INIT_DOXYGEN([Babeltrace], [$(srcdir)/Doxyfile], [output])
 382 ])
 383
 384 AC_CONFIG_FILES([
 385         Makefile
 386         types/Makefile
 387         compat/Makefile
 388         formats/Makefile
 389         formats/ctf/Makefile
 390         formats/ctf/types/Makefile
 391         formats/ctf-text/Makefile
 392         formats/ctf-text/types/Makefile
 393         formats/ctf-metadata/Makefile
 394         formats/bt-dummy/Makefile
 395         formats/lttng-live/Makefile
 396         formats/ctf/metadata/Makefile
 397         formats/ctf/writer/Makefile
 398         formats/ctf/ir/Makefile
 399         converter/Makefile
 400         doc/Makefile
 401         doc/api/Makefile
 402         doc/api/Doxyfile
 403         doc/bindings/Makefile
 404         doc/bindings/python/Makefile
 405         doc/images/Makefile
 406         lib/Makefile
 407         lib/prio_heap/Makefile
 408         lib/plugin/Makefile
 409         lib/component/Makefile
 410         lib/component/notification/Makefile
 411         include/Makefile
 412         bindings/Makefile
 413         bindings/python/Makefile
 414         bindings/python/babeltrace/Makefile
 415         tests/Makefile
 416         tests/bin/Makefile
 417         tests/bin/intersection/Makefile
 418         tests/lib/Makefile
 419         tests/lib/writer/Makefile
 420         tests/lib/test-plugin-plugins/Makefile
 421         tests/utils/Makefile
 422         tests/utils/tap/Makefile
 423         extras/Makefile
 424         extras/valgrind/Makefile
 425         plugins/Makefile
 426         plugins/ctf/Makefile
 427         plugins/ctf/common/Makefile
 428         plugins/ctf/common/btr/Makefile
 429         plugins/ctf/common/metadata/Makefile
 430         plugins/ctf/common/notif-iter/Makefile
 431         plugins/ctf/fs/Makefile
 432         plugins/ctf/lttng-live/Makefile
 433         plugins/muxer/Makefile
 434         plugins/text/Makefile
 435         plugins/trimmer/Makefile
 436         plugins/writer/Makefile
 437         babeltrace.pc
 438         babeltrace-ctf.pc
 439 ])
 440
 441 #AC_CONFIG_FILES([converter/babeltrace], [chmod +x converter/babeltrace])
 442 AC_CONFIG_FILES([tests/lib/test_ctf_writer_complete], [chmod +x tests/lib/test_ctf_writer_complete])
 443 AC_CONFIG_FILES([tests/lib/test_plugin_complete], [chmod +x tests/lib/test_plugin_complete])
 444 AC_CONFIG_FILES([tests/lib/test_seek_big_trace], [chmod +x tests/lib/test_seek_big_trace])
 445 AC_CONFIG_FILES([tests/lib/test_seek_empty_packet], [chmod +x tests/lib/test_seek_empty_packet])
 446 AC_CONFIG_FILES([tests/lib/test_dwarf_complete], [chmod +x tests/lib/test_dwarf_complete])
 447 AC_CONFIG_FILES([tests/lib/test_bin_info_complete], [chmod +x tests/lib/test_bin_info_complete])
 448
 449 AC_CONFIG_FILES([tests/bin/test_trace_read], [chmod +x tests/bin/test_trace_read])
 450 AC_CONFIG_FILES([tests/bin/intersection/test_intersection], [chmod +x tests/bin/intersection/test_intersection])
 451 AC_CONFIG_FILES([tests/bin/intersection/bt_python_helper.py])
 452 AC_CONFIG_FILES([tests/lib/writer/bt_python_helper.py])
 453 AC_CONFIG_FILES([tests/bin/test_packet_seq_num], [chmod +x tests/bin/test_packet_seq_num])
 454 AC_CONFIG_FILES([tests/bin/test_formats], [chmod +x tests/bin/test_formats])
 455
 456 AC_OUTPUT
 457
 458 #
 459 # Mini-report on what will be built.
 460 #
 461
 462 PPRINT_INIT
 463 PPRINT_SET_INDENT(1)
 464 PPRINT_SET_TS(38)
 465
 466 AS_ECHO
 467 AS_ECHO("${PPRINT_COLOR_BLDBLU}Babeltrace $PACKAGE_VERSION$PPRINT_COLOR_RST")
 468 AS_ECHO
 469
 470 PPRINT_SUBTITLE([Features])
 471
 472 # Target architecture we're building for.
 473 target_arch=$host_cpu
 474 [
 475 for f in $CFLAGS; do
 476         if test $f = "-m32"; then
 477                 target_arch="32-bit"
 478         elif test $f = "-m64"; then
 479                 target_arch="64-bit"
 480         fi
 481 done
 482 ]
 483 PPRINT_PROP_STRING([Target architecture], $target_arch)
 484
 485 # API doc
 486 test "x$enable_api_doc" = "xyes" && value=1 || value=0
 487 PPRINT_PROP_BOOL([HTML API documentation], $value)
 488
 489 # python bindings enabled/disabled
 490 test "x$enable_python" = "xyes" && value=1 || value=0
 491 PPRINT_PROP_BOOL([Python bindings], $value)
 492
 493 # python bindings doc enabled/disabled
 494 test "x$enable_python_bindings_doc" = "xyes" && value=1 || value=0
 495 PPRINT_PROP_BOOL([Python bindings doc], $value)
 496
 497 # debug info enabled/disabled
 498 test "x$_enable_debug_info" = "xyes" && value=1 || value=0
 499 PPRINT_PROP_BOOL([Debug information output], $value)
 500
 501 # built-in plug-ins enabled/disabled
 502 test "x$built_in_plugins" = "xyes" && value=1 || value=0
 503 PPRINT_PROP_BOOL([Built-in plug-ins], $value)
 504
 505 report_bindir="`eval eval echo $bindir`"
 506 report_libdir="`eval eval echo $libdir`"
 507
 508 # Print the bindir and libdir this `make install' will install into.
 509 AS_ECHO
 510 PPRINT_SUBTITLE([Install directories])
 511 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 512 PPRINT_PROP_STRING([Libraries], [$report_libdir])