gas/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl   Copyright (C) 2012-2018 Free Software Foundation, Inc.
   7 dnl
   8 dnl This file is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; see the file COPYING3.  If not see
  20 dnl <http://www.gnu.org/licenses/>.
  21 dnl
  22 dnl v2.5 needed for --bindir et al
  23 AC_PREREQ(2.59)
  24 m4_include([../bfd/version.m4])
  25 AC_INIT([gas], BFD_VERSION)
  26 AC_CONFIG_SRCDIR(as.h)
  27
  28 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  29 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  30 dnl gas/ instead of gas/../.
  31 AC_CONFIG_AUX_DIR(..)
  32 AC_CANONICAL_TARGET
  33 AC_ISC_POSIX
  34
  35 AM_INIT_AUTOMAKE
  36
  37 AC_PROG_CC
  38 AC_GNU_SOURCE
  39 AC_USE_SYSTEM_EXTENSIONS
  40
  41 LT_INIT
  42 ACX_LARGEFILE
  43 ACX_PROG_CMP_IGNORE_INITIAL
  44
  45 AC_ARG_ENABLE(targets,
  46 [  --enable-targets        alternative target configurations besides the primary],
  47 [case "${enableval}" in
  48   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  49             ;;
  50   no)       enable_targets= ;;
  51   *)        enable_targets=$enableval ;;
  52 esac])dnl
  53
  54 ac_checking=yes
  55 if grep '^RELEASE=y' ${srcdir}/../bfd/Makefile.am >/dev/null 2>/dev/null ; then
  56   ac_checking=
  57 fi
  58 AC_ARG_ENABLE(checking,
  59 [  --enable-checking       enable run-time checks],
  60 [case "${enableval}" in
  61   no|none)  ac_checking= ;;
  62   *)        ac_checking=yes ;;
  63 esac])dnl
  64 if test x$ac_checking != x ; then
  65   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  66 fi
  67
  68 # PR gas/19109
  69 # Decide the default method for compressing debug sections.
  70 ac_default_compressed_debug_sections=unset
  71 # Provide a configure time option to override our default.
  72 AC_ARG_ENABLE(compressed_debug_sections,
  73               AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,none}],
  74               [compress debug sections by default]),
  75 [case ,"${enableval}", in
  76   ,yes, | ,all, | *,gas,*) ac_default_compressed_debug_sections=yes ;;
  77   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
  78   *)   ac_default_compressed_debug_sections=unset ;;
  79 esac])dnl
  80
  81 # PR gas/19520
  82 # Decide if x86 assembler should generate relax relocations.
  83 ac_default_x86_relax_relocations=unset
  84 # Provide a configure time option to override our default.
  85 AC_ARG_ENABLE(x86_relax_relocations,
  86               AS_HELP_STRING([--enable-x86-relax-relocations],
  87               [generate x86 relax relocations by default]),
  88 [case "${enableval}" in
  89   no)  ac_default_x86_relax_relocations=0 ;;
  90 esac])dnl
  91
  92 # Decide if ELF assembler should generate common symbols with the
  93 # STT_COMMON type.
  94 ac_default_elf_stt_common=unset
  95 # Provide a configure time option to override our default.
  96 AC_ARG_ENABLE(elf_stt_common,
  97               AS_HELP_STRING([--enable-elf-stt-common],
  98               [generate ELF common symbols with STT_COMMON type by default]),
  99 [case "${enableval}" in
 100   yes)  ac_default_elf_stt_common=1 ;;
 101 esac])dnl
 102
 103 using_cgen=no
 104
 105 AM_BINUTILS_WARNINGS
 106
 107 # Generate a header file
 108 AC_CONFIG_HEADERS(config.h:config.in)
 109
 110 dnl Option --with-cpu=TYPE allows configure type control of the default
 111 dnl cpu type within the assembler.  Currently only the ARC target
 112 dnl supports this feature, but others may be added in the future.
 113 AC_ARG_WITH(cpu,
 114             AS_HELP_STRING([--with-cpu=CPU],
 115             [default cpu variant is CPU (currently only supported on ARC)]),
 116             [AC_DEFINE_UNQUOTED(TARGET_WITH_CPU,
 117                                 "${with_cpu}",
 118                                 [Target specific CPU.])],
 119             [])
 120
 121 # PR 14072
 122 AH_VERBATIM([00_CONFIG_H_CHECK],
 123 [/* Check that config.h is #included before system headers
 124    (this works only for glibc, but that should be enough).  */
 125 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 126 #  error config.h must be #included before system headers
 127 #endif
 128 #define __CONFIG_H__ 1])
 129
 130 # If we are on a DOS filesystem, we must use gdb.ini rather than
 131 # .gdbinit.
 132 case "${host}" in
 133   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
 134     GDBINIT="gdb.ini"
 135     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
 136     ;;
 137   *)
 138     GDBINIT=".gdbinit"
 139     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
 140     ;;
 141 esac
 142 AC_SUBST(GDBINIT)
 143
 144 #We need this for the host.
 145 AC_C_BIGENDIAN
 146
 147 te_file=generic
 148
 149 # Makefile target for installing gas in $(tooldir)/bin.
 150 install_tooldir=install-exec-tooldir
 151
 152 canon_targets=""
 153 all_targets=no
 154 if test -n "$enable_targets" ; then
 155   for t in `echo $enable_targets | sed 's/,/ /g'`; do
 156     if test $t = "all"; then
 157       all_targets=yes
 158       continue
 159     fi
 160     result=`$ac_config_sub $t 2>/dev/null`
 161     if test -n "$result" ; then
 162       canon_targets="$canon_targets $result"
 163 #    else
 164 #      # Permit "all", etc.  We don't support it yet though.
 165 #      canon_targets="$canon_targets $t"
 166     fi
 167   done
 168   GAS_UNIQ(canon_targets)
 169 fi
 170
 171 emulations=""
 172
 173 for this_target in $target $canon_targets ; do
 174
 175     targ=${this_target}
 176     . ${srcdir}/configure.tgt
 177
 178     case ${target_cpu} in
 179       crisv32)
 180         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 181                            [Default CRIS architecture.])
 182         ;;
 183     esac
 184
 185     if test ${this_target} = $target ; then
 186       target_cpu_type=${cpu_type}
 187     elif test ${target_cpu_type} != ${cpu_type} ; then
 188       continue
 189     fi
 190
 191     generic_target=${cpu_type}-${target_vendor}-${target_os}
 192     case ${generic_target} in
 193       i386-*-msdosdjgpp* \
 194       | i386-*-go32* \
 195       | i386-go32-rtems*)
 196         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 197         ;;
 198
 199       i386-*-solaris2 \
 200       | x86_64-*-solaris2 \
 201       | i386-*-solaris2.[[0-9]] \
 202       | i386-*-solaris2.1[[01]] \
 203       | x86_64-*-solaris2.1[[01]])
 204         if test ${this_target} = $target \
 205            && test ${ac_default_x86_relax_relocations} = unset; then
 206           ac_default_x86_relax_relocations=0
 207         fi
 208         ;;
 209
 210       microblaze*)
 211         ;;
 212
 213 changequote(,)dnl
 214       ppc-*-aix[5-9].*)
 215 changequote([,])dnl
 216         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 217                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 218         ;;
 219       ppc-*-solaris*)
 220         if test ${this_target} = $target; then
 221           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 222                     [Define if default target is PowerPC Solaris.])
 223         fi
 224         if test x${endian} = xbig; then
 225           AC_MSG_ERROR(Solaris must be configured little endian)
 226         fi
 227         ;;
 228     esac
 229
 230     if test ${this_target} = $target ; then
 231       endian_def=
 232       if test x${endian} = xbig; then
 233         endian_def=1
 234       elif test x${endian} = xlittle; then
 235         endian_def=0
 236       fi
 237       if test x${endian_def} != x; then
 238         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 239                            [Define as 1 if big endian.])
 240       fi
 241     fi
 242
 243 # Other random stuff.
 244
 245     case ${cpu_type} in
 246       mips)
 247         # Set mips_cpu to the name of the default CPU.
 248         case ${target_cpu} in
 249           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 250             mips_cpu=from-abi
 251             ;;
 252           mipsisa32 | mipsisa32el)
 253             mips_cpu=mips32
 254             ;;
 255           mipsisa32r2 | mipsisa32r2el)
 256             mips_cpu=mips32r2
 257             ;;
 258           mipsisa32r3 | mipsisa32r3el)
 259             mips_cpu=mips32r3
 260             ;;
 261           mipsisa32r5 | mipsisa32r5el)
 262             mips_cpu=mips32r5
 263             ;;
 264           mipsisa32r6 | mipsisa32r6el)
 265             mips_cpu=mips32r6
 266             ;;
 267           mipsisa64 | mipsisa64el)
 268             mips_cpu=mips64
 269             ;;
 270           mipsisa64r2 | mipsisa64r2el)
 271             mips_cpu=mips64r2
 272             ;;
 273           mipsisa64r3 | mipsisa64r3el)
 274             mips_cpu=mips64r3
 275             ;;
 276           mipsisa64r5 | mipsisa64r5el)
 277             mips_cpu=mips64r5
 278             ;;
 279           mipsisa64r6 | mipsisa64r6el)
 280             mips_cpu=mips64r6
 281             ;;
 282           mipstx39 | mipstx39el)
 283             mips_cpu=r3900
 284             ;;
 285           mips64vr | mips64vrel)
 286             mips_cpu=vr4100
 287             ;;
 288           mipsisa32r2* | mipsisa64r2*)
 289 changequote(,)dnl
 290             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 291 changequote([,])dnl
 292             ;;
 293           mipsisa32r6* | mipsisa64r6*)
 294 changequote(,)dnl
 295             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r6//' -e 's/el$//'`
 296 changequote([,])dnl
 297             ;;
 298           mips64* | mipsisa64* | mipsisa32*)
 299 changequote(,)dnl
 300             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 301 changequote([,])dnl
 302             ;;
 303           mips*)
 304 changequote(,)dnl
 305             mips_cpu=`echo $target_cpu | sed -e 's/^mips//' -e 's/el$//'`
 306 changequote([,])dnl
 307             ;;
 308           *)
 309             AC_MSG_ERROR($target_cpu isn't a supported MIPS CPU name)
 310             ;;
 311         esac
 312         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 313         # binaries.  It's a GNU extension that some OSes don't understand.
 314         case ${target} in
 315           *-*-irix*)
 316             use_e_mips_abi_o32=0
 317             ;;
 318           *)
 319             use_e_mips_abi_o32=1
 320             ;;
 321         esac
 322         # Decide whether to generate 32-bit or 64-bit code by default.
 323         # Used to resolve -march=from-abi when an embedded ABI is selected.
 324         case ${target} in
 325           mips64*-*-* | mipsisa64*-*-*)
 326             mips_default_64bit=1
 327             ;;
 328           *)
 329             mips_default_64bit=0
 330             ;;
 331         esac
 332         # Decide which ABI to target by default.
 333         case ${target} in
 334           mips64*-linux* | mips-sgi-irix6* | mips64*-freebsd* \
 335           | mips64*-kfreebsd*-gnu | mips64*-ps2-elf*)
 336             mips_default_abi=N32_ABI
 337             ;;
 338           mips*-linux* | mips*-freebsd* | mips*-kfreebsd*-gnu)
 339             mips_default_abi=O32_ABI
 340             ;;
 341           mips64*-openbsd*)
 342             mips_default_abi=N64_ABI
 343             ;;
 344           *)
 345             mips_default_abi=NO_ABI
 346             ;;
 347         esac
 348         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 349                            [Default CPU for MIPS targets. ])
 350         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 351                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 352         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 353                            [Generate 64-bit code by default on MIPS targets. ])
 354         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 355                            [Choose a default ABI for MIPS targets. ])
 356         ;;
 357     esac
 358
 359     # Do we need the opcodes library?
 360     case ${cpu_type} in
 361       vax | tic30)
 362         ;;
 363
 364       *)
 365         need_opcodes=yes
 366
 367         case "${enable_shared}" in
 368         yes) shared_opcodes=true ;;
 369         *opcodes*) shared_opcodes=true ;;
 370         *) shared_opcodes=false ;;
 371         esac
 372         ;;
 373     esac
 374
 375     # Any other special object files needed ?
 376     case ${cpu_type} in
 377
 378       bfin)
 379         echo ${extra_objects} | grep -s "bfin-parse.o"
 380         if test $? -ne 0 ; then
 381           extra_objects="$extra_objects bfin-parse.o"
 382         fi
 383
 384         echo ${extra_objects} | grep -s "bfin-lex-wrapper.o"
 385         if test $? -ne 0 ; then
 386           extra_objects="$extra_objects bfin-lex-wrapper.o"
 387         fi
 388         ;;
 389
 390       epiphany | fr30 | ip2k | iq2000 | lm32 | m32r | or1k)
 391         using_cgen=yes
 392         ;;
 393
 394       m32c)
 395         using_cgen=yes
 396         ;;
 397       frv)
 398         using_cgen=yes
 399         ;;
 400       m68k)
 401         case ${extra_objects} in
 402         *m68k-parse.o*) ;;
 403         *) extra_objects="$extra_objects m68k-parse.o" ;;
 404         esac
 405         ;;
 406
 407       mep)
 408         using_cgen=yes
 409         ;;
 410
 411       mips)
 412         echo ${extra_objects} | grep -s "itbl-parse.o"
 413         if test $? -ne 0 ; then
 414           extra_objects="$extra_objects itbl-parse.o"
 415         fi
 416
 417         echo ${extra_objects} | grep -s "itbl-lex-wrapper.o"
 418         if test $? -ne 0 ; then
 419           extra_objects="$extra_objects itbl-lex-wrapper.o"
 420         fi
 421
 422         echo ${extra_objects} | grep -s "itbl-ops.o"
 423         if test $? -ne 0 ; then
 424           extra_objects="$extra_objects itbl-ops.o"
 425         fi
 426         ;;
 427
 428       mt)
 429         using_cgen=yes
 430         ;;
 431
 432       nds32)
 433         # Decide BASELINE, REDUCED_REGS, FPU_DP_EXT, FPU_SP_EXT features
 434         # based on arch_name.
 435         AC_MSG_CHECKING(for default configuration of --with-arch)
 436         if test "x${with_arch}" != x; then
 437           case ${with_arch} in
 438             v2j | v2s | v2f | v2 | v3m | v3j | v3s | v3f | v3 )
 439               AC_DEFINE_UNQUOTED(NDS32_DEFAULT_ARCH_NAME, "$with_arch",
 440                                  [Define value for nds32_arch_name])
 441               ;;
 442             *)
 443               AC_MSG_ERROR(This kind of arch name does *NOT* exist!)
 444               ;;
 445           esac
 446         fi
 447         AC_MSG_RESULT($with_arch)
 448
 449         # Decide features one by one.
 450         AC_MSG_CHECKING(for default configuration of --enable-dx-regs)
 451         if test "x${enable_dx_regs}" = xyes; then
 452           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 1,
 453                     [Define value for nds32_dx_regs])
 454         else
 455           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 0,
 456                     [Define default value for nds32_dx_regs])
 457         fi
 458         AC_MSG_RESULT($enable_dx_regs)
 459
 460         AC_MSG_CHECKING(for default configuration of --enable-perf-ext)
 461         if test "x${enable_perf_ext}" = xno; then
 462           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 0,
 463                     [Define value for nds32_perf_ext])
 464         else
 465           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 1,
 466                     [Define default value for nds32_perf_ext])
 467         fi
 468         AC_MSG_RESULT($enable_perf_ext)
 469
 470         AC_MSG_CHECKING(for default configuration of --enable-perf-ext2)
 471         if test "x${enable_perf_ext2}" = xno; then
 472           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 0,
 473                     [Define value for nds32_perf_ext2])
 474         else
 475           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 1,
 476                     [Define default value for nds32_perf_ext2])
 477         fi
 478         AC_MSG_RESULT($enable_perf_ext2)
 479
 480         AC_MSG_CHECKING(for default configuration of --enable-string-ext)
 481         if test "x${enable_string_ext}" = xno; then
 482           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 0,
 483                     [Define value for nds32_string_ext])
 484         else
 485           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 1,
 486                     [Define default value for nds32_string_ext])
 487         fi
 488         AC_MSG_RESULT($enable_string_ext)
 489
 490         AC_MSG_CHECKING(for default configuration of --enable-audio-ext)
 491         if test "x${enable_audio_ext}" = xno; then
 492           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 0,
 493                     [Define value for nds32_audio_ext])
 494         else
 495           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 1,
 496                     [Define default value for nds32_audio_ext])
 497         fi
 498         AC_MSG_RESULT($enable_audio_ext)
 499         ;;
 500
 501       aarch64 | i386 | riscv | s390 | sparc)
 502         if test $this_target = $target ; then
 503           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 504         fi
 505         ;;
 506
 507       rl78)
 508         echo ${extra_objects} | grep -s "rl78-parse.o"
 509         if test $? -ne 0 ; then
 510           extra_objects="$extra_objects rl78-parse.o"
 511         fi
 512         ;;
 513
 514       rx)
 515         echo ${extra_objects} | grep -s "rx-parse.o"
 516         if test $? -ne 0 ; then
 517           extra_objects="$extra_objects rx-parse.o"
 518         fi
 519         ;;
 520
 521       xstormy16)
 522         using_cgen=yes
 523         ;;
 524
 525       xc16x)
 526         using_cgen=yes
 527         ;;
 528
 529       xtensa)
 530         echo ${extra_objects} | grep -s "xtensa-relax.o"
 531         if test $? -ne 0 ; then
 532           extra_objects="$extra_objects xtensa-relax.o"
 533         fi
 534         ;;
 535
 536       *)
 537         ;;
 538     esac
 539
 540     if test $using_cgen = yes ; then
 541         case "x${extra_objects}" in
 542         *cgen.o*) ;;
 543         *) extra_objects="$extra_objects cgen.o" ;;
 544         esac
 545     fi
 546
 547 # See if we really can support this configuration with the emulation code.
 548
 549     if test $this_target = $target ; then
 550       obj_format=$fmt
 551       te_file=$em
 552     fi
 553
 554    case ${te_file} in
 555       vms) extra_objects="$extra_objects te-vms.o" ;;
 556    esac
 557
 558 # From target name and format, produce a list of supported emulations.
 559
 560     case ${generic_target}-${fmt} in
 561       mips-*-*-*)       case "$endian" in
 562                         big)    emulation="mipsbelf mipslelf mipself" ;;
 563                         *)      emulation="mipslelf mipsbelf mipself" ;;
 564                         esac ;;
 565       # i386-pc-pe-coff != i386-pc-coff.
 566       i386-*-pe-coff)   ;;
 567       # Uncommenting the next line will turn on support for i386 AOUT
 568       # for the default linux configuration
 569       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 570       #
 571       i386-*-aout)      emulation="i386aout" ;;
 572       i386-*-coff)      emulation="i386coff" ;;
 573       i386-*-elf)       emulation="i386elf" ;;
 574
 575       # Always all formats.  The first stated emulation becomes the default.
 576       cris-*-*aout*)    emulation="crisaout criself" ;;
 577       cris-*-*)         emulation="criself crisaout" ;;
 578     esac
 579
 580     emulations="$emulations $emulation"
 581
 582 done
 583
 584 if test ${ac_default_x86_relax_relocations} = unset; then
 585   ac_default_x86_relax_relocations=1
 586 fi
 587 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_X86_RELAX_RELOCATIONS,
 588   $ac_default_x86_relax_relocations,
 589   [Define to 1 if you want to generate x86 relax relocations by default.])
 590
 591 if test ${ac_default_elf_stt_common} = unset; then
 592   ac_default_elf_stt_common=0
 593 fi
 594 AC_DEFINE_UNQUOTED(DEFAULT_GENERATE_ELF_STT_COMMON,
 595   $ac_default_elf_stt_common,
 596   [Define to 1 if you want to generate ELF common symbols with the
 597    STT_COMMON type by default.])
 598
 599 if test x$ac_default_compressed_debug_sections = xyes ; then
 600   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 601 fi
 602
 603 # Turn on all targets if possible
 604 if test ${all_targets} = "yes"; then
 605   case ${target_cpu_type} in
 606   i386)
 607     case ${obj_format} in
 608     aout)
 609       emulations="$emulations i386coff i386elf"
 610       ;;
 611     coff)
 612       emulations="$emulations i386aout i386elf"
 613     ;;
 614     elf)
 615       emulations="$emulations i386aout i386coff"
 616       ;;
 617     esac
 618   ;;
 619   x86_64)
 620     case ${obj_format} in
 621     aout)
 622       emulations="$emulations i386coff i386elf"
 623       ;;
 624     coff)
 625       emulations="$emulations i386aout i386elf"
 626     ;;
 627     elf)
 628       emulations="$emulations i386aout i386coff"
 629       ;;
 630     esac
 631   ;;
 632   esac
 633 fi
 634
 635 # PE code has way too many macros tweaking behaviour
 636 case ${te_file} in
 637   pe*) emulations="" ;;
 638 esac
 639
 640 # Assign floating point type.  Most processors with FP support
 641 # IEEE FP.  On those that don't support FP at all, usually IEEE
 642 # is emulated.
 643 case ${target_cpu} in
 644   vax | pdp11 ) atof=vax ;;
 645   *)            atof=ieee ;;
 646 esac
 647
 648 case "${obj_format}" in
 649   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 650 esac
 651
 652 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 653 cgen_cpu_prefix=""
 654 if test $using_cgen = yes ; then
 655   case ${target_cpu} in
 656     or1knd)
 657        cgen_cpu_prefix=or1k ;;
 658     *) cgen_cpu_prefix=${target_cpu} ;;
 659   esac
 660   AC_SUBST(cgen_cpu_prefix)
 661   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 662 fi
 663
 664 dnl
 665 dnl Make sure the desired support files exist.
 666 dnl
 667
 668 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 669   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 670 fi
 671
 672 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 673   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 674 fi
 675
 676 # Some COFF configurations want these random other flags set.
 677 case ${obj_format} in
 678   coff)
 679     case ${target_cpu_type} in
 680       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 681       x86_64) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 682     esac
 683     ;;
 684 esac
 685
 686 # Getting this done right is going to be a bitch.  Each configuration specified
 687 # with --enable-targets=... should be checked for environment, format, cpu
 688 # setting.
 689 #
 690 # For each configuration, the necessary object file support code must be linked
 691 # in.  This might be only one, it might be up to four.  The necessary emulation
 692 # code needs to be provided, too.
 693 #
 694 # And then there's "--enable-targets=all"....
 695 #
 696 # For now, just always do it for MIPS ELF configurations.  Sigh.
 697
 698 formats="${obj_format}"
 699 emfiles=""
 700 EMULATIONS=""
 701 GAS_UNIQ(emulations)
 702 for em in . $emulations ; do
 703   case $em in
 704     .)  continue ;;
 705     mipsbelf | mipslelf | mipself)
 706         fmt=elf   file=mipself ;;
 707     *coff)
 708         fmt=coff  file=$em ;;
 709     *aout)
 710         fmt=aout file=$em ;;
 711     *elf)
 712         fmt=elf file=$em ;;
 713   esac
 714   formats="$formats $fmt"
 715   emfiles="$emfiles e-$file.o"
 716   EMULATIONS="$EMULATIONS &$em,"
 717 done
 718 GAS_UNIQ(formats)
 719 GAS_UNIQ(emfiles)
 720 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 721   for fmt in $formats ; do
 722     case $fmt in
 723       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 724       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 725       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 726       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 727       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 728       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 729     esac
 730     extra_objects="$extra_objects obj-$fmt.o"
 731   done
 732   obj_format=multi
 733 fi
 734 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 735   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 736   # e-mipself has more than one emulation per file, e-i386* has just one at the
 737   # moment.  If only one emulation is specified, then don't define
 738   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 739   case "${obj_format}${emfiles}" in
 740     multi* | *mipself*)
 741       extra_objects="$extra_objects $emfiles"
 742       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 743   esac
 744 fi
 745 AC_SUBST(extra_objects)
 746 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 747 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 748                    [Default emulation.])
 749
 750 reject_dev_configs=yes
 751
 752 case ${reject_dev_configs}-${dev} in
 753   yes-yes) # Oops.
 754     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 755     ;;
 756 esac
 757
 758 AC_SUBST(target_cpu_type)
 759 AC_SUBST(obj_format)
 760 AC_SUBST(te_file)
 761 AC_SUBST(install_tooldir)
 762 AC_SUBST(atof)
 763 dnl AC_SUBST(emulation)
 764
 765 # do we need the opcodes library?
 766 case "${need_opcodes}" in
 767 yes)
 768   OPCODES_LIB=../opcodes/libopcodes.la
 769   ;;
 770 esac
 771
 772 AC_SUBST(OPCODES_LIB)
 773
 774 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 775 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 776 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 777 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 778 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 779
 780 AC_PROG_YACC
 781 AM_PROG_LEX
 782
 783 ALL_LINGUAS="es fi fr id ja ru rw sv tr uk zh_CN"
 784 ZW_GNU_GETTEXT_SISTER_DIR
 785 AM_PO_SUBDIRS
 786
 787 AM_MAINTAINER_MODE
 788 AM_CONDITIONAL(GENINSRC_NEVER, false)
 789 AC_EXEEXT
 790
 791 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h errno.h sys/types.h limits.h locale.h time.h sys/stat.h)
 792 ACX_HEADER_STRING
 793
 794 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 795 # people who are not cross-compiling but are compiling cross-assemblers.
 796 AC_MSG_CHECKING(whether compiling a cross-assembler)
 797 if test "${host}" = "${target}"; then
 798   cross_gas=no
 799 else
 800   cross_gas=yes
 801   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 802 fi
 803 AC_MSG_RESULT($cross_gas)
 804
 805 dnl ansidecl.h will deal with const
 806 dnl AC_C_CONST
 807 AC_FUNC_ALLOCA
 808 AC_C_INLINE
 809
 810 # VMS doesn't have unlink.
 811 AC_CHECK_FUNCS(unlink remove, break)
 812 AC_CHECK_FUNCS(sbrk setlocale)
 813 AC_CHECK_FUNCS(strsignal)
 814
 815 AM_LC_MESSAGES
 816
 817 # do we need the math library?
 818 case "${need_libm}" in
 819 yes)
 820   LT_LIB_M
 821   AC_SUBST(LIBM)
 822   ;;
 823 esac
 824
 825 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 826 # enough, but on some of those systems, the assert macro relies on requoting
 827 # working properly!
 828 GAS_WORKING_ASSERT
 829
 830 # On some systems, the system header files may not declare malloc, realloc,
 831 # and free.  There are places where gas needs these functions to have been
 832 # declared -- such as when taking their addresses.
 833 gas_test_headers="
 834 #ifdef HAVE_MEMORY_H
 835 #include <memory.h>
 836 #endif
 837 #ifdef HAVE_STRING_H
 838 #include <string.h>
 839 #else
 840 #ifdef HAVE_STRINGS_H
 841 #include <strings.h>
 842 #endif
 843 #endif
 844 #ifdef HAVE_STDLIB_H
 845 #include <stdlib.h>
 846 #endif
 847 #ifdef HAVE_UNISTD_H
 848 #include <unistd.h>
 849 #endif
 850 "
 851
 852 # Does errno.h declare errno, or do we have to add a separate declaration
 853 # for it?
 854 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 855 #ifdef HAVE_ERRNO_H
 856 #include <errno.h>
 857 #endif
 858 ])
 859
 860 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 861 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
 862 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 863 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
 864 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
 865 if test $gas_cv_decl_getopt_unistd_h = yes; then
 866   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 867             [Is the prototype for getopt in <unistd.h> in the expected format?])
 868 fi
 869
 870 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 871 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
 872 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 873 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 874 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 875 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 876
 877 AC_CHECK_DECLS([free, getenv, malloc, mempcpy, realloc, stpcpy, strstr, vsnprintf, asprintf])
 878
 879 BFD_BINARY_FOPEN
 880
 881 # Link in zlib if we can.  This allows us to write compressed debug sections.
 882 AM_ZLIB
 883
 884 # Support for VMS timestamps via cross compile
 885
 886 if test "$ac_cv_header_time_h" = yes; then
 887   GAS_HAVE_TIME_TYPE_MEMBER(struct tm, tm_gmtoff)
 888 fi
 889
 890 if test "$ac_cv_header_sys_stat_h" = yes; then
 891     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_sec)
 892     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_nsec)
 893 fi
 894
 895
 896 dnl Required for html, pdf, install-pdf and install-html targets.
 897 AC_SUBST(datarootdir)
 898 AC_SUBST(docdir)
 899 AC_SUBST(htmldir)
 900 AC_SUBST(pdfdir)
 901
 902 dnl This must come last.
 903
 904 dnl We used to make symlinks to files in the source directory, but now
 905 dnl we just use the right name for .c files, and create .h files in
 906 dnl the build directory which include the right .h file.  Make sure
 907 dnl the old symlinks don't exist, so that a reconfigure in an existing
 908 dnl directory behaves reasonably.
 909
 910 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 911 AC_CONFIG_COMMANDS([default],
 912 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 913  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 914  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 915  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 916  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 917  if test "x$cgen_cpu_prefix" != x ; then
 918    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 919  fi],
 920 [target_cpu_type=${target_cpu_type}
 921  cgen_cpu_prefix=${cgen_cpu_prefix}
 922  obj_format=${obj_format}
 923  te_file=${te_file}])
 924
 925 AC_OUTPUT