configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.9.6],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24
  25 # Checks for programs.
  26 AC_PROG_GREP
  27 AC_PROG_LEX
  28 AC_PROG_MAKE_SET
  29 AC_PROG_SED
  30 AC_PROG_YACC
  31 AC_PATH_PROG(report_fold, fold)
  32 LT_INIT
  33
  34 # Check for objcopy, required by the base address statedump and dynamic linker tests
  35 AC_CHECK_TOOL([OBJCOPY], objcopy, no)
  36 AS_IF([test "x$OBJCOPY" = xno],
  37         [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  38 )
  39 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  40
  41 # Checks for typedefs, structures, and compiler characteristics.
  42 AC_C_INLINE
  43 AC_TYPE_INT32_T
  44 AC_TYPE_INT64_T
  45 AC_TYPE_MODE_T
  46 AC_TYPE_OFF_T
  47 AC_TYPE_PID_T
  48 AC_TYPE_SIZE_T
  49 AC_TYPE_SSIZE_T
  50 AC_TYPE_UID_T
  51 AC_TYPE_UINT16_T
  52 AC_TYPE_UINT32_T
  53 AC_TYPE_UINT64_T
  54 AC_TYPE_UINT8_T
  55
  56 AX_C___ATTRIBUTE__
  57 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  58         [:],
  59         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  60
  61 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  62 LIBS="$PTHREAD_LIBS $LIBS"
  63 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  64 CC="$PTHREAD_CC"
  65
  66 AX_LIB_SOCKET_NSL
  67
  68 LT_NO_UNDEFINED=""
  69 AS_CASE([$host_os],
  70   [cygwin*],
  71     [
  72       LT_NO_UNDEFINED="-no-undefined"
  73     ]
  74 )
  75
  76 AC_SUBST(LT_NO_UNDEFINED)
  77
  78 # Compute minor/major/patchlevel version numbers
  79 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  80 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  81 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  82
  83 AC_SUBST([MAJOR_VERSION], [$major_version])
  84 AC_SUBST([MINOR_VERSION], [$minor_version])
  85 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  86 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  87 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  88 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  89
  90 version_name="Joannès"
  91 version_description='Berliner Weisse style beer from the Trèfle Noir microbrewery in Rouyn-Noranda. It is a tangy beer with a distinct pink dress and intense fruit flavor, thanks to the presence of fresh blackcurrant grown in Témiscamingue.'
  92 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
  93
  94 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  95 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
  96
  97 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  98 AC_ARG_ENABLE(libtool-linkdep-fixup,
  99         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 100                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 101         libtool_fixup=$enableval,
 102         libtool_fixup=yes)
 103
 104 AS_IF([test "x$libtool_fixup" = "xyes"],
 105             [
 106             libtool_m4="$srcdir/m4/libtool.m4"
 107             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 108             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 109             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 110             AS_IF([test $libtool_flag_pattern_count -ne 0],
 111             [
 112                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 113                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 114                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 115                   ],
 116                   [
 117                   AC_MSG_RESULT([none])
 118                   ])
 119             ])
 120
 121 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 122
 123 AC_CHECK_HEADERS([ \
 124         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 125         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 126         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 127         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 128         sys/mount.h sys/param.h sys/time.h
 129 ])
 130
 131 # Basic functions check
 132 AC_CHECK_FUNCS([ \
 133         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 134         gethostbyname gethostname getpagesize localtime_r memchr memset \
 135         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 136         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 137         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 138 ])
 139
 140 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 141 # add -lrt to LIBS
 142 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 143
 144 # Checks for dl.
 145 AC_CHECK_LIB([dl], [dlopen], [
 146         have_libdl=yes
 147         libdl_name=dl
 148 ], [
 149         # libdl not found, check for dlopen in libc.
 150         AC_CHECK_LIB([c], [dlopen], [
 151                 have_libc_dl=yes
 152                 libdl_name=c
 153         ], [
 154                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 155         ])
 156 ])
 157
 158 # Check if libdl has dlmopen support.
 159 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 160 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 161         AC_DEFINE([HAVE_DLMOPEN], [1])
 162         HAVE_DLMOPEN=1
 163 ], [
 164         HAVE_DLMOPEN=0
 165 ])
 166 AC_SUBST(HAVE_DLMOPEN)
 167
 168 # Babeltrace viewer check
 169 AC_ARG_WITH([babeltrace-bin],
 170         AS_HELP_STRING([--with-babeltrace-bin],
 171         [Location of the babeltrace viewer executable (including the filename)]),
 172         [BABELTRACE_BIN="$withval"],
 173         [BABELTRACE_BIN=''])
 174 AC_SUBST([BABELTRACE_BIN])
 175
 176 # lttv-gui
 177 AC_ARG_WITH([lttv-gui-bin],
 178         AS_HELP_STRING([--with-lttv-gui-bin],
 179    [Location of the lttv GUI viewer executable (including the filename)]),
 180    [LTTV_GUI_BIN="$withval"],
 181    [LTTV_GUI_BIN=''])
 182 AC_SUBST([LTTV_GUI_BIN])
 183
 184 AC_ARG_WITH([consumerd32-bin],
 185         AS_HELP_STRING([--with-consumerd32-bin],
 186         [Location of the 32-bit consumerd executable (including the filename)]),
 187         [CONSUMERD32_BIN="$withval"],
 188         [CONSUMERD32_BIN=''])
 189 AC_SUBST([CONSUMERD32_BIN])
 190
 191 AC_ARG_WITH([consumerd64-bin],
 192         AS_HELP_STRING([--with-consumerd64-bin],
 193         [Location of the 64-bit consumerd executable (including the filename)]),
 194         [CONSUMERD64_BIN="$withval"],
 195         [CONSUMERD64_BIN=''])
 196 AC_SUBST([CONSUMERD64_BIN])
 197
 198 AC_ARG_WITH([consumerd32-libdir],
 199         AS_HELP_STRING([--with-consumerd32-libdir],
 200         [Directory containing the 32-bit consumerd libraries]),
 201         [CONSUMERD32_LIBDIR="$withval"],
 202         [CONSUMERD32_LIBDIR=''])
 203 AC_SUBST([CONSUMERD32_LIBDIR])
 204
 205 AC_ARG_WITH([consumerd64-libdir],
 206         AS_HELP_STRING([--with-consumerd64-libdir],
 207         [Directory containing the 64-bit consumerd libraries]),
 208         [CONSUMERD64_LIBDIR="$withval"],
 209         [CONSUMERD64_LIBDIR=''])
 210 AC_SUBST([CONSUMERD64_LIBDIR])
 211
 212 AC_ARG_WITH([sessiond-bin],
 213         AS_HELP_STRING([--with-sessiond-bin],
 214         [Location of the sessiond executable (including the filename)]),
 215         [SESSIOND_BIN="$withval"],
 216         [SESSIOND_BIN=''])
 217 AC_SUBST([SESSIOND_BIN])
 218
 219 AC_ARG_WITH([lttng-system-rundir],
 220         AS_HELP_STRING([--with-lttng-system-rundir],
 221         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 222         [LTTNG_SYSTEM_RUNDIR="$withval"],
 223         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 224 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 225
 226 AC_ARG_ENABLE([test-java-agent-jul],
 227         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 228         [test_java_agent_jul=$enableval],
 229         [test_java_agent_jul=no]
 230 )
 231
 232 AC_ARG_ENABLE([test-java-agent-log4j],
 233         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 234         [test_java_agent_log4j=$enableval],
 235         [test_java_agent_log4j=no]
 236 )
 237
 238 AC_ARG_ENABLE([test-java-agent-all],
 239         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 240         [test_java_agent_jul=$enableval
 241          test_java_agent_log4j=$enableval],
 242         [:]
 243 )
 244
 245 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 246 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 247 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 248 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 249 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 250 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 251 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 252 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 253
 254 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 255         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 256         $1="$2"
 257         AC_SUBST([$1])
 258 ])
 259
 260 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 261         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 262         $1="$2"
 263         AC_SUBST([$1])
 264 ])
 265
 266 # Default values
 267 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [4096])
 268 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 269 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 270 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 271 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 272 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
 273 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 274 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 275 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 276 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 277 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 278 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 279 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 280 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [262144])
 281 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 282 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 283 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 284 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 285 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 286 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 287 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 288 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 289 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 290 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 291 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 292 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 293 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 294 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 295 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 296 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 297 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 298 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 299 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [131072])
 300 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 301 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 302 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 303 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 304 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 305
 306 # Command short descriptions
 307 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 308 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 309 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 310 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 311 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 312 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 313 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 314 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 315 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 316 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 317 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 318 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 319 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 320 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 321 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 322 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 323 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 324 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 325 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 326 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 327 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 328
 329 if test "x$prefix" = "xNONE"; then
 330         prefix=$ac_default_prefix
 331 fi
 332 CONFDIR=`eval echo $sysconfdir`
 333 AC_SUBST(CONFDIR)
 334 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 335
 336 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 337
 338 #
 339 # Check for pthread
 340 AC_CHECK_LIB([pthread], [pthread_create], [],
 341         [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
 342 )
 343
 344 # Check libpopt
 345 PKG_CHECK_MODULES([POPT], [popt],
 346         [LIBS="$LIBS $POPT_LIBS"],
 347         [
 348                 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 349                 AC_MSG_WARN([Finding libpopt without pkg-config.])
 350                 AC_CHECK_LIB([popt],
 351                         [poptGetContext],
 352                         [],
 353                         [
 354                                  AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 355                         ]
 356                 )
 357         ]
 358 )
 359
 360 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 361
 362 # Check for uuid in system libs
 363 AC_CHECK_FUNCS([uuid_generate],
 364 [
 365         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 366         link_with_libuuid=no
 367 ],
 368 [
 369 # First, check the pkg-config module is available, otherwise explicitly check
 370 # for libuuid, or uuid support in the C-library.
 371 PKG_CHECK_MODULES([UUID], [uuid],
 372 [
 373         LIBS="$LIBS $UUID_LIBS"
 374         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 375         link_with_libuuid=yes
 376 ],
 377 [
 378         # Check for libuuid
 379         AC_CHECK_LIB([uuid],
 380                 [uuid_generate],
 381                 [
 382                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 383                         link_with_libuuid=yes
 384                 ],
 385                 [
 386                         # libuuid not found, check for uuid_create in libc.
 387                         AC_CHECK_LIB([c],
 388                                 [uuid_create],
 389                                 [
 390                                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 391                                         link_with_libc_uuid=yes
 392                                 ],
 393                                 [
 394                                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 395                                 ]
 396                         )
 397                 ]
 398         )
 399 ])
 400 ])
 401
 402 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 403 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 404
 405 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 406
 407 # URCU library version needed or newer
 408 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
 409
 410 # Check liburcu needed function calls
 411 AC_CHECK_DECL([cds_list_add], [],
 412         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 413 AC_CHECK_DECL([cds_wfcq_init], [],
 414         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 415 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 416         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 417 AC_CHECK_DECL([futex_async], [],
 418         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 419 AC_CHECK_DECL([rcu_thread_offline], [],
 420         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 421 AC_CHECK_DECL([rcu_thread_online], [],
 422         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 423 AC_CHECK_DECL([caa_likely], [],
 424         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 425 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 426         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 427
 428 #Function added in urcu 0.7.0
 429 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 430         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 431 )
 432
 433 # Check kmod library
 434 AC_ARG_WITH(kmod-prefix,
 435   AS_HELP_STRING([--with-kmod-prefix=PATH],
 436                 [Specify the installation prefix of the kmod library.
 437                 Headers must be in PATH/include; libraries in PATH/lib.]),
 438                 [
 439                         CPPFLAGS="$CPPFLAGS -I${withval}/include"
 440                         LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 441                 ])
 442
 443 AC_ARG_ENABLE(kmod,
 444         AS_HELP_STRING([--disable-kmod],[build without kmod support]),
 445         kmod_support=$enableval, kmod_support=yes)
 446
 447 AS_IF([test "x$kmod_support" = "xyes"], [
 448         AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 449                 [
 450                         AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
 451                         LIBS="$LIBS -lkmod"
 452                         kmod_found=yes
 453                 ],
 454                 kmod_found=no
 455         )
 456 ])
 457 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
 458
 459 AC_ARG_WITH(lttng-ust-prefix,
 460   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 461                  [Specify the installation prefix of the lttng-ust library.
 462                   Headers must be in PATH/include; libraries in PATH/lib.]),
 463                   [
 464                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 465                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 466                   ])
 467
 468 # Check liblttng-ust-ctl library
 469 AC_ARG_WITH(lttng-ust,
 470         AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 471         lttng_ust_support=$withval, lttng_ust_support=yes)
 472
 473 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 474         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 475                 [
 476                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 477                         lttng_ust_ctl_found=yes
 478                 ],
 479                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])],
 480                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 481         )
 482 ])
 483 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 484 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 485
 486 # check for dlopen
 487 AC_CHECK_LIB([dl], [dlopen],
 488 [
 489         have_libdl=yes
 490 ],
 491 [
 492         #libdl not found, check for dlopen in libc.
 493         AC_CHECK_LIB([c], [dlopen],
 494         [
 495                 have_libc_dl=yes
 496         ],
 497         [
 498                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 499         ])
 500 ])
 501 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 502 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 503
 504 # Check for fmemopen
 505 AC_CHECK_LIB([c], [fmemopen],
 506 [
 507         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 508 ]
 509 )
 510
 511 # Check for open_memstream
 512 AC_CHECK_LIB([c], [open_memstream],
 513 [
 514         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 515 ]
 516 )
 517
 518 # check for libpfm
 519 AC_CHECK_LIB([pfm], [pfm_initialize],
 520              [
 521               have_libpfm=yes
 522               ])
 523 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 524
 525 AC_ARG_ENABLE([git-version],
 526               [AC_HELP_STRING([--disable-git-version],
 527                               [Do not use the git version for the build])],
 528               [have_git_version=$enableval], [have_git_version=yes]
 529 )
 530
 531 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 532         [test "x${have_git_version}" = "xyes"])
 533
 534 # For Python
 535 # SWIG version needed or newer:
 536 swig_version=2.0.0
 537
 538 AC_ARG_ENABLE([python-bindings],
 539               [AC_HELP_STRING([--enable-python-bindings],
 540                               [compile Python bindings])],
 541               [enable_python_binding=$enableval], [enable_python_binding=no])
 542
 543 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 544
 545 if test "x$enable_python_binding" = xyes; then
 546   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 547   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 548   AM_PATH_PYTHON([3.0])
 549
 550   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 551   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 552   AS_IF([test -z "$PYTHON_INCLUDE"], [
 553     AS_IF([test -z "$PYTHON_CONFIG"], [
 554       AC_PATH_PROGS([PYTHON_CONFIG],
 555                     [python$PYTHON_VERSION-config python-config],
 556                     [no],
 557                     [`dirname $PYTHON`])
 558       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 559     ])
 560     AC_MSG_CHECKING([python include flags])
 561     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 562     AC_MSG_RESULT([$PYTHON_INCLUDE])
 563   ])
 564
 565 else
 566     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 567 [if you want Python bindings.])
 568
 569 fi
 570
 571 # Epoll check. If not present, the build will fallback on poll() API
 572 AX_HAVE_EPOLL(
 573         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 574         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 575 )
 576 AX_CONFIG_FEATURE(
 577         [epoll], [This platform supports epoll(7)],
 578         [HAVE_EPOLL], [This platform supports epoll(7).],
 579         [enable_epoll="yes"], [enable_epoll="no"]
 580 )
 581 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 582
 583 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 584 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 585
 586 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 587         AX_JAVA_OPTIONS
 588         AX_PROG_JAVAC
 589         AX_PROG_JAVA
 590         AX_PROG_JAR
 591
 592         AX_CHECK_CLASSPATH
 593
 594         # Check for Java UST agent common class first
 595         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 596         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 597                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 598         fi
 599
 600         if test "x$test_java_agent_jul" = "xyes"; then
 601                 # Check for JUL agent class
 602                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 603                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 604                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 605                 fi
 606         fi
 607
 608         if test "x$test_java_agent_log4j" = "xyes"; then
 609                 # Check for Log4j agent class
 610                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 611                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 612                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 613                 fi
 614
 615                 # Check for Log4j class
 616                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 617                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 618                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 619                 fi
 620         fi
 621 fi
 622
 623 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 624 # is not distributed in tarballs
 625 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 626 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 627
 628 # enable building man pages (user's intention)
 629 AC_ARG_ENABLE(
 630         man-pages,
 631         AS_HELP_STRING(
 632                 [--disable-man-pages],
 633                 [Do not build and install man pages (already built in a distributed tarball)]
 634         ),
 635         [man_pages_opt=$enableval],
 636         [man_pages_opt=yes]
 637 )
 638
 639 # check for asciidoc and xmlto if we enabled building the man pages
 640 have_asciidoc_xmlto=no
 641 warn_prebuilt_man_pages=no
 642
 643 AS_IF([test "x$man_pages_opt" = "xyes"], [
 644         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 645         AC_PATH_PROG([XMLTO], [xmlto], [no])
 646
 647         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 648                 AS_IF([test "x$in_git_repo" = "xyes"], [
 649                         # this is an error because we're in the Git repo, which
 650                         # means the man pages are not already generated for us,
 651                         # thus asciidoc/xmlto are required because we were asked
 652                         # to build the man pages
 653                         AC_MSG_ERROR([
 654 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 655 --disable-man-pages to disable building the man pages, in which case
 656 they will not be installed.
 657                         ])
 658                 ], [
 659                         # only warn here: since we're in the tarball, the man
 660                         # pages should already be generated at this point, thus
 661                         # asciidoc/xmlto are not strictly required
 662                         warn_prebuilt_man_pages=yes
 663                 ])
 664         ], [
 665                 have_asciidoc_xmlto=yes
 666         ])
 667 ])
 668
 669 # export man page build condition: build the man pages if the user
 670 # asked for it, and if the tools are available
 671 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 672 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 673
 674 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 675
 676 # Python agent test
 677 UST_PYTHON_AGENT="lttngust"
 678
 679 AC_ARG_ENABLE(test-python2-agent,
 680         AS_HELP_STRING([--enable-test-python2-agent],
 681                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 682         ),[:],[test_python2_agent_autodetect=yes]
 683 )
 684
 685 AC_ARG_ENABLE(test-python3-agent,
 686         AS_HELP_STRING([--enable-test-python3-agent],
 687                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 688         ),[:],[test_python3_agent_autodetect=yes]
 689 )
 690
 691 AC_ARG_ENABLE(test-python-agent-all,
 692         AS_HELP_STRING([--enable-test-python-agent-all],
 693                 [enable test for all python{2/3} agent.]
 694         ),
 695 )
 696
 697 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 698        unset test_python2_agent_autodetect
 699        unset test_python3_agent_autodetect
 700 ])
 701
 702 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 703        enable_test_python2_agent=yes
 704        enable_test_python3_agent=yes
 705 ])
 706
 707 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 708        enable_test_python2_agent=no
 709        enable_test_python3_agent=no
 710 ])
 711
 712
 713 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 714         AS_IF([test -z "$PYTHON2"], [
 715                         PYTHON2=python2
 716                 ], [
 717                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 718         ])
 719
 720         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 721         AS_IF([test -z "$PYTHON2_BIN"], [
 722                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 723                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 724                 ])
 725         ], [
 726                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 727                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 728                         PYTHON2_AGENT=$PYTHON2_BIN
 729                         AC_MSG_RESULT([yes])
 730                         RUN_PYTHON_AGENT_TEST=yes
 731                 ], [
 732                         AC_MSG_RESULT([no])
 733                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 734                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 735                         ])
 736                 ])
 737
 738         ])
 739
 740 ])
 741
 742 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 743         AS_IF([test -z "$PYTHON3"], [
 744                 PYTHON3=python3
 745         ], [
 746                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 747         ])
 748
 749         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 750         AS_IF([test -z "$PYTHON3_BIN"], [
 751                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 752                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 753                 ])
 754         ], [
 755                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 756                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 757                         PYTHON3_AGENT=$PYTHON3_BIN
 758                         AC_MSG_RESULT([yes])
 759                         RUN_PYTHON_AGENT_TEST=yes
 760                 ], [
 761                         AC_MSG_RESULT([no])
 762                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 763                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 764                         ])
 765                 ])
 766
 767         ])
 768 ])
 769 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 770 AC_SUBST([PYTHON2_AGENT])
 771 AC_SUBST([PYTHON3_AGENT])
 772
 773 # Arguments for binaries build exclusion
 774 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 775 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 776               [Disable the build of lttng-consumerd binaries]))
 777 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 778 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 779               [Disable the build of lttng-relayd binaries]))
 780 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 781               [Disable the build of lttng-sessiond binaries]))
 782 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 783               [Disable the build of the extra components]))
 784
 785
 786 # Always build libconfig since it a dependency of libcommon
 787 build_lib_config=yes
 788
 789 build_lib_compat=no
 790 build_lib_consumer=no
 791 build_lib_hashtable=no
 792 build_lib_health=no
 793 build_lib_index=no
 794 build_lib_kernel_consumer=no
 795 build_lib_kernel_ctl=no
 796 build_lib_lttng_ctl=no
 797 build_lib_relayd=no
 798 build_lib_sessiond_comm=no
 799 build_lib_testpoint=no
 800 build_lib_ust_consumer=no
 801
 802 # There is an overlap for enabled dependencies, but this makes everything
 803 # simpler. libcommon and libconfig are always compiled so they are not repeated
 804 # here.
 805
 806 # Enable binary dependencies.
 807 AS_IF([test x$enable_bin_lttng != xno],
 808       [
 809        build_lib_lttng_ctl=yes
 810       ]
 811 )
 812
 813 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 814       [
 815        build_lib_consumer=yes
 816        build_lib_sessiond_comm=yes
 817        build_lib_index=yes
 818        build_lib_health=yes
 819        build_lib_testpoint=yes
 820       ]
 821 )
 822
 823 AS_IF([test x$enable_bin_lttng_crash != xno],
 824       # Do nothing since libconfig and libcommon are built by default.
 825       []
 826 )
 827
 828 AS_IF([test x$enable_bin_lttng_relayd != xno],
 829       [
 830        build_lib_lttng_ctl=yes
 831        build_lib_sessiond_comm=yes
 832        build_lib_hashtable=yes
 833        build_lib_compat=yes
 834        build_lib_index=yes
 835        build_lib_health=yes
 836        build_lib_testpoint=yes
 837       ]
 838 )
 839 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 840       [
 841        build_lib_lttng_ctl=yes
 842        build_lib_sessiond_comm=yes
 843        build_lib_kernel_ctl=yes
 844        build_lib_hashtable=yes
 845        build_lib_compat=yes
 846        build_lib_relayd=yes
 847        build_lib_testpoint=yes
 848        build_lib_health=yes
 849        build_lib_health=yes
 850       ]
 851 )
 852
 853 # Libraries dependencies enabling
 854 AS_IF([test x$build_lib_lttng_ctl = xyes],
 855       [
 856        build_lib_sessiond_comm=yes
 857        build_lib_hashtable=yes
 858       ]
 859 )
 860
 861 AS_IF([test x$build_lib_consumer = xyes],
 862       [
 863        build_lib_sessiond_comm=yes
 864        build_lib_kernel_consumer=yes
 865        build_lib_hashtable=yes
 866        build_lib_compat=yes
 867        build_lib_relayd=yes
 868        AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes])
 869       ]
 870 )
 871
 872 AS_IF([test x$build_lib_kernel_consumer = xyes],
 873       [
 874        build_lib_kernel_ctl=yes
 875        build_lib_relayd=yes
 876       ]
 877 )
 878
 879 AS_IF([test x$build_lib_relayd = xyes],
 880       [
 881        build_lib_sessiond_comm=yes
 882       ]
 883 )
 884
 885
 886 # Export binaries build conditions.
 887 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 888 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 889 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 890 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 891 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 892
 893 # Export the tests and extras build conditions.
 894 AS_IF([\
 895 test "x$enable_bin_lttng" != "xno" && \
 896 test "x$enable_bin_lttng_consumerd" != "xno" && \
 897 test "x$enable_bin_lttng_crash" != "xno" && \
 898 test "x$enable_bin_lttng_relayd" != "xno" && \
 899 test "x$enable_bin_lttng_sessiond" != "xno"],
 900 [build_tests=yes],
 901 [build_tests=no]
 902 )
 903
 904 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 905 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 906
 907 # Export libraries build conditions.
 908 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 909 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 910 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 911 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 912 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 913 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 914 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 915 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 916 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 917 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 918 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 919 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 920 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
 921
 922 # check for pgrep
 923 AC_PATH_PROG([PGREP], [pgrep], [no])
 924 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
 925
 926 # check for bison
 927 have_bison=yes
 928
 929 AS_IF([test "x$(basename "$YACC")" != "xbison -y"], [have_bison=no])
 930 AC_PATH_PROG([BISON], [bison])
 931 AX_PROG_BISON_VERSION([2.4], [], [have_bison=no])
 932
 933 AS_IF([test "x$have_bison" = "xno"], [
 934         AS_IF([test "x$in_git_repo" = "xyes"], [
 935                 AC_MSG_ERROR([Bison >= 2.4 is required when building from the Git repository.])
 936         ], [
 937                 AC_MSG_WARN([
 938 Missing Bison >= 2.4. Note that the parser files are already built in
 939 this distribution tarball, so Bison is only needed if you intend to
 940 modify their sources.
 941                 ])
 942         ])
 943 ])
 944
 945 # export bison condition
 946 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 947
 948 # check for flex
 949 have_flex=yes
 950
 951 AS_IF([test "x$LEX" != "xflex"], [have_flex=no])
 952 AC_PATH_PROG([FLEX], [flex])
 953 AX_PROG_FLEX_VERSION([2.5.35], [], [have_flex=no])
 954
 955 AS_IF([test "x$have_flex" = "xno"], [
 956         AS_IF([test "x$in_git_repo" = "xyes"], [
 957                 AC_MSG_ERROR([Flex >= 2.5.35 is required when building from the Git repository.])
 958         ], [
 959                 AC_MSG_WARN([
 960 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 961 this distribution tarball, so Flex is only needed if you intend to
 962 modify their sources.
 963                 ])
 964         ])
 965 ])
 966
 967 # export flex condition
 968 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 969
 970 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 971
 972 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 973
 974 lttngincludedir="${includedir}/lttng"
 975
 976 AC_SUBST(lttngincludedir)
 977 AC_SUBST(DEFAULT_INCLUDES)
 978
 979 lttnglibexecdir="${libdir}/lttng/libexec"
 980 AC_SUBST(lttnglibexecdir)
 981
 982 AC_CONFIG_FILES([
 983         Makefile
 984         doc/Makefile
 985         doc/man/Makefile
 986         doc/man/asciidoc-attrs.conf
 987         include/Makefile
 988         extras/Makefile
 989         extras/bindings/Makefile
 990         extras/bindings/swig/Makefile
 991         extras/bindings/swig/python/Makefile
 992         extras/core-handler/Makefile
 993         src/Makefile
 994         src/common/Makefile
 995         src/common/kernel-ctl/Makefile
 996         src/common/kernel-consumer/Makefile
 997         src/common/consumer/Makefile
 998         src/common/ust-consumer/Makefile
 999         src/common/hashtable/Makefile
1000         src/common/sessiond-comm/Makefile
1001         src/common/compat/Makefile
1002         src/common/relayd/Makefile
1003         src/common/testpoint/Makefile
1004         src/common/index/Makefile
1005         src/common/health/Makefile
1006         src/common/config/Makefile
1007         src/lib/Makefile
1008         src/lib/lttng-ctl/Makefile
1009         src/lib/lttng-ctl/filter/Makefile
1010         src/lib/lttng-ctl/lttng-ctl.pc
1011         src/bin/Makefile
1012         src/bin/lttng-consumerd/Makefile
1013         src/bin/lttng-sessiond/Makefile
1014         src/bin/lttng-relayd/Makefile
1015         src/bin/lttng/Makefile
1016         src/bin/lttng-crash/Makefile
1017         tests/Makefile
1018         tests/destructive/Makefile
1019         tests/regression/Makefile
1020         tests/regression/kernel/Makefile
1021         tests/regression/tools/Makefile
1022         tests/regression/tools/streaming/Makefile
1023         tests/regression/tools/filtering/Makefile
1024         tests/regression/tools/health/Makefile
1025         tests/regression/tools/tracefile-limits/Makefile
1026         tests/regression/tools/snapshots/Makefile
1027         tests/regression/tools/live/Makefile
1028         tests/regression/tools/exclusion/Makefile
1029         tests/regression/tools/save-load/Makefile
1030         tests/regression/tools/save-load/configuration/Makefile
1031         tests/regression/tools/mi/Makefile
1032         tests/regression/tools/wildcard/Makefile
1033         tests/regression/tools/crash/Makefile
1034         tests/regression/tools/regen-metadata/Makefile
1035         tests/regression/tools/regen-statedump/Makefile
1036         tests/regression/ust/Makefile
1037         tests/regression/ust/nprocesses/Makefile
1038         tests/regression/ust/high-throughput/Makefile
1039         tests/regression/ust/low-throughput/Makefile
1040         tests/regression/ust/before-after/Makefile
1041         tests/regression/ust/buffers-pid/Makefile
1042         tests/regression/ust/periodical-metadata-flush/Makefile
1043         tests/regression/ust/multi-session/Makefile
1044         tests/regression/ust/overlap/Makefile
1045         tests/regression/ust/overlap/demo/Makefile
1046         tests/regression/ust/linking/Makefile
1047         tests/regression/ust/daemon/Makefile
1048         tests/regression/ust/exit-fast/Makefile
1049         tests/regression/ust/fork/Makefile
1050         tests/regression/ust/libc-wrapper/Makefile
1051         tests/regression/ust/baddr-statedump/Makefile
1052         tests/regression/ust/ust-dl/Makefile
1053         tests/regression/ust/java-jul/Makefile
1054         tests/regression/ust/java-log4j/Makefile
1055         tests/regression/ust/python-logging/Makefile
1056         tests/regression/ust/getcpu-override/Makefile
1057         tests/regression/ust/clock-override/Makefile
1058         tests/regression/ust/type-declarations/Makefile
1059         tests/regression/ust/rotation-destroy-flush/Makefile
1060         tests/stress/Makefile
1061         tests/unit/Makefile
1062         tests/unit/ini_config/Makefile
1063         tests/perf/Makefile
1064         tests/utils/Makefile
1065         tests/utils/tap/Makefile
1066         tests/utils/testapp/Makefile
1067         tests/utils/testapp/gen-ust-events/Makefile
1068         tests/utils/testapp/gen-ust-nevents/Makefile
1069         tests/utils/testapp/gen-ust-tracef/Makefile
1070 ])
1071
1072 # Inject variable into python test script.
1073 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1074 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1075 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1076 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1077
1078 AC_OUTPUT
1079
1080 #
1081 # Mini-report on what will be built.
1082 #
1083
1084 PPRINT_INIT
1085 PPRINT_SET_INDENT(1)
1086 PPRINT_SET_TS(38)
1087
1088 AS_ECHO
1089 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1090 AS_ECHO
1091
1092 AS_IF([test -n "$report_fold"], [
1093         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1094 ], [
1095         AS_ECHO("$version_description")
1096 ])
1097
1098 AS_ECHO
1099 PPRINT_SUBTITLE([Features])
1100
1101 # Target architecture we're building for.
1102 target_arch=$host_cpu
1103 [
1104 for f in $CFLAGS; do
1105         if test $f = "-m32"; then
1106                         target_arch="32-bit"
1107         elif test $f = "-m64"; then
1108                         target_arch="64-bit"
1109         fi
1110 done
1111 ]
1112 PPRINT_PROP_STRING([Target architecture], $target_arch)
1113
1114 # kmod enabled/disabled
1115 test "x$kmod_found" = "xyes" && value=1 || value=0
1116 PPRINT_PROP_BOOL([libkmod support], $value)
1117
1118 # LTTng-UST enabled/disabled
1119 test "x$lttng_ust_support" = "xyes" && value=1 || value=0
1120 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1121
1122 AS_ECHO
1123 PPRINT_SUBTITLE([Binaries])
1124
1125 # List binaries to be built
1126 test x$enable_bin_lttng != xno && value=1 || value=0
1127 PPRINT_PROP_BOOL([lttng], $value)
1128
1129 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1130 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1131
1132 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1133 PPRINT_PROP_BOOL([lttng-crash], $value)
1134
1135 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1136 PPRINT_PROP_BOOL([lttng-relayd], $value)
1137
1138 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1139 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1140
1141 # Extras
1142 test x$enable_extras != xno && value=1 || value=0
1143 AS_ECHO
1144 PPRINT_SET_INDENT(0)
1145 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1146 PPRINT_SET_INDENT(1)
1147
1148 AS_ECHO
1149 PPRINT_SUBTITLE([Tests])
1150
1151 # Print clear message that tests won't be built
1152 AS_IF([test "x$build_tests" = "xno"],[
1153         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1154 ])
1155
1156 # LTTng UST Java agent JUL tests enabled/disabled
1157 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1158 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1159
1160 # LTTng UST Java agent Log4j tests enabled/disabled
1161 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1162 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1163
1164 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1165 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1166
1167 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1168 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1169
1170 #Python binding enabled/disabled
1171 test "x$enable_python_binding" = xyes && value=1 || value=0
1172 AS_ECHO
1173 PPRINT_SET_INDENT(0)
1174 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1175
1176 # man pages build enabled/disabled
1177 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1178
1179 AS_IF([test "x$man_pages_opt" != "xno"], [
1180         AS_IF([test "x$in_git_repo" = "xyes"], [
1181                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1182         ], [
1183                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1184                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1185                 ], [
1186                         PPRINT_PROP_STRING([build_man_pages_msg],
1187                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1188                                 $PPRINT_COLOR_SUBTITLE)
1189                 ])
1190         ])
1191 ], [
1192         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1193 ])
1194
1195 m4_popdef([build_man_pages_msg])
1196
1197 PPRINT_SET_INDENT(1)
1198
1199 report_bindir="`eval eval echo $bindir`"
1200 report_libdir="`eval eval echo $libdir`"
1201
1202 # Print the bindir and libdir this `make install' will install into.
1203 AS_ECHO
1204 PPRINT_SUBTITLE([Install directories])
1205 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1206 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1207
1208 AS_ECHO
1209 PPRINT_SUBTITLE([Search directories])
1210
1211 # If we build the sessiond, print the paths it will use
1212 AS_IF([test "$SESSIOND_BIN" = ""],[
1213         path="$report_bindir/lttng-sessiond"
1214 ],[
1215         path="$SESSIOND_BIN"
1216 ])
1217 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1218
1219 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1220         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1221 ],[
1222         path="$CONSUMERD32_BIN"
1223 ])
1224 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1225
1226 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1227         path="`eval eval echo $libdir`"
1228 ],[
1229         path="$CONSUMERD32_LIBDIR"
1230 ])
1231 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1232
1233 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1234         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1235 ],[
1236         path="$CONSUMERD64_BIN"
1237 ])
1238 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1239
1240 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1241         path="`eval eval echo $libdir`"
1242 ],[
1243         path="$CONSUMERD64_LIBDIR"
1244 ])
1245 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1246 PPRINT_SET_INDENT(0)
1247
1248 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1249         AS_ECHO
1250         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1251
1252 Note that the man pages are already built in this distribution tarball,
1253 therefore asciidoc and xmlto are only needed if you intend to modify
1254 their sources.
1255
1256 Also note that the installed man pages will contain the project's
1257 default command-line option and environment variable values.
1258
1259 Use --disable-man-pages to completely disable building and installing
1260 the man pages.])
1261 ])