configure.ac

   1 AC_PREREQ(2.59)
   2 AC_INIT([userspace-rcu],[0.9.7],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([URCU_LIBRARY_VERSION], [5:0:1])
   7
   8 AC_CONFIG_SRCDIR([urcu.h])
   9 AC_CONFIG_HEADERS([config.h urcu/config.h])
  10 AC_CONFIG_AUX_DIR([config])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  17 AM_MAINTAINER_MODE([enable])
  18
  19 # Enable silent rules if available (Introduced in AM 1.11)
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  21
  22 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  23 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  24 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  25 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  26 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  27 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  28 AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
  29
  30 # Allow overriding storage used for TLS variables.
  31 AC_ARG_ENABLE([compiler-tls],
  32         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  33         [def_compiler_tls=$enableval],
  34         [def_compiler_tls="yes"])
  35
  36 AS_IF([test "x$def_compiler_tls" = "xyes"], AC_DEFINE([CONFIG_RCU_TLS], [1]), [:])
  37
  38 # Checks for C compiler
  39 AC_USE_SYSTEM_EXTENSIONS
  40 AC_PROG_CC
  41 AC_PROG_CC_STDC
  42
  43 # Checks for programs.
  44 AC_PROG_AWK
  45 AC_PROG_MAKE_SET
  46 AC_CHECK_PROGS(NPROC, [nproc gnproc])
  47 AC_CHECK_PROGS(GETCONF, [getconf])
  48 AS_IF([test "x$NPROC" != "x"],
  49         [NPROC_CMD=$NPROC],
  50         [AS_IF([test "x$GETCONF" != "x"],
  51                 [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
  52                 [NPROC_CMD="echo 1"]
  53         )]
  54 )
  55 AC_SUBST([NPROC_CMD], [$NPROC_CMD])
  56
  57 LT_INIT
  58
  59 # Checks for typedefs, structures, and compiler characteristics.
  60 AC_C_INLINE
  61 AC_TYPE_PID_T
  62 AC_TYPE_SIZE_T
  63 AC_TYPE_SSIZE_T
  64 AC_TYPE_UINT16_T
  65 AC_TYPE_INT32_T
  66 AC_TYPE_UINT32_T
  67 AC_TYPE_UINT64_T
  68 AC_TYPE_UINT8_T
  69
  70 AX_C___ATTRIBUTE__
  71 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  72         [:],
  73         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  74
  75 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  76
  77 AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
  78
  79 # Checks for library functions.
  80 AC_FUNC_MMAP
  81 AC_FUNC_FORK
  82 AC_CHECK_FUNCS([ \
  83         atexit \
  84         getcpuid \
  85         gettid \
  86         gettimeofday \
  87         memeset \
  88         memset \
  89         munmap \
  90         sched_getcpu \
  91         strerror \
  92         strtoul \
  93         sysconf \
  94         sched_getcpu
  95 ])
  96
  97 # AC_FUNC_MALLOC causes problems when cross-compiling.
  98 #AC_FUNC_MALLOC
  99
 100 # Check for headers
 101 AC_HEADER_STDBOOL
 102 AC_CHECK_HEADERS([ \
 103         limits.h \
 104         stddef.h \
 105         sys/param.h \
 106         sys/time.h \
 107 ])
 108
 109 # Find arch type
 110 AS_CASE([$host_cpu],
 111         [k1om], [ARCHTYPE="x86"],
 112         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
 113         [i486], [ARCHTYPE="x86"],
 114         [i586], [ARCHTYPE="x86"],
 115         [i686], [ARCHTYPE="x86"],
 116         [amd64], [ARCHTYPE="x86"],
 117         [x86_64], [ARCHTYPE="x86"],
 118         [powerpc], [ARCHTYPE="ppc"],
 119         [ppc64], [ARCHTYPE="ppc"],
 120         [powerpc64], [ARCHTYPE="ppc"],
 121         [powerpc64le], [ARCHTYPE="ppc"],
 122         [ppc], [ARCHTYPE="ppc"],
 123         [s390], [ARCHTYPE="s390"],
 124         [s390x], [ARCHTYPE="s390"],
 125         [sparc], [ARCHTYPE="sparc64"],
 126         [sparc64], [ARCHTYPE="sparc64"],
 127         [alpha*], [ARCHTYPE="alpha"],
 128         [ia64], [ARCHTYPE="ia64"],
 129         [arm*], [ARCHTYPE="arm"],
 130         [aarch64*], [ARCHTYPE="aarch64"],
 131         [mips*], [ARCHTYPE="mips"],
 132         [tile*], [ARCHTYPE="tile"],
 133         [hppa*], [ARCHTYPE="hppa"],
 134         [ARCHTYPE="unknown"]
 135 )
 136
 137 AS_CASE([$host],[*-*-linux-androideabi],
 138         [AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
 139         [AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
 140 )
 141
 142 AS_CASE([$host],[*-cygwin*],
 143         [AM_CONDITIONAL(USE_CYGWIN, true)],
 144         [AM_CONDITIONAL(USE_CYGWIN, false)]
 145 )
 146
 147 AC_SUBST(ARCHTYPE)
 148 AC_SUBST(SUBARCHTYPE)
 149
 150 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
 151 ARCHSRC=urcu/arch/$ARCHTYPE.h
 152
 153 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
 154         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 155 ])
 156
 157 AS_IF([test "$host_cpu" = "armv7l"],[
 158         AM_CFLAGS="$AM_CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
 159 ])
 160
 161 # ARM-specific checks
 162 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 163         AC_MSG_CHECKING([for dmb instruction])
 164         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 165                                 int main()
 166                                 {
 167                                         asm volatile("dmb":::"memory");
 168                                         return 0;
 169                                 }
 170                 ]])
 171         ],[
 172                 AC_MSG_RESULT([yes])
 173                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 174         ],[
 175                 AC_MSG_RESULT([no])
 176         ])
 177 ])
 178
 179 # Tile-specific checks
 180 AS_IF([echo "$host_cpu" | grep "^tile"],[
 181         AC_MSG_CHECKING([for Tile architecture type])
 182         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 183                                 #ifndef __tilegx__
 184                                 #error
 185                                 #endif
 186                 ]])
 187         ],[
 188                 AC_MSG_RESULT([ok])
 189         ],[
 190                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 191         ])
 192 ])
 193
 194 # x86-specific checks
 195 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 196         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 197         #For now, using lock; addl compatibility mode even for i686, because the
 198         #Pentium III is seen as a i686, but lacks mfence instruction.
 199         #Only using fence for x86_64.
 200         #
 201         #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
 202         #variant but lacks fence instructions.
 203         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
 204                 AC_MSG_RESULT([yes])
 205                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 206         ],[
 207                 AC_MSG_RESULT([no])
 208         ])
 209 ])
 210
 211 # Check if sys_futex() is available
 212 AC_MSG_CHECKING([for sys_futex()])
 213 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 214                 #include <sys/syscall.h>
 215                 #ifndef __NR_futex
 216                 #error "futexes not available"
 217                 #endif
 218         ]])
 219 ],[
 220         AC_MSG_RESULT([yes])
 221         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 222         compat_futex_test=0
 223 ],[
 224         AC_MSG_RESULT([no])
 225         compat_futex_test=1
 226 ])
 227
 228 # Search for clock_gettime
 229 AC_SEARCH_LIBS([clock_gettime], [rt], [
 230         AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
 231 ], [])
 232
 233 # Check for pthread
 234 AC_CHECK_LIB([pthread], [pthread_create],
 235         [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
 236         [AC_CHECK_LIB([c], [pthread_create],
 237                 [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
 238                 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 239         )]
 240 )
 241
 242 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 243 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 244 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 245
 246 # smp-support configure option
 247 AC_ARG_ENABLE([smp-support],
 248         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 249         [def_smp_support=$enableval],
 250         [def_smp_support="yes"])
 251 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 252
 253
 254 # From the sched_setaffinity(2)'s man page:
 255 # ~~~~
 256 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 257 # The library interfaces were introduced in glibc 2.3.  Initially, the
 258 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 259 # the cpuset size argument was removed, but this argument was
 260 # restored in glibc 2.3.4.
 261 # ~~~~
 262
 263 # In addition to that, some vendors ported the system call to 2.4
 264 # kernels.
 265
 266 # Furthermore, when the function first appeared, the MASK argument was
 267 # an unsigned long pointer, while later it was made into a cpu_set_t
 268 # pointer.  Systems that have the cpu_set_t version also should have
 269 # the CPU_ZERO, CPU_SET, etc. macros.
 270
 271 # All this mess means we have to cater for at least 3 different
 272 # sched_setaffinity prototypes:
 273
 274 # ~~~~
 275 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 276 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 277 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 278 # ~~~~
 279
 280 # Since we define _GNU_SOURCE in the sources, must do so too in the
 281 # autoconf tests, as defining _GNU_SOURCE or not exposes
 282 # sched_setaffinity bits differently.
 283 saved_CFLAGS="$CFLAGS"
 284 CFLAGS="$CFLAGS $AM_CFLAGS -D_GNU_SOURCE"
 285
 286 AC_CHECK_TYPES([cpu_set_t],
 287         [have_cpu_set_t="yes"],
 288         [have_cpu_set_t="no"],
 289         [#include <sched.h>])
 290
 291 # Confirm that we have CPU_ZERO, and it actually works.
 292 AC_MSG_CHECKING([whether CPU_ZERO works])
 293 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 294 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 295                 #define _GNU_SOURCE
 296                 #include <sched.h>
 297                 int main()
 298                 {
 299                         cpu_set_t foo; CPU_ZERO(&foo);
 300                         return 0;
 301                 }
 302         ]])
 303 ],[
 304         AC_DEFINE(HAVE_CPU_ZERO, 1)
 305         AC_MSG_RESULT([yes])
 306 ],[
 307         AC_MSG_RESULT([no])
 308 ])
 309
 310 # Confirm that we have CPU_SET, and it actually works.
 311 AC_MSG_CHECKING([whether CPU_SET works])
 312 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 313 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 314                 #define _GNU_SOURCE
 315                 #include <sched.h>
 316                 int main()
 317                 {
 318                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 319                         return 0;
 320                 }
 321         ]])
 322 ],[
 323         AC_DEFINE(HAVE_CPU_SET, 1)
 324         AC_MSG_RESULT([yes])
 325 ],[
 326         AC_MSG_RESULT([no])
 327 ])
 328
 329 # First check if the function is available at all.
 330 AC_CHECK_FUNCS([sched_setaffinity],[
 331         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 332         # then we have the first version using unsigned long, and no
 333         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 334         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 335         # should also be present, but we confirm nonetheless.
 336
 337         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 338                 # We do have it.
 339                 # Check how many arguments does sched_setaffinity take.
 340                 # Should be 3 or 2.
 341                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 342                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 343                                 #include <sched.h>
 344                                 int main()
 345                                 {
 346                                         cpu_set_t foo;
 347                                         sched_setaffinity(0, sizeof (foo), &foo);
 348                                         return 0;
 349                                 }
 350                         ]])
 351                 ],
 352                 [sched_set_affinity_args=3],
 353                 [sched_set_affinity_args=2])
 354                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 355                         $sched_set_affinity_args,
 356                         [Defined to sched_setaffinity's number of arguments.])
 357                 AC_MSG_RESULT([$sched_set_affinity_args])
 358         ],[
 359                 # No cpu_set_t, always 3 args.
 360                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 361         ])
 362 ])
 363
 364 CFLAGS=$saved_CFLAGS
 365 AC_SUBST(AM_CFLAGS)
 366
 367 AC_CONFIG_LINKS([
 368         urcu/arch.h:$ARCHSRC
 369         urcu/uatomic.h:$UATOMICSRC
 370 ])
 371 AC_CONFIG_FILES([
 372         Makefile
 373         doc/Makefile
 374         doc/examples/Makefile
 375         tests/Makefile
 376         tests/common/Makefile
 377         tests/unit/Makefile
 378         tests/benchmark/Makefile
 379         tests/regression/Makefile
 380         tests/regression/regression_tests
 381         tests/utils/Makefile
 382         liburcu.pc
 383         liburcu-bp.pc
 384         liburcu-cds.pc
 385         liburcu-qsbr.pc
 386         liburcu-mb.pc
 387         liburcu-signal.pc
 388 ])
 389 AC_OUTPUT
 390
 391 # Report on selected configure options
 392 AS_IF([test "x$def_smp_support" = "xyes"],[
 393         AS_ECHO("SMP support enabled.")
 394 ],[
 395         AS_ECHO("SMP support disabled.")
 396 ])
 397
 398 AS_IF([test "x$def_compiler_tls" = "xyes"],[
 399         AS_ECHO("Thread Local Storage (TLS): compiler TLS.")
 400 ],[
 401         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 402 ])