gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 AC_PREREQ(2.3)dnl We only need 2.0, but pre-2.3 loses on some AIX version.
   8 AC_INIT(as.h)dnl
   9 dnl
  10 user_bfd_gas=
  11 AC_ARG_ENABLE(bfd-assembler,
  12 [  --enable-bfd-assembler  use BFD back end for writing object files],
  13 [case "${enableval}" in
  14   yes) need_bfd=yes user_bfd_gas=yes ;;
  15   no)  user_bfd_gas=no ;;
  16   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  17 esac])dnl
  18 AC_ARG_ENABLE(targets,
  19 [    targets            alternative target configurations besides the primary],
  20 [case "${enableval}" in
  21   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  22             ;;
  23   no)       enable_targets= ;;
  24   *)        enable_targets=$enableval ;;
  25 esac])dnl
  26 AC_ARG_ENABLE(shared,
  27 [  --enable-shared         build shared BFD library],
  28 [case "${enableval}" in
  29   yes) shared=true shared_bfd=true shared_opcodes=true ;;
  30   no)  shared=false ;;
  31   *bfd*opcodes*) shared=true shared_bfd=true shared_opcodes=true ;;
  32   *opcodes*bfd*) shared=true shared_bfd=true shared_opcodes=true ;;
  33   *bfd*) shared=true shared_bfd=true ;;
  34   *opcodes*) shared=true shared_opcodes=true ;;
  35   *) shared=false ;;
  36 esac])dnl
  37
  38 # Generate a header file -- gets more post-processing by Makefile later.
  39 AC_CONFIG_HEADER(conf)
  40
  41 dnl For recursion to work right, this must be an absolute pathname.
  42 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  43 AC_CANONICAL_SYSTEM
  44 AC_ARG_PROGRAM
  45
  46 te_file=generic
  47
  48 canon_targets=""
  49 if test -n "$enable_targets" ; then
  50   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  51     result=`$ac_config_sub $t 2>/dev/null`
  52     if test -n "$result" ; then
  53       canon_targets="$canon_targets $result"
  54 #    else
  55 #      # Permit "all", etc.  We don't support it yet though.
  56 #      canon_targets="$canon_targets $t"
  57     fi
  58   done
  59   GAS_UNIQ(canon_targets)
  60 fi
  61
  62 emulations=""
  63
  64 for this_target in $target $canon_targets ; do
  65
  66     eval `echo $this_target | sed 's/^\(.*\)-\(.*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
  67
  68     # check for architecture variants
  69     case ${cpu} in
  70       armeb)            cpu_type=arm endian=big ;;
  71       arm*)             cpu_type=arm endian=little ;;
  72       hppa*)            cpu_type=hppa ;;
  73 changequote(,)dnl
  74       i[456]86)         cpu_type=i386 ;;
  75       m680[012346]0)    cpu_type=m68k ;;
  76       m68008)           cpu_type=m68k ;;
  77       m683??)           cpu_type=m68k ;;
  78 changequote([,])dnl
  79       m8*)              cpu_type=m88k ;;
  80       mips*el)          cpu_type=mips endian=little;;
  81       mips*)            cpu_type=mips endian=big ;;
  82       powerpcle*)       cpu_type=ppc endian=little ;;
  83       powerpc*)         cpu_type=ppc endian=big ;;
  84       rs6000*)          cpu_type=ppc ;;
  85       sparc64)          cpu_type=sparc want_sparc_v9=true ;;
  86       sparc*)           cpu_type=sparc ;;
  87       *)                cpu_type=${cpu} ;;
  88     esac
  89
  90     if test ${this_target} = $target ; then
  91       target_cpu_type=${cpu_type}
  92     elif test ${target_cpu_type} != ${cpu_type} ; then
  93       continue
  94     fi
  95
  96     targ=${cpu_type}
  97     generic_target=${cpu_type}-$vendor-$os
  98     dev=no
  99     bfd_gas=no
 100     em=generic
 101
 102     # assign object format
 103     case ${generic_target} in
 104       a29k-*-coff)          fmt=coff targ=ebmon29k ;;
 105       a29k-amd-udi)         fmt=coff targ=ebmon29k ;;
 106       a29k-amd-ebmon)       fmt=coff targ=ebmon29k ;;
 107       a29k-nyu-sym1)        fmt=coff targ=ebmon29k ;;
 108       a29k-*-vxworks*)      fmt=coff ;;
 109
 110       alpha-*-netware*)     fmt=ecoff ;;
 111       alpha-*-osf*)         fmt=ecoff ;;
 112       alpha-*-linux*)       fmt=ecoff ;;
 113
 114 # start-sanitize-arc
 115       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 116 # end-sanitize-arc
 117
 118       arm-*-riscix*)        fmt=aout targ=arm-lit ;;
 119       arm-*-aout)           fmt=aout
 120                             case "$endian" in
 121                               big)      targ=arm-big ;;
 122                               *)        targ=arm-lit ;;
 123                             esac
 124                             ;;
 125       arm-*-coff)           fmt=coff ;;
 126       arm-*-riscix*)        fmt=aout ;;
 127       arm-*-pe)             fmt=coff targ=armcoff em=pe ;;
 128
 129       hppa-*-*elf*)         fmt=elf em=hppa ;;
 130       hppa-*-lites*)        fmt=elf em=hppa ;;
 131       hppa-*-osf*)          fmt=som em=hppa ;;
 132       hppa-*-hpux*)         fmt=som em=hppa ;;
 133       hppa-*-bsd*)          fmt=som em=hppa ;;
 134       hppa-*-hiux*)         fmt=som em=hppa ;;
 135
 136       h8300-*-coff)         fmt=coff ;;
 137
 138       i386-ibm-aix*)        fmt=coff targ=i386coff
 139                              em=i386aix ;;
 140       i386-*-bsd*)          fmt=aout em=386bsd ;;
 141       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 142       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 143       i386-*-linux*aout* | i386-*-linuxoldld)   fmt=aout em=linux ;;
 144       i386-*-linux*coff*)   fmt=coff em=linux
 145                              targ=i386coff ;;
 146       i386-*-linux*)        fmt=elf em=linux ;;
 147       i386-*-lynxos*)       fmt=coff targ=i386coff
 148                              em=lynx ;;
 149       i386-*-sysv4* | i386-*-solaris* | i386-*-elf | i386-*-freebsdelf*)
 150                             fmt=elf ;;
 151       i386-*-sco*elf*)      fmt=elf targ=sco5 ;;
 152       i386-*-coff | i386-*-sysv* | i386-*-sco* | i386-*-isc*)
 153                             fmt=coff targ=i386coff ;;
 154       i386-*-vsta)          fmt=aout ;;
 155       i386-*-go32)          fmt=coff targ=i386coff ;;
 156       i386-*-gnu*)          fmt=elf ;;
 157       i386-*-mach*)
 158                             fmt=aout em=mach bfd_gas=yes ;;
 159       i386-*-msdos*)        fmt=aout ;;
 160       i386-*-moss*)         fmt=elf ;;
 161       i386-*-pe)            fmt=coff targ=i386coff em=pe ;;
 162       i386-*-cygwin32)      fmt=coff targ=i386coff em=pe ;;
 163       i386-*-*nt)           fmt=coff targ=i386coff em=pe ;;
 164       i960-*-bout)          fmt=bout ;;
 165       i960-*-coff)          fmt=coff em=ic960 targ=ic960coff ;;
 166       i960-*-nindy*)        fmt=bout ;;
 167       i960-*-vxworks4*)     fmt=bout ;;
 168       i960-*-vxworks5.0)    fmt=bout ;;
 169       i960-*-vxworks5.*)    fmt=coff em=ic960 targ=ic960coff ;;
 170       i960-*-vxworks*)      fmt=bout ;;
 171
 172       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 173                             fmt=aout em=sun3 ;;
 174       m68k-motorola-sysv*)  fmt=coff targ=m68kcoff em=delta ;;
 175       m68k-bull-sysv3*)     fmt=coff targ=m68kcoff em=dpx2 ;;
 176       m68k-apollo-*)        fmt=coff targ=apollo em=apollo ;;
 177       m68k-*-sysv4 | m68k-*-elf) # must be before -sysv*
 178                             fmt=elf ;;
 179       m68k-*-coff | m68k-*-sysv*)
 180                             fmt=coff targ=m68kcoff ;;
 181       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 182       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 183       m68k-*-linux*)        fmt=elf em=linux ;;
 184       m68k-*-lynxos*)       fmt=coff targ=m68kcoff
 185                              em=lynx ;;
 186       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 187       m68k-apple-aux*)      fmt=coff targ=m68kcoff em=aux ;;
 188       m68k-*-psos*)         fmt=elf em=psos;;
 189
 190       m88k-motorola-sysv3*) fmt=coff targ=m88kcoff em=delt88 ;;
 191       m88k-*-coff*)         fmt=coff targ=m88kcoff ;;
 192
 193       # don't change em like *-*-bsd does
 194       mips-dec-netbsd*)     fmt=elf targ=mips-lit endian=little ;;
 195       mips-dec-bsd*)        fmt=aout targ=mips-lit ;;
 196       mips-sony-bsd*)       fmt=ecoff targ=mips-big ;;
 197       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 198       mips-*-ultrix*)       fmt=ecoff targ=mips-lit endian=little ;;
 199       mips-*-ecoff*)        fmt=ecoff
 200                             case "$endian" in
 201                             big) targ=mips-big ;;
 202                             *)   targ=mips-lit ;;
 203                             esac
 204                             ;;
 205       mips-*-ecoff*)        fmt=ecoff targ=mips-big ;;
 206       mips-*-gnu*)          fmt=aout
 207                             case "$endian" in
 208                             big) targ=mips-big ;;
 209                             *)   targ=mips-lit ;;
 210                             esac
 211                             ;;
 212       mips-*-irix5*)        fmt=elf targ=mips-big ;;
 213       mips-*-irix*)         fmt=ecoff targ=mips-big ;;
 214       mips-*-riscos*)       fmt=ecoff targ=mips-big ;;
 215       mips-*-sysv*)         fmt=ecoff targ=mips-big ;;
 216       mips-*-elf*)          fmt=elf
 217                             case "$endian" in
 218                             big) targ=mips-big ;;
 219                             *)   targ=mips-lit ;;
 220                             esac
 221                             ;;
 222       ppc-*-pe | ppc-*-cygwin32 | ppc-*-winnt*)
 223                             fmt=coff em=pe
 224                             case "$endian" in
 225                             big) targ=ppc-big ;;
 226                             *)   targ=ppc-lit ;;
 227                             esac
 228                             ;;
 229       ppc-*-aix*)           fmt=coff ;;
 230       ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 231                             fmt=elf
 232                             case "$endian" in
 233                             big)  targ=ppc-big ;;
 234                             *)    targ=ppc-lit ;;
 235                             esac
 236                             ;;
 237       ppc-*-linux*)         fmt=elf
 238                             case "$endian" in
 239                             big)  targ=ppc-big ;;
 240                             *)    AC_MSG_ERROR(Linux must be configured big endian) ;;
 241                             esac
 242                             ;;
 243       ppc-*-solaris*)       fmt=elf
 244                             case "$endian" in
 245                             big)  AC_MSG_ERROR(Solaris must be configured little endian) ;;
 246                             *)    targ=ppc-sol ;;
 247                             esac
 248                             ;;
 249       ppc-*-macos* | ppc-*-mpw*)
 250                             fmt=coff em=macos ;;
 251       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 252
 253       sh-*-coff)            fmt=coff ;;
 254
 255 # start-sanitize-rce
 256       rce-*-aout)           fmt=aout ;;
 257 # end-sanitize-rce
 258
 259       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 260       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 261
 262       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 263       sparc-*-aout | sparc*-*-vxworks)
 264                             fmt=aout ;;
 265       sparc-*-coff)         fmt=coff ;;
 266       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 267       sparc-fujitsu-none)   fmt=aout ;;
 268       sparc-*-elf | sparc-*-solaris*)
 269                             fmt=elf ;;
 270       sparc-*-netbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 271
 272       vax-*-bsd* | vax-*-ultrix*)
 273                             fmt=aout ;;
 274       vax-*-vms)            fmt=vms ;;
 275
 276       z8k-*-coff | z8k-*-sim)
 277                             fmt=coff ;;
 278
 279       w65-*-*)              fmt=coff ;;
 280
 281       *-*-aout | *-*-scout)
 282                             fmt=aout ;;
 283       *-*-nindy*)
 284                             fmt=bout ;;
 285       *-*-bsd*)
 286                             fmt=aout em=sun3 ;;
 287       *-*-generic)          fmt=generic ;;
 288       *-*-xray | *-*-hms)   fmt=coff ;;
 289       *-*-sim)              fmt=coff ;;
 290       *-*-elf | *-*-sysv4* | *-*-solaris*)
 291                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 292                             fmt=elf dev=yes ;;
 293       *-*-vxworks)          fmt=aout ;;
 294       *-*-netware)          fmt=elf ;;
 295     esac
 296
 297     case ${cpu_type}-${fmt} in
 298       arm-*)    bfd_gas=yes ;;
 299     # not yet
 300     # i386-aout)        bfd_gas=preferred ;;
 301       mips-*)   bfd_gas=yes ;;
 302       ns32k-*)  bfd_gas=yes ;;
 303       ppc-*)    bfd_gas=yes ;;
 304       sparc-*)  bfd_gas=yes ;;
 305       *-elf)    bfd_gas=yes ;;
 306       *-ecoff)  bfd_gas=yes ;;
 307       *-som)    bfd_gas=yes ;;
 308       *)                ;;
 309     esac
 310
 311 # Other random stuff.
 312
 313     # do we need the opcodes library?
 314     case ${cpu_type} in
 315       alpha | vax | i386)
 316         ;;
 317       *)
 318         need_opcodes=yes
 319         if test "${shared_opcodes}" = "true"; then
 320           # A shared libopcodes must be linked against libbfd.
 321           need_bfd=yes
 322         fi
 323         ;;
 324     esac
 325
 326     test -n "$want_sparc_v9" && AC_DEFINE(SPARC_V9)
 327
 328     case ${cpu}-${vendor}-${os} in
 329       sparc64-*-elf*) AC_DEFINE(SPARC_ARCH64) ;;
 330     esac
 331
 332     case ${cpu_type} in
 333       m68k)
 334         case ${extra_objects} in
 335         *m68k-parse.o*) ;;
 336         *) extra_objects="$extra_objects m68k-parse.o" ;;
 337         esac
 338         ;;
 339     esac
 340
 341 # See if we really can support this configuration with the emulation code.
 342
 343     if test $this_target = $target ; then
 344       primary_bfd_gas=$bfd_gas
 345       obj_format=$fmt
 346       gas_target=$targ
 347       te_file=$em
 348
 349       if test $bfd_gas = no ; then
 350         # Can't support other configurations this way.
 351         break
 352       fi
 353     elif test $bfd_gas = no ; then
 354       # Can't support this configuration.
 355       break
 356     fi
 357
 358 # From target name and format, produce a list of supported emulations.
 359
 360     case ${generic_target}-${fmt} in
 361       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 362       mips-*-*-ecoff)   case "$endian" in
 363                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 364                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 365                         esac ;;
 366       mips-*-*-elf)     case "$endian" in
 367                         big)    emulation="mipsbelf mipslelf mipself" ;;
 368                         *)      emulation="mipslelf mipsbelf mipself" ;;
 369                         esac ;;
 370     esac
 371
 372     emulations="$emulations $emulation"
 373
 374 done
 375
 376 # Assign floating point type.  Most processors with FP support
 377 # IEEE FP.  On those that don't support FP at all, usually IEEE
 378 # is emulated.
 379 case ${target_cpu} in
 380   vax | tahoe ) atof=${target_cpu} ;;
 381   *)            atof=ieee ;;
 382 esac
 383
 384 case "${obj_format}" in
 385   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 386 esac
 387
 388 dnl
 389 dnl Make sure the desired support files exist.
 390 dnl
 391
 392 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 393   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 394 fi
 395
 396 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 397   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 398 fi
 399
 400 # and target makefile frag
 401
 402 target_frag=${srcdir}/config/${gas_target}.mt
 403 if test ! -r ${target_frag}; then
 404   target_frag=/dev/null # ick! but subst_file can't be conditionalized
 405 fi
 406 AC_SUBST_FILE(target_frag)
 407
 408 case ${user_bfd_gas}-${primary_bfd_gas} in
 409   yes-yes | no-no)
 410     # We didn't override user's choice.
 411     ;;
 412   no-yes)
 413     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 414     ;;
 415   no-preferred)
 416     primary_bfd_gas=no
 417     ;;
 418   *-preferred)
 419     primary_bfd_gas=yes
 420     ;;
 421   yes-*)
 422     primary_bfd_gas=yes
 423     ;;
 424   -*)
 425     # User specified nothing.
 426     ;;
 427 esac
 428
 429 # Some COFF configurations want these random other flags set.
 430 case ${obj_format} in
 431   coff)
 432     case ${target_cpu_type} in
 433       i386) AC_DEFINE(I386COFF) ;;
 434       m68k) AC_DEFINE(M68KCOFF) ;;
 435       m88k) AC_DEFINE(M88KCOFF) ;;
 436     esac
 437     ;;
 438 esac
 439
 440 # Getting this done right is going to be a bitch.  Each configuration specified
 441 # with --enable-targets=... should be checked for environment, format, cpu, and
 442 # bfd_gas setting.
 443 #
 444 # For each configuration, the necessary object file support code must be linked
 445 # in.  This might be only one, it might be up to four.  The necessary emulation
 446 # code needs to be provided, too.
 447 #
 448 # And then there's "--enable-targets=all"....
 449 #
 450 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 451
 452 formats="${obj_format}"
 453 emfiles=""
 454 EMULATIONS=""
 455 GAS_UNIQ(emulations)
 456 for em in . $emulations ; do
 457   case $em in
 458     .)  continue ;;
 459     mipsbelf | mipslelf)
 460         fmt=elf   file=mipself ;;
 461     mipsbecoff | mipslecoff)
 462         fmt=ecoff file=mipsecoff ;;
 463   esac
 464   formats="$formats $fmt"
 465   emfiles="$emfiles e-$file.o"
 466   EMULATIONS="$EMULATIONS &$em,"
 467 done
 468 GAS_UNIQ(formats)
 469 GAS_UNIQ(emfiles)
 470 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 471   for fmt in $formats ; do
 472     case $fmt in
 473       aout)     AC_DEFINE(OBJ_MAYBE_AOUT)    ;;
 474       bout)     AC_DEFINE(OBJ_MAYBE_BOUT)    ;;
 475       coff)     AC_DEFINE(OBJ_MAYBE_COFF)    ;;
 476       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF)   ;;
 477       elf)      AC_DEFINE(OBJ_MAYBE_ELF)     ;;
 478       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC) ;;
 479       hp300)    AC_DEFINE(OBJ_MAYBE_HP300)   ;;
 480       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE)    ;;
 481       som)      AC_DEFINE(OBJ_MAYBE_SOM)     ;;
 482       vms)      AC_DEFINE(OBJ_MAYBE_VMS)     ;;
 483     esac
 484     extra_objects="$extra_objects obj-$fmt.o"
 485   done
 486   obj_format=multi
 487 fi
 488 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 489   te_file=multi
 490   extra_objects="$extra_objects $emfiles"
 491   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 492   AC_DEFINE(USE_EMULATIONS)
 493 fi
 494 AC_SUBST(extra_objects)
 495 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS)
 496 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION")
 497
 498 files="config/tc-${target_cpu_type}.c config/tc-${target_cpu_type}.h \
 499         config/obj-${obj_format}.h config/obj-${obj_format}.c \
 500         config/te-${te_file}.h config/atof-${atof}.c \
 501         $extra_files"
 502 links="targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c \
 503         $extra_links"
 504
 505 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 506   yes-*-coff)   need_bfd=yes ;;
 507   no-*-coff)    need_bfd=yes
 508                 AC_DEFINE(MANY_SEGMENTS) ;;
 509 esac
 510
 511 reject_dev_configs=yes
 512
 513 case ${reject_dev_configs}-${dev} in
 514   yes-yes) # Oops.
 515     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 516     ;;
 517 esac
 518
 519 AC_SUBST(target_cpu_type)
 520 AC_SUBST(obj_format)
 521 AC_SUBST(atof)
 522 dnl AC_SUBST(emulation)
 523
 524 AC_LINK_FILES($files, $links)
 525
 526 case "${primary_bfd_gas}" in
 527   yes)  AC_DEFINE(BFD_ASSEMBLER)
 528         need_bfd=yes ;;
 529 esac
 530
 531 # do we need the opcodes library?
 532 case "${need_opcodes}" in
 533   yes)
 534     OPCODES_DEP=../opcodes/libopcodes.a
 535     OPCODES_LIB='-L../opcodes -lopcodes'
 536
 537     # We need to handle some special cases if opcodes was built shared.
 538     if test "${shared_opcodes}" = "true"; then
 539       case "${host}" in
 540       *-*-sunos*)
 541       # On SunOS, we must link against the name we are going to install,
 542       # not -lbfd, since SunOS does not support SONAME.
 543       OPCODES_LIB='-L../opcodes -l`echo opcodes | sed '"'"'$(program_transform_name)'"'"'`'
 544       ;;
 545       esac
 546     fi
 547     ;;
 548 esac
 549 AC_SUBST(OPCODES_DEP)
 550 AC_SUBST(OPCODES_LIB)
 551
 552 case "${need_bfd}" in
 553   yes)
 554     BFDDEP=../bfd/libbfd.a
 555     BFDLIB='-L../bfd -lbfd'
 556     ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 557
 558     # We need to handle some special cases if BFD was built shared.
 559     if test "${shared_bfd}" = "true"; then
 560       case "${host}" in
 561         *-*-sunos*)
 562         # On SunOS, we must link against the name we are going to install,
 563         # not -lbfd, since SunOS does not support SONAME.
 564         BFDLIB='-L../bfd -l`echo bfd | sed '"'"'$(program_transform_name)'"'"'`'
 565         ;;
 566       esac
 567     fi
 568     ;;
 569 esac
 570 AC_SUBST(BFDDEP)
 571 AC_SUBST(BFDLIB)
 572 AC_SUBST(ALL_OBJ_DEPS)
 573
 574 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}")
 575 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}")
 576 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}")
 577 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}")
 578 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}")
 579
 580 AC_PROG_CC
 581 AC_PROG_INSTALL
 582
 583 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 584
 585 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 586 # people who are not cross-compiling but are compiling cross-assemblers.
 587 AC_MSG_CHECKING(whether compiling a cross-assembler)
 588 if test "${host}" = "${target}"; then
 589   cross_gas=no
 590 else
 591   cross_gas=yes
 592   AC_DEFINE(CROSS_COMPILE)
 593 fi
 594 AC_MSG_RESULT($cross_gas)
 595
 596 dnl ansidecl.h will deal with const
 597 dnl AC_CONST
 598 AC_FUNC_ALLOCA
 599 AC_C_INLINE
 600
 601 # VMS doesn't have unlink.
 602 AC_CHECK_FUNCS(unlink remove, break)
 603
 604 # Some systems don't have sbrk().
 605 AC_CHECK_FUNCS(sbrk)
 606
 607 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 608 # enough, but on some of those systems, the assert macro relies on requoting
 609 # working properly!
 610 GAS_WORKING_ASSERT
 611
 612 # On some systems, the system header files may not declare malloc, realloc,
 613 # and free.  There are places where gas needs these functions to have been
 614 # declared -- such as when taking their addresses.
 615 gas_test_headers="
 616 #ifdef HAVE_MEMORY_H
 617 #include <memory.h>
 618 #endif
 619 #ifdef HAVE_STRING_H
 620 #include <string.h>
 621 #endif
 622 #ifdef HAVE_STDLIB_H
 623 #include <stdlib.h>
 624 #endif
 625 #ifdef HAVE_UNISTD_H
 626 #include <unistd.h>
 627 #endif
 628 "
 629 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 630 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 631
 632 # Does errno.h declare errno, or do we have to add a separate declaration
 633 # for it?
 634 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 635 #ifdef HAVE_ERRNO_H
 636 #include <errno.h>
 637 #endif
 638 ])
 639
 640 HLDFLAGS=
 641 RPATH_ENVVAR=LD_LIBRARY_PATH
 642 # If we have shared libraries, try to set rpath reasonably.
 643 if test "${shared}" = "true"; then
 644   case "${host}" in
 645   *-*-hpux*)
 646     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 647     RPATH_ENVVAR=SHLIB_PATH
 648     ;;
 649   *-*-irix5*)
 650     HLDFLAGS='-Wl,-rpath,$(libdir)'
 651     ;;
 652   *-*-linux*aout*)
 653     ;;
 654   *-*-linux*)
 655     HLDFLAGS='-Wl,-rpath,$(libdir)'
 656     ;;
 657   *-*-sysv4* | *-*-solaris*)
 658     HLDFLAGS='-R $(libdir)'
 659     ;;
 660   esac
 661 fi
 662
 663 # On SunOS, if the linker supports the -rpath option, use it to
 664 # prevent ../bfd and ../opcodes from being included in the run time
 665 # search path.
 666 case "${host}" in
 667   *-*-sunos*)
 668     echo 'main () { }' > conftest.c
 669     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 670     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 671       :
 672     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 673       :
 674     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 675       :
 676     elif test "${shared}" = "true"; then
 677       HLDFLAGS='-Wl,-rpath=$(libdir)'
 678     else
 679       HLDFLAGS='-Wl,-rpath='
 680     fi
 681     rm -f conftest.t conftest.c conftest
 682     ;;
 683 esac
 684 AC_SUBST(HLDFLAGS)
 685 AC_SUBST(RPATH_ENVVAR)
 686
 687 dnl This must come last.
 688 AC_OUTPUT(Makefile doc/Makefile .gdbinit:gdbinit.in)