gas/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl   Copyright (C) 2012-2021 Free Software Foundation, Inc.
   7 dnl
   8 dnl This file is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; see the file COPYING3.  If not see
  20 dnl <http://www.gnu.org/licenses/>.
  21 dnl
  22 dnl v2.5 needed for --bindir et al
  23 m4_include([../bfd/version.m4])
  24 AC_INIT([gas], BFD_VERSION)
  25 AC_CONFIG_SRCDIR(as.h)
  26
  27 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  28 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  29 dnl gas/ instead of gas/../.
  30 AC_CONFIG_AUX_DIR(..)
  31 AC_CANONICAL_TARGET
  32 AC_ISC_POSIX
  33
  34 AM_INIT_AUTOMAKE
  35
  36 AC_PROG_CC
  37 AC_GNU_SOURCE
  38 AC_USE_SYSTEM_EXTENSIONS
  39
  40 LT_INIT
  41 ACX_LARGEFILE
  42 ACX_PROG_CMP_IGNORE_INITIAL
  43
  44 AC_ARG_ENABLE(targets,
  45 [  --enable-targets        alternative target configurations besides the primary],
  46 [case "${enableval}" in
  47   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  48             ;;
  49   no)       enable_targets= ;;
  50   *)        enable_targets=$enableval ;;
  51 esac])dnl
  52
  53 ac_checking=
  54 . ${srcdir}/../bfd/development.sh
  55 test "$development" = true && ac_checking=yes
  56 AC_ARG_ENABLE(checking,
  57 [  --enable-checking       enable run-time checks],
  58 [case "${enableval}" in
  59   no|none)  ac_checking= ;;
  60   *)        ac_checking=yes ;;
  61 esac])dnl
  62 if test x$ac_checking != x ; then
  63   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  64 fi
  65
  66 # PR gas/19109
  67 # Decide the default method for compressing debug sections.
  68 ac_default_compressed_debug_sections=unset
  69 # Provide a configure time option to override our default.
  70 AC_ARG_ENABLE(compressed_debug_sections,
  71               AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,none}],
  72               [compress debug sections by default]),
  73 [case ,"${enableval}", in
  74   ,yes, | ,all, | *,gas,*) ac_default_compressed_debug_sections=yes ;;
  75   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
  76   *)   ac_default_compressed_debug_sections=unset ;;
  77 esac])dnl
  78
  79 # PR gas/19520
  80 # Decide if x86 assembler should generate relax relocations.
  81 ac_default_x86_relax_relocations=unset
  82 # Provide a configure time option to override our default.
  83 AC_ARG_ENABLE(x86_relax_relocations,
  84               AS_HELP_STRING([--enable-x86-relax-relocations],
  85               [generate x86 relax relocations by default]),
  86 [case "${enableval}" in
  87   no)  ac_default_x86_relax_relocations=0 ;;
  88 esac])dnl
  89
  90 # Decide if ELF assembler should generate common symbols with the
  91 # STT_COMMON type.
  92 ac_default_elf_stt_common=unset
  93 # Provide a configure time option to override our default.
  94 AC_ARG_ENABLE(elf_stt_common,
  95               AS_HELP_STRING([--enable-elf-stt-common],
  96               [generate ELF common symbols with STT_COMMON type by default]),
  97 [case "${enableval}" in
  98   yes)  ac_default_elf_stt_common=1 ;;
  99 esac])dnl
 100
 101
 102 # Decide if the ELF assembler should default to generating
 103 # GNU Build notes if none are provided by the input.
 104 ac_default_generate_build_notes=0
 105 # Provide a configuration option to override the default.
 106 AC_ARG_ENABLE(generate_build_notes,
 107               AS_HELP_STRING([--enable-generate-build-notes],
 108               [generate GNU Build notes if none are provided by the input]),
 109 [case "${enableval}" in
 110   yes)  ac_default_generate_build_notes=1 ;;
 111   no)   ac_default_generate_build_notes=0 ;;
 112 esac])dnl
 113
 114 # Decide if the MIPS assembler should default to enable MIPS fix Loongson3
 115 # LLSC errata.
 116 ac_default_mips_fix_loongson3_llsc=unset
 117 # Provide a configuration option to override the default.
 118 AC_ARG_ENABLE(mips-fix-loongson3-llsc,
 119              AS_HELP_STRING([--enable-mips-fix-loongson3-llsc],
 120              [enable MIPS fix Loongson3 LLSC errata]),
 121 [case "${enableval}" in
 122   yes)  ac_default_mips_fix_loongson3_llsc=1 ;;
 123   no)   ac_default_mips_fix_loongson3_llsc=0 ;;
 124 esac])dnl
 125
 126 # Decide if the x86 ELF assembler should default to generating GNU x86
 127 # used ISA and feature properties.
 128 ac_default_generate_x86_used_note=unset
 129 # Provide a configuration option to override the default.
 130 AC_ARG_ENABLE(x86-used-note,
 131               AS_HELP_STRING([--enable-x86-used-note],
 132               [generate GNU x86 used ISA and feature properties]),
 133 [case "${enableval}" in
 134   yes)  ac_default_generate_x86_used_note=1 ;;
 135   no)   ac_default_generate_x86_used_note=0 ;;
 136 esac])dnl
 137
 138 # Decide if the RISC-V ELF assembler should default to generating attribute.
 139 ac_default_generate_riscv_attr=unset
 140 # Provide a configuration option to override the default.
 141 AC_ARG_ENABLE(default-riscv-attribute,
 142               AS_HELP_STRING([--enable-default-riscv-attribute],
 143               [generate RISC-V arch attribute by default]),
 144 [case "${enableval}" in
 145   yes)  ac_default_generate_riscv_attr=1 ;;
 146   no)   ac_default_generate_riscv_attr=0 ;;
 147 esac])dnl
 148
 149 using_cgen=no
 150
 151 AM_BINUTILS_WARNINGS
 152
 153 # Generate a header file
 154 AC_CONFIG_HEADERS(config.h:config.in)
 155
 156 dnl Option --with-cpu=TYPE allows configure type control of the default
 157 dnl cpu type within the assembler.  Currently only the ARC target
 158 dnl supports this feature, but others may be added in the future.
 159 AC_ARG_WITH(cpu,
 160             AS_HELP_STRING([--with-cpu=CPU],
 161             [default cpu variant is CPU (currently only supported on ARC)]),
 162             [AC_DEFINE_UNQUOTED(TARGET_WITH_CPU,
 163                                 "${with_cpu}",
 164                                 [Target specific CPU.])],
 165             [])
 166
 167 # PR 14072
 168 AH_VERBATIM([00_CONFIG_H_CHECK],
 169 [/* Check that config.h is #included before system headers
 170    (this works only for glibc, but that should be enough).  */
 171 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 172 #  error config.h must be #included before system headers
 173 #endif
 174 #define __CONFIG_H__ 1])
 175
 176 # If we are on a DOS filesystem, we must use gdb.ini rather than
 177 # .gdbinit.
 178 case "${host}" in
 179   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
 180     GDBINIT="gdb.ini"
 181     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
 182     ;;
 183   *)
 184     GDBINIT=".gdbinit"
 185     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
 186     ;;
 187 esac
 188 AC_SUBST(GDBINIT)
 189
 190 #We need this for the host.
 191 AC_C_BIGENDIAN
 192
 193 te_file=generic
 194
 195 # Makefile target for installing gas in $(tooldir)/bin.
 196 install_tooldir=install-exec-tooldir
 197
 198 canon_targets=""
 199 all_targets=no
 200 if test -n "$enable_targets" ; then
 201   for t in `echo $enable_targets | sed 's/,/ /g'`; do
 202     if test $t = "all"; then
 203       all_targets=yes
 204       continue
 205     fi
 206     result=`$ac_config_sub $t 2>/dev/null`
 207     if test -n "$result" ; then
 208       canon_targets="$canon_targets $result"
 209 #    else
 210 #      # Permit "all", etc.  We don't support it yet though.
 211 #      canon_targets="$canon_targets $t"
 212     fi
 213   done
 214   GAS_UNIQ(canon_targets)
 215 fi
 216
 217 emulations=""
 218
 219 for this_target in $target $canon_targets ; do
 220
 221     targ=${this_target}
 222     . ${srcdir}/configure.tgt
 223
 224     case ${target_cpu} in
 225       crisv32)
 226         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 227                            [Default CRIS architecture.])
 228         ;;
 229     esac
 230
 231     if test ${this_target} = $target ; then
 232       target_cpu_type=${cpu_type}
 233     elif test ${target_cpu_type} != ${cpu_type} ; then
 234       continue
 235     fi
 236
 237     generic_target=${cpu_type}-${target_vendor}-${target_os}
 238     case ${generic_target} in
 239       i386-*-msdosdjgpp* \
 240       | i386-*-go32* \
 241       | i386-go32-rtems*)
 242         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 243         ;;
 244
 245       i386-*-linux-* | x86_64-*-linux-*)
 246         if test ${this_target} = $target \
 247            && test ${ac_default_generate_x86_used_note} = unset; then
 248           ac_default_generate_x86_used_note=1
 249         fi
 250         ;;
 251
 252       i386-*-solaris2 \
 253       | x86_64-*-solaris2 \
 254       | i386-*-solaris2.[[0-9]] \
 255       | i386-*-solaris2.1[[01]] \
 256       | x86_64-*-solaris2.1[[01]])
 257         if test ${this_target} = $target \
 258            && test ${ac_default_x86_relax_relocations} = unset; then
 259           ac_default_x86_relax_relocations=0
 260         fi
 261         ;;
 262
 263       microblaze*)
 264         ;;
 265
 266 changequote(,)dnl
 267       ppc-*-aix[5-9].*)
 268 changequote([,])dnl
 269         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 270                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 271         ;;
 272       ppc-*-solaris*)
 273         if test ${this_target} = $target; then
 274           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 275                     [Define if default target is PowerPC Solaris.])
 276         fi
 277         if test x${endian} = xbig; then
 278           AC_MSG_ERROR(Solaris must be configured little endian)
 279         fi
 280         ;;
 281     esac
 282
 283     if test ${this_target} = $target ; then
 284       endian_def=
 285       if test x${endian} = xbig; then
 286         endian_def=1
 287       elif test x${endian} = xlittle; then
 288         endian_def=0
 289       fi
 290       if test x${endian_def} != x; then
 291         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 292                            [Define as 1 if big endian.])
 293       fi
 294     fi
 295
 296 # Other random stuff.
 297
 298     case ${cpu_type} in
 299       mips)
 300         # Set mips_cpu to the name of the default CPU.
 301         case ${target_cpu} in
 302           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 303             mips_cpu=from-abi
 304             ;;
 305           mipsisa32 | mipsisa32el)
 306             mips_cpu=mips32
 307             ;;
 308           mipsisa32r2 | mipsisa32r2el)
 309             mips_cpu=mips32r2
 310             ;;
 311           mipsisa32r3 | mipsisa32r3el)
 312             mips_cpu=mips32r3
 313             ;;
 314           mipsisa32r5 | mipsisa32r5el)
 315             mips_cpu=mips32r5
 316             ;;
 317           mipsisa32r6 | mipsisa32r6el)
 318             mips_cpu=mips32r6
 319             ;;
 320           mipsisa64 | mipsisa64el)
 321             mips_cpu=mips64
 322             ;;
 323           mipsisa64r2 | mipsisa64r2el)
 324             mips_cpu=mips64r2
 325             ;;
 326           mipsisa64r3 | mipsisa64r3el)
 327             mips_cpu=mips64r3
 328             ;;
 329           mipsisa64r5 | mipsisa64r5el)
 330             mips_cpu=mips64r5
 331             ;;
 332           mipsisa64r6 | mipsisa64r6el)
 333             mips_cpu=mips64r6
 334             ;;
 335           mipstx39 | mipstx39el)
 336             mips_cpu=r3900
 337             ;;
 338           mips64vr | mips64vrel)
 339             mips_cpu=vr4100
 340             ;;
 341           mipsisa32r2* | mipsisa64r2*)
 342 changequote(,)dnl
 343             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 344 changequote([,])dnl
 345             ;;
 346           mipsisa32r6* | mipsisa64r6*)
 347 changequote(,)dnl
 348             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r6//' -e 's/el$//'`
 349 changequote([,])dnl
 350             ;;
 351           mips64* | mipsisa64* | mipsisa32*)
 352 changequote(,)dnl
 353             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 354 changequote([,])dnl
 355             ;;
 356           mips*)
 357 changequote(,)dnl
 358             mips_cpu=`echo $target_cpu | sed -e 's/^mips//' -e 's/el$//'`
 359 changequote([,])dnl
 360             ;;
 361           *)
 362             AC_MSG_ERROR($target_cpu isn't a supported MIPS CPU name)
 363             ;;
 364         esac
 365         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 366         # binaries.  It's a GNU extension that some OSes don't understand.
 367         case ${target} in
 368           *-*-irix*)
 369             use_e_mips_abi_o32=0
 370             ;;
 371           *)
 372             use_e_mips_abi_o32=1
 373             ;;
 374         esac
 375         # Decide whether to generate 32-bit or 64-bit code by default.
 376         # Used to resolve -march=from-abi when an embedded ABI is selected.
 377         case ${target} in
 378           mips64*-*-* | mipsisa64*-*-*)
 379             mips_default_64bit=1
 380             ;;
 381           *)
 382             mips_default_64bit=0
 383             ;;
 384         esac
 385         # Decide which ABI to target by default.
 386         case ${target} in
 387           mips64*-linux* | mips-sgi-irix6* | mips64*-freebsd* \
 388           | mips64*-kfreebsd*-gnu | mips64*-ps2-elf*)
 389             mips_default_abi=N32_ABI
 390             ;;
 391           mips*-linux* | mips*-freebsd* | mips*-kfreebsd*-gnu)
 392             mips_default_abi=O32_ABI
 393             ;;
 394           mips64*-openbsd*)
 395             mips_default_abi=N64_ABI
 396             ;;
 397           *)
 398             mips_default_abi=NO_ABI
 399             ;;
 400         esac
 401         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 402                            [Default CPU for MIPS targets. ])
 403         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 404                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 405         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 406                            [Generate 64-bit code by default on MIPS targets. ])
 407         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 408                            [Choose a default ABI for MIPS targets. ])
 409         ;;
 410     esac
 411
 412     # Do we need the opcodes library?
 413     case ${cpu_type} in
 414       vax | tic30)
 415         ;;
 416
 417       *)
 418         need_opcodes=yes
 419
 420         case "${enable_shared}" in
 421         yes) shared_opcodes=true ;;
 422         *opcodes*) shared_opcodes=true ;;
 423         *) shared_opcodes=false ;;
 424         esac
 425         ;;
 426     esac
 427
 428     # Any other special object files needed ?
 429     case ${cpu_type} in
 430
 431       bfin)
 432         for f in bfin-parse.o bfin-lex-wrapper.o; do
 433           case " $extra_objects " in
 434             *" $f "*) ;;
 435             *) extra_objects="$extra_objects $f" ;;
 436           esac
 437         done
 438         ;;
 439
 440       bpf)
 441         if test $this_target = $target ; then
 442           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 443         fi
 444         using_cgen=yes
 445         ;;
 446       epiphany | fr30 | ip2k | iq2000 | lm32 | m32r | or1k)
 447         using_cgen=yes
 448         ;;
 449
 450       m32c)
 451         using_cgen=yes
 452         ;;
 453       frv)
 454         using_cgen=yes
 455         ;;
 456       m68k)
 457         f=m68k-parse.o
 458         case " $extra_objects " in
 459           *" $f "*) ;;
 460           *) extra_objects="$extra_objects $f" ;;
 461         esac
 462         ;;
 463
 464       mep)
 465         using_cgen=yes
 466         ;;
 467
 468       mips)
 469         for f in itbl-parse.o itbl-lex-wrapper.o itbl-ops.o; do
 470           case " $extra_objects " in
 471             *" $f "*) ;;
 472             *) extra_objects="$extra_objects $f" ;;
 473           esac
 474         done
 475         ;;
 476
 477       mt)
 478         using_cgen=yes
 479         ;;
 480
 481       nds32)
 482         # setup NDS32_LINUX_TOOLCHAIN definition
 483         if test "linux" = $em; then
 484           AC_DEFINE(NDS32_LINUX_TOOLCHAIN, 1,
 485             [Define value for nds32_linux_toolchain])
 486         else
 487           AC_DEFINE(NDS32_LINUX_TOOLCHAIN, 0,
 488             [Define default value for nds32_linux_toolchain])
 489         fi
 490
 491         # Decide BASELINE, REDUCED_REGS, FPU_DP_EXT, FPU_SP_EXT features
 492         # based on arch_name.
 493         AC_MSG_CHECKING(for default configuration of --with-arch)
 494         if test "x${with_arch}" != x; then
 495           case ${with_arch} in
 496             v2j | v2s | v2f | v2 | v3m | v3j | v3s | v3f | v3 )
 497               AC_DEFINE_UNQUOTED(NDS32_DEFAULT_ARCH_NAME, "$with_arch",
 498                                  [Define value for nds32_arch_name])
 499               ;;
 500             *)
 501               AC_MSG_ERROR(This kind of arch name does *NOT* exist!)
 502               ;;
 503           esac
 504         fi
 505         AC_MSG_RESULT($with_arch)
 506
 507         # Decide features one by one.
 508         AC_MSG_CHECKING(for default configuration of --enable-dx-regs)
 509         if test "x${enable_dx_regs}" = xyes; then
 510           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 1,
 511                     [Define value for nds32_dx_regs])
 512         else
 513           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 0,
 514                     [Define default value for nds32_dx_regs])
 515         fi
 516         AC_MSG_RESULT($enable_dx_regs)
 517
 518         AC_MSG_CHECKING(for default configuration of --enable-perf-ext)
 519         if test "x${enable_perf_ext}" = xno; then
 520           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 0,
 521                     [Define value for nds32_perf_ext])
 522         else
 523           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 1,
 524                     [Define default value for nds32_perf_ext])
 525         fi
 526         AC_MSG_RESULT($enable_perf_ext)
 527
 528         AC_MSG_CHECKING(for default configuration of --enable-perf-ext2)
 529         if test "x${enable_perf_ext2}" = xno; then
 530           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 0,
 531                     [Define value for nds32_perf_ext2])
 532         else
 533           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 1,
 534                     [Define default value for nds32_perf_ext2])
 535         fi
 536         AC_MSG_RESULT($enable_perf_ext2)
 537
 538         AC_MSG_CHECKING(for default configuration of --enable-string-ext)
 539         if test "x${enable_string_ext}" = xno; then
 540           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 0,
 541                     [Define value for nds32_string_ext])
 542         else
 543           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 1,
 544                     [Define default value for nds32_string_ext])
 545         fi
 546         AC_MSG_RESULT($enable_string_ext)
 547
 548         AC_MSG_CHECKING(for default configuration of --enable-audio-ext)
 549         if test "x${enable_audio_ext}" = xno; then
 550           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 0,
 551                     [Define value for nds32_audio_ext])
 552         else
 553           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 1,
 554                     [Define default value for nds32_audio_ext])
 555         fi
 556         AC_MSG_RESULT($enable_audio_ext)
 557
 558         AC_MSG_CHECKING(for default configuration of --enable-dsp-ext)
 559         if test "x${enable_dsp_ext}" = xno; then
 560           AC_DEFINE(NDS32_DEFAULT_DSP_EXT, 0,
 561                     [Define value for nds32_dsp_ext])
 562         else
 563           AC_DEFINE(NDS32_DEFAULT_DSP_EXT, 1,
 564                     [Define default value for nds32_dsp_ext])
 565         fi
 566         AC_MSG_RESULT($enable_dsp_ext)
 567
 568         AC_MSG_CHECKING(for default configuration of --enable-zol-ext)
 569         if test "x${enable_zol_ext}" = xno; then
 570           AC_DEFINE(NDS32_DEFAULT_ZOL_EXT, 0,
 571                     [Define value for nds32_zol_ext])
 572         else
 573           AC_DEFINE(NDS32_DEFAULT_ZOL_EXT, 1,
 574                     [Define default value for nds32_zol_ext])
 575         fi
 576         AC_MSG_RESULT($enable_zol_ext)
 577         ;;
 578
 579       aarch64 | i386 | s390 | sparc)
 580         if test $this_target = $target ; then
 581           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 582         fi
 583         ;;
 584
 585       riscv)
 586         # --target=riscv[32|64]-*-*.  */
 587         if test $this_target = $target ; then
 588           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 589         fi
 590
 591         # --with-arch=<value>.  The syntax of <value> is same as Gas option -march.
 592         AC_MSG_CHECKING(for default configuration of --with-arch)
 593         if test "x${with_arch}" != x; then
 594         AC_DEFINE_UNQUOTED(DEFAULT_RISCV_ARCH_WITH_EXT, "$with_arch",
 595                            [Define default value for RISC-V -march.])
 596         fi
 597         AC_MSG_RESULT($with_arch)
 598
 599         # --with-isa-spec=[2.2|20190608|20191213].
 600         AC_MSG_CHECKING(for default configuration of --with-isa-spec)
 601         if test "x${with_isa_spec}" != x; then
 602           AC_DEFINE_UNQUOTED(DEFAULT_RISCV_ISA_SPEC, "$with_isa_spec",
 603                              [Define default value for RISC-V -misa-spec.])
 604         fi
 605         AC_MSG_RESULT($with_isa_spec)
 606
 607         # --with-priv-spec=[1.9|1.9.1|1.10|1.11].
 608         AC_MSG_CHECKING(for default configuration of --with-priv-spec)
 609         if test "x${with_priv_spec}" != x; then
 610           AC_DEFINE_UNQUOTED(DEFAULT_RISCV_PRIV_SPEC, "$with_priv_spec",
 611                              [Define default value for RISC-V -mpriv-spec])
 612         fi
 613         AC_MSG_RESULT($with_priv_spec)
 614         ;;
 615
 616       rl78)
 617         f=rl78-parse.o
 618         case " $extra_objects " in
 619           *" $f "*) ;;
 620           *) extra_objects="$extra_objects $f" ;;
 621         esac
 622         ;;
 623
 624       rx)
 625         f=rx-parse.o
 626         case " $extra_objects " in
 627           *" $f "*) ;;
 628           *) extra_objects="$extra_objects $f" ;;
 629         esac
 630         ;;
 631
 632       xstormy16)
 633         using_cgen=yes
 634         ;;
 635
 636       xc16x)
 637         using_cgen=yes
 638         ;;
 639
 640       xtensa)
 641         f=config/xtensa-relax.o
 642         case " $extra_objects " in
 643           *" $f "*) ;;
 644           *) extra_objects="$extra_objects $f" ;;
 645         esac
 646         ;;
 647
 648       *)
 649         ;;
 650     esac
 651
 652     if test $using_cgen = yes ; then
 653         f=cgen.o
 654         case " $extra_objects " in
 655           *" $f "*) ;;
 656           *) extra_objects="$extra_objects $f" ;;
 657         esac
 658     fi
 659
 660 # See if we really can support this configuration with the emulation code.
 661
 662     if test $this_target = $target ; then
 663       obj_format=$fmt
 664       te_file=$em
 665     fi
 666
 667     case ${te_file} in
 668       vms)
 669         f=config/te-vms.o
 670         case " $extra_objects " in
 671           *" $f "*) ;;
 672           *) extra_objects="$extra_objects $f" ;;
 673         esac ;;
 674     esac
 675
 676 # From target name and format, produce a list of supported emulations.
 677
 678     case ${generic_target}-${fmt} in
 679       mips-*-*-*)       case "$endian" in
 680                         big)    emulation="mipsbelf mipslelf mipself" ;;
 681                         *)      emulation="mipslelf mipsbelf mipself" ;;
 682                         esac ;;
 683       # i386-pc-pe-coff != i386-pc-coff.
 684       i386-*-pe-coff)   ;;
 685       # Uncommenting the next line will turn on support for i386 AOUT
 686       # for the default linux configuration
 687       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 688       #
 689       i386-*-aout)      emulation="i386aout" ;;
 690       i386-*-coff)      emulation="i386coff" ;;
 691       i386-*-elf)       emulation="i386elf" ;;
 692
 693       # Always all formats.  The first stated emulation becomes the default.
 694       cris-*-*aout*)    emulation="crisaout criself" ;;
 695       cris-*-*)         emulation="criself crisaout" ;;
 696     esac
 697
 698     emulations="$emulations $emulation"
 699
 700 done
 701
 702 if test ${ac_default_x86_relax_relocations} = unset; then
 703   ac_default_x86_relax_relocations=1
 704 fi
 705 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_X86_RELAX_RELOCATIONS,
 706   $ac_default_x86_relax_relocations,
 707   [Define to 1 if you want to generate x86 relax relocations by default.])
 708
 709 if test ${ac_default_elf_stt_common} = unset; then
 710   ac_default_elf_stt_common=0
 711 fi
 712 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_ELF_STT_COMMON,
 713   $ac_default_elf_stt_common,
 714   [Define to 1 if you want to generate ELF common symbols with the
 715    STT_COMMON type by default.])
 716
 717 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_BUILD_NOTES,
 718   $ac_default_generate_build_notes,
 719   [Define to 1 if you want to generate GNU Build attribute notes
 720    by default, if none are contained in the input.])
 721
 722 if test ${ac_default_generate_x86_used_note} = unset; then
 723   ac_default_generate_x86_used_note=0
 724 fi
 725 AC_DEFINE_UNQUOTED(DEFAULT_X86_USED_NOTE,
 726   $ac_default_generate_x86_used_note,
 727   [Define to 1 if you want to generate GNU x86 used ISA and feature
 728    properties by default.])
 729
 730 if test ${ac_default_generate_riscv_attr} = unset; then
 731     case ${target_os} in
 732       elf)
 733         ac_default_generate_riscv_attr=1
 734         ;;
 735       *)
 736         ac_default_generate_riscv_attr=0
 737         ;;
 738   esac
 739 fi
 740
 741 AC_DEFINE_UNQUOTED(DEFAULT_RISCV_ATTR,
 742   $ac_default_generate_riscv_attr,
 743   [Define to 1 if you want to generate RISC-V arch attribute by default.])
 744
 745 if test ${ac_default_mips_fix_loongson3_llsc} = unset; then
 746   ac_default_mips_fix_loongson3_llsc=0
 747 fi
 748 AC_DEFINE_UNQUOTED(DEFAULT_MIPS_FIX_LOONGSON3_LLSC,
 749   $ac_default_mips_fix_loongson3_llsc,
 750   [Define to 1 if you want to fix Loongson3 LLSC Errata by default.])
 751
 752 if test x$ac_default_compressed_debug_sections = xyes ; then
 753   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 754 fi
 755
 756 # Turn on all targets if possible
 757 if test ${all_targets} = "yes"; then
 758   case ${target_cpu_type} in
 759   i386)
 760     case ${obj_format} in
 761     aout)
 762       emulations="$emulations i386coff i386elf"
 763       ;;
 764     coff)
 765       emulations="$emulations i386aout i386elf"
 766     ;;
 767     elf)
 768       emulations="$emulations i386aout i386coff"
 769       ;;
 770     esac
 771   ;;
 772   x86_64)
 773     case ${obj_format} in
 774     aout)
 775       emulations="$emulations i386coff i386elf"
 776       ;;
 777     coff)
 778       emulations="$emulations i386aout i386elf"
 779     ;;
 780     elf)
 781       emulations="$emulations i386aout i386coff"
 782       ;;
 783     esac
 784   ;;
 785   esac
 786 fi
 787
 788 # PE code has way too many macros tweaking behaviour
 789 case ${te_file} in
 790   pe*) emulations="" ;;
 791 esac
 792
 793 # Assign floating point type.  Most processors with FP support
 794 # IEEE FP.  On those that don't support FP at all, usually IEEE
 795 # is emulated.
 796 case ${target_cpu} in
 797   vax | pdp11 ) atof=vax ;;
 798   *)            atof=ieee ;;
 799 esac
 800
 801 case "${obj_format}" in
 802   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 803 esac
 804
 805 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 806 cgen_cpu_prefix=""
 807 if test $using_cgen = yes ; then
 808   case ${target_cpu} in
 809     or1knd)
 810        cgen_cpu_prefix=or1k ;;
 811     *) cgen_cpu_prefix=${target_cpu} ;;
 812   esac
 813   AC_SUBST(cgen_cpu_prefix)
 814   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 815 fi
 816
 817 dnl
 818 dnl Make sure the desired support files exist.
 819 dnl
 820
 821 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 822   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 823 fi
 824
 825 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 826   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 827 fi
 828
 829 # Some COFF configurations want these random other flags set.
 830 case ${obj_format} in
 831   coff)
 832     case ${target_cpu_type} in
 833       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 834       x86_64) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 835     esac
 836     ;;
 837 esac
 838
 839 # Getting this done right is going to be a bitch.  Each configuration specified
 840 # with --enable-targets=... should be checked for environment, format, cpu
 841 # setting.
 842 #
 843 # For each configuration, the necessary object file support code must be linked
 844 # in.  This might be only one, it might be up to four.  The necessary emulation
 845 # code needs to be provided, too.
 846 #
 847 # And then there's "--enable-targets=all"....
 848 #
 849 # For now, just always do it for MIPS ELF configurations.  Sigh.
 850
 851 formats="${obj_format}"
 852 emfiles=""
 853 EMULATIONS=""
 854 GAS_UNIQ(emulations)
 855 for em in . $emulations ; do
 856   case $em in
 857     .)  continue ;;
 858     mipsbelf | mipslelf | mipself)
 859         fmt=elf   file=mipself ;;
 860     *coff)
 861         fmt=coff  file=$em ;;
 862     *aout)
 863         fmt=aout file=$em ;;
 864     *elf)
 865         fmt=elf file=$em ;;
 866   esac
 867   formats="$formats $fmt"
 868   emfiles="$emfiles config/e-$file.o"
 869   EMULATIONS="$EMULATIONS &$em,"
 870 done
 871 GAS_UNIQ(formats)
 872 GAS_UNIQ(emfiles)
 873 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 874   for fmt in $formats ; do
 875     case $fmt in
 876       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 877       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 878       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 879       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 880       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 881       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 882     esac
 883     extra_objects="$extra_objects config/obj-$fmt.o"
 884   done
 885   obj_format=multi
 886 fi
 887 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 888   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 889   # e-mipself has more than one emulation per file, e-i386* has just one at the
 890   # moment.  If only one emulation is specified, then don't define
 891   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 892   case "${obj_format}${emfiles}" in
 893     multi* | *mipself*)
 894       extra_objects="$extra_objects $emfiles"
 895       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 896   esac
 897 fi
 898 AC_SUBST(extra_objects)
 899 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 900 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 901                    [Default emulation.])
 902
 903 reject_dev_configs=yes
 904
 905 case ${reject_dev_configs}-${dev} in
 906   yes-yes) # Oops.
 907     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 908     ;;
 909 esac
 910
 911 AC_SUBST(target_cpu_type)
 912 AC_SUBST(obj_format)
 913 AC_SUBST(te_file)
 914 AC_SUBST(install_tooldir)
 915 AC_SUBST(atof)
 916 dnl AC_SUBST(emulation)
 917
 918 # do we need the opcodes library?
 919 case "${need_opcodes}" in
 920 yes)
 921   OPCODES_LIB=../opcodes/libopcodes.la
 922   ;;
 923 esac
 924
 925 AC_SUBST(OPCODES_LIB)
 926
 927 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 928 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 929 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 930 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 931 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 932
 933 AC_PROG_YACC
 934 AM_PROG_LEX
 935
 936 ALL_LINGUAS="es fi fr id ja ru rw sv tr uk zh_CN"
 937 ZW_GNU_GETTEXT_SISTER_DIR
 938 AM_PO_SUBDIRS
 939
 940 AM_MAINTAINER_MODE
 941 AM_CONDITIONAL(GENINSRC_NEVER, false)
 942 AC_EXEEXT
 943
 944 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h errno.h sys/types.h limits.h locale.h time.h sys/stat.h)
 945 ACX_HEADER_STRING
 946
 947 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 948 # people who are not cross-compiling but are compiling cross-assemblers.
 949 AC_MSG_CHECKING(whether compiling a cross-assembler)
 950 if test "${host}" = "${target}"; then
 951   cross_gas=no
 952 else
 953   cross_gas=yes
 954   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 955 fi
 956 AC_MSG_RESULT($cross_gas)
 957
 958 dnl ansidecl.h will deal with const
 959 dnl AC_C_CONST
 960 AC_FUNC_ALLOCA
 961 AC_C_INLINE
 962
 963 # VMS doesn't have unlink.
 964 AC_CHECK_FUNCS(unlink remove, break)
 965 AC_CHECK_FUNCS(sbrk setlocale)
 966 AC_CHECK_FUNCS(strsignal)
 967
 968 AM_LC_MESSAGES
 969
 970 # do we need the math library?
 971 case "${need_libm}" in
 972 yes)
 973   LT_LIB_M
 974   AC_SUBST(LIBM)
 975   ;;
 976 esac
 977
 978 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 979 # enough, but on some of those systems, the assert macro relies on requoting
 980 # working properly!
 981 GAS_WORKING_ASSERT
 982
 983 # On some systems, the system header files may not declare malloc, realloc,
 984 # and free.  There are places where gas needs these functions to have been
 985 # declared -- such as when taking their addresses.
 986 gas_test_headers="
 987 #ifdef HAVE_MEMORY_H
 988 #include <memory.h>
 989 #endif
 990 #ifdef HAVE_STRING_H
 991 #include <string.h>
 992 #else
 993 #ifdef HAVE_STRINGS_H
 994 #include <strings.h>
 995 #endif
 996 #endif
 997 #ifdef HAVE_STDLIB_H
 998 #include <stdlib.h>
 999 #endif
