gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ISC_POSIX
  13
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  18
  19 AM_PROG_LIBTOOL
  20
  21 user_bfd_gas=
  22 AC_ARG_ENABLE(bfd-assembler,
  23 [  --enable-bfd-assembler  use BFD back end for writing object files],
  24 [case "${enableval}" in
  25   yes) need_bfd=yes user_bfd_gas=yes ;;
  26   no)  user_bfd_gas=no ;;
  27   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(targets,
  30 [    targets            alternative target configurations besides the primary],
  31 [case "${enableval}" in
  32   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  33             ;;
  34   no)       enable_targets= ;;
  35   *)        enable_targets=$enableval ;;
  36 esac])dnl
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 using_cgen=no
  46
  47 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  48 AC_ARG_ENABLE(build-warnings,
  49 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  50 [case "${enableval}" in
  51   yes)  ;;
  52   no)   build_warnings="-w";;
  53   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  54         build_warnings="${build_warnings} ${t}";;
  55   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  56         build_warnings="${t} ${build_warnings}";;
  57   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  58 esac
  59 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  60   echo "Setting warning flags = $build_warnings" 6>&1
  61 fi])dnl
  62 WARN_CFLAGS=""
  63 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  64     WARN_CFLAGS="${build_warnings}"
  65 fi
  66 AC_SUBST(WARN_CFLAGS)
  67
  68 # Generate a header file
  69 AM_CONFIG_HEADER(config.h:config.in)
  70
  71 # If we are on a DOS filesystem, we must use gdb.ini rather than
  72 # .gdbinit.
  73 GDBINIT=".gdbinit"
  74 case "${host}" in
  75   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
  76     GDBINIT="gdb.ini"
  77     ;;
  78 esac
  79 AC_SUBST(GDBINIT)
  80
  81 te_file=generic
  82
  83 # Makefile target for installing gas in $(tooldir)/bin.
  84 install_tooldir=install-exec-tooldir
  85
  86 canon_targets=""
  87 all_targets=no
  88 if test -n "$enable_targets" ; then
  89   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  90     if test $t = "all"; then
  91       all_targets=yes
  92       continue
  93     fi
  94     result=`$ac_config_sub $t 2>/dev/null`
  95     if test -n "$result" ; then
  96       canon_targets="$canon_targets $result"
  97 #    else
  98 #      # Permit "all", etc.  We don't support it yet though.
  99 #      canon_targets="$canon_targets $t"
 100     fi
 101   done
 102   GAS_UNIQ(canon_targets)
 103 fi
 104
 105 emulations=""
 106
 107 for this_target in $target $canon_targets ; do
 108
 109 changequote(,)dnl
 110     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 111 changequote([,])dnl
 112
 113     # check for architecture variants
 114     arch=
 115     endian=
 116     case ${cpu} in
 117       alpha*)           cpu_type=alpha ;;
 118       armeb)            cpu_type=arm endian=big ;;
 119       arm*)             cpu_type=arm endian=little ;;
 120       armb*)            cpu_type=arm endian=little ;;
 121       armv*l)           cpu_type=arm endian=little ;;
 122       armv*b)           cpu_type=arm endian=big ;;
 123       xscale*)          cpu_type=arm endian=little ;;
 124       strongarm*)       cpu_type=arm endian=little ;;
 125       thumb*)           cpu_type=arm endian=little ;;
 126       hppa*)            cpu_type=hppa ;;
 127 changequote(,)dnl
 128       i[3456]86)        cpu_type=i386 arch=i386;;
 129       x86_64)           cpu_type=i386 arch=x86_64;;
 130       ia64)             cpu_type=ia64 ;;
 131       ip2k)             cpu_type=ip2k endian=big ;;
 132       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 133       m680[012346]0)    cpu_type=m68k ;;
 134 changequote([,])dnl
 135       m68008)           cpu_type=m68k ;;
 136       m683??)           cpu_type=m68k ;;
 137       m5200)            cpu_type=m68k ;;
 138       m8*)              cpu_type=m88k ;;
 139       mips*el)          cpu_type=mips endian=little ;;
 140       mips*)            cpu_type=mips endian=big ;;
 141       or32*)            cpu_type=or32 endian=big ;;
 142       pjl*)             cpu_type=pj endian=little ;;
 143       pj*)              cpu_type=pj endian=big ;;
 144       powerpc*le*)      cpu_type=ppc endian=little ;;
 145       powerpc*)         cpu_type=ppc endian=big ;;
 146       rs6000*)          cpu_type=ppc ;;
 147       s390x*)           cpu_type=s390 arch=s390x ;;
 148       s390*)            cpu_type=s390 arch=s390 ;;
 149       sh5*)             cpu_type=sh64 endian=big ;;
 150       sh5le*)           cpu_type=sh64 endian=little ;;
 151       sh64*)            cpu_type=sh64 endian=big ;;
 152       sh64le*)          cpu_type=sh64 endian=little ;;
 153       sh*le)            cpu_type=sh endian=little ;;
 154       sh*)              cpu_type=sh endian=big ;;
 155       sparclite*)       cpu_type=sparc arch=sparclite ;;
 156       sparclet*)        cpu_type=sparc arch=sparclet ;;
 157       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 158       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 159       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 160       v850*)            cpu_type=v850 ;;
 161       *)                cpu_type=${cpu} ;;
 162     esac
 163
 164     if test ${this_target} = $target ; then
 165       target_cpu_type=${cpu_type}
 166     elif test ${target_cpu_type} != ${cpu_type} ; then
 167       continue
 168     fi
 169
 170     generic_target=${cpu_type}-$vendor-$os
 171     dev=no
 172     bfd_gas=no
 173     em=generic
 174
 175     # assign object format
 176     case ${generic_target} in
 177       a29k-*-coff)          fmt=coff ;;
 178       a29k-amd-udi)         fmt=coff ;;
 179       a29k-amd-ebmon)       fmt=coff ;;
 180       a29k-nyu-sym1)        fmt=coff ;;
 181       a29k-*-rtems*)        fmt=coff ;;
 182       a29k-*-vxworks*)      fmt=coff ;;
 183
 184       alpha*-*-*vms*)       fmt=evax ;;
 185       alpha*-*-netware*)    fmt=ecoff ;;
 186       alpha*-*-osf*)        fmt=ecoff ;;
 187       alpha*-*-linuxecoff*) fmt=ecoff ;;
 188       alpha*-*-linux-gnu*)  fmt=elf em=linux ;;
 189       alpha*-*-netbsd*)     fmt=elf em=nbsd ;;
 190       alpha*-*-openbsd*)    fmt=elf em=obsd ;;
 191
 192       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 193
 194       arm-*-aout)                       fmt=aout ;;
 195       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 196       arm-*-rtems | thumb-*-rtems)      fmt=elf ;;
 197       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 198       arm*-*-conix*)                    fmt=elf ;;
 199       arm-*-linux*aout*)                fmt=aout em=linux ;;
 200       arm*-*-linux-gnu* | arm*-*-uclinux*)
 201                                         fmt=elf  em=linux ;;
 202       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 203       arm-*-netbsd* | arm-*-openbsd*)   fmt=aout em=nbsd ;;
 204       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 205       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 206       arm-*-wince)                      fmt=coff em=wince-pe ;;
 207       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 208       arm-*-riscix*)                    fmt=aout em=riscix ;;
 209       arm-*-vxworks)                    fmt=coff ;;
 210
 211       avr-*-*)              fmt=elf bfd_gas=yes ;;
 212
 213       cris-*-*)             fmt=multi bfd_gas=yes ;;
 214
 215       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 216       d30v-*-*)             fmt=elf bfd_gas=yes ;;
 217       dlx-*-*)              fmt=elf ;;
 218
 219
 220       fr30-*-*)             fmt=elf bfd_gas=yes ;;
 221       frv-*-*)              fmt=elf bfd_gas=yes ;;
 222
 223       hppa-*-linux-gnu*)    case ${cpu} in
 224                                 hppa*64*)
 225                                         fmt=elf em=hppalinux64;;
 226                                 hppa*)
 227                                         fmt=elf em=linux;;
 228                             esac ;;
 229       hppa-*-*elf*)         fmt=elf em=hppa ;;
 230       hppa-*-lites*)        fmt=elf em=hppa ;;
 231       hppa-*-netbsd*)       fmt=elf em=nbsd ;;
 232       hppa-*-openbsd*)      fmt=elf em=hppa ;;
 233       hppa-*-osf*)          fmt=som em=hppa ;;
 234       hppa-*-rtems*)        fmt=elf em=hppa ;;
 235       hppa-*-hpux11*)       case ${cpu} in
 236                                 hppa*64*)
 237                                         fmt=elf em=hppa64 ;;
 238                                 hppa*)
 239                                         fmt=som em=hppa ;;
 240                             esac ;;
 241       hppa-*-hpux*)         fmt=som em=hppa ;;
 242       hppa-*-mpeix*)        fmt=som em=hppa ;;
 243       hppa-*-bsd*)          fmt=som em=hppa ;;
 244       hppa-*-hiux*)         fmt=som em=hppa ;;
 245
 246       h8300-*-rtems*)       fmt=coff ;;
 247       h8300-*-coff)         fmt=coff ;;
 248       h8300-*-elf)          fmt=elf ;;
 249       h8500-*-rtems*)       fmt=coff ;;
 250       h8500-*-coff)         fmt=coff ;;
 251
 252       i370-*-elf* | i370-*-linux*) fmt=elf ;;
 253       i386-ibm-aix*)        fmt=coff em=i386aix ;;
 254       i386-sequent-bsd*)    fmt=aout em=dynix bfd_gas=yes ;;
 255       i386-*-beospe*)       fmt=coff em=pe bfd_gas=yes ;;
 256       i386-*-beoself* | i386-*-beos*) fmt=elf bfd_gas=yes ;;
 257       i386-*-bsd*)          fmt=aout em=386bsd ;;
 258       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 259       i386-*-netbsdpe*)       fmt=coff em=pe bfd_gas=yes ;;
 260       i386-*-netbsd*)       em=nbsd bfd_gas=yes
 261                             case ${cpu} in
 262                               x86_64)   fmt=elf ;;
 263                               *)        case ${os} in
 264                                           *elf*) fmt=elf ;;
 265                                           *)     fmt=aout ;;
 266                                         esac
 267                                         ;;
 268                             esac
 269                             ;;
 270       i386-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes;;
 271       i386-*-linux*aout* | i386-*-linux*oldld)   fmt=aout em=linux ;;
 272       i386-*-linux*coff*)   fmt=coff em=linux ;;
 273       i386-*-linux-gnu*)    fmt=elf em=linux bfd_gas=yes ;;
 274       x86_64-*-linux-gnu*)  fmt=elf em=linux bfd_gas=yes ;;
 275       i386-*-lynxos*)       fmt=coff em=lynx ;;
 276 changequote(,)dnl
 277       i386-*-sysv[45]* | i386-*-solaris* | i386-*-elf)
 278                             fmt=elf bfd_gas=yes ;;
 279       i386-*-freebsdaout* | i386-*-freebsd[12].* | i386-*-freebsd[12])
 280                             fmt=aout em=386bsd ;;
 281 changequote([,])dnl
 282       i386-*-coff | i386-*-sysv* | i386-*-sco3.2v5*coff | i386-*-isc*)
 283                           fmt=coff ;;
 284       i386-*-sco3.2v5*)      fmt=elf
 285                             if test ${this_target} = $target; then
 286                                 AC_DEFINE(SCO_ELF, 1,
 287                                     [Define if defaulting to ELF on SCO 5.])
 288                             fi
 289                             ;;
 290       i386-*-sco3.2*)       fmt=coff ;;
 291       i386-*-vsta)          fmt=aout ;;
 292       i386-*-msdosdjgpp* | i386-*-go32* | i386-go32-rtems*)
 293                             fmt=coff em=go32 bfd_gas=yes
 294                             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 295                             ;;
 296       i386-*-rtemself*)     fmt=elf ;;
 297       i386-*-rtemscoff*)    fmt=coff ;;
 298       i386-*-rtems*)        fmt=elf ;;
 299       i386-*-gnu*)          fmt=elf ;;
 300       i386-*-mach*)
 301                             fmt=aout em=mach bfd_gas=yes ;;
 302       i386-*-msdos*)        fmt=aout ;;
 303       i386-*-moss*)         fmt=elf ;;
 304       i386-*-pe)            fmt=coff em=pe bfd_gas=yes ;;
 305       i386-*-cygwin*)       fmt=coff em=pe bfd_gas=yes ;;
 306       i386-*-interix*)      fmt=coff em=interix bfd_gas=yes ;;
 307       i386-*-mingw32*)      fmt=coff em=pe bfd_gas=yes ;;
 308       i386-*-nto-qnx*)      fmt=elf ;;
 309       i386-*-*nt*)          fmt=coff em=pe bfd_gas=yes ;;
 310       i386-*-vxworks*)      fmt=aout ;;
 311       i386-*-chaos)         fmt=elf ;;
 312       i860-stardent-sysv4* | i860-stardent-elf*)
 313                             fmt=elf bfd_gas=yes endian=little
 314                             AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 315       i960-*-bout)          fmt=bout ;;
 316       i960-*-coff)          fmt=coff em=ic960 ;;
 317       i960-*-rtems*)        fmt=coff em=ic960 ;;
 318       i960-*-nindy*)        fmt=bout ;;
 319       i960-*-vxworks4*)     fmt=bout ;;
 320       i960-*-vxworks5.0)    fmt=bout ;;
 321       i960-*-vxworks5.*)    fmt=coff em=ic960 ;;
 322       i960-*-vxworks*)      fmt=bout ;;
 323       i960-*-elf*)          fmt=elf ;;
 324
 325       ia64-*-elf*)          fmt=elf ;;
 326       ia64-*-aix*)          fmt=elf em=ia64aix ;;
 327       ia64-*-linux-gnu*)    fmt=elf em=linux ;;
 328       ia64-*-hpux*)         fmt=elf em=hpux ;;
 329       ia64-*-netbsd*)       fmt=elf em=nbsd ;;
 330
 331       ip2k-*-*)             fmt=elf bfd_gas=yes ;;
 332
 333       m32r-*-*)             fmt=elf bfd_gas=yes ;;
 334
 335       m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)fmt=elf bfd_gas=yes ;;
 336
 337       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 338                             fmt=aout em=sun3 ;;
 339       m68k-motorola-sysv*)  fmt=coff em=delta ;;
 340       m68k-bull-sysv3*)     fmt=coff em=dpx2 ;;
 341       m68k-apollo-*)        fmt=coff em=apollo ;;
 342       m68k-*-sysv4*) # must be before -sysv*
 343                             fmt=elf em=svr4 ;;
 344       m68k-*-elf*)          fmt=elf ;;
 345       m68k-*-coff | m68k-*-sysv* | m68k-*-rtemscoff*)
 346                             fmt=coff ;;
 347       m68k-*-rtems*)        fmt=elf ;;
 348       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 349       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 350       m68k-*-linux-gnu*)    fmt=elf em=linux ;;
 351       m68k-*-gnu*)          fmt=elf ;;
 352       m68k-*-lynxos*)       fmt=coff em=lynx ;;
 353       m68k-*-netbsdelf*)    fmt=elf em=nbsd bfd_gas=yes ;;
 354       m68k-*-netbsdaout* | m68k-*-netbsd*)
 355                             fmt=aout em=nbsd bfd_gas=yes ;;
 356       m68k-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 357       m68k-apple-aux*)      fmt=coff em=aux ;;
 358       m68k-*-psos*)         fmt=elf em=psos;;
 359
 360       m88k-motorola-sysv3*) fmt=coff em=delt88 ;;
 361       m88k-*-coff*)         fmt=coff ;;
 362
 363       mcore-*-elf)          fmt=elf bfd_gas=yes ;;
 364       mcore-*-pe)           fmt=coff em=pe bfd_gas=yes ;;
 365
 366       # don't change em like *-*-bsd does
 367       mips-dec-openbsd*)    fmt=elf endian=little ;;
 368       mips-dec-bsd*)        fmt=aout endian=little ;;
 369       mips-sony-bsd*)       fmt=ecoff ;;
 370       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 371       mips-*-ultrix*)       fmt=ecoff endian=little ;;
 372       mips-*-osf*)          fmt=ecoff endian=little ;;
 373       mips-*-ecoff*)        fmt=ecoff ;;
 374       mips-*-pe*)           fmt=coff endian=little em=pe ;;
 375       mips-*-irix6*)        fmt=elf ;;
 376       mips-*-irix5*)        fmt=elf ;;
 377       mips-*-irix*)         fmt=ecoff ;;
 378       mips-*-lnews*)        fmt=ecoff em=lnews ;;
 379       mips-*-riscos*)       fmt=ecoff ;;
 380       mips*-*-linux*)       fmt=elf em=tmips ;;
 381       mips-*-sysv4*MP* | mips-*-gnu*)
 382                             fmt=elf em=tmips ;;
 383       mips-*-sysv*)         fmt=ecoff ;;
 384       mips-*-elf* | mips-*-rtems* | mips-*-netbsd* | mips-*-openbsd*)
 385                             fmt=elf ;;
 386       mips-*-vxworks*)      fmt=elf ;;
 387       mmix-*-*)             fmt=elf bfd_gas=yes ;;
 388       mn10200-*-*)          fmt=elf bfd_gas=yes ;;
 389       mn10300-*-*)          fmt=elf bfd_gas=yes ;;
 390       openrisc-*-*)         fmt=elf bfd_gas=yes ;;
 391       or32-*-rtems*)        fmt=coff ;;
 392       or32-*-coff)          fmt=coff ;;
 393       or32-*-elf)           fmt=elf ;;
 394       pj*)                  fmt=elf ;;
 395       ppc-*-pe | ppc-*-cygwin* | ppc-*-winnt*)
 396                             fmt=coff em=pe ;;
 397       ppc-*-aix5*)          fmt=coff em=aix5 ;;
 398       ppc-*-aix*)           fmt=coff ;;
 399       ppc-*-beos*)          fmt=coff ;;
 400       ppc-*-*bsd* | ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 401                             fmt=elf ;;
 402       ppc-*-linux-gnu*)     fmt=elf
 403                             case "$endian" in
 404                             big)  ;;
 405                             *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 406                             esac
 407                             ;;
 408       ppc-*-solaris*)       fmt=elf
 409                             if test ${this_target} = $target; then
 410                                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 411                                 [Define if default target is PowerPC Solaris.])
 412                             fi
 413                             if test x${endian} = xbig; then
 414                                 AC_MSG_ERROR(Solaris must be configured little endian)
 415                             fi
 416                             ;;
 417       ppc-*-rtems*)         fmt=elf ;;
 418       ppc-*-macos* | ppc-*-mpw*)
 419                             fmt=coff em=macos ;;
 420       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 421       ppc-*-vxworks*)       fmt=elf ;;
 422       ppc-*-windiss*)       fmt=elf ;;
 423
 424       s390x-*-linux-gnu*)   fmt=elf em=linux ;;
 425       s390-*-linux-gnu*)    fmt=elf em=linux ;;
 426
 427       sh*-*-linux*)         fmt=elf em=linux
 428                             case ${cpu} in
 429                                 sh*eb)
 430                                         endian=big ;;
 431                                 sh*)
 432                                         endian=little ;;
 433                             esac ;;
 434       sh5*-*-netbsd*)       fmt=elf em=nbsd ;;
 435       sh64*-*-netbsd*)      fmt=elf em=nbsd ;;
 436       sh*-*-netbsdelf*)     fmt=elf em=nbsd ;;
 437       sh-*-elf*)            fmt=elf ;;
 438       sh-*-coff*)           fmt=coff ;;
 439       sh-*-pe*)             fmt=coff em=pe bfd_gas=yes endian=little ;;
 440       sh-*-rtemself*)       fmt=elf ;;
 441       sh-*-rtems*)          fmt=coff ;;
 442
 443       sh64-*-elf*)          fmt=elf ;;
 444       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 445       ns32k-*-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 446       ns32k-pc532-openbsd*) fmt=aout em=nbsd532 ;;
 447
 448       sparc-*-rtemsaout*)   fmt=aout ;;
 449       sparc-*-rtemself*)    fmt=elf ;;
 450       sparc-*-rtems*)       fmt=elf ;;
 451       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 452       sparc-*-aout | sparc*-*-vxworks*)
 453                             fmt=aout em=sparcaout ;;
 454       sparc-*-coff)         fmt=coff ;;
 455       sparc-*-linux*aout*)  fmt=aout em=linux ;;
 456       sparc-*-linux-gnu*)   fmt=elf em=linux ;;
 457       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 458       sparc-fujitsu-none)   fmt=aout ;;
 459       sparc-*-elf | sparc-*-sysv4* | sparc-*-solaris*)
 460                             fmt=elf ;;
 461       sparc-*-netbsd*)      em=nbsd bfd_gas=yes
 462                             case ${cpu} in
 463                                 sparc) case ${os} in
 464                                            *elf*) fmt=elf ;;
 465                                            *)     fmt=aout ;;
 466                                        esac ;;
 467                                 sparc64) fmt=elf ;;
 468                             esac
 469                             ;;
 470       sparc-*-openbsd*)     em=nbsd
 471                             case ${cpu} in
 472                                sparc) fmt=aout ;;
 473                                sparc64) fmt=elf ;;
 474                             esac
 475                             ;;
 476
 477       strongarm-*-coff)     fmt=coff ;;
 478       strongarm-*-elf)      fmt=elf ;;
 479       xscale-*-coff)     fmt=coff ;;
 480       xscale-*-elf)      fmt=elf ;;
 481
 482       tic30-*-*aout*)       fmt=aout bfd_gas=yes ;;
 483       tic30-*-*coff*)       fmt=coff bfd_gas=yes ;;
 484       tic54x-*-* | c54x*-*-*)
 485                             fmt=coff bfd_gas=yes need_libm=yes;;
 486       tic80-*-*)            fmt=coff ;;
 487
 488       v850-*-*)             fmt=elf bfd_gas=yes ;;
 489       v850e-*-*)            fmt=elf bfd_gas=yes ;;
 490       v850ea-*-*)           fmt=elf bfd_gas=yes ;;
 491
 492       vax-*-netbsdelf*)     fmt=elf em=nbsd bfd_gas=yes ;;
 493       vax-*-netbsdaout* | vax-*-netbsd*)
 494                             fmt=aout em=nbsd ;;
 495       vax-*-bsd* | vax-*-ultrix*)
 496                             fmt=aout ;;
 497       vax-*-vms)            fmt=vms ;;
 498
 499       w65-*-*)              fmt=coff ;;
 500
 501       xstormy16-*-*)        fmt=elf bfd_gas=yes ;;
 502
 503       z8k-*-coff | z8k-*-sim)
 504                             fmt=coff ;;
 505
 506       *-*-aout | *-*-scout)
 507                             fmt=aout ;;
 508       *-*-freebsd*)         fmt=elf em=freebsd bfd_gas=yes ;;
 509       *-*-nindy*)
 510                             fmt=bout ;;
 511       *-*-bsd*)
 512                             fmt=aout em=sun3 ;;
 513       *-*-generic)          fmt=generic ;;
 514       *-*-xray | *-*-hms)   fmt=coff ;;
 515       *-*-sim)              fmt=coff ;;
 516       *-*-elf | *-*-sysv4* | *-*-solaris*)
 517                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 518                             fmt=elf dev=yes ;;
 519       *-*-vxworks)          fmt=aout ;;
 520       *-*-netware)          fmt=elf ;;
 521     esac
 522
 523     if test ${this_target} = $target ; then
 524       endian_def=
 525       if test x${endian} = xbig; then
 526         endian_def=1
 527       elif test x${endian} = xlittle; then
 528         endian_def=0
 529       fi
 530       if test x${endian_def} != x; then
 531         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 532                            [Define as 1 if big endian.])
 533       fi
 534     fi
 535
 536     case ${cpu_type}-${fmt} in
 537       alpha*-*) bfd_gas=yes ;;
 538       arm-*)    bfd_gas=yes ;;
 539     # not yet
 540     # i386-aout)        bfd_gas=preferred ;;
 541       ia64*-*)  bfd_gas=yes ;;
 542       mips-*)   bfd_gas=yes ;;
 543       ns32k-*)  bfd_gas=yes ;;
 544       pdp11-*)  bfd_gas=yes ;;
 545       ppc-*)    bfd_gas=yes ;;
 546       sparc-*)  bfd_gas=yes ;;
 547       strongarm-*)      bfd_gas=yes ;;
 548       xscale-*) bfd_gas=yes ;;
 549       *-elf)    bfd_gas=yes ;;
 550       *-ecoff)  bfd_gas=yes ;;
 551       *-som)    bfd_gas=yes ;;
 552     #enable bfd for coff and aout to allow testing if a bfd target is
 553     #the primary target, but not for coff or aout as the primary target
 554       i386-coff)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 555       i386-aout)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 556       *)                ;;
 557     esac
 558
 559 # Other random stuff.
 560
 561     case ${cpu_type} in
 562       mips)
 563         # Set mips_cpu to the name of the default CPU.
 564         case ${target_cpu} in
 565           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 566             mips_cpu=from-abi
 567             ;;
 568           mipsisa32 | mipsisa32el)
 569             mips_cpu=mips32
 570             ;;
 571           mipsisa64 | mipsisa64el)
 572             mips_cpu=mips64
 573             ;;
 574           mipstx39 | mipstx39el)
 575             mips_cpu=r3900
 576             ;;
 577           mips64* | mipsisa64* | mipsisa32*)
 578 changequote(,)dnl
 579             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 580 changequote([,])dnl
 581             ;;
 582           *)
 583             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 584             ;;
 585         esac
 586         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 587         # binaries.  It's a GNU extension that some OSes don't understand.
 588         # The value only matters on ELF targets.
 589         case ${target} in
 590           *-*-irix*)
 591             use_e_mips_abi_o32=0
 592             ;;
 593           *)
 594             use_e_mips_abi_o32=1
 595             ;;
 596         esac
 597         # Decide whether to generate 32-bit or 64-bit code by default.
 598         # Used to resolve -march=from-abi when an embedded ABI is selected.
 599         case ${target} in
 600           mips64*-*-* | mipsisa64*-*-*)
 601             mips_default_64bit=1
 602             ;;
 603           *)
 604             mips_default_64bit=0
 605             ;;
 606         esac
 607         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 608                            [Default CPU for MIPS targets. ])
 609         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 610                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 611         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 612                            [Generate 64-bit code by default on MIPS targets. ])
 613         ;;
 614     esac
 615
 616     # Do we need the opcodes library?
 617     case ${cpu_type} in
 618       vax | i386 | tic30)
 619         ;;
 620
 621       *)
 622         need_opcodes=yes
 623
 624         case "${enable_shared}" in
 625         yes) shared_opcodes=true ;;
 626         *opcodes*) shared_opcodes=true ;;
 627         *) shared_opcodes=false ;;
 628         esac
 629         if test "${shared_opcodes}" = "true"; then
 630           # A shared libopcodes must be linked against libbfd.
 631           need_bfd=yes
 632         fi
 633         ;;
 634     esac
 635
 636     # Any other special object files needed ?
 637     case ${cpu_type} in
 638       fr30 | ip2k | m32r | openrisc)
 639         using_cgen=yes
 640         ;;
 641
 642       frv)
 643         using_cgen=yes
 644         ;;
 645       m68k)
 646         case ${extra_objects} in
 647         *m68k-parse.o*) ;;
 648         *) extra_objects="$extra_objects m68k-parse.o" ;;
 649         esac
 650         ;;
 651
 652       mips)
 653         echo ${extra_objects} | grep -s "itbl-parse.o"
 654         if test $? -ne 0 ; then
 655           extra_objects="$extra_objects itbl-parse.o"
 656         fi
 657
 658         echo ${extra_objects} | grep -s "itbl-lex.o"
 659         if test $? -ne 0 ; then
 660           extra_objects="$extra_objects itbl-lex.o"
 661         fi
 662
 663         echo ${extra_objects} | grep -s "itbl-ops.o"
 664         if test $? -ne 0 ; then
 665           extra_objects="$extra_objects itbl-ops.o"
 666         fi
 667         ;;
 668
 669       i386 | s390 | sparc)
 670         if test $this_target = $target ; then
 671           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 672         fi
 673         ;;
 674
 675       xstormy16)
 676         using_cgen=yes
 677         ;;
 678
 679       *)
 680         ;;
 681     esac
 682
 683     if test $using_cgen = yes ; then
 684         case "x${extra_objects}" in
 685         *cgen.o*) ;;
 686         *) extra_objects="$extra_objects cgen.o" ;;
 687         esac
 688     fi
 689
 690 # See if we really can support this configuration with the emulation code.
 691
 692     if test $this_target = $target ; then
 693       primary_bfd_gas=$bfd_gas
 694       obj_format=$fmt
 695       te_file=$em
 696
 697       if test $bfd_gas = no ; then
 698         # Can't support other configurations this way.
 699         break
 700       fi
 701     elif test $bfd_gas = no ; then
 702       # Can't support this configuration.
 703       break
 704     fi
 705
 706 # From target name and format, produce a list of supported emulations.
 707
 708     case ${generic_target}-${fmt} in
 709       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 710       mips*-*-linux*-*) case "$endian" in
 711                         big)    emulation="mipsbelf mipslelf mipself" ;;
 712                         *)      emulation="mipslelf mipsbelf mipself" ;;
 713                         esac ;;
 714       mips-*-lnews*-ecoff) ;;
 715       mips-*-*-ecoff)   case "$endian" in
 716                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 717                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 718                         esac ;;
 719       mips-*-*-elf)     case "$endian" in
 720                         big)    emulation="mipsbelf mipslelf mipself" ;;
 721                         *)      emulation="mipslelf mipsbelf mipself" ;;
 722                         esac ;;
 723       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 724       # i386-pc-pe-coff != i386-pc-coff.
 725       i386-*-pe-coff)   ;;
 726       # Uncommenting the next line will turn on support for i386 AOUT
 727       # for the default linux configuration
 728       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 729       #
 730       i386-*-aout)      emulation="i386aout" ;;
 731       i386-*-coff)      emulation="i386coff" ;;
 732       i386-*-elf)       emulation="i386elf" ;;
 733
 734       # Always all formats.  The first stated emulation becomes the default.
 735       cris-*-*aout*)    emulation="crisaout criself" ;;
 736       cris-*-*)         emulation="criself crisaout" ;;
 737     esac
 738
 739     emulations="$emulations $emulation"
 740
 741 done
 742
 743 # Turn on all targets if possible
 744 if test ${all_targets} = "yes"; then
 745   case ${target_cpu_type} in
 746   i386)
 747     case ${obj_format} in
 748     aout)
 749       emulations="$emulations i386coff i386elf"
 750       ;;
 751     coff)
 752       emulations="$emulations i386aout i386elf"
 753     ;;
 754     elf)
 755       emulations="$emulations i386aout i386coff"
 756       ;;
 757     esac
 758   ;;
 759   esac
 760 fi
 761
 762 # Assign floating point type.  Most processors with FP support
 763 # IEEE FP.  On those that don't support FP at all, usually IEEE
 764 # is emulated.
 765 case ${target_cpu} in
 766   vax | tahoe ) atof=${target_cpu} ;;
 767   pdp11)        atof=vax ;;
 768   *)            atof=ieee ;;
 769 esac
 770
 771 case "${obj_format}" in
 772   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 773 esac
 774
 775 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 776 cgen_cpu_prefix=""
 777 if test $using_cgen = yes ; then
 778   case ${target_cpu} in
 779     *) cgen_cpu_prefix=${target_cpu} ;;
 780   esac
 781   AC_SUBST(cgen_cpu_prefix)
 782   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 783 fi
 784
 785 dnl
 786 dnl Make sure the desired support files exist.
 787 dnl
 788
 789 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 790   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 791 fi
 792
 793 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 794   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 795 fi
 796
 797 case ${user_bfd_gas}-${primary_bfd_gas} in
 798   yes-yes | no-no)
 799     # We didn't override user's choice.
 800     ;;
 801   no-yes)
 802     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 803     ;;
 804   no-preferred)
 805     primary_bfd_gas=no
 806     ;;
 807   *-preferred)
 808     primary_bfd_gas=yes
 809     ;;
 810   yes-*)
 811     primary_bfd_gas=yes
 812     ;;
 813   -*)
 814     # User specified nothing.
 815     ;;
 816 esac
 817
 818 # Some COFF configurations want these random other flags set.
 819 case ${obj_format} in
 820   coff)
 821     case ${target_cpu_type} in
 822       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 823       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 824       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 825     esac
 826     ;;
 827 esac
 828
 829 # Getting this done right is going to be a bitch.  Each configuration specified
 830 # with --enable-targets=... should be checked for environment, format, cpu, and
 831 # bfd_gas setting.
 832 #
 833 # For each configuration, the necessary object file support code must be linked
 834 # in.  This might be only one, it might be up to four.  The necessary emulation
 835 # code needs to be provided, too.
 836 #
 837 # And then there's "--enable-targets=all"....
 838 #
 839 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 840
 841 formats="${obj_format}"
 842 emfiles=""
 843 EMULATIONS=""
 844 GAS_UNIQ(emulations)
 845 for em in . $emulations ; do
 846   case $em in
 847     .)  continue ;;
 848     mipsbelf | mipslelf | mipself)
 849         fmt=elf   file=mipself ;;
 850     mipsbecoff | mipslecoff | mipsecoff)
 851         fmt=ecoff file=mipsecoff ;;
 852     *coff)
 853         fmt=coff  file=$em ;;
 854     *aout)
 855         fmt=aout file=$em ;;
 856     *elf)
 857         fmt=elf file=$em ;;
 858   esac
 859   formats="$formats $fmt"
 860   emfiles="$emfiles e-$file.o"
 861   EMULATIONS="$EMULATIONS &$em,"
 862 done
 863 GAS_UNIQ(formats)
 864 GAS_UNIQ(emfiles)
 865 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 866   for fmt in $formats ; do
 867     case $fmt in
 868       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 869       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 870       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 871       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 872       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 873       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 874       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 875       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 876       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 877       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 878     esac
 879     extra_objects="$extra_objects obj-$fmt.o"
 880   done
 881   obj_format=multi
 882 fi
 883 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 884   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 885   # e-mips* has more than one emulation per file, e-i386* has just one at the
 886   # moment.  If only one emulation is specified, then don't define
 887   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 888   case "${obj_format}${emfiles}" in
 889     multi* | *mips*)
 890       extra_objects="$extra_objects $emfiles"
 891       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 892   esac
 893 fi
 894 AC_SUBST(extra_objects)
 895 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 896 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 897                    [Default emulation.])
 898
 899 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 900   yes-*-coff)   need_bfd=yes ;;
 901   no-*-coff)    need_bfd=yes
 902                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 903 esac
 904
 905 reject_dev_configs=yes
 906
 907 case ${reject_dev_configs}-${dev} in
 908   yes-yes) # Oops.
 909     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 910     ;;
 911 esac
 912
 913 AC_SUBST(target_cpu_type)
 914 AC_SUBST(obj_format)
 915 AC_SUBST(te_file)
 916 AC_SUBST(install_tooldir)
 917 AC_SUBST(atof)
 918 dnl AC_SUBST(emulation)
 919
 920 case "${primary_bfd_gas}" in
 921   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 922         need_bfd=yes ;;
 923 esac
 924
 925 # do we need the opcodes library?
 926 case "${need_opcodes}" in
 927 yes)
 928   OPCODES_LIB=../opcodes/libopcodes.la
 929   ;;
 930 esac
 931
 932 case "${need_bfd}" in
 933 yes)
 934   BFDLIB=../bfd/libbfd.la
 935   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 936   ;;
 937 esac
 938
 939 AC_SUBST(BFDLIB)
 940 AC_SUBST(OPCODES_LIB)
 941
 942 AC_SUBST(ALL_OBJ_DEPS)
 943
 944 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 945 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 946 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 947 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 948 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 949
 950 AC_PROG_CC
 951
 952 AC_PROG_YACC
 953 AM_PROG_LEX
 954
 955 ALL_LINGUAS="fr tr es"
 956 CY_GNU_GETTEXT
 957
 958 AM_MAINTAINER_MODE
 959 AC_EXEEXT
 960
 961 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 962
 963 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 964 # people who are not cross-compiling but are compiling cross-assemblers.
 965 AC_MSG_CHECKING(whether compiling a cross-assembler)
 966 if test "${host}" = "${target}"; then
 967   cross_gas=no
 968 else
 969   cross_gas=yes
 970   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 971 fi
 972 AC_MSG_RESULT($cross_gas)
 973
 974 dnl ansidecl.h will deal with const
 975 dnl AC_CONST
 976 AC_FUNC_ALLOCA
 977 AC_C_INLINE
 978
 979 # VMS doesn't have unlink.
 980 AC_CHECK_FUNCS(unlink remove, break)
 981
 982 # Some systems don't have sbrk().
 983 AC_CHECK_FUNCS(sbrk)
 984
 985 # do we need the math library?
 986 case "${need_libm}" in
 987 yes)
 988   AC_CHECK_LIBM
 989   AC_SUBST(LIBM)
 990   ;;
 991 esac
 992
 993 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 994 # enough, but on some of those systems, the assert macro relies on requoting
 995 # working properly!
 996 GAS_WORKING_ASSERT
 997
 998 # On some systems, the system header files may not declare malloc, realloc,
 999 # and free.  There are places where gas needs these functions to have been
