1 # SPDX-License-Identifier: LGPL-2.1-only
4 m4_define([V_MAJOR], [2])
5 m4_define([V_MINOR], [13])
6 m4_define([V_PATCH], [0])
7 m4_define([V_EXTRA], [pre])
8 m4_define([V_NAME], [[Codename TBD]])
9 m4_define([V_DESC], [[Description TBD]])
11 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
12 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
15 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])
17 dnl Substitute minor/major/patchlevel version numbers
18 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
19 AC_SUBST([MINOR_VERSION], [V_MINOR])
20 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
22 # Following the numbering scheme proposed by libtool for the library version
23 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
24 # This is the library version of liblttng-ust.
25 m4_define([UST_LIB_V_MAJOR], [1])
26 m4_define([UST_LIB_V_MINOR], [0])
27 m4_define([UST_LIB_V_PATCH], [0])
29 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [UST_LIB_V_MAJOR:UST_LIB_V_MINOR:UST_LIB_V_PATCH])
30 AC_DEFINE([CONFIG_LTTNG_UST_LIBRARY_VERSION_MAJOR], [UST_LIB_V_MAJOR], [Major SONAME number of the ust library])
31 # note: remember to update tracepoint.h dlopen() to match this version
32 # number. TODO: eventually automate by exporting the major number.
34 # This is the library version of liblttng-ust-ctl, used internally by
35 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
36 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [5:0:0])
38 AC_CONFIG_HEADERS([include/config.h include/lttng/ust-config.h])
39 AC_CONFIG_AUX_DIR([config])
40 AC_CONFIG_MACRO_DIR([m4])
41 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
46 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
47 AM_MAINTAINER_MODE([enable])
49 # Enable silent rules by default
50 AM_SILENT_RULES([yes])
52 # Checks for C compiler
53 AC_USE_SYSTEM_EXTENSIONS
56 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
57 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
59 AX_CXX_COMPILE_STDCXX([11])
61 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
63 # Check if the compiler support weak symbols
66 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
67 AC_MSG_ERROR([Your platform doesn't support weak symbols.])
70 # Checks for programs.
77 AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
78 AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
80 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
81 AC_ARG_ENABLE([libtool-linkdep-fixup], [
82 AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
84 libtool_fixup=$enableval
89 AS_IF([test "x$libtool_fixup" = "xyes"], [
90 libtool_m4="$srcdir/m4/libtool.m4"
91 libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
92 AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
93 libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
95 AS_IF([test $libtool_flag_pattern_count -ne 0], [
96 AC_MSG_RESULT([$libtool_flag_pattern_count])
97 AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
98 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
100 AC_MSG_RESULT([none])
103 LT_INIT([disable-static])
105 AC_MSG_CHECKING([whether shared libraries are enabled])
106 AS_IF([test "x$enable_shared" = "xyes"], [
110 AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
113 # Checks for typedefs, structures, and compiler characteristics.
129 AC_CHECK_TYPES([ptrdiff_t])
132 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
134 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
136 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
138 # Checks for library functions.
168 # Check for pthread_setname_np and its signature
169 LTTNG_PTHREAD_SETNAME_NP
170 LTTNG_PTHREAD_GETNAME_NP
172 # AC_FUNC_MALLOC causes problems when cross-compiling.
175 # Checks for header files.
189 # Set architecture specific options
211 # Set os specific options
213 [freebsd*], [NO_NUMA=1]
216 # Configuration options, which will be installed in the config.h
217 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
219 # Checks for libraries.
220 AC_CHECK_LIB([dl], [dlopen], [
224 #libdl not found, check for dlopen in libc.
225 AC_CHECK_LIB([c], [dlopen], [
229 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
234 # Check if libdl has dlmopen support.
235 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
236 AC_CHECK_LIB([$libdl_name], [dlmopen],
237 [AC_DEFINE([HAVE_DLMOPEN], [1])]
241 AC_CHECK_HEADER([dlfcn.h])
242 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
243 AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
247 ac_cv_have_decl_RTLD_DI_LINKMAP="no"
250 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
252 # Require URCU >= 0.12 for DEFINE_URCU_TLS_INIT
253 PKG_CHECK_MODULES([URCU], [liburcu >= 0.12])
256 AS_IF([test "x$NO_NUMA" = "x1"],[
257 AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
260 AC_ARG_ENABLE([numa], [
261 AS_HELP_STRING([--disable-numa], [disable NUMA support])
263 enable_numa=$enableval
268 AS_IF([test "x$enable_numa" = "xyes"], [
269 # numa - check that numa lib is available
270 AC_CHECK_LIB([numa], [numa_available], [],
271 [AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
274 AM_CONDITIONAL([HAVE_LIBNUMA], [test "x$have_libnuma" = "xyes"])
276 # optional linux/perf_event.h
277 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
279 # Perf event counters are supported on all architectures supported by
280 # perf, using the read system call as fallback.
281 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
283 AH_TEMPLATE([HAVE_PERF_EVENT], ["Perf event integration via perf_event.h"])
284 AS_IF([test "x$have_perf_event" = "xyes"], [
285 AC_DEFINE([HAVE_PERF_EVENT], [1])
288 # Check for JNI header files if requested
289 AC_ARG_ENABLE([jni-interface], [
290 AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
292 jni_interface=$enableval
297 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
300 AC_ARG_ENABLE([java-agent-jul], [
301 AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
303 java_agent_jul=$enableval
308 AC_ARG_ENABLE([java-agent-log4j], [
309 AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
311 java_agent_log4j=$enableval
316 AC_ARG_ENABLE([java-agent-all], [
317 AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
319 java_agent_jul=$enableval
320 java_agent_log4j=$enableval
323 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
324 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
325 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
327 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
332 AC_ARG_VAR([CLASSPATH], [Java class path])
335 for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
337 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
340 saved_CPPFLAGS="$CPPFLAGS"
341 CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
343 CPPFLAGS="$saved_CPPFLAGS"
346 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
348 AS_IF([test "x$java_agent_log4j" = "xyes"], [
350 AX_CHECK_CLASS([org.apache.log4j.Logger])
351 AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
352 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
356 # Option to build the python agent
357 AC_ARG_ENABLE([python-agent], [
358 AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
360 python_agent=$enableval
362 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
363 AS_IF([test "x$python_agent" = "xyes"], [
364 AM_PATH_PYTHON([2.7])
369 AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
376 AS_IF([test "x$with_sdt" = "xyes"], [
377 AC_MSG_CHECKING([STAP_PROBEV()])
378 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
379 #define SDT_USE_VARIADIC
383 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
387 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
390 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
394 AC_ARG_WITH([lttng-system-rundir], [
395 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
397 lttng_system_rundir="$withval"
399 lttng_system_rundir="/var/run/lttng"
401 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
402 [LTTng system runtime directory])
404 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
405 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
407 # Enable building examples
411 [--disable-examples],
412 [Do not build and install examples]
414 [enable_examples=$enableval],
415 [enable_examples=yes]
418 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])
420 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
421 # is not distributed in tarballs.
422 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
423 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
425 # Enable building man pages (user's intention).
429 [--disable-man-pages],
430 [Do not build and install man pages (already built in a distributed tarball)]
432 [man_pages_opt=$enableval],
436 # Check for asciidoc and xmlto if we enabled building the man pages.
437 have_asciidoc_xmlto=no
438 warn_prebuilt_man_pages=no
440 AS_IF([test "x$man_pages_opt" = "xyes"], [
441 AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
442 AC_PATH_PROG([XMLTO], [xmlto], [no])
444 AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
445 AS_IF([test "x$in_git_repo" = "xyes"], [
446 # This is an error because we're in the Git repo, which
447 # means the man pages are not already generated for us,
448 # thus asciidoc/xmlto are required because we were asked
449 # to build the man pages.
451 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
452 --disable-man-pages to disable building the man pages, in which case
453 they will not be installed.
456 # Only warn here: since we're in the tarball, the man
457 # pages should already be generated at this point, thus
458 # asciidoc/xmlto are not strictly required.
459 warn_prebuilt_man_pages=yes
462 have_asciidoc_xmlto=yes
466 # Export man page build condition: build the man pages if the user
467 # asked for it, and if the tools are available.
468 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
469 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
471 AM_CFLAGS="-Wall $URCU_CFLAGS $PTHREAD_CFLAGS"
474 AM_CXXFLAGS="$AM_CFLAGS"
475 AC_SUBST(AM_CXXFLAGS)
477 # The order in which the include folders are searched is important.
478 # The top_builddir should always be searched first in the event that a build
479 # time generated file is included.
480 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
481 AC_SUBST(AM_CPPFLAGS)
483 AC_SUBST(JNI_CPPFLAGS)
488 doc/examples/Makefile
491 include/lttng/ust-version.h
495 libringbuffer/Makefile
496 liblttng-ust-comm/Makefile
497 liblttng-ust/Makefile
498 liblttng-ust-ctl/Makefile
499 liblttng-ust-fork/Makefile
500 liblttng-ust-dl/Makefile
501 liblttng-ust-fd/Makefile
502 liblttng-ust-java/Makefile
503 liblttng-ust-java-agent/Makefile
504 liblttng-ust-java-agent/java/Makefile
505 liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
506 liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
507 liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
508 liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
509 liblttng-ust-java-agent/jni/Makefile
510 liblttng-ust-java-agent/jni/common/Makefile
511 liblttng-ust-java-agent/jni/jul/Makefile
512 liblttng-ust-java-agent/jni/log4j/Makefile
513 liblttng-ust-libc-wrapper/Makefile
514 liblttng-ust-cyg-profile/Makefile
515 liblttng-ust-python-agent/Makefile
516 python-lttngust/Makefile
517 python-lttngust/setup.py
518 python-lttngust/lttngust/__init__.py
521 tests/compile/Makefile
522 tests/compile/ctf-types/Makefile
523 tests/compile/hello.cxx/Makefile
524 tests/compile/hello/Makefile
525 tests/compile/hello-many/Makefile
526 tests/compile/same_line_tracepoint/Makefile
527 tests/compile/test-app-ctx/Makefile
528 tests/benchmark/Makefile
529 tests/unit/gcc-weak-hidden/Makefile
530 tests/unit/libmsgpack/Makefile
532 tests/unit/libringbuffer/Makefile
533 tests/unit/pthread_name/Makefile
534 tests/unit/snprintf/Makefile
535 tests/unit/ust-elf/Makefile
545 # Mini-report on what will be built.
553 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"V_NAME\"$PPRINT_COLOR_RST")
559 PPRINT_SUBTITLE([System])
561 PPRINT_PROP_STRING([Target architecture], $host_cpu)
563 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
564 PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
568 PPRINT_SUBTITLE([Features])
571 test "x$with_sdt" = "xyes" && value=1 || value=0
572 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
574 test "x$java_agent_jul" = xyes && value=1 || value=0
575 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
577 test "x$java_agent_log4j" = xyes && value=1 || value=0
578 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
580 test "x$jni_interface" = xyes && value=1 || value=0
581 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
583 test "x$python_agent" = xyes && value=1 || value=0
584 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
586 test "x$have_perf_event" = "xyes" && value=1 || value=0
587 PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
589 test "x$enable_numa" = xyes && value=1 || value=0
590 PPRINT_PROP_BOOL([NUMA], $value)
595 test "x$enable_examples" = xyes && value=1 || value=0
596 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
598 # man pages build enabled/disabled
599 m4_pushdef([build_man_pages_msg], [Build and install man pages])
601 AS_IF([test "x$man_pages_opt" != "xno"], [
602 AS_IF([test "x$in_git_repo" = "xyes"], [
603 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
605 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
606 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
608 PPRINT_PROP_STRING([build_man_pages_msg],
609 [${PPRINT_COLOR_BLDGRN}yes (already built)],
610 $PPRINT_COLOR_SUBTITLE)
614 PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
617 m4_popdef([build_man_pages_msg])
621 report_bindir="`eval eval echo $bindir`"
622 report_libdir="`eval eval echo $libdir`"
624 # Print the bindir and libdir this `make install' will install into.
626 PPRINT_SUBTITLE([Install directories])
627 PPRINT_PROP_STRING([Binaries], [$report_bindir])
628 PPRINT_PROP_STRING([Libraries], [$report_libdir])
631 PPRINT_SUBTITLE([System directories])
633 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
637 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
639 PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
641 Note that the man pages are already built in this distribution tarball,
642 therefore asciidoc and xmlto are only needed if you intend to modify
645 Use --disable-man-pages to completely disable building and installing