configure.ac

   1 dnl SPDX-License-Identifier: GPL-2.0-only
   2 AC_PREREQ([2.64])
   3 AC_INIT([lttng-tools],[2.14.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   4
   5 AC_CONFIG_HEADERS([include/config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18
  19 ##                   ##
  20 ## C compiler checks ##
  21 ##                   ##
  22
  23 # Choose the C compiler
  24 AC_PROG_CC
  25 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  26 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  27
  28 # Make sure the C compiler supports C99
  29 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
  30
  31 # Enable available system extensions and LFS support
  32 AC_USE_SYSTEM_EXTENSIONS
  33 AC_SYS_LARGEFILE
  34
  35 # Make sure the C compiler supports __attribute__
  36 AX_C___ATTRIBUTE__
  37 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
  38   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  39
  40 # Make sure we have pthread support
  41 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
  42
  43 # Checks for typedefs, structures, and compiler characteristics.
  44 AC_C_INLINE
  45 AC_TYPE_INT32_T
  46 AC_TYPE_INT64_T
  47 AC_TYPE_MODE_T
  48 AC_TYPE_OFF_T
  49 AC_TYPE_PID_T
  50 AC_TYPE_SIZE_T
  51 AC_TYPE_SSIZE_T
  52 AC_TYPE_UID_T
  53 AC_TYPE_UINT16_T
  54 AC_TYPE_UINT32_T
  55 AC_TYPE_UINT64_T
  56 AC_TYPE_UINT8_T
  57
  58 # Detect warning flags supported by the C and C++ compilers and append them to
  59 # WARN_CFLAGS and WARN_CXXFLAGS.
  60 m4_define([WARN_FLAGS_LIST], [ dnl
  61   -Wall dnl
  62   dnl We currently get this warning when building with Clang:
  63   dnl
  64   dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration]
  65   dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL;
  66   dnl            ^
  67   -Wno-incomplete-setjmp-declaration dnl
  68   -Wdiscarded-qualifiers dnl
  69   -Wmissing-declarations dnl
  70   -Wmissing-prototypes dnl
  71   -Wmissing-parameter-type dnl
  72   -Wshadow dnl
  73   -Wno-gnu-folding-constant dnl
  74 ])
  75
  76 # Pass -Werror as an extra flag during the test: this is needed to make the
  77 # -Wunknown-warning-option diagnostic fatal with clang.
  78 AC_LANG_PUSH([C])
  79 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CFLAGS], [-Werror])
  80 AC_LANG_POP([C])
  81
  82 # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is
  83 # written in such a way that it triggers warnings with the following warning
  84 # flags.  So they would always end up disabled if we put them there, because
  85 # the test program would not build.
  86 #
  87 # Enable them here unconditionally.  They are supported by GCC >= 4.8 and by
  88 # Clang >= 3.3 (required by the project) and are only valid for C code.
  89 WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition -Wstrict-prototypes"
  90
  91 # Disable 'strict aliasing' if the C compiler supports it.
  92 AC_LANG_PUSH([C])
  93 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CFLAGS], [-Werror])
  94 AC_LANG_POP([C])
  95
  96
  97 ##                     ##
  98 ## C++ compiler checks ##
  99 ##                     ##
 100
 101 # Find a C++11 compiler with GNU extensions (-std=gnu++11)
 102 AX_CXX_COMPILE_STDCXX([11], [ext], [mandatory])
 103
 104 # Pass -Werror as an extra flag during the test: this is needed to make the
 105 # -Wunknown-warning-option diagnostic fatal with clang.
 106 AC_LANG_PUSH([C++])
 107 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CXXFLAGS], [-Werror])
 108 AC_LANG_POP([C++])
 109
 110 # Disable 'strict aliasing' if the C++ compiler supports it.
 111 AC_LANG_PUSH([C++])
 112 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CXXFLAGS], [-Werror])
 113 AC_LANG_POP([C++])
 114
 115
 116 # When given, add -Werror to WARN_CFLAGS and WARN_CXXFLAGS.
 117 AC_ARG_ENABLE([Werror],[
 118   AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])
 119 ])
 120
 121 AS_IF([test "x$enable_Werror" = "xyes"], [
 122   WARN_CFLAGS="${WARN_CFLAGS} -Werror"
 123   WARN_CXXFLAGS="${WARN_CXXFLAGS} -Werror"
 124 ])
 125
 126 # Checks for programs.
 127 AC_PROG_GREP
 128 AC_PROG_MAKE_SET
 129 AC_PROG_SED
 130 AC_PATH_PROG([report_fold], [fold])
 131 LT_INIT
 132
 133 # Check for objcopy, required by the base address statedump and dynamic linker tests
 134 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
 135 AS_IF([test "x$OBJCOPY" = "xno"],
 136         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
 137 )
 138 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
 139
 140 # check for pgrep
 141 AC_PATH_PROG([PGREP], [pgrep], [no])
 142 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
 143
 144 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 145 # is not distributed in tarballs
 146 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 147 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 148
 149 # check for bison
 150 AC_PROG_YACC
 151 BISON=$YACC
 152 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
 153
 154 AS_IF([test "x$have_bison" != "xyes"], [
 155   AS_IF([test "x$in_git_repo" = "xyes"], [
 156     AC_MSG_FAILURE([
 157 Bison >= 2.4 is required when building from the Git repository. You can
 158 set the YACC variable to override automatic detection.
 159     ])
 160   ], [
 161     AC_MSG_WARN([
 162 Missing Bison >= 2.4. Note that the parser files are already built in
 163 this distribution tarball, so Bison is only needed if you intend to
 164 modify their sources. You can set the YACC variable to override automatic
 165 detection.
 166     ])
 167   ])
 168 ])
 169 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 170
 171 # check for flex
 172 # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a
 173 # problem since the argument is silently ignored by older versions.
 174 AC_PROG_LEX([noyywrap])
 175 FLEX=$LEX
 176 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 177
 178 AS_IF([test "x$have_flex" != "xyes"], [
 179   AS_IF([test "x$in_git_repo" = "xyes"], [
 180     AC_MSG_FAILURE([
 181 Flex >= 2.5.35 is required when building from the Git repository. You can
 182 set the LEX variable to override automatic detection.
 183     ])
 184   ], [
 185     AC_MSG_WARN([
 186 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 187 this distribution tarball, so Flex is only needed if you intend to
 188 modify their sources. You can set the LEX variable to override automatic
 189 detection.
 190     ])
 191   ])
 192 ])
 193 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 194
 195
 196
 197 # Check if linker has the -no-pie option.
 198 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 199 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 200
 201 AX_LIB_SOCKET_NSL
 202
 203 LT_NO_UNDEFINED=""
 204 AS_CASE([$host_os],
 205   [cygwin*],
 206     [
 207       LT_NO_UNDEFINED="-no-undefined"
 208     ],
 209   [cygwin*|darwin*|mingw*|solaris*],
 210     [
 211       # On platforms where we only support the relayd, disable the other binaries by default
 212       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 213       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 214       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 215       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 216       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 217       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 218     ]
 219 )
 220
 221 AC_SUBST(LT_NO_UNDEFINED)
 222
 223 # Compute minor/major/patchlevel version numbers
 224 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 225 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 226 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 227
 228 AC_SUBST([MAJOR_VERSION], [$major_version])
 229 AC_SUBST([MINOR_VERSION], [$minor_version])
 230 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 231 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 232 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 233 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 234
 235 version_name="O-Beer"
 236 version_description="An alcoholic drink made from yeast-fermented malt flavored with hops."
 237 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 238
 239 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 240 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 241
 242 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 243 AC_ARG_ENABLE(libtool-linkdep-fixup,
 244         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 245                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 246         libtool_fixup=$enableval,
 247         libtool_fixup=yes)
 248
 249 AS_IF([test "x$libtool_fixup" = "xyes"],
 250             [
 251             libtool_m4="$srcdir/m4/libtool.m4"
 252             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 253             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 254             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 255             AS_IF([test $libtool_flag_pattern_count -ne 0],
 256             [
 257                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 258                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 259                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 260                   ],
 261                   [
 262                   AC_MSG_RESULT([none])
 263                   ])
 264             ])
 265
 266 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 267
 268 AC_CHECK_HEADERS([ \
 269         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 270         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 271         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 272         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 273         sys/mount.h sys/param.h sys/time.h elf.h
 274 ])
 275
 276 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 277
 278 # Basic functions check
 279 AC_CHECK_FUNCS([ \
 280         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 281         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 282         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 283         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 284         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 285         sched_getcpu sysconf sync_file_range
 286 ])
 287
 288 # Check for pthread_setname_np and pthread_getname_np
 289 LTTNG_PTHREAD_SETNAME_NP
 290 LTTNG_PTHREAD_GETNAME_NP
 291
 292 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 293 # add -lrt to LIBS
 294 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 295
 296 # Checks for dl.
 297 AC_CHECK_LIB([dl], [dlopen], [
 298         have_libdl=yes
 299         libdl_name=dl
 300         DL_LIBS="-ldl"
 301 ], [
 302         # libdl not found, check for dlopen in libc.
 303         AC_CHECK_LIB([c], [dlopen], [
 304                 have_libc_dl=yes
 305                 libdl_name=c
 306                 DL_LIBS="-lc"
 307         ], [
 308                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 309         ])
 310 ])
 311 AC_SUBST(DL_LIBS)
 312
 313 # Check if libdl has dlmopen support.
 314 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 315 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 316         AC_DEFINE([HAVE_DLMOPEN], [1])
 317         HAVE_DLMOPEN=1
 318 ], [
 319         HAVE_DLMOPEN=0
 320 ])
 321 AC_SUBST(HAVE_DLMOPEN)
 322
 323 # Babeltrace viewer check
 324 AC_ARG_WITH([babeltrace-bin],
 325         AS_HELP_STRING([--with-babeltrace-bin],
 326         [Location of the babeltrace viewer executable (including the filename)]),
 327         [BABELTRACE_BIN="$withval"],
 328         [BABELTRACE_BIN=''])
 329 AC_SUBST([BABELTRACE_BIN])
 330
 331 AC_ARG_WITH([babeltrace2-bin],
 332         AS_HELP_STRING([--with-babeltrace2-bin],
 333         [Location of the babeltrace2 viewer executable (including the filename)]),
 334         [BABELTRACE2_BIN="$withval"],
 335         [BABELTRACE2_BIN=''])
 336 AC_SUBST([BABELTRACE2_BIN])
 337
 338 AC_ARG_WITH([consumerd32-bin],
 339         AS_HELP_STRING([--with-consumerd32-bin],
 340         [Location of the 32-bit consumerd executable (including the filename)]),
 341         [CONSUMERD32_BIN="$withval"],
 342         [CONSUMERD32_BIN=''])
 343 AC_SUBST([CONSUMERD32_BIN])
 344
 345 AC_ARG_WITH([consumerd64-bin],
 346         AS_HELP_STRING([--with-consumerd64-bin],
 347         [Location of the 64-bit consumerd executable (including the filename)]),
 348         [CONSUMERD64_BIN="$withval"],
 349         [CONSUMERD64_BIN=''])
 350 AC_SUBST([CONSUMERD64_BIN])
 351
 352 AC_ARG_WITH([consumerd32-libdir],
 353         AS_HELP_STRING([--with-consumerd32-libdir],
 354         [Directory containing the 32-bit consumerd libraries]),
 355         [CONSUMERD32_LIBDIR="$withval"],
 356         [CONSUMERD32_LIBDIR=''])
 357 AC_SUBST([CONSUMERD32_LIBDIR])
 358
 359 AC_ARG_WITH([consumerd64-libdir],
 360         AS_HELP_STRING([--with-consumerd64-libdir],
 361         [Directory containing the 64-bit consumerd libraries]),
 362         [CONSUMERD64_LIBDIR="$withval"],
 363         [CONSUMERD64_LIBDIR=''])
 364 AC_SUBST([CONSUMERD64_LIBDIR])
 365
 366 AC_ARG_WITH([sessiond-bin],
 367         AS_HELP_STRING([--with-sessiond-bin],
 368         [Location of the sessiond executable (including the filename)]),
 369         [SESSIOND_BIN="$withval"],
 370         [SESSIOND_BIN=''])
 371 AC_SUBST([SESSIOND_BIN])
 372
 373 AC_ARG_WITH([lttng-system-rundir],
 374         AS_HELP_STRING([--with-lttng-system-rundir],
 375         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 376         [LTTNG_SYSTEM_RUNDIR="$withval"],
 377         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 378 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 379
 380 AC_ARG_ENABLE([test-java-agent-jul],
 381         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 382         [test_java_agent_jul=$enableval],
 383         [test_java_agent_jul=no]
 384 )
 385
 386 AC_ARG_ENABLE([test-java-agent-log4j],
 387         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 388         [test_java_agent_log4j=$enableval],
 389         [test_java_agent_log4j=no]
 390 )
 391
 392 AC_ARG_ENABLE([test-java-agent-all],
 393         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 394         [test_java_agent_jul=$enableval
 395          test_java_agent_log4j=$enableval],
 396         [:]
 397 )
 398
 399 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 400 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 401 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 402 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 403 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 404 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
 405 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 406 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 407
 408 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 409         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 410         $1="$2"
 411         AC_SUBST([$1])
 412 ])
 413
 414 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 415         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 416         $1="$2"
 417         AC_SUBST([$1])
 418 ])
 419
 420 # Default values
 421 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 422 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 423 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 424 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 425 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 426 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 427 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 428 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 429 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 430 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 431 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 432 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 433 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 434 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 435 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 436 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 437 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 438 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 439 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 440 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 441 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 442 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 443 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 444 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 445 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 446 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 447 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 448 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 449 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 450 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 451 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 452 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 453 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 454 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 455 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 456 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 457 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 458 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 459 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 460 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 461 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 462 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 463 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 464 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 465 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 466 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 467 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 468 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 469 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 470 _AC_DEFINE_AND_SUBST([DEFAULT_EVENT_NOTIFIER_ERROR_COUNT_MAP_SIZE], [4096])
 471
 472 # Command short descriptions
 473 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to be recorded])
 474 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_TRIGGER], [Add a trigger])
 475 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a recording session])
 476 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a recording session])
 477 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Destroy recording sessions])
 478 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable channels])
 479 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable recording event rules])
 480 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a recording session rotation schedule])
 481 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable a channel])
 482 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable recording event rules])
 483 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a recording session rotation schedule])
 484 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Show the help of a command])
 485 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List recording sessions and instrumentation points])
 486 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST_TRIGGERS], [List triggers])
 487 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load recording session configurations])
 488 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Regenerate specific recording session data])
 489 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REMOVE_TRIGGER], [Remove a trigger])
 490 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive the current trace chunk of a recording session])
 491 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save recording session configurations])
 492 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set the current recording session])
 493 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Take a recording session snapshot])
 494 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start a recording session])
 495 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Show the status of the current recording session])
 496 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop a recording session])
 497 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Allow specific processes to record events])
 498 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Disallow specific processes to record events])
 499 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show LTTng-tools version information])
 500 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Launch a trace reader])
 501
 502 if test "x$prefix" = "xNONE"; then
 503         prefix=$ac_default_prefix
 504 fi
 505 CONFDIR=`eval echo $sysconfdir`
 506 AC_SUBST(CONFDIR)
 507 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 508
 509 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 510
 511 # Check libpopt
 512 PKG_CHECK_MODULES([POPT], [popt],
 513   [
 514     dnl PKG_CHECK_MODULES defines POPT_LIBS
 515   ],
 516   [
 517     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 518     AC_MSG_WARN([Finding libpopt without pkg-config.])
 519     AC_CHECK_LIB([popt],
 520       [poptGetContext],
 521       [POPT_LIBS="-lpopt"],
 522       [
 523         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 524       ]
 525     )
 526   ]
 527 )
 528 AC_SUBST(POPT_LIBS)
 529
 530 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 531
 532 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 533
 534 # URCU library version needed or newer
 535 PKG_CHECK_MODULES([URCU], [liburcu >= 0.11])
 536 PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.11])
 537 AM_CPPFLAGS="$AM_CPPFLAGS $URCU_CFLAGS"
 538
 539 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 540 # it can be explicitly disabled with --without-kmod
 541 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 542 AC_ARG_WITH([kmod],
 543   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 544   [],
 545   [with_kmod=check]
 546 )
 547
 548 AS_IF([test "x$with_kmod" != "xno"],
 549   [
 550     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 551       [
 552         AC_DEFINE([HAVE_KMOD], [1])
 553         KMOD_LIBS="-lkmod"
 554       ],
 555       [
 556         if test "x$with_kmod" != xcheck; then
 557           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 558         else
 559           with_kmod=no
 560         fi
 561       ]
 562     )
 563   ]
 564 )
 565 AC_SUBST(KMOD_LIBS)
 566
 567 # Check for liblttng-ust-ctl, fail if it's not found,
 568 # it can be explicitly disabled with --without-lttng-ust
 569 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 570 AC_ARG_WITH([lttng-ust],
 571   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 572   [],
 573   [with_lttng_ust=yes]
 574 )
 575
 576 AS_IF([test "x$with_lttng_ust" = "xyes"], [
 577   AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 578
 579   # Check for liblttng-ust
 580   PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
 581
 582   # Check for liblttng-ust-ctl
 583   PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
 584
 585   AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
 586 ])
 587
 588 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 589
 590
 591 # Check for fmemopen
 592 AC_CHECK_LIB([c], [fmemopen],
 593 [
 594         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 595 ]
 596 )
 597
 598 # check for libpfm
 599 AC_CHECK_LIB([pfm], [pfm_initialize],
 600              [
 601               have_libpfm=yes
 602               ])
 603 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 604
 605 # For Python
 606 # SWIG version needed or newer:
 607 swig_version=2.0.0
 608
 609 AC_ARG_ENABLE([python-bindings],
 610               [AS_HELP_STRING([--enable-python-bindings],
 611                               [compile Python bindings])],
 612               [enable_python_binding=$enableval], [enable_python_binding=no])
 613
 614 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 615
 616 if test "x$enable_python_binding" = xyes; then
 617   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 618   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 619   AM_PATH_PYTHON([3.0])
 620
 621   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 622   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 623   AS_IF([test -z "$PYTHON_INCLUDE"], [
 624     AS_IF([test -z "$PYTHON_CONFIG"], [
 625       AC_PATH_PROGS([PYTHON_CONFIG],
 626                     [python$PYTHON_VERSION-config python-config],
 627                     [no],
 628                     [`dirname $PYTHON`])
 629       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 630     ])
 631     AC_MSG_CHECKING([python include flags])
 632     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 633     AC_MSG_RESULT([$PYTHON_INCLUDE])
 634   ])
 635
 636 else
 637     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 638 [if you want Python bindings.])
 639
 640 fi
 641
 642 # Epoll check. If not present, the build will fallback on poll() API
 643 AX_HAVE_EPOLL(
 644         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 645         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 646 )
 647 AX_CONFIG_FEATURE(
 648         [epoll], [This platform supports epoll(7)],
 649         [HAVE_EPOLL], [This platform supports epoll(7).]
 650 )
 651
 652 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 653         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 654         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 655 )
 656 AX_CONFIG_FEATURE(
 657         [dirfd], [Use directory file descriptors],
 658         [HAVE_DIRFD], [This platform supports directory file descriptors.]
 659 )
 660
 661 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 662 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 663
 664 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 665         AX_JAVA_OPTIONS
 666         AX_PROG_JAVAC
 667         AX_PROG_JAVA
 668         AX_PROG_JAR
 669
 670         AX_CHECK_CLASSPATH
 671
 672         # Check for Java UST agent common class first
 673         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 674         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 675                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 676         fi
 677
 678         if test "x$test_java_agent_jul" = "xyes"; then
 679                 # Check for JUL agent class
 680                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 681                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 682                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 683                 fi
 684         fi
 685
 686         if test "x$test_java_agent_log4j" = "xyes"; then
 687                 # Check for Log4j agent class
 688                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 689                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 690                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 691                 fi
 692
 693                 # Check for Log4j class
 694                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 695                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 696                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 697                 fi
 698         fi
 699 fi
 700
 701 # enable building man pages (user's intention)
 702 AC_ARG_ENABLE(
 703         man-pages,
 704         AS_HELP_STRING(
 705                 [--disable-man-pages],
 706                 [Do not build and install man pages (already built in a distributed tarball)]
 707         ),
 708         [man_pages_opt=$enableval],
 709         [man_pages_opt=yes]
 710 )
 711
 712 # check for asciidoc and xmlto if we enabled building the man pages
 713 have_asciidoc_xmlto=no
 714 warn_prebuilt_man_pages=no
 715
 716 AS_IF([test "x$man_pages_opt" = "xyes"], [
 717         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 718         AC_PATH_PROG([XMLTO], [xmlto], [no])
 719
 720         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 721                 AS_IF([test "x$in_git_repo" = "xyes"], [
 722                         # this is an error because we're in the Git repo, which
 723                         # means the man pages are not already generated for us,
 724                         # thus asciidoc/xmlto are required because we were asked
 725                         # to build the man pages
 726                         AC_MSG_ERROR([
 727 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 728 --disable-man-pages to disable building the man pages, in which case
 729 they will not be installed.
 730                         ])
 731                 ], [
 732                         # only warn here: since we're in the tarball, the man
 733                         # pages should already be generated at this point, thus
 734                         # asciidoc/xmlto are not strictly required
 735                         warn_prebuilt_man_pages=yes
 736                 ])
 737         ], [
 738                 have_asciidoc_xmlto=yes
 739         ])
 740 ])
 741
 742 # export man page build condition: build the man pages if the user
 743 # asked for it, and if the tools are available
 744 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 745 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 746
 747 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 748
 749 # embedded --help message
 750 AC_ARG_ENABLE(
 751         [embedded-help],
 752         AS_HELP_STRING(
 753                 [--enable-embedded-help],
 754                 [Embed the --help messages in the executable files]
 755         ),
 756         [embedded_help=$enableval],
 757         [embedded_help=no]
 758 )
 759 AS_IF([test "x$embedded_help" = "xyes"], [
 760         AS_IF([test "x$man_pages_opt" = "xno"], [
 761                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 762         ])
 763         AC_PATH_PROG([man_prog_path], [man], [no])
 764         AS_IF([test "x$man_prog_path" = "xno"], [
 765                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 766         ])
 767         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 768         AC_SUBST([MANPROG], [$man_prog_path])
 769 ])
 770 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 771
 772 # Python agent test
 773 UST_PYTHON_AGENT="lttngust"
 774
 775 AC_ARG_ENABLE(test-python2-agent,
 776         AS_HELP_STRING([--enable-test-python2-agent],
 777                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 778         ),[:],[test_python2_agent_autodetect=yes]
 779 )
 780
 781 AC_ARG_ENABLE(test-python3-agent,
 782         AS_HELP_STRING([--enable-test-python3-agent],
 783                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 784         ),[:],[test_python3_agent_autodetect=yes]
 785 )
 786
 787 AC_ARG_ENABLE(test-python-agent-all,
 788         AS_HELP_STRING([--enable-test-python-agent-all],
 789                 [enable test for all python{2/3} agent.]
 790         ),
 791 )
 792
 793 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 794        unset test_python2_agent_autodetect
 795        unset test_python3_agent_autodetect
 796 ])
 797
 798 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 799        enable_test_python2_agent=yes
 800        enable_test_python3_agent=yes
 801 ])
 802
 803 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 804        enable_test_python2_agent=no
 805        enable_test_python3_agent=no
 806 ])
 807
 808
 809 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 810         AS_IF([test -z "$PYTHON2"], [
 811                         PYTHON2=python2
 812                 ], [
 813                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 814         ])
 815
 816         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 817         AS_IF([test -z "$PYTHON2_BIN"], [
 818                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 819                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 820                 ])
 821         ], [
 822                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 823                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 824                         PYTHON2_AGENT=$PYTHON2_BIN
 825                         AC_MSG_RESULT([yes])
 826                         RUN_PYTHON_AGENT_TEST=yes
 827                 ], [
 828                         AC_MSG_RESULT([no])
 829                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 830                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 831                         ])
 832                 ])
 833
 834         ])
 835
 836 ])
 837
 838 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 839         AS_IF([test -z "$PYTHON3"], [
 840                 PYTHON3=python3
 841         ], [
 842                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 843         ])
 844
 845         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 846         AS_IF([test -z "$PYTHON3_BIN"], [
 847                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 848                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 849                 ])
 850         ], [
 851                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 852                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 853                         PYTHON3_AGENT=$PYTHON3_BIN
 854                         AC_MSG_RESULT([yes])
 855                         RUN_PYTHON_AGENT_TEST=yes
 856                 ], [
 857                         AC_MSG_RESULT([no])
 858                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 859                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 860                         ])
 861                 ])
 862
 863         ])
 864 ])
 865 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 866 AC_SUBST([PYTHON2_AGENT])
 867 AC_SUBST([PYTHON3_AGENT])
 868
 869 AC_ARG_ENABLE([test-sdt-uprobe],
 870   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 871   [test_sdt_uprobe="$enableval"],
 872   [test_sdt_uprobe=autodetect]
 873 )
 874
 875 AS_IF([test "$test_sdt_uprobe" != "no"], [
 876   LTTNG_CHECK_SDT_WORKS
 877   AC_PATH_PROG([DTRACE], [dtrace])
 878 ])
 879
 880 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 881   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 882     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 883   ])
 884   AS_IF([test "x$DTRACE" = "x"], [
 885     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 886   ])
 887 ])
 888
 889 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 890   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 891     AS_IF([test "x$DTRACE" != "x"], [
 892       test_sdt_uprobe=yes
 893     ])
 894   ])
 895 ])
 896
 897 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 898
 899 # Arguments for binaries build exclusion
 900 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 901 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 902               [Disable the build of lttng-consumerd binaries]))
 903 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 904 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 905               [Disable the build of lttng-relayd binaries]))
 906 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 907               [Disable the build of lttng-sessiond binaries]))
 908 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 909               [Disable the build of the extra components]))
 910
 911
 912 build_lib_consumer=no
 913 build_lib_health=no
 914 build_lib_index=no
 915 build_lib_kernel_consumer=no
 916 build_lib_kernel_ctl=no
 917 build_lib_lttng_ctl=no
 918 build_lib_relayd=no
 919 build_lib_sessiond_comm=no
 920 build_lib_testpoint=no
 921 build_lib_ust_consumer=no
 922
 923 # There is an overlap for enabled dependencies, but this makes everything
 924 # simpler. libcommon and libconfig are always compiled so they are not repeated
 925 # here.
 926
 927 # Enable binary dependencies.
 928 AS_IF([test x$enable_bin_lttng != xno],
 929       [
 930        build_lib_lttng_ctl=yes
 931       ]
 932 )
 933
 934 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 935       [
 936        build_lib_consumer=yes
 937        build_lib_sessiond_comm=yes
 938        build_lib_index=yes
 939        build_lib_health=yes
 940        build_lib_testpoint=yes
 941       ]
 942 )
 943
 944 AS_IF([test x$enable_bin_lttng_crash != xno],
 945       # Do nothing since libconfig and libcommon are built by default.
 946       []
 947 )
 948
 949 AS_IF([test x$enable_bin_lttng_relayd != xno],
 950       [
 951        build_lib_lttng_ctl=yes
 952        build_lib_sessiond_comm=yes
 953        build_lib_index=yes
 954        build_lib_health=yes
 955        build_lib_testpoint=yes
 956       ]
 957 )
 958 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 959       [
 960        build_lib_lttng_ctl=yes
 961        build_lib_sessiond_comm=yes
 962        build_lib_kernel_ctl=yes
 963        build_lib_relayd=yes
 964        build_lib_testpoint=yes
 965        build_lib_health=yes
 966       ]
 967 )
 968
 969 # Libraries dependencies enabling
 970 AS_IF([test x$build_lib_lttng_ctl = xyes],
 971       [
 972        build_lib_sessiond_comm=yes
 973       ]
 974 )
 975
 976 AS_IF([test x$build_lib_consumer = xyes],
 977       [
 978        build_lib_sessiond_comm=yes
 979        build_lib_kernel_consumer=yes
 980        build_lib_relayd=yes
 981        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 982       ]
 983 )
 984
 985 AS_IF([test x$build_lib_kernel_consumer = xyes],
 986       [
 987        build_lib_kernel_ctl=yes
 988        build_lib_relayd=yes
 989       ]
 990 )
 991
 992 AS_IF([test x$build_lib_relayd = xyes],
 993       [
 994        build_lib_sessiond_comm=yes
 995       ]
 996 )
 997
 998 # Find arch type
 999 AS_CASE([$host_cpu],
1000         [k1om], [ARCHTYPE="x86"],
1001         [i386], [ARCHTYPE="x86"],
1002         [i486], [ARCHTYPE="x86"],
1003         [i586], [ARCHTYPE="x86"],
1004         [i686], [ARCHTYPE="x86"],
1005         [amd64], [ARCHTYPE="x86"],
1006         [x86_64], [ARCHTYPE="x86"],
1007         [powerpc], [ARCHTYPE="ppc"],
1008         [ppc64], [ARCHTYPE="ppc"],
1009         [powerpc64], [ARCHTYPE="ppc"],
1010         [powerpc64le], [ARCHTYPE="ppc"],
1011         [ppc], [ARCHTYPE="ppc"],
1012         [s390], [ARCHTYPE="s390"],
1013         [s390x], [ARCHTYPE="s390"],
1014         [sparc], [ARCHTYPE="sparc64"],
1015         [sparc64], [ARCHTYPE="sparc64"],
1016         [alpha*], [ARCHTYPE="alpha"],
1017         [ia64], [ARCHTYPE="ia64"],
1018         [arm*], [ARCHTYPE="arm"],
1019         [aarch64*], [ARCHTYPE="aarch64"],
1020         [mips*], [ARCHTYPE="mips"],
1021         [nios2*], [ARCHTYPE="nios2"],
1022         [tile*], [ARCHTYPE="tile"],
1023         [hppa*], [ARCHTYPE="hppa"],
1024         [m68k], [ARCHTYPE="m68k"],
1025         [riscv*], [ARCHTYPE="riscv"],
1026         [ARCHTYPE="unknown"]
1027 )
1028
1029 AC_SUBST(ARCHTYPE)
1030
1031 AS_CASE([$host_os],
1032         [linux*], [OSTYPE="linux"],
1033         [freebsd*], [OSTYPE="freebsd"],
1034         [solaris*], [OSTYPE="solaris"],
1035         [cygwin*], [OSTYPE="cygwin"],
1036         [mingw*], [OSTYPE="mingw"],
1037         [OSTYPE="unknown"]
1038 )
1039 AC_SUBST(OSTYPE)
1040 AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"])
1041
1042
1043
1044 # Userspace callstack capture is only supported by the Linux kernel on x86.
1045 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1046 AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[
1047         have_modules_userspace_callstack_context=yes
1048         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1049 ])
1050 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes])
1051
1052 # Export binaries build conditions.
1053 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1054 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1055 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1056 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1057 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1058
1059 # Export the tests and extras build conditions.
1060 AS_IF([\
1061 test "x$enable_bin_lttng" != "xno" && \
1062 test "x$enable_bin_lttng_consumerd" != "xno" && \
1063 test "x$enable_bin_lttng_crash" != "xno" && \
1064 test "x$enable_bin_lttng_relayd" != "xno" && \
1065 test "x$enable_bin_lttng_sessiond" != "xno"],
1066 [build_tests=yes],
1067 [build_tests=no]
1068 )
1069
1070 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1071 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1072
1073 # Export libraries build conditions.
1074 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1075 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1076 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1077 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1078 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1079 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1080 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1081 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1082 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1083 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1084
1085 AM_CFLAGS="$OPT_CFLAGS $WARN_CFLAGS $PTHREAD_CFLAGS"
1086 AC_SUBST(AM_CFLAGS)
1087
1088 AM_CXXFLAGS="$OPT_CXXFLAGS $WARN_CXXFLAGS $PTHREAD_CFLAGS"
1089 AC_SUBST(AM_CXXFLAGS)
1090
1091 # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...".
1092 AM_LDFLAGS=""
1093 AC_SUBST(AM_LDFLAGS)
1094
1095 # The order in which the include folders are searched is important.
1096 # The top_builddir should always be searched first in the event that a build
1097 # time generated file is included. An example of this is the "version.i" file.
1098 # In a scenario where lttng-tools is built from a distribution tarball and in a
1099 # out-of-tree manner, the generated "version.i" has priority on the one from
1100 # the source (distribution tarball) and must be found first.
1101 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1102 AC_SUBST(AM_CPPFLAGS)
1103
1104 lttngincludedir="${includedir}/lttng"
1105 AC_SUBST(lttngincludedir)
1106
1107 lttngactionincludedir="${includedir}/lttng/action"
1108 AC_SUBST(lttngactionincludedir)
1109
1110 lttngconditionincludedir="${includedir}/lttng/condition"
1111 AC_SUBST(lttngconditionincludedir)
1112
1113 lttngnotificationincludedir="${includedir}/lttng/notification"
1114 AC_SUBST(lttngnotificationincludedir)
1115
1116 lttngtriggerincludedir="${includedir}/lttng/trigger"
1117 AC_SUBST(lttngtriggerincludedir)
1118
1119 lttngeventruleincludedir="${includedir}/lttng/event-rule"
1120 AC_SUBST(lttngeventruleincludedir)
1121
1122 lttnglibexecdir="${libdir}/lttng/libexec"
1123 AC_SUBST(lttnglibexecdir)
1124
1125 AC_CONFIG_FILES([
1126         Makefile
1127         doc/Makefile
1128         doc/examples/Makefile
1129         doc/examples/rotation/Makefile
1130         doc/examples/trigger-condition-event-matches/Makefile
1131         doc/man/Makefile
1132         doc/man/asciidoc-attrs.conf
1133         include/Makefile
1134         extras/Makefile
1135         extras/bindings/Makefile
1136         extras/bindings/swig/Makefile
1137         extras/bindings/swig/python/Makefile
1138         extras/core-handler/Makefile
1139         src/Makefile
1140         src/common/Makefile
1141         src/common/argpar/Makefile
1142         src/common/bytecode/Makefile
1143         src/common/kernel-ctl/Makefile
1144         src/common/kernel-consumer/Makefile
1145         src/common/consumer/Makefile
1146         src/common/ust-consumer/Makefile
1147         src/common/hashtable/Makefile
1148         src/common/sessiond-comm/Makefile
1149         src/common/compat/Makefile
1150         src/common/relayd/Makefile
1151         src/common/testpoint/Makefile
1152         src/common/index/Makefile
1153         src/common/health/Makefile
1154         src/common/config/Makefile
1155         src/common/string-utils/Makefile
1156         src/common/fd-tracker/Makefile
1157         src/common/filter/Makefile
1158         src/lib/Makefile
1159         src/lib/lttng-ctl/Makefile
1160         src/lib/lttng-ctl/lttng-ctl.pc
1161         src/bin/Makefile
1162         src/bin/lttng-consumerd/Makefile
1163         src/bin/lttng-sessiond/Makefile
1164         src/bin/lttng-relayd/Makefile
1165         src/bin/lttng/Makefile
1166         src/bin/lttng-crash/Makefile
1167         src/vendor/Makefile
1168         src/vendor/msgpack/Makefile
1169         tests/Makefile
1170         tests/destructive/Makefile
1171         tests/regression/Makefile
1172         tests/regression/kernel/Makefile
1173         tests/regression/tools/Makefile
1174         tests/regression/tools/streaming/Makefile
1175         tests/regression/tools/filtering/Makefile
1176         tests/regression/tools/health/Makefile
1177         tests/regression/tools/tracefile-limits/Makefile
1178         tests/regression/tools/snapshots/Makefile
1179         tests/regression/tools/live/Makefile
1180         tests/regression/tools/exclusion/Makefile
1181         tests/regression/tools/save-load/Makefile
1182         tests/regression/tools/save-load/configuration/Makefile
1183         tests/regression/tools/mi/Makefile
1184         tests/regression/tools/wildcard/Makefile
1185         tests/regression/tools/channel/Makefile
1186         tests/regression/tools/crash/Makefile
1187         tests/regression/tools/regen-metadata/Makefile
1188         tests/regression/tools/regen-statedump/Makefile
1189         tests/regression/tools/notification/Makefile
1190         tests/regression/tools/rotation/Makefile
1191         tests/regression/tools/base-path/Makefile
1192         tests/regression/tools/metadata/Makefile
1193         tests/regression/tools/tracker/Makefile
1194         tests/regression/tools/working-directory/Makefile
1195         tests/regression/tools/relayd-grouping/Makefile
1196         tests/regression/tools/clear/Makefile
1197         tests/regression/tools/trigger/Makefile
1198         tests/regression/tools/trigger/rate-policy/Makefile
1199         tests/regression/tools/trigger/start-stop/Makefile
1200         tests/regression/tools/trigger/utils/Makefile
1201         tests/regression/tools/trigger/name/Makefile
1202         tests/regression/tools/trigger/hidden/Makefile
1203         tests/regression/ust/Makefile
1204         tests/regression/ust/nprocesses/Makefile
1205         tests/regression/ust/high-throughput/Makefile
1206         tests/regression/ust/low-throughput/Makefile
1207         tests/regression/ust/before-after/Makefile
1208         tests/regression/ust/buffers-pid/Makefile
1209         tests/regression/ust/periodical-metadata-flush/Makefile
1210         tests/regression/ust/multi-session/Makefile
1211         tests/regression/ust/multi-lib/Makefile
1212         tests/regression/ust/overlap/Makefile
1213         tests/regression/ust/overlap/demo/Makefile
1214         tests/regression/ust/linking/Makefile
1215         tests/regression/ust/daemon/Makefile
1216         tests/regression/ust/exit-fast/Makefile
1217         tests/regression/ust/fork/Makefile
1218         tests/regression/ust/libc-wrapper/Makefile
1219         tests/regression/ust/baddr-statedump/Makefile
1220         tests/regression/ust/ust-dl/Makefile
1221         tests/regression/ust/java-jul/Makefile
1222         tests/regression/ust/java-log4j/Makefile
1223         tests/regression/ust/getcpu-override/Makefile
1224         tests/regression/ust/clock-override/Makefile
1225         tests/regression/ust/type-declarations/Makefile
1226         tests/regression/ust/rotation-destroy-flush/Makefile
1227         tests/regression/ust/blocking/Makefile
1228         tests/regression/ust/namespaces/Makefile
1229         tests/stress/Makefile
1230         tests/unit/Makefile
1231         tests/unit/ini_config/Makefile
1232         tests/perf/Makefile
1233         tests/utils/Makefile
1234         tests/utils/tap/Makefile
1235         tests/utils/testapp/Makefile
1236         tests/utils/testapp/gen-ns-events/Makefile
1237         tests/utils/testapp/gen-kernel-test-events/Makefile
1238         tests/utils/testapp/gen-py-events/Makefile
1239         tests/utils/testapp/gen-ust-events/Makefile
1240         tests/utils/testapp/gen-ust-events-ns/Makefile
1241         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1242         tests/utils/testapp/gen-ust-nevents/Makefile
1243         tests/utils/testapp/gen-ust-nevents-str/Makefile
1244         tests/utils/testapp/gen-syscall-events/Makefile
1245         tests/utils/testapp/gen-ust-tracef/Makefile
1246         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1247         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1248         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1249         tests/utils/xml-utils/Makefile
1250 ])
1251
1252 # Inject variable into python test script.
1253 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1254 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1255 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1256 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1257
1258 AC_OUTPUT
1259
1260 #
1261 # Mini-report on what will be built.
1262 #
1263
1264 PPRINT_INIT
1265 PPRINT_SET_INDENT(1)
1266 PPRINT_SET_TS(38)
1267
1268 AS_ECHO
1269 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1270 AS_ECHO
1271
1272 AS_IF([test -n "$report_fold"], [
1273         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1274 ], [
1275         AS_ECHO("$version_description")
1276 ])
1277
1278 AS_ECHO
1279 PPRINT_SUBTITLE([Features])
1280
1281 # Target architecture we're building for.
1282 target_arch=$host_cpu
1283 [
1284 for f in $CFLAGS; do
1285         if test $f = "-m32"; then
1286                         target_arch="32-bit"
1287         elif test $f = "-m64"; then
1288                         target_arch="64-bit"
1289         fi
1290 done
1291 ]
1292 PPRINT_PROP_STRING([Target architecture], $target_arch)
1293
1294 # kmod enabled/disabled
1295 test "x$with_kmod" != "xno" && value=1 || value=0
1296 PPRINT_PROP_BOOL([libkmod support], $value)
1297
1298 # LTTng-UST enabled/disabled
1299 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1300 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1301
1302 AS_ECHO
1303 PPRINT_SUBTITLE([Binaries])
1304
1305 # List binaries to be built
1306 test x$enable_bin_lttng != xno && value=1 || value=0
1307 PPRINT_PROP_BOOL([lttng], $value)
1308
1309 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1310 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1311
1312 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1313 PPRINT_PROP_BOOL([lttng-crash], $value)
1314
1315 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1316 PPRINT_PROP_BOOL([lttng-relayd], $value)
1317
1318 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1319 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1320
1321 # Extras
1322 test x$enable_extras != xno && value=1 || value=0
1323 AS_ECHO
1324 PPRINT_SET_INDENT(0)
1325 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1326 PPRINT_SET_INDENT(1)
1327
1328 AS_ECHO
1329 PPRINT_SUBTITLE([Tests])
1330
1331 # Print clear message that tests won't be built
1332 AS_IF([test "x$build_tests" = "xno"],[
1333         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1334 ])
1335
1336 # LTTng UST Java agent JUL tests enabled/disabled
1337 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1338 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1339
1340 # LTTng UST Java agent Log4j tests enabled/disabled
1341 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1342 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1343
1344 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1345 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1346
1347 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1348 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1349
1350 # LTTng UST Java agent Log4j tests enabled/disabled
1351 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1352 PPRINT_PROP_BOOL([LTTng-UST SDT uprobe tests], $value)
1353
1354 #Python binding enabled/disabled
1355 test "x$enable_python_binding" = xyes && value=1 || value=0
1356 AS_ECHO
1357 PPRINT_SET_INDENT(0)
1358 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1359
1360 # man pages build enabled/disabled
1361 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1362
1363 AS_IF([test "x$man_pages_opt" != "xno"], [
1364         AS_IF([test "x$in_git_repo" = "xyes"], [
1365                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1366         ], [
1367                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1368                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1369                 ], [
1370                         PPRINT_PROP_STRING([build_man_pages_msg],
1371                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1372                                 $PPRINT_COLOR_SUBTITLE)
1373                 ])
1374         ])
1375 ], [
1376         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1377 ])
1378
1379 m4_popdef([build_man_pages_msg])
1380
1381 test "x$embedded_help" = xyes && value=1 || value=0
1382 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1383
1384 PPRINT_SET_INDENT(1)
1385
1386 report_bindir="`eval eval echo $bindir`"
1387 report_libdir="`eval eval echo $libdir`"
1388
1389 # Print the bindir and libdir this `make install' will install into.
1390 AS_ECHO
1391 PPRINT_SUBTITLE([Install directories])
1392 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1393 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1394
1395 AS_ECHO
1396 PPRINT_SUBTITLE([Search directories])
1397
1398 # If we build the sessiond, print the paths it will use
1399 AS_IF([test "$SESSIOND_BIN" = ""],[
1400         path="$report_bindir/lttng-sessiond"
1401 ],[
1402         path="$SESSIOND_BIN"
1403 ])
1404 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1405
1406 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1407         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1408 ],[
1409         path="$CONSUMERD32_BIN"
1410 ])
1411 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1412
1413 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1414         path="`eval eval echo $libdir`"
1415 ],[
1416         path="$CONSUMERD32_LIBDIR"
1417 ])
1418 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1419
1420 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1421         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1422 ],[
1423         path="$CONSUMERD64_BIN"
1424 ])
1425 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1426
1427 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1428         path="`eval eval echo $libdir`"
1429 ],[
1430         path="$CONSUMERD64_LIBDIR"
1431 ])
1432 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1433 PPRINT_SET_INDENT(0)
1434
1435 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1436         AS_ECHO
1437         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1438
1439 Note that the man pages are already built in this distribution tarball,
1440 therefore asciidoc and xmlto are only needed if you intend to modify
1441 their sources.
1442
1443 Also note that the installed man pages will contain the project's
1444 default command-line option and environment variable values.
1445
1446 Use --disable-man-pages to completely disable building and installing
1447 the man pages.])
1448 ])