1000 # declared -- such as when taking their addresses.
1001 gas_test_headers="
1002 #ifdef HAVE_MEMORY_H
1003 #include <memory.h>
1004 #endif
1005 #ifdef HAVE_STRING_H
1006 #include <string.h>
1007 #else
1008 #ifdef HAVE_STRINGS_H
1009 #include <strings.h>
1010 #endif
1011 #endif
1012 #ifdef HAVE_STDLIB_H
1013 #include <stdlib.h>
1014 #endif
1015 #ifdef HAVE_UNISTD_H
1016 #include <unistd.h>
1017 #endif
1018 "
1019 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
1020 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
1021 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
1022 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
1023 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
1024
1025 # Does errno.h declare errno, or do we have to add a separate declaration
1026 # for it?
1027 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
1028 #ifdef HAVE_ERRNO_H
1029 #include <errno.h>
1030 #endif
1031 ])
1032
1033 dnl This must come last.
1034
1035 dnl We used to make symlinks to files in the source directory, but now
1036 dnl we just use the right name for .c files, and create .h files in
1037 dnl the build directory which include the right .h file.  Make sure
1038 dnl the old symlinks don't exist, so that a reconfigure in an existing
1039 dnl directory behaves reasonably.
1040
1041 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
1042 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1043  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1044  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1045  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1046  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1047  if test "x$cgen_cpu_prefix" != x ; then
1048    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1049  fi
1050
1051  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
1052 [target_cpu_type=${target_cpu_type}
1053  cgen_cpu_prefix=${cgen_cpu_prefix}
1054  obj_format=${obj_format}
1055  te_file=${te_file}])