gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl   Copyright 2012, 2013 Free Software Foundation
   7 dnl
   8 dnl This file is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; see the file COPYING3.  If not see
  20 dnl <http://www.gnu.org/licenses/>.
  21 dnl
  22 dnl v2.5 needed for --bindir et al
  23 AC_PREREQ(2.59)
  24 AC_INIT
  25 AC_CONFIG_SRCDIR(as.h)
  26
  27 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  28 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  29 dnl gas/ instead of gas/../.
  30 AC_CONFIG_AUX_DIR(..)
  31 AC_CANONICAL_TARGET
  32 AC_ISC_POSIX
  33
  34 changequote(,)dnl
  35 BFD_VERSION=`${srcdir}/../bfd/configure --version | sed -n -e '1s,.* ,,p'`
  36 changequote([,])dnl
  37 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  38
  39 AC_PROG_CC
  40 AC_GNU_SOURCE
  41 AC_USE_SYSTEM_EXTENSIONS
  42 ACX_LARGEFILE
  43
  44 LT_INIT
  45
  46 AC_ARG_ENABLE(targets,
  47 [  --enable-targets        alternative target configurations besides the primary],
  48 [case "${enableval}" in
  49   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  50             ;;
  51   no)       enable_targets= ;;
  52   *)        enable_targets=$enableval ;;
  53 esac])dnl
  54
  55 ac_checking=yes
  56 if grep '^RELEASE=y' ${srcdir}/../bfd/Makefile.am >/dev/null 2>/dev/null ; then
  57   ac_checking=
  58 fi
  59 AC_ARG_ENABLE(checking,
  60 [  --enable-checking       enable run-time checks],
  61 [case "${enableval}" in
  62   no|none)  ac_checking= ;;
  63   *)        ac_checking=yes ;;
  64 esac])dnl
  65 if test x$ac_checking != x ; then
  66   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  67 fi
  68
  69 using_cgen=no
  70
  71 AM_BINUTILS_WARNINGS
  72
  73 # Generate a header file
  74 AC_CONFIG_HEADERS(config.h:config.in)
  75
  76 # PR 14072
  77 AH_VERBATIM([00_CONFIG_H_CHECK],
  78 [/* Check that config.h is #included before system headers
  79    (this works only for glibc, but that should be enough).  */
  80 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
  81 #  error config.h must be #included before system headers
  82 #endif
  83 #define __CONFIG_H__ 1])
  84
  85 # If we are on a DOS filesystem, we must use gdb.ini rather than
  86 # .gdbinit.
  87 case "${host}" in
  88   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  89     GDBINIT="gdb.ini"
  90     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  91     ;;
  92   *)
  93     GDBINIT=".gdbinit"
  94     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  95     ;;
  96 esac
  97 AC_SUBST(GDBINIT)
  98
  99 #We need this for the host.  BOUT header is in host order.
 100 AC_C_BIGENDIAN
 101
 102 te_file=generic
 103
 104 # Makefile target for installing gas in $(tooldir)/bin.
 105 install_tooldir=install-exec-tooldir
 106
 107 canon_targets=""
 108 all_targets=no
 109 if test -n "$enable_targets" ; then
 110   for t in `echo $enable_targets | sed 's/,/ /g'`; do
 111     if test $t = "all"; then
 112       all_targets=yes
 113       continue
 114     fi
 115     result=`$ac_config_sub $t 2>/dev/null`
 116     if test -n "$result" ; then
 117       canon_targets="$canon_targets $result"
 118 #    else
 119 #      # Permit "all", etc.  We don't support it yet though.
 120 #      canon_targets="$canon_targets $t"
 121     fi
 122   done
 123   GAS_UNIQ(canon_targets)
 124 fi
 125
 126 emulations=""
 127
 128 for this_target in $target $canon_targets ; do
 129
 130     targ=${this_target}
 131     . ${srcdir}/configure.tgt
 132
 133     case ${target_cpu} in
 134       crisv32)
 135         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 136                            [Default CRIS architecture.])
 137         ;;
 138     esac
 139
 140     if test ${this_target} = $target ; then
 141       target_cpu_type=${cpu_type}
 142     elif test ${target_cpu_type} != ${cpu_type} ; then
 143       continue
 144     fi
 145
 146     generic_target=${cpu_type}-${target_vendor}-${target_os}
 147     case ${generic_target} in
 148       i386-*-sco3.2v5*)
 149         if test ${this_target} = $target; then
 150           AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 151         fi
 152         ;;
 153
 154       i386-*-msdosdjgpp* \
 155       | i386-*-go32* \
 156       | i386-go32-rtems*)
 157         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 158         ;;
 159
 160       i860-*-*)
 161         AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress)
 162         ;;
 163
 164       microblaze*)
 165         ;;
 166
 167       mips-sony-bsd*)
 168         ;;
 169       mips-*-bsd*)
 170         AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.)
 171         ;;
 172
 173 changequote(,)dnl
 174       ppc-*-aix[5-9].*)
 175 changequote([,])dnl
 176         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 177                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 178         ;;
 179       ppc-*-solaris*)
 180         if test ${this_target} = $target; then
 181           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 182                     [Define if default target is PowerPC Solaris.])
 183         fi
 184         if test x${endian} = xbig; then
 185           AC_MSG_ERROR(Solaris must be configured little endian)
 186         fi
 187         ;;
 188
 189       sh*-*-symbianelf*)
 190         AC_DEFINE(TARGET_SYMBIAN, 1, [Define if target is Symbian OS.])
 191         ;;
 192     esac
 193
 194     if test ${this_target} = $target ; then
 195       endian_def=
 196       if test x${endian} = xbig; then
 197         endian_def=1
 198       elif test x${endian} = xlittle; then
 199         endian_def=0
 200       fi
 201       if test x${endian_def} != x; then
 202         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 203                            [Define as 1 if big endian.])
 204       fi
 205     fi
 206
 207 # Other random stuff.
 208
 209     case ${cpu_type} in
 210       mips)
 211         # Set mips_cpu to the name of the default CPU.
 212         case ${target_cpu} in
 213           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 214             mips_cpu=from-abi
 215             ;;
 216           mipsisa32 | mipsisa32el)
 217             mips_cpu=mips32
 218             ;;
 219           mipsisa32r2 | mipsisa32r2el)
 220             mips_cpu=mips32r2
 221             ;;
 222           mipsisa64 | mipsisa64el)
 223             mips_cpu=mips64
 224             ;;
 225           mipsisa64r2 | mipsisa64r2el)
 226             mips_cpu=mips64r2
 227             ;;
 228           mipstx39 | mipstx39el)
 229             mips_cpu=r3900
 230             ;;
 231           mips64vr | mips64vrel)
 232             mips_cpu=vr4100
 233             ;;
 234           mipsisa32r2* | mipsisa64r2*)
 235 changequote(,)dnl
 236             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 237 changequote([,])dnl
 238             ;;
 239           mips64* | mipsisa64* | mipsisa32*)
 240 changequote(,)dnl
 241             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 242 changequote([,])dnl
 243             ;;
 244           mips*)
 245 changequote(,)dnl
 246             mips_cpu=`echo $target_cpu | sed -e 's/^mips//' -e 's/el$//'`
 247 changequote([,])dnl
 248             ;;
 249           *)
 250             AC_MSG_ERROR($target_cpu isn't a supported MIPS CPU name)
 251             ;;
 252         esac
 253         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 254         # binaries.  It's a GNU extension that some OSes don't understand.
 255         # The value only matters on ELF targets.
 256         case ${target} in
 257           *-*-irix*)
 258             use_e_mips_abi_o32=0
 259             ;;
 260           *)
 261             use_e_mips_abi_o32=1
 262             ;;
 263         esac
 264         # Decide whether to generate 32-bit or 64-bit code by default.
 265         # Used to resolve -march=from-abi when an embedded ABI is selected.
 266         case ${target} in
 267           mips64*-*-* | mipsisa64*-*-*)
 268             mips_default_64bit=1
 269             ;;
 270           *)
 271             mips_default_64bit=0
 272             ;;
 273         esac
 274         # Decide which ABI to target by default.
 275         case ${target} in
 276           mips64*-linux* | mips-sgi-irix6* | mips64*-freebsd* | mips64*-kfreebsd*-gnu)
 277             mips_default_abi=N32_ABI
 278             ;;
 279           mips*-linux* | mips*-freebsd* | mips*-kfreebsd*-gnu)
 280             mips_default_abi=O32_ABI
 281             ;;
 282           mips64*-openbsd*)
 283             mips_default_abi=N64_ABI
 284             ;;
 285           *)
 286             mips_default_abi=NO_ABI
 287             ;;
 288         esac
 289         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 290                            [Default CPU for MIPS targets. ])
 291         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 292                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 293         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 294                            [Generate 64-bit code by default on MIPS targets. ])
 295         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 296                            [Choose a default ABI for MIPS targets. ])
 297         ;;
 298     esac
 299
 300     # Do we need the opcodes library?
 301     case ${cpu_type} in
 302       vax | tic30)
 303         ;;
 304
 305       *)
 306         need_opcodes=yes
 307
 308         case "${enable_shared}" in
 309         yes) shared_opcodes=true ;;
 310         *opcodes*) shared_opcodes=true ;;
 311         *) shared_opcodes=false ;;
 312         esac
 313         ;;
 314     esac
 315
 316     # Any other special object files needed ?
 317     case ${cpu_type} in
 318
 319       bfin)
 320         echo ${extra_objects} | grep -s "bfin-parse.o"
 321         if test $? -ne 0 ; then
 322           extra_objects="$extra_objects bfin-parse.o"
 323         fi
 324
 325         echo ${extra_objects} | grep -s "bfin-lex-wrapper.o"
 326         if test $? -ne 0 ; then
 327           extra_objects="$extra_objects bfin-lex-wrapper.o"
 328         fi
 329         ;;
 330
 331       epiphany | fr30 | ip2k | iq2000 | lm32 | m32r | openrisc)
 332         using_cgen=yes
 333         ;;
 334
 335       m32c)
 336         using_cgen=yes
 337         ;;
 338       frv)
 339         using_cgen=yes
 340         ;;
 341       m68k)
 342         case ${extra_objects} in
 343         *m68k-parse.o*) ;;
 344         *) extra_objects="$extra_objects m68k-parse.o" ;;
 345         esac
 346         ;;
 347
 348       mep)
 349         using_cgen=yes
 350         ;;
 351
 352       mips)
 353         echo ${extra_objects} | grep -s "itbl-parse.o"
 354         if test $? -ne 0 ; then
 355           extra_objects="$extra_objects itbl-parse.o"
 356         fi
 357
 358         echo ${extra_objects} | grep -s "itbl-lex-wrapper.o"
 359         if test $? -ne 0 ; then
 360           extra_objects="$extra_objects itbl-lex-wrapper.o"
 361         fi
 362
 363         echo ${extra_objects} | grep -s "itbl-ops.o"
 364         if test $? -ne 0 ; then
 365           extra_objects="$extra_objects itbl-ops.o"
 366         fi
 367         ;;
 368
 369       mt)
 370         using_cgen=yes
 371         ;;
 372
 373       i386 | s390 | sparc)
 374         if test $this_target = $target ; then
 375           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 376         fi
 377         ;;
 378
 379       rl78)
 380         echo ${extra_objects} | grep -s "rl78-parse.o"
 381         if test $? -ne 0 ; then
 382           extra_objects="$extra_objects rl78-parse.o"
 383         fi
 384         ;;
 385
 386       rx)
 387         echo ${extra_objects} | grep -s "rx-parse.o"
 388         if test $? -ne 0 ; then
 389           extra_objects="$extra_objects rx-parse.o"
 390         fi
 391         ;;
 392
 393       xstormy16)
 394         using_cgen=yes
 395         ;;
 396
 397       xc16x)
 398         using_cgen=yes
 399         ;;
 400
 401       xtensa)
 402         echo ${extra_objects} | grep -s "xtensa-relax.o"
 403         if test $? -ne 0 ; then
 404           extra_objects="$extra_objects xtensa-relax.o"
 405         fi
 406         ;;
 407
 408       *)
 409         ;;
 410     esac
 411
 412     if test $using_cgen = yes ; then
 413         case "x${extra_objects}" in
 414         *cgen.o*) ;;
 415         *) extra_objects="$extra_objects cgen.o" ;;
 416         esac
 417     fi
 418
 419 # See if we really can support this configuration with the emulation code.
 420
 421     if test $this_target = $target ; then
 422       obj_format=$fmt
 423       te_file=$em
 424     fi
 425
 426    case ${te_file} in
 427       vms) extra_objects="$extra_objects te-vms.o" ;;
 428    esac
 429
 430 # From target name and format, produce a list of supported emulations.
 431
 432     case ${generic_target}-${fmt} in
 433       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 434       mips*-*-linux*-* | mips*-*-freebsd* | mips*-*-kfreebsd*-gnu)
 435                         case "$endian" in
 436                         big)    emulation="mipsbelf mipslelf mipself" ;;
 437                         *)      emulation="mipslelf mipsbelf mipself" ;;
 438                         esac ;;
 439       mips-*-lnews*-ecoff) ;;
 440       mips-*-*-ecoff)   case "$endian" in
 441                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 442                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 443                         esac ;;
 444       mips-*-*-elf)     case "$endian" in
 445                         big)    emulation="mipsbelf mipslelf mipself" ;;
 446                         *)      emulation="mipslelf mipsbelf mipself" ;;
 447                         esac ;;
 448       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 449       # i386-pc-pe-coff != i386-pc-coff.
 450       i386-*-pe-coff)   ;;
 451       # Uncommenting the next line will turn on support for i386 AOUT
 452       # for the default linux configuration
 453       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 454       #
 455       i386-*-aout)      emulation="i386aout" ;;
 456       i386-*-coff)      emulation="i386coff" ;;
 457       i386-*-elf)       emulation="i386elf" ;;
 458
 459       # Always all formats.  The first stated emulation becomes the default.
 460       cris-*-*aout*)    emulation="crisaout criself" ;;
 461       cris-*-*)         emulation="criself crisaout" ;;
 462     esac
 463
 464     emulations="$emulations $emulation"
 465
 466 done
 467
 468 # Turn on all targets if possible
 469 if test ${all_targets} = "yes"; then
 470   case ${target_cpu_type} in
 471   i386)
 472     case ${obj_format} in
 473     aout)
 474       emulations="$emulations i386coff i386elf"
 475       ;;
 476     coff)
 477       emulations="$emulations i386aout i386elf"
 478     ;;
 479     elf)
 480       emulations="$emulations i386aout i386coff"
 481       ;;
 482     esac
 483   ;;
 484   x86_64)
 485     case ${obj_format} in
 486     aout)
 487       emulations="$emulations i386coff i386elf"
 488       ;;
 489     coff)
 490       emulations="$emulations i386aout i386elf"
 491     ;;
 492     elf)
 493       emulations="$emulations i386aout i386coff"
 494       ;;
 495     esac
 496   ;;
 497   esac
 498 fi
 499
 500 # PE code has way too many macros tweaking behaviour
 501 case ${te_file} in
 502   pe*) emulations="" ;;
 503 esac
 504
 505 # Assign floating point type.  Most processors with FP support
 506 # IEEE FP.  On those that don't support FP at all, usually IEEE
 507 # is emulated.
 508 case ${target_cpu} in
 509   vax | pdp11 ) atof=vax ;;
 510   *)            atof=ieee ;;
 511 esac
 512
 513 case "${obj_format}" in
 514   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 515 esac
 516
 517 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 518 cgen_cpu_prefix=""
 519 if test $using_cgen = yes ; then
 520   case ${target_cpu} in
 521     *) cgen_cpu_prefix=${target_cpu} ;;
 522   esac
 523   AC_SUBST(cgen_cpu_prefix)
 524   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 525 fi
 526
 527 dnl
 528 dnl Make sure the desired support files exist.
 529 dnl
 530
 531 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 532   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 533 fi
 534
 535 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 536   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 537 fi
 538
 539 # Some COFF configurations want these random other flags set.
 540 case ${obj_format} in
 541   coff)
 542     case ${target_cpu_type} in
 543       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 544       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 545       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 546       x86_64) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 547     esac
 548     ;;
 549 esac
 550
 551 # Getting this done right is going to be a bitch.  Each configuration specified
 552 # with --enable-targets=... should be checked for environment, format, cpu
 553 # setting.
 554 #
 555 # For each configuration, the necessary object file support code must be linked
 556 # in.  This might be only one, it might be up to four.  The necessary emulation
 557 # code needs to be provided, too.
 558 #
 559 # And then there's "--enable-targets=all"....
 560 #
 561 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 562
 563 formats="${obj_format}"
 564 emfiles=""
 565 EMULATIONS=""
 566 GAS_UNIQ(emulations)
 567 for em in . $emulations ; do
 568   case $em in
 569     .)  continue ;;
 570     mipsbelf | mipslelf | mipself)
 571         fmt=elf   file=mipself ;;
 572     mipsbecoff | mipslecoff | mipsecoff)
 573         fmt=ecoff file=mipsecoff ;;
 574     *coff)
 575         fmt=coff  file=$em ;;
 576     *aout)
 577         fmt=aout file=$em ;;
 578     *elf)
 579         fmt=elf file=$em ;;
 580   esac
 581   formats="$formats $fmt"
 582   emfiles="$emfiles e-$file.o"
 583   EMULATIONS="$EMULATIONS &$em,"
 584 done
 585 GAS_UNIQ(formats)
 586 GAS_UNIQ(emfiles)
 587 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 588   for fmt in $formats ; do
 589     case $fmt in
 590       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 591       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 592       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 593       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 594       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 595       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 596       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 597     esac
 598     extra_objects="$extra_objects obj-$fmt.o"
 599   done
 600   obj_format=multi
 601 fi
 602 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 603   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 604   # e-mips* has more than one emulation per file, e-i386* has just one at the
 605   # moment.  If only one emulation is specified, then don't define
 606   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 607   case "${obj_format}${emfiles}" in
 608     multi* | *mips*)
 609       extra_objects="$extra_objects $emfiles"
 610       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 611   esac
 612 fi
 613 AC_SUBST(extra_objects)
 614 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 615 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 616                    [Default emulation.])
 617
 618 reject_dev_configs=yes
 619
 620 case ${reject_dev_configs}-${dev} in
 621   yes-yes) # Oops.
 622     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 623     ;;
 624 esac
 625
 626 AC_SUBST(target_cpu_type)
 627 AC_SUBST(obj_format)
 628 AC_SUBST(te_file)
 629 AC_SUBST(install_tooldir)
 630 AC_SUBST(atof)
 631 dnl AC_SUBST(emulation)
 632
 633 # do we need the opcodes library?
 634 case "${need_opcodes}" in
 635 yes)
 636   OPCODES_LIB=../opcodes/libopcodes.la
 637   ;;
 638 esac
 639
 640 AC_SUBST(OPCODES_LIB)
 641
 642 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 643 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 644 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 645 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 646 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 647
 648 AC_PROG_YACC
 649 AM_PROG_LEX
 650
 651 ALL_LINGUAS="fr tr es rw id ru fi ja"
 652 ZW_GNU_GETTEXT_SISTER_DIR
 653 AM_PO_SUBDIRS
 654
 655 AM_MAINTAINER_MODE
 656 AM_CONDITIONAL(GENINSRC_NEVER, false)
 657 AC_EXEEXT
 658
 659 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h errno.h sys/types.h limits.h locale.h time.h sys/stat.h)
 660 ACX_HEADER_STRING
 661
 662 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 663 # people who are not cross-compiling but are compiling cross-assemblers.
 664 AC_MSG_CHECKING(whether compiling a cross-assembler)
 665 if test "${host}" = "${target}"; then
 666   cross_gas=no
 667 else
 668   cross_gas=yes
 669   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 670 fi
 671 AC_MSG_RESULT($cross_gas)
 672
 673 dnl ansidecl.h will deal with const
 674 dnl AC_C_CONST
 675 AC_FUNC_ALLOCA
 676 AC_C_INLINE
 677
 678 # VMS doesn't have unlink.
 679 AC_CHECK_FUNCS(unlink remove, break)
 680 AC_CHECK_FUNCS(sbrk setlocale)
 681
 682 AM_LC_MESSAGES
 683
 684 # do we need the math library?
 685 case "${need_libm}" in
 686 yes)
 687   LT_LIB_M
 688   AC_SUBST(LIBM)
 689   ;;
 690 esac
 691
 692 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 693 # enough, but on some of those systems, the assert macro relies on requoting
 694 # working properly!
 695 GAS_WORKING_ASSERT
 696
 697 # On some systems, the system header files may not declare malloc, realloc,
 698 # and free.  There are places where gas needs these functions to have been
 699 # declared -- such as when taking their addresses.
 700 gas_test_headers="
 701 #ifdef HAVE_MEMORY_H
 702 #include <memory.h>
 703 #endif
 704 #ifdef HAVE_STRING_H
 705 #include <string.h>
 706 #else
 707 #ifdef HAVE_STRINGS_H
 708 #include <strings.h>
 709 #endif
 710 #endif
 711 #ifdef HAVE_STDLIB_H
 712 #include <stdlib.h>
 713 #endif
 714 #ifdef HAVE_UNISTD_H
 715 #include <unistd.h>
 716 #endif
 717 "
 718
 719 # Does errno.h declare errno, or do we have to add a separate declaration
 720 # for it?
 721 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 722 #ifdef HAVE_ERRNO_H
 723 #include <errno.h>
 724 #endif
 725 ])
 726
 727 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 728 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
 729 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 730 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
 731 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
 732 if test $gas_cv_decl_getopt_unistd_h = yes; then
 733   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 734             [Is the prototype for getopt in <unistd.h> in the expected format?])
 735 fi
 736
 737 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 738 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
 739 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 740 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 741 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 742 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 743
 744 AC_CHECK_DECLS([free, getenv, malloc, mempcpy, realloc, stpcpy, strstr, vsnprintf])
 745
 746 BFD_BINARY_FOPEN
 747
 748 # Link in zlib if we can.  This allows us to write compressed debug sections.
 749 AM_ZLIB
 750
 751 # Support for VMS timestamps via cross compile
 752
 753 if test "$ac_cv_header_time_h" = yes; then
 754   GAS_HAVE_TIME_TYPE_MEMBER(struct tm, tm_gmtoff)
 755 fi
 756
 757 if test "$ac_cv_header_sys_stat_h" = yes; then
 758     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_sec)
 759     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_nsec)
 760 fi
 761
 762
 763 dnl Required for html, pdf, install-pdf and install-html targets.
 764 AC_SUBST(datarootdir)
 765 AC_SUBST(docdir)
 766 AC_SUBST(htmldir)
 767 AC_SUBST(pdfdir)
 768
 769 dnl This must come last.
 770
 771 dnl We used to make symlinks to files in the source directory, but now
 772 dnl we just use the right name for .c files, and create .h files in
 773 dnl the build directory which include the right .h file.  Make sure
 774 dnl the old symlinks don't exist, so that a reconfigure in an existing
 775 dnl directory behaves reasonably.
 776
 777 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 778 AC_CONFIG_COMMANDS([default],
 779 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 780  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 781  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 782  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 783  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 784  if test "x$cgen_cpu_prefix" != x ; then
 785    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 786  fi],
 787 [target_cpu_type=${target_cpu_type}
 788  cgen_cpu_prefix=${cgen_cpu_prefix}
 789  obj_format=${obj_format}
 790  te_file=${te_file}])
 791
 792 AC_OUTPUT