configure.ac

   1 AC_PREREQ(2.59)
   2 AC_INIT([userspace-rcu],[0.9.3],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([URCU_LIBRARY_VERSION], [5:0:1])
   7
   8 AC_CONFIG_SRCDIR([urcu.h])
   9 AC_CONFIG_HEADERS([config.h urcu/config.h])
  10 AC_CONFIG_AUX_DIR([config])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  17 AM_MAINTAINER_MODE([enable])
  18
  19 # Enable silent rules if available (Introduced in AM 1.11)
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  21
  22 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  23 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  24 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  25 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  26 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  27 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  28 AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
  29
  30 # Allow overriding storage used for TLS variables.
  31 AC_ARG_ENABLE([compiler-tls],
  32         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  33         [def_compiler_tls=$enableval],
  34         [def_compiler_tls="yes"])
  35
  36 # If not overridden, use ax_tls.m4 to check if TLS is available.
  37 AS_IF([test "x$def_compiler_tls" = "xyes"],
  38         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  39         [:])
  40
  41 AS_IF([test "x$def_tls_detect" = "x"],
  42         [:],
  43         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  44
  45 # Checks for C compiler
  46 AC_USE_SYSTEM_EXTENSIONS
  47 AC_PROG_CC
  48 AC_PROG_CC_STDC
  49
  50 # Checks for programs.
  51 AC_PROG_AWK
  52 AC_PROG_MAKE_SET
  53 AC_CHECK_PROGS(NPROC, [nproc gnproc])
  54 AC_CHECK_PROGS(GETCONF, [getconf])
  55 AS_IF([test "x$NPROC" != "x"],
  56         [NPROC_CMD=$NPROC],
  57         [AS_IF([test "x$GETCONF" != "x"],
  58                 [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
  59                 [NPROC_CMD="echo 1"]
  60         )]
  61 )
  62 AC_SUBST([NPROC_CMD], [$NPROC_CMD])
  63
  64 LT_INIT
  65
  66 # Checks for typedefs, structures, and compiler characteristics.
  67 AC_C_INLINE
  68 AC_TYPE_PID_T
  69 AC_TYPE_SIZE_T
  70 AC_TYPE_SSIZE_T
  71 AC_TYPE_UINT16_T
  72 AC_TYPE_INT32_T
  73 AC_TYPE_UINT32_T
  74 AC_TYPE_UINT64_T
  75 AC_TYPE_UINT8_T
  76
  77 AX_C___ATTRIBUTE__
  78 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  79         [:],
  80         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  81
  82 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  83 LIBS="$PTHREAD_LIBS $LIBS"
  84 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  85 CC="$PTHREAD_CC"
  86
  87 # Checks for library functions.
  88 AC_FUNC_MMAP
  89 AC_FUNC_FORK
  90 AC_CHECK_FUNCS([ \
  91         atexit \
  92         getcpuid \
  93         gettid \
  94         gettimeofday \
  95         memeset \
  96         memset \
  97         munmap \
  98         sched_getcpu \
  99         strerror \
 100         strtoul \
 101         sysconf \
 102 ])
 103
 104 # AC_FUNC_MALLOC causes problems when cross-compiling.
 105 #AC_FUNC_MALLOC
 106
 107 # Check for headers
 108 AC_HEADER_STDBOOL
 109 AC_CHECK_HEADERS([ \
 110         limits.h \
 111         stddef.h \
 112         sys/param.h \
 113         sys/time.h \
 114 ])
 115
 116 # Find arch type
 117 AS_CASE([$host_cpu],
 118         [k1om], [ARCHTYPE="x86"],
 119         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
 120         [i486], [ARCHTYPE="x86"],
 121         [i586], [ARCHTYPE="x86"],
 122         [i686], [ARCHTYPE="x86"],
 123         [amd64], [ARCHTYPE="x86"],
 124         [x86_64], [ARCHTYPE="x86"],
 125         [powerpc], [ARCHTYPE="ppc"],
 126         [ppc64], [ARCHTYPE="ppc"],
 127         [powerpc64], [ARCHTYPE="ppc"],
 128         [powerpc64le], [ARCHTYPE="ppc"],
 129         [ppc], [ARCHTYPE="ppc"],
 130         [s390], [ARCHTYPE="s390"],
 131         [s390x], [ARCHTYPE="s390"],
 132         [sparc], [ARCHTYPE="sparc64"],
 133         [sparc64], [ARCHTYPE="sparc64"],
 134         [alpha*], [ARCHTYPE="alpha"],
 135         [ia64], [ARCHTYPE="ia64"],
 136         [arm*], [ARCHTYPE="arm"],
 137         [aarch64*], [ARCHTYPE="aarch64"],
 138         [mips*], [ARCHTYPE="mips"],
 139         [tile*], [ARCHTYPE="tile"],
 140         [hppa*], [ARCHTYPE="hppa"],
 141         [ARCHTYPE="unknown"]
 142 )
 143
 144 AS_CASE([$host],[*-*-linux-androideabi],
 145         [AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
 146         [AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
 147 )
 148
 149 AS_CASE([$host],[*-cygwin*],
 150         [AM_CONDITIONAL(USE_CYGWIN, true)],
 151         [AM_CONDITIONAL(USE_CYGWIN, false)]
 152 )
 153
 154 AC_SUBST(ARCHTYPE)
 155 AC_SUBST(SUBARCHTYPE)
 156
 157 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
 158 ARCHSRC=urcu/arch/$ARCHTYPE.h
 159
 160 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
 161         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 162 ])
 163
 164 AS_IF([test "$host_cpu" = "armv7l"],[
 165         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
 166 ])
 167
 168 # ARM-specific checks
 169 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 170         AC_MSG_CHECKING([for dmb instruction])
 171         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 172                                 int main()
 173                                 {
 174                                         asm volatile("dmb":::"memory");
 175                                         return 0;
 176                                 }
 177                 ]])
 178         ],[
 179                 AC_MSG_RESULT([yes])
 180                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 181         ],[
 182                 AC_MSG_RESULT([no])
 183         ])
 184 ])
 185
 186 # Tile-specific checks
 187 AS_IF([echo "$host_cpu" | grep "^tile"],[
 188         AC_MSG_CHECKING([for Tile architecture type])
 189         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 190                                 #ifndef __tilegx__
 191                                 #error
 192                                 #endif
 193                 ]])
 194         ],[
 195                 AC_MSG_RESULT([ok])
 196         ],[
 197                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 198         ])
 199 ])
 200
 201 # x86-specific checks
 202 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 203         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 204         #For now, using lock; addl compatibility mode even for i686, because the
 205         #Pentium III is seen as a i686, but lacks mfence instruction.
 206         #Only using fence for x86_64.
 207         #
 208         #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
 209         #variant but lacks fence instructions.
 210         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
 211                 AC_MSG_RESULT([yes])
 212                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 213         ],[
 214                 AC_MSG_RESULT([no])
 215         ])
 216 ])
 217
 218 # Check if sys_futex() is available
 219 AC_MSG_CHECKING([for sys_futex()])
 220 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 221                 #include <sys/syscall.h>
 222                 #ifndef __NR_futex
 223                 #error "futexes not available"
 224                 #endif
 225         ]])
 226 ],[
 227         AC_MSG_RESULT([yes])
 228         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 229         compat_futex_test=0
 230 ],[
 231         AC_MSG_RESULT([no])
 232         compat_futex_test=1
 233 ])
 234
 235 # Search for clock_gettime
 236 AC_SEARCH_LIBS([clock_gettime], [rt], [
 237         AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
 238 ], [])
 239
 240 # Check for pthread
 241 AC_CHECK_LIB([pthread], [pthread_create],
 242         [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
 243         [AC_CHECK_LIB([c], [pthread_create],
 244                 [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
 245                 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 246         )]
 247 )
 248
 249 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 250 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 251 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 252
 253 # smp-support configure option
 254 AC_ARG_ENABLE([smp-support],
 255         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 256         [def_smp_support=$enableval],
 257         [def_smp_support="yes"])
 258 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 259
 260
 261 # From the sched_setaffinity(2)'s man page:
 262 # ~~~~
 263 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 264 # The library interfaces were introduced in glibc 2.3.  Initially, the
 265 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 266 # the cpuset size argument was removed, but this argument was
 267 # restored in glibc 2.3.4.
 268 # ~~~~
 269
 270 # In addition to that, some vendors ported the system call to 2.4
 271 # kernels.
 272
 273 # Furthermore, when the function first appeared, the MASK argument was
 274 # an unsigned long pointer, while later it was made into a cpu_set_t
 275 # pointer.  Systems that have the cpu_set_t version also should have
 276 # the CPU_ZERO, CPU_SET, etc. macros.
 277
 278 # All this mess means we have to cater for at least 3 different
 279 # sched_setaffinity prototypes:
 280
 281 # ~~~~
 282 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 283 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 284 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 285 # ~~~~
 286
 287 # Since we define _GNU_SOURCE in the sources, must do so too in the
 288 # autoconf tests, as defining _GNU_SOURCE or not exposes
 289 # sched_setaffinity bits differently.
 290 saved_CFLAGS=$CFLAGS
 291 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 292
 293 AC_CHECK_TYPES([cpu_set_t],
 294         [have_cpu_set_t="yes"],
 295         [have_cpu_set_t="no"],
 296         [#include <sched.h>])
 297
 298 # Confirm that we have CPU_ZERO, and it actually works.
 299 AC_MSG_CHECKING([whether CPU_ZERO works])
 300 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 301 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 302                 #define _GNU_SOURCE
 303                 #include <sched.h>
 304                 int main()
 305                 {
 306                         cpu_set_t foo; CPU_ZERO(&foo);
 307                         return 0;
 308                 }
 309         ]])
 310 ],[
 311         AC_DEFINE(HAVE_CPU_ZERO, 1)
 312         AC_MSG_RESULT([yes])
 313 ],[
 314         AC_MSG_RESULT([no])
 315 ])
 316
 317 # Confirm that we have CPU_SET, and it actually works.
 318 AC_MSG_CHECKING([whether CPU_SET works])
 319 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 320 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 321                 #define _GNU_SOURCE
 322                 #include <sched.h>
 323                 int main()
 324                 {
 325                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 326                         return 0;
 327                 }
 328         ]])
 329 ],[
 330         AC_DEFINE(HAVE_CPU_SET, 1)
 331         AC_MSG_RESULT([yes])
 332 ],[
 333         AC_MSG_RESULT([no])
 334 ])
 335
 336 # First check if the function is available at all.
 337 AC_CHECK_FUNCS([sched_setaffinity],[
 338         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 339         # then we have the first version using unsigned long, and no
 340         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 341         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 342         # should also be present, but we confirm nonetheless.
 343
 344         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 345                 # We do have it.
 346                 # Check how many arguments does sched_setaffinity take.
 347                 # Should be 3 or 2.
 348                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 349                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 350                                 #include <sched.h>
 351                                 int main()
 352                                 {
 353                                         cpu_set_t foo;
 354                                         sched_setaffinity(0, sizeof (foo), &foo);
 355                                         return 0;
 356                                 }
 357                         ]])
 358                 ],
 359                 [sched_set_affinity_args=3],
 360                 [sched_set_affinity_args=2])
 361                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 362                         $sched_set_affinity_args,
 363                         [Defined to sched_setaffinity's number of arguments.])
 364                 AC_MSG_RESULT([$sched_set_affinity_args])
 365         ],[
 366                 # No cpu_set_t, always 3 args.
 367                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 368         ])
 369 ])
 370
 371 CFLAGS=$saved_CFLAGS
 372
 373 AC_CONFIG_LINKS([
 374         urcu/arch.h:$ARCHSRC
 375         urcu/uatomic.h:$UATOMICSRC
 376 ])
 377 AC_CONFIG_FILES([
 378         Makefile
 379         doc/Makefile
 380         doc/examples/Makefile
 381         tests/Makefile
 382         tests/common/Makefile
 383         tests/unit/Makefile
 384         tests/benchmark/Makefile
 385         tests/regression/Makefile
 386         tests/regression/regression_tests
 387         tests/utils/Makefile
 388         liburcu.pc
 389         liburcu-bp.pc
 390         liburcu-cds.pc
 391         liburcu-qsbr.pc
 392         liburcu-mb.pc
 393         liburcu-signal.pc
 394 ])
 395 AC_OUTPUT
 396
 397 # Report on selected configure options
 398 AS_IF([test "x$def_smp_support" = "xyes"],[
 399         AS_ECHO("SMP support enabled.")
 400 ],[
 401         AS_ECHO("SMP support disabled.")
 402 ])
 403
 404 AS_IF([test "x$def_tls_detect" = "x"],[
 405         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 406 ],[
 407         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 408 ])