1000 #ifdef HAVE_UNISTD_H
1001 #include <unistd.h>
1002 #endif
1003 "
1004
1005 # Does errno.h declare errno, or do we have to add a separate declaration
1006 # for it?
1007 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
1008 #ifdef HAVE_ERRNO_H
1009 #include <errno.h>
1010 #endif
1011 ])
1012
1013 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
1014 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
1015 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
1016 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
1017 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
1018 if test $gas_cv_decl_getopt_unistd_h = yes; then
1019   AC_DEFINE([HAVE_DECL_GETOPT], 1,
1020             [Is the prototype for getopt in <unistd.h> in the expected format?])
1021 fi
1022
1023 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
1024 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
1025 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
1026 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
1027 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
1028 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
1029
1030 AC_CHECK_DECLS([free, getenv, malloc, mempcpy, realloc, stpcpy, strstr, vsnprintf, asprintf])
1031
1032 BFD_BINARY_FOPEN
1033
1034 # Link in zlib if we can.  This allows us to write compressed debug sections.
1035 AM_ZLIB
1036
1037 # Support for VMS timestamps via cross compile
1038
1039 if test "$ac_cv_header_time_h" = yes; then
1040   GAS_HAVE_TIME_TYPE_MEMBER(struct tm, tm_gmtoff)
1041 fi
1042
1043 if test "$ac_cv_header_sys_stat_h" = yes; then
1044     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_sec)
1045     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_nsec)
1046 fi
1047
1048
1049 dnl Required for html, pdf, install-pdf and install-html targets.
1050 AC_SUBST(datarootdir)
1051 AC_SUBST(docdir)
1052 AC_SUBST(htmldir)
1053 AC_SUBST(pdfdir)
1054
1055 dnl This must come last.
1056
1057 dnl We used to make symlinks to files in the source directory, but now
1058 dnl we just use the right name for .c files, and create .h files in
1059 dnl the build directory which include the right .h file.  Make sure
1060 dnl the old symlinks don't exist, so that a reconfigure in an existing
1061 dnl directory behaves reasonably.
1062
1063 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
1064 AC_CONFIG_COMMANDS([default],
1065 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1066  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1067  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1068  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1069  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1070  if test "x$cgen_cpu_prefix" != x ; then
1071    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1072  fi],
1073 [target_cpu_type=${target_cpu_type}
1074  cgen_cpu_prefix=${cgen_cpu_prefix}
1075  obj_format=${obj_format}
1076  te_file=${te_file}])
1077
1078 AC_OUTPUT
1079
1080 GNU_MAKE_JOBSERVER