gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.57)
   9 AC_INIT(as.h)
  10
  11 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  12 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  13 dnl gas/ instead of gas/../.
  14 AC_CONFIG_AUX_DIR(..)
  15 AC_CANONICAL_SYSTEM
  16 AC_ISC_POSIX
  17
  18 changequote(,)dnl
  19 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  20 changequote([,])dnl
  21 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  22
  23 AM_PROG_LIBTOOL
  24
  25 user_bfd_gas=
  26 AC_ARG_ENABLE(bfd-assembler,
  27 [  --enable-bfd-assembler  use BFD back end for writing object files],
  28 [case "${enableval}" in
  29   yes) need_bfd=yes user_bfd_gas=yes ;;
  30   no)  user_bfd_gas=no ;;
  31   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  32 esac])dnl
  33 AC_ARG_ENABLE(targets,
  34 [    targets            alternative target configurations besides the primary],
  35 [case "${enableval}" in
  36   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  37             ;;
  38   no)       enable_targets= ;;
  39   *)        enable_targets=$enableval ;;
  40 esac])dnl
  41 AC_ARG_ENABLE(commonbfdlib,
  42 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  43 [case "${enableval}" in
  44   yes) commonbfdlib=true ;;
  45   no)  commonbfdlib=false ;;
  46   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  47 esac])dnl
  48
  49 using_cgen=no
  50
  51 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  52 AC_ARG_ENABLE(build-warnings,
  53 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  54 [case "${enableval}" in
  55   yes)  ;;
  56   no)   build_warnings="-w";;
  57   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  58         build_warnings="${build_warnings} ${t}";;
  59   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  60         build_warnings="${t} ${build_warnings}";;
  61   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  62 esac
  63 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  64   echo "Setting warning flags = $build_warnings" 6>&1
  65 fi])dnl
  66 WARN_CFLAGS=""
  67 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  68     WARN_CFLAGS="${build_warnings}"
  69 fi
  70 AC_SUBST(WARN_CFLAGS)
  71
  72 # Generate a header file
  73 AM_CONFIG_HEADER(config.h:config.in)
  74
  75 # If we are on a DOS filesystem, we must use gdb.ini rather than
  76 # .gdbinit.
  77 case "${host}" in
  78   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  79     GDBINIT="gdb.ini"
  80     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  81     ;;
  82   *)
  83     GDBINIT=".gdbinit"
  84     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  85     ;;
  86 esac
  87 AC_SUBST(GDBINIT)
  88
  89 te_file=generic
  90
  91 # Makefile target for installing gas in $(tooldir)/bin.
  92 install_tooldir=install-exec-tooldir
  93
  94 canon_targets=""
  95 all_targets=no
  96 if test -n "$enable_targets" ; then
  97   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  98     if test $t = "all"; then
  99       all_targets=yes
 100       continue
 101     fi
 102     result=`$ac_config_sub $t 2>/dev/null`
 103     if test -n "$result" ; then
 104       canon_targets="$canon_targets $result"
 105 #    else
 106 #      # Permit "all", etc.  We don't support it yet though.
 107 #      canon_targets="$canon_targets $t"
 108     fi
 109   done
 110   GAS_UNIQ(canon_targets)
 111 fi
 112
 113 emulations=""
 114
 115 for this_target in $target $canon_targets ; do
 116
 117 changequote(,)dnl
 118     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 119 changequote([,])dnl
 120
 121     # Check for architecture variants.
 122     # Note: This table is alpha-sorted, please try to keep it that way.
 123     arch=
 124     endian=
 125     case ${cpu} in
 126       am33_2.0)         cpu_type=mn10300 endian=little ;;
 127       alpha*)           cpu_type=alpha ;;
 128       arm*be|xscale*be|strongarm*be | \
 129       arm*b|xscale*b|strongarm*b) cpu_type=arm endian=big ;;
 130       arm*|xscale*|strongarm*)    cpu_type=arm endian=little ;;
 131       c4x*)             cpu_type=tic4x ;;
 132       crx*)             cpu_type=crx endian=little ;;
 133       hppa*)            cpu_type=hppa ;;
 134 changequote(,)dnl
 135       i[3-7]86)         cpu_type=i386 arch=i386;;
 136       ia64)             cpu_type=ia64 ;;
 137       ip2k)             cpu_type=ip2k endian=big ;;
 138       iq2000)           cpu_type=iq2000 endian=big ;;
 139       m32r)             cpu_type=m32r target_cpu=m32r endian=big ;;
 140       m32rle)           cpu_type=m32r target_cpu=m32r endian=little ;;
 141       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 142       m680[012346]0)    cpu_type=m68k ;;
 143 changequote([,])dnl
 144       m68008)           cpu_type=m68k ;;
 145       m683??)           cpu_type=m68k ;;
 146       m5200)            cpu_type=m68k ;;
 147       m8*)              cpu_type=m88k ;;
 148       mips*el)          cpu_type=mips endian=little ;;
 149       mips*)            cpu_type=mips endian=big ;;
 150       or32*)            cpu_type=or32 endian=big ;;
 151       pjl*)             cpu_type=pj endian=little ;;
 152       pj*)              cpu_type=pj endian=big ;;
 153       powerpc*le*)      cpu_type=ppc endian=little ;;
 154       powerpc*)         cpu_type=ppc endian=big ;;
 155       rs6000*)          cpu_type=ppc ;;
 156       s390x*)           cpu_type=s390 arch=s390x ;;
 157       s390*)            cpu_type=s390 arch=s390 ;;
 158       sh5*)             cpu_type=sh64 endian=big ;;
 159       sh5le*)           cpu_type=sh64 endian=little ;;
 160       sh64*)            cpu_type=sh64 endian=big ;;
 161       sh64le*)          cpu_type=sh64 endian=little ;;
 162       sh*le)            cpu_type=sh endian=little ;;
 163       sh*)              cpu_type=sh endian=big ;;
 164       sparclite*)       cpu_type=sparc arch=sparclite ;;
 165       sparclet*)        cpu_type=sparc arch=sparclet ;;
 166       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 167       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 168       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 169       v850*)            cpu_type=v850 ;;
 170       x86_64)           cpu_type=i386 arch=x86_64;;
 171       xtensa*)          cpu_type=xtensa arch=xtensa ;;
 172       *)                cpu_type=${cpu} ;;
 173     esac
 174
 175     if test ${this_target} = $target ; then
 176       target_cpu_type=${cpu_type}
 177     elif test ${target_cpu_type} != ${cpu_type} ; then
 178       continue
 179     fi
 180
 181     generic_target=${cpu_type}-$vendor-$os
 182     dev=no
 183     bfd_gas=no
 184     em=generic
 185
 186     # Assign object format.
 187     # Note: This table is alpha-sorted, please try to keep it that way.
 188     case ${generic_target} in
 189       a29k-*-coff)                      fmt=coff ;;
 190       a29k-amd-udi)                     fmt=coff ;;
 191       a29k-amd-ebmon)                   fmt=coff ;;
 192       a29k-nyu-sym1)                    fmt=coff ;;
 193       a29k-*-rtems*)                    fmt=coff ;;
 194       a29k-*-vxworks*)                  fmt=coff ;;
 195
 196       alpha*-*-*vms*)                   fmt=evax ;;
 197       alpha*-*-osf*)                    fmt=ecoff ;;
 198       alpha*-*-linuxecoff*)             fmt=ecoff ;;
 199       alpha*-*-linux-gnu*)              fmt=elf em=linux ;;
 200       alpha*-*-netbsd*)                 fmt=elf em=nbsd ;;
 201       alpha*-*-openbsd*)                fmt=elf em=obsd ;;
 202
 203       arc-*-elf*)                       fmt=elf ;;
 204
 205       arm-*-aout)                       fmt=aout ;;
 206       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 207       arm-*-rtems* | thumb-*-rtems*)    fmt=elf ;;
 208       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 209       arm-*-kaos*)                      fmt=elf ;;
 210       arm*-*-conix*)                    fmt=elf ;;
 211       arm-*-linux*aout*)                fmt=aout em=linux ;;
 212       arm*-*-linux-gnu*)                fmt=elf  em=linux ;;
 213       arm*-*-uclinux*)                  fmt=elf  em=linux ;;
 214       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 215       arm-*-*n*bsd*)                    fmt=aout em=nbsd ;;
 216       arm-**-nto*)                      fmt=elf ;;
 217       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 218       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 219       arm-wince-pe | arm-*-wince)       fmt=coff em=wince-pe ;;
 220       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 221       arm-*-riscix*)                    fmt=aout em=riscix ;;
 222
 223       avr-*-*)                          fmt=elf ;;
 224
 225       cris-*-linux-gnu*)                fmt=multi bfd_gas=yes em=linux ;;
 226       cris-*-*)                         fmt=multi bfd_gas=yes ;;
 227
 228       crx-*-elf*)                       fmt=elf ;;
 229
 230       d10v-*-*)                         fmt=elf ;;
 231       d30v-*-*)                         fmt=elf ;;
 232       dlx-*-*)                          fmt=elf ;;
 233
 234       fr30-*-*)                         fmt=elf ;;
 235       frv-*-*linux*)                    fmt=elf em=linux;;
 236       frv-*-*)                          fmt=elf ;;
 237
 238       hppa-*-linux*)    case ${cpu} in
 239                             hppa*64*)   fmt=elf em=hppalinux64;;
 240                             hppa*)      fmt=elf em=linux;;
 241                         esac ;;
 242       hppa-*-*elf*)                     fmt=elf em=hppa ;;
 243       hppa-*-lites*)                    fmt=elf em=hppa ;;
 244       hppa-*-netbsd*)                   fmt=elf em=nbsd ;;
 245       hppa-*-openbsd*)                  fmt=elf em=hppa ;;
 246       hppa-*-osf*)                      fmt=som em=hppa ;;
 247       hppa-*-rtems*)                    fmt=elf em=hppa ;;
 248       hppa-*-hpux11*)   case ${cpu} in
 249                             hppa*64*)   fmt=elf em=hppa64 ;;
 250                             hppa*)      fmt=som em=hppa ;;
 251                         esac ;;
 252       hppa-*-hpux*)                     fmt=som em=hppa ;;
 253       hppa-*-mpeix*)                    fmt=som em=hppa ;;
 254       hppa-*-bsd*)                      fmt=som em=hppa ;;
 255       hppa-*-hiux*)                     fmt=som em=hppa ;;
 256
 257       h8300-*-rtems*)                   fmt=coff ;;
 258       h8300-*-coff)                     fmt=coff ;;
 259       h8300-*-elf)                      fmt=elf ;;
 260       h8500-*-rtems*)                   fmt=coff ;;
 261       h8500-*-coff)                     fmt=coff ;;
 262
 263       i370-*-elf* | i370-*-linux*)      fmt=elf ;;
 264       i386-ibm-aix*)                    fmt=coff em=i386aix ;;
 265       i386-sequent-bsd*)                fmt=aout em=dynix ;;
 266       i386-*-beospe*)                   fmt=coff em=pe ;;
 267       i386-*-beos*)                     fmt=elf ;;
 268       i386-*-coff)                      fmt=coff ;;
 269       i386-*-elf)                       fmt=elf ;;
 270       i386-*-kaos*)                     fmt=elf ;;
 271       i386-*-bsd*)                      fmt=aout em=386bsd ;;
 272       i386-*-netbsd0.8)                 fmt=aout em=386bsd ;;
 273       i386-*-netbsdpe*)                 fmt=coff em=pe ;;
 274       i386-*-netbsd*-gnu* | \
 275       i386-*-knetbsd*-gnu | \
 276       i386-*-netbsdelf*)                fmt=elf em=nbsd ;;
 277       i386-*-*n*bsd*)   case ${cpu} in
 278                             x86_64)     fmt=elf em=nbsd ;;
 279                             *)          fmt=aout em=nbsd ;;
 280                         esac ;;
 281       i386-*-linux*aout*)               fmt=aout em=linux ;;
 282       i386-*-linux*oldld)               fmt=aout em=linux ;;
 283       i386-*-linux*coff*)               fmt=coff em=linux ;;
 284       i386-*-linux-gnu*)                fmt=elf em=linux ;;
 285       x86_64-*-linux-gnu*)              fmt=elf em=linux ;;
 286       i386-*-lynxos*)                   fmt=elf em=lynx bfd_gas=yes ;;
 287 changequote(,)dnl
 288       i386-*-sysv[45]*)                 fmt=elf ;;
 289       i386-*-solaris*)                  fmt=elf ;;
 290       i386-*-freebsdaout*)              fmt=aout em=386bsd ;;
 291       i386-*-freebsd[12].*)             fmt=aout em=386bsd ;;
 292       i386-*-freebsd[12])               fmt=aout em=386bsd ;;
 293 changequote([,])dnl
 294       i386-*-freebsd* | i386-*-kfreebsd*-gnu)
 295                                         fmt=elf em=freebsd ;;
 296       i386-*-sysv*)                     fmt=coff ;;
 297       i386-*-sco3.2v5*coff)             fmt=coff ;;
 298       i386-*-isc*)                      fmt=coff ;;
 299       i386-*-sco3.2v5*)                 fmt=elf
 300           if test ${this_target} = $target; then
 301             AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 302           fi ;;
 303       i386-*-sco3.2*)                   fmt=coff ;;
 304       i386-*-vsta)                      fmt=aout ;;
 305       i386-*-msdosdjgpp* \
 306       | i386-*-go32* \
 307       | i386-go32-rtems*)               fmt=coff em=go32
 308             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?]) ;;
 309       i386-*-rtemself*)                 fmt=elf ;;
 310       i386-*-rtemscoff*)                fmt=coff ;;
 311       i386-*-rtems*)                    fmt=elf ;;
 312       i386-*-gnu*)                      fmt=elf ;;
 313       i386-*-mach*)                     fmt=aout em=mach ;;
 314       i386-*-msdos*)                    fmt=aout ;;
 315       i386-*-moss*)                     fmt=elf ;;
 316       i386-*-pe)                        fmt=coff em=pe ;;
 317       i386-*-cygwin*)                   fmt=coff em=pe ;;
 318       i386-*-interix*)                  fmt=coff em=interix ;;
 319       i386-*-mingw32*)                  fmt=coff em=pe ;;
 320       i386-*-nto-qnx*)                  fmt=elf ;;
 321       i386-*-*nt*)                      fmt=coff em=pe ;;
 322       i386-*-chaos)                     fmt=elf ;;
 323
 324       i860-*-*)                         fmt=elf endian=little
 325                 AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 326       i960-*-bout)                      fmt=bout ;;
 327       i960-*-coff)                      fmt=coff em=ic960 ;;
 328       i960-*-rtems*)                    fmt=coff em=ic960 ;;
 329       i960-*-nindy*)                    fmt=bout ;;
 330       i960-*-vxworks5.0)                fmt=bout ;;
 331       i960-*-vxworks5.*)                fmt=coff em=ic960 ;;
 332       i960-*-vxworks*)                  fmt=bout ;;
 333       i960-*-elf*)                      fmt=elf ;;
 334
 335       ia64-*-elf*)                      fmt=elf ;;
 336       ia64-*-aix*)                      fmt=elf em=ia64aix ;;
 337       ia64-*-linux-gnu*)                fmt=elf em=linux ;;
 338       ia64-*-hpux*)                     fmt=elf em=hpux ;;
 339       ia64-*-netbsd*)                   fmt=elf em=nbsd ;;
 340
 341       ip2k-*-*)                         fmt=elf ;;
 342
 343       iq2000-*-elf)                     fmt=elf bfd_gas=yes ;;
 344
 345       m32r-*-elf*)                      fmt=elf ;;
 346       m32r-*-linux*)                    fmt=elf em=linux;;
 347
 348       m68hc11-*-* | m6811-*-*)          fmt=elf ;;
 349       m68hc12-*-* | m6812-*-*)          fmt=elf ;;
 350
 351       m68k-*-vxworks*)                  fmt=aout em=sun3 ;;
 352       m68k-ericsson-ose)                fmt=aout em=sun3 ;;
 353       m68k-*-sunos*)                    fmt=aout em=sun3 ;;
 354       m68k-motorola-sysv*)              fmt=coff em=delta ;;
 355       m68k-bull-sysv3*)                 fmt=coff em=dpx2 ;;
 356       m68k-apollo-*)                    fmt=coff em=apollo ;;
 357       m68k-*-elf*)                      fmt=elf ;;
 358       m68k-*-sysv4*)                    fmt=elf em=svr4 ;;
 359       m68k-*-sysv*)                     fmt=coff ;;
 360       m68k-*-coff | m68k-*-rtemscoff*)  fmt=coff ;;
 361       m68k-*-rtems*)                    fmt=elf ;;
 362       m68k-*-hpux*)                     fmt=hp300 em=hp300 ;;
 363       m68k-*-linux*aout*)               fmt=aout em=linux ;;
 364       m68k-*-linux-gnu*)                fmt=elf em=linux ;;
 365       m68k-*-uclinux*)                  fmt=elf ;;
 366       m68k-*-gnu*)                      fmt=elf ;;
 367       m68k-*-lynxos*)                   fmt=coff em=lynx ;;
 368       m68k-*-netbsdelf*)                fmt=elf em=nbsd ;;
 369       m68k-*-netbsd*)                   fmt=aout em=nbsd bfd_gas=yes ;;
 370       m68k-*-openbsd*)                  fmt=aout em=nbsd bfd_gas=yes ;;
 371       m68k-apple-aux*)                  fmt=coff em=aux ;;
 372       m68k-*-psos*)                     fmt=elf em=psos;;
 373
 374       m88k-motorola-sysv3*)             fmt=coff em=delt88 ;;
 375       m88k-*-coff*)                     fmt=coff ;;
 376
 377       mcore-*-elf)                      fmt=elf ;;
 378       mcore-*-pe)                       fmt=coff em=pe bfd_gas=yes ;;
 379
 380       # don't change em like *-*-bsd does
 381       mips-dec-openbsd*)                fmt=elf endian=little ;;
 382       mips-sony-bsd*)                   fmt=ecoff ;;
 383       mips-*-bsd*)
 384             AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 385       mips-*-ultrix*)                   fmt=ecoff endian=little ;;
 386       mips-*-osf*)                      fmt=ecoff endian=little ;;
 387       mips-*-ecoff*)                    fmt=ecoff ;;
 388       mips-*-pe*)                       fmt=coff endian=little em=pe ;;
 389       mips-*-irix6*)                    fmt=elf em=irix ;;
 390       mips-*-irix5*)                    fmt=elf em=irix ;;
 391       mips-*-irix*)                     fmt=ecoff em=irix ;;
 392       mips-*-lnews*)                    fmt=ecoff em=lnews ;;
 393       mips-*-riscos*)                   fmt=ecoff ;;
 394       mips*-*-linux*)                   fmt=elf em=tmips ;;
 395       mips-*-sysv4*MP* | mips-*-gnu*)   fmt=elf em=tmips ;;
 396       mips-*-sysv*)                     fmt=ecoff ;;
 397       mips-*-elf* | mips-*-rtems*)      fmt=elf ;;
 398       mips-*-netbsd*)                   fmt=elf ;;
 399       mips-*-openbsd*)                  fmt=elf ;;
 400
 401       mmix-*-*)                         fmt=elf ;;
 402       mn10200-*-*)                      fmt=elf ;;
 403       # cpu_type for am33_2.0 is set to mn10300
 404       mn10300-*-linux*)                 fmt=elf bfd_gas=yes em=linux ;;
 405       mn10300-*-*)                      fmt=elf ;;
 406
 407       msp430-*-*)                       fmt=elf ;;
 408
 409       ns32k-pc532-mach*)                fmt=aout em=pc532mach ;;
 410       ns32k-pc532-ux*)                  fmt=aout em=pc532mach ;;
 411       ns32k-pc532-lites*)               fmt=aout em=nbsd532 ;;
 412       ns32k-*-*n*bsd*)                  fmt=aout em=nbsd532 ;;
 413
 414       openrisc-*-*)                     fmt=elf ;;
 415       or32-*-rtems*)                    fmt=elf ;;
 416       or32-*-coff)                      fmt=coff ;;
 417       or32-*-elf)                       fmt=elf ;;
 418
 419       pj*)                              fmt=elf ;;
 420
 421       ppc-*-pe | ppc-*-cygwin*)         fmt=coff em=pe ;;
 422       ppc-*-winnt*)                     fmt=coff em=pe ;;
 423 changequote(,)dnl
 424       ppc-*-aix5.[01])                  fmt=coff em=aix5 ;;
 425 changequote([,])dnl
 426       ppc-*-aix5.*)                     fmt=coff em=aix5
 427         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 428                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 429       ;;
 430       ppc-*-aix*)                       fmt=coff ;;
 431       ppc-*-beos*)                      fmt=coff ;;
 432       ppc-*-*n*bsd* | ppc-*-elf*)       fmt=elf ;;
 433       ppc-*-eabi* | ppc-*-sysv4*)       fmt=elf ;;
 434       ppc-*-linux-gnu*)                 fmt=elf em=linux
 435             case "$endian" in
 436                 big)  ;;
 437                 *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 438             esac ;;
 439       ppc-*-solaris*)                   fmt=elf
 440             if test ${this_target} = $target; then
 441                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 442                           [Define if default target is PowerPC Solaris.])
 443             fi
 444             if test x${endian} = xbig; then
 445                 AC_MSG_ERROR(Solaris must be configured little endian)
 446             fi ;;
 447       ppc-*-rtems*)                     fmt=elf ;;
 448       ppc-*-macos*)                     fmt=coff em=macos ;;
 449       ppc-*-nto*)                       fmt=elf ;;
 450       ppc-*-kaos*)                      fmt=elf ;;
 451       ppc-*-lynxos*)                    fmt=elf em=lynx bfd_gas=yes ;;
 452
 453       s390x-*-linux-gnu*)               fmt=elf em=linux ;;
 454       s390-*-linux-gnu*)                fmt=elf em=linux ;;
 455
 456       sh*-*-linux*)                     fmt=elf em=linux
 457             case ${cpu} in
 458                 sh*eb)  endian=big ;;
 459                 *)      endian=little ;;
 460             esac ;;
 461       sh5*-*-netbsd*)                   fmt=elf em=nbsd ;;
 462       sh64*-*-netbsd*)                  fmt=elf em=nbsd ;;
 463       sh*-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 464       sh*-*-symbianelf*)                fmt=elf endian=little
 465                 AC_DEFINE(TARGET_SYMBIAN, 1, [Define if target is Symbian OS.])
 466                 ;;
 467       sh-*-elf*)                        fmt=elf ;;
 468       sh-*-coff*)                       fmt=coff ;;
 469       sh-*-nto*)                        fmt=elf ;;
 470       sh-*-pe*)                         fmt=coff em=pe bfd_gas=yes endian=little ;;
 471       sh-*-rtemscoff*)                  fmt=coff ;;
 472       sh-*-rtems*)                      fmt=elf ;;
 473       sh-*-kaos*)                       fmt=elf ;;
 474       shle*-*-kaos*)                    fmt=elf ;;
 475       sh64-*-elf*)                      fmt=elf ;;
 476
 477       sparc-*-rtemsaout*)               fmt=aout ;;
 478       sparc-*-rtemself*)                fmt=elf ;;
 479       sparc-*-rtems*)                   fmt=elf ;;
 480       sparc-*-sunos4*)                  fmt=aout em=sun3 ;;
 481       sparc-*-aout | sparc*-*-vxworks*) fmt=aout em=sparcaout ;;
 482       sparc-*-coff)                     fmt=coff ;;
 483       sparc-*-linux*aout*)              fmt=aout em=linux ;;
 484       sparc-*-linux-gnu*)               fmt=elf em=linux ;;
 485       sparc-*-lynxos*)                  fmt=coff em=lynx ;;
 486       sparc-fujitsu-none)               fmt=aout ;;
 487       sparc-*-elf)                      fmt=elf ;;
 488       sparc-*-sysv4*)                   fmt=elf ;;
 489       sparc-*-solaris*)                 fmt=elf ;;
 490       sparc-*-netbsdelf*)               fmt=elf em=nbsd ;;
 491       sparc-*-*n*bsd*)  case ${cpu} in
 492                             sparc64)    fmt=elf em=nbsd ;;
 493                             *)          fmt=aout em=nbsd ;;
 494                         esac ;;
 495       strongarm-*-coff)                 fmt=coff ;;
 496       strongarm-*-elf)                  fmt=elf ;;
 497       strongarm-*-kaos*)                fmt=elf ;;
 498
 499       tic30-*-*aout*)                   fmt=aout bfd_gas=yes ;;
 500       tic30-*-*coff*)                   fmt=coff bfd_gas=yes ;;
 501       tic4x-*-* | c4x-*-*)              fmt=coff bfd_gas=yes ;;
 502       tic54x-*-* | c54x*-*-*)           fmt=coff bfd_gas=yes need_libm=yes;;
 503       tic80-*-*)                        fmt=coff ;;
 504
 505       v850-*-*)                         fmt=elf ;;
 506       v850e-*-*)                        fmt=elf ;;
 507       v850ea-*-*)                       fmt=elf ;;
 508
 509       vax-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 510       vax-*-netbsd*)                    fmt=aout em=nbsd ;;
 511       vax-*-bsd* | vax-*-ultrix*)       fmt=aout ;;
 512       vax-*-linux-gnu*)                 fmt=elf em=linux bfd_gas=yes ;;
 513       vax-*-vms)                        fmt=vms ;;
 514
 515       w65-*-*)                          fmt=coff ;;
 516
 517       xscale-*-coff)                    fmt=coff ;;
 518       xscale-*-elf)                     fmt=elf ;;
 519
 520       xstormy16-*-*)                    fmt=elf ;;
 521
 522       xtensa-*-*)                       fmt=elf ;;
 523
 524       z8k-*-coff | z8k-*-sim)           fmt=coff ;;
 525
 526       *-*-aout | *-*-scout)             fmt=aout ;;
 527       *-*-freebsd* | *-*-kfreebsd*-gnu) fmt=elf em=freebsd ;;
 528       *-*-nindy*)                       fmt=bout ;;
 529       *-*-bsd*)                         fmt=aout em=sun3 ;;
 530       *-*-generic)                      fmt=generic ;;
 531       *-*-xray | *-*-hms)               fmt=coff ;;
 532       *-*-sim)                          fmt=coff ;;
 533       *-*-elf | *-*-sysv4* | *-*-solaris*) fmt=elf dev=yes ;;
 534       *-*-aros*)                        fmt=elf em=linux bfd_gas=yes ;;
 535       *-*-vxworks | *-*-windiss)        fmt=elf ;;
 536       *-*-netware)                      fmt=elf em=netware ;;
 537     esac
 538
 539     if test ${this_target} = $target ; then
 540       endian_def=
 541       if test x${endian} = xbig; then
 542         endian_def=1
 543       elif test x${endian} = xlittle; then
 544         endian_def=0
 545       fi
 546       if test x${endian_def} != x; then
 547         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 548                            [Define as 1 if big endian.])
 549       fi
 550     fi
 551
 552     case ${cpu_type}-${fmt} in
 553         alpha*-* | arm-* | i386-* | ia64*-* | mips-* | ns32k-* \
 554                 | pdp11-* | ppc-* | sparc-* | strongarm-* | xscale-* \
 555                 | *-elf | *-ecoff | *-som)
 556             bfd_gas=yes ;;
 557     esac
 558
 559 # Other random stuff.
 560
 561     case ${cpu_type} in
 562       mips)
 563         # Set mips_cpu to the name of the default CPU.
 564         case ${target_cpu} in
 565           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 566             mips_cpu=from-abi
 567             ;;
 568           mipsisa32 | mipsisa32el)
 569             mips_cpu=mips32
 570             ;;
 571           mipsisa32r2 | mipsisa32r2el)
 572             mips_cpu=mips32r2
 573             ;;
 574           mipsisa64 | mipsisa64el)
 575             mips_cpu=mips64
 576             ;;
 577           mipsisa64r2 | mipsisa64r2el)
 578             mips_cpu=mips64r2
 579             ;;
 580           mipstx39 | mipstx39el)
 581             mips_cpu=r3900
 582             ;;
 583           mips64vr | mips64vrel)
 584             mips_cpu=vr4100
 585             ;;
 586           mipsisa32r2* | mipsisa64r2*)
 587 changequote(,)dnl
 588             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 589 changequote([,])dnl
 590             ;;
 591           mips64* | mipsisa64* | mipsisa32*)
 592 changequote(,)dnl
 593             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 594 changequote([,])dnl
 595             ;;
 596           *)
 597             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 598             ;;
 599         esac
 600         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 601         # binaries.  It's a GNU extension that some OSes don't understand.
 602         # The value only matters on ELF targets.
 603         case ${target} in
 604           *-*-irix*)
 605             use_e_mips_abi_o32=0
 606             ;;
 607           *)
 608             use_e_mips_abi_o32=1
 609             ;;
 610         esac
 611         # Decide whether to generate 32-bit or 64-bit code by default.
 612         # Used to resolve -march=from-abi when an embedded ABI is selected.
 613         case ${target} in
 614           mips64*-*-* | mipsisa64*-*-*)
 615             mips_default_64bit=1
 616             ;;
 617           *)
 618             mips_default_64bit=0
 619             ;;
 620         esac
 621         # Decide which ABI to target by default.
 622         case ${target} in
 623           mips64*-linux* | mips-sgi-irix6*)
 624             mips_default_abi=N32_ABI
 625             ;;
 626           mips*-linux*)
 627             mips_default_abi=O32_ABI
 628             ;;
 629           *)
 630             mips_default_abi=NO_ABI
 631             ;;
 632         esac
 633         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 634                            [Default CPU for MIPS targets. ])
 635         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 636                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 637         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 638                            [Generate 64-bit code by default on MIPS targets. ])
 639         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 640                            [Choose a default ABI for MIPS targets. ])
 641         ;;
 642     esac
 643
 644     # Do we need the opcodes library?
 645     case ${cpu_type} in
 646       vax | i386 | tic30)
 647         ;;
 648
 649       *)
 650         need_opcodes=yes
 651
 652         case "${enable_shared}" in
 653         yes) shared_opcodes=true ;;
 654         *opcodes*) shared_opcodes=true ;;
 655         *) shared_opcodes=false ;;
 656         esac
 657         if test "${shared_opcodes}" = "true"; then
 658           # A shared libopcodes must be linked against libbfd.
 659           need_bfd=yes
 660         fi
 661         ;;
 662     esac
 663
 664     # Any other special object files needed ?
 665     case ${cpu_type} in
 666       fr30 | ip2k | iq2000 | m32r | openrisc)
 667         using_cgen=yes
 668         ;;
 669
 670       frv)
 671         using_cgen=yes
 672         ;;
 673       m68k)
 674         case ${extra_objects} in
 675         *m68k-parse.o*) ;;
 676         *) extra_objects="$extra_objects m68k-parse.o" ;;
 677         esac
 678         ;;
 679
 680       mips)
 681         echo ${extra_objects} | grep -s "itbl-parse.o"
 682         if test $? -ne 0 ; then
 683           extra_objects="$extra_objects itbl-parse.o"
 684         fi
 685
 686         echo ${extra_objects} | grep -s "itbl-lex.o"
 687         if test $? -ne 0 ; then
 688           extra_objects="$extra_objects itbl-lex.o"
 689         fi
 690
 691         echo ${extra_objects} | grep -s "itbl-ops.o"
 692         if test $? -ne 0 ; then
 693           extra_objects="$extra_objects itbl-ops.o"
 694         fi
 695         ;;
 696
 697       i386 | s390 | sparc)
 698         if test $this_target = $target ; then
 699           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 700         fi
 701         ;;
 702
 703       xstormy16)
 704         using_cgen=yes
 705         ;;
 706
 707       xtensa)
 708         echo ${extra_objects} | grep -s "xtensa-relax.o"
 709         if test $? -ne 0 ; then
 710           extra_objects="$extra_objects xtensa-relax.o"
 711         fi
 712         ;;
 713
 714       *)
 715         ;;
 716     esac
 717
 718     if test $using_cgen = yes ; then
 719         case "x${extra_objects}" in
 720         *cgen.o*) ;;
 721         *) extra_objects="$extra_objects cgen.o" ;;
 722         esac
 723     fi
 724
 725 # See if we really can support this configuration with the emulation code.
 726
 727     if test $this_target = $target ; then
 728       primary_bfd_gas=$bfd_gas
 729       obj_format=$fmt
 730       te_file=$em
 731
 732       if test $bfd_gas = no ; then
 733         # Can't support other configurations this way.
 734         break
 735       fi
 736     elif test $bfd_gas = no ; then
 737       # Can't support this configuration.
 738       break
 739     fi
 740
 741 # From target name and format, produce a list of supported emulations.
 742
 743     case ${generic_target}-${fmt} in
 744       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 745       mips*-*-linux*-*) case "$endian" in
 746                         big)    emulation="mipsbelf mipslelf mipself" ;;
 747                         *)      emulation="mipslelf mipsbelf mipself" ;;
 748                         esac ;;
 749       mips-*-lnews*-ecoff) ;;
 750       mips-*-*-ecoff)   case "$endian" in
 751                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 752                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 753                         esac ;;
 754       mips-*-*-elf)     case "$endian" in
 755                         big)    emulation="mipsbelf mipslelf mipself" ;;
 756                         *)      emulation="mipslelf mipsbelf mipself" ;;
 757                         esac ;;
 758       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 759       # i386-pc-pe-coff != i386-pc-coff.
 760       i386-*-pe-coff)   ;;
 761       # Uncommenting the next line will turn on support for i386 AOUT
 762       # for the default linux configuration
 763       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 764       #
 765       i386-*-aout)      emulation="i386aout" ;;
 766       i386-*-coff)      emulation="i386coff" ;;
 767       i386-*-elf)       emulation="i386elf" ;;
 768
 769       # Always all formats.  The first stated emulation becomes the default.
 770       cris-*-*aout*)    emulation="crisaout criself" ;;
 771       cris-*-*)         emulation="criself crisaout" ;;
 772     esac
 773
 774     emulations="$emulations $emulation"
 775
 776 done
 777
 778 # Turn on all targets if possible
 779 if test ${all_targets} = "yes"; then
 780   case ${target_cpu_type} in
 781   i386)
 782     case ${obj_format} in
 783     aout)
 784       emulations="$emulations i386coff i386elf"
 785       ;;
 786     coff)
 787       emulations="$emulations i386aout i386elf"
 788     ;;
 789     elf)
 790       emulations="$emulations i386aout i386coff"
 791       ;;
 792     esac
 793   ;;
 794   esac
 795 fi
 796
 797 # Assign floating point type.  Most processors with FP support
 798 # IEEE FP.  On those that don't support FP at all, usually IEEE
 799 # is emulated.
 800 case ${target_cpu} in
 801   vax | tahoe ) atof=${target_cpu} ;;
 802   pdp11)        atof=vax ;;
 803   *)            atof=ieee ;;
 804 esac
 805
 806 case "${obj_format}" in
 807   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 808 esac
 809
 810 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 811 cgen_cpu_prefix=""
 812 if test $using_cgen = yes ; then
 813   case ${target_cpu} in
 814     *) cgen_cpu_prefix=${target_cpu} ;;
 815   esac
 816   AC_SUBST(cgen_cpu_prefix)
 817   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 818 fi
 819
 820 dnl
 821 dnl Make sure the desired support files exist.
 822 dnl
 823
 824 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 825   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 826 fi
 827
 828 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 829   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 830 fi
 831
 832 case ${user_bfd_gas}-${primary_bfd_gas} in
 833   yes-yes | no-no)
 834     # We didn't override user's choice.
 835     ;;
 836   no-yes)
 837     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 838     ;;
 839   no-preferred)
 840     primary_bfd_gas=no
 841     ;;
 842   *-preferred)
 843     primary_bfd_gas=yes
 844     ;;
 845   yes-*)
 846     primary_bfd_gas=yes
 847     ;;
 848   -*)
 849     # User specified nothing.
 850     ;;
 851 esac
 852
 853 # Some COFF configurations want these random other flags set.
 854 case ${obj_format} in
 855   coff)
 856     case ${target_cpu_type} in
 857       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 858       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 859       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 860     esac
 861     ;;
 862 esac
 863
 864 # Getting this done right is going to be a bitch.  Each configuration specified
 865 # with --enable-targets=... should be checked for environment, format, cpu, and
 866 # bfd_gas setting.
 867 #
 868 # For each configuration, the necessary object file support code must be linked
 869 # in.  This might be only one, it might be up to four.  The necessary emulation
 870 # code needs to be provided, too.
 871 #
 872 # And then there's "--enable-targets=all"....
 873 #
 874 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 875
 876 formats="${obj_format}"
 877 emfiles=""
 878 EMULATIONS=""
 879 GAS_UNIQ(emulations)
 880 for em in . $emulations ; do
 881   case $em in
 882     .)  continue ;;
 883     mipsbelf | mipslelf | mipself)
 884         fmt=elf   file=mipself ;;
 885     mipsbecoff | mipslecoff | mipsecoff)
 886         fmt=ecoff file=mipsecoff ;;
 887     *coff)
 888         fmt=coff  file=$em ;;
 889     *aout)
 890         fmt=aout file=$em ;;
 891     *elf)
 892         fmt=elf file=$em ;;
 893   esac
 894   formats="$formats $fmt"
 895   emfiles="$emfiles e-$file.o"
 896   EMULATIONS="$EMULATIONS &$em,"
 897 done
 898 GAS_UNIQ(formats)
 899 GAS_UNIQ(emfiles)
 900 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 901   for fmt in $formats ; do
 902     case $fmt in
 903       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 904       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 905       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 906       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 907       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 908       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 909       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 910       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 911       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 912       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 913     esac
 914     extra_objects="$extra_objects obj-$fmt.o"
 915   done
 916   obj_format=multi
 917 fi
 918 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 919   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 920   # e-mips* has more than one emulation per file, e-i386* has just one at the
 921   # moment.  If only one emulation is specified, then don't define
 922   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 923   case "${obj_format}${emfiles}" in
 924     multi* | *mips*)
 925       extra_objects="$extra_objects $emfiles"
 926       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 927   esac
 928 fi
 929 AC_SUBST(extra_objects)
 930 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 931 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 932                    [Default emulation.])
 933
 934 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 935   yes-*-coff)   need_bfd=yes ;;
 936   no-*-coff)    need_bfd=yes
 937                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 938 esac
 939
 940 reject_dev_configs=yes
 941
 942 case ${reject_dev_configs}-${dev} in
 943   yes-yes) # Oops.
 944     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 945     ;;
 946 esac
 947
 948 AC_SUBST(target_cpu_type)
 949 AC_SUBST(obj_format)
 950 AC_SUBST(te_file)
 951 AC_SUBST(install_tooldir)
 952 AC_SUBST(atof)
 953 dnl AC_SUBST(emulation)
 954
 955 case "${primary_bfd_gas}" in
 956   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 957         need_bfd=yes ;;
 958 esac
 959
 960 # do we need the opcodes library?
 961 case "${need_opcodes}" in
 962 yes)
 963   OPCODES_LIB=../opcodes/libopcodes.la
 964   ;;
 965 esac
 966
 967 case "${need_bfd}" in
 968 yes)
 969   BFDLIB=../bfd/libbfd.la
 970   BFDVER_H=../bfd/bfdver.h
 971   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 972   ;;
 973 esac
 974
 975 AC_SUBST(BFDLIB)
 976 AC_SUBST(OPCODES_LIB)
 977
 978 AC_SUBST(BFDVER_H)
 979 AC_SUBST(ALL_OBJ_DEPS)
 980
 981 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 982 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 983 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 984 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 985 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 986
 987 AC_PROG_CC
 988
 989 AC_PROG_YACC
 990 AM_PROG_LEX
 991
 992 ALL_LINGUAS="fr tr es"
 993 CY_GNU_GETTEXT
 994
 995 AM_MAINTAINER_MODE
 996 AC_EXEEXT
 997
 998 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 999
1000 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
1001 # people who are not cross-compiling but are compiling cross-assemblers.
1002 AC_MSG_CHECKING(whether compiling a cross-assembler)
1003 if test "${host}" = "${target}"; then
1004   cross_gas=no
1005 else
1006   cross_gas=yes
1007   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
1008 fi
1009 AC_MSG_RESULT($cross_gas)
1010
1011 dnl ansidecl.h will deal with const
1012 dnl AC_CONST
1013 AC_FUNC_ALLOCA
1014 AC_C_INLINE
1015
1016 # VMS doesn't have unlink.
1017 AC_CHECK_FUNCS(unlink remove, break)
1018
1019 # Some systems don't have sbrk().
1020 AC_CHECK_FUNCS(sbrk)
1021
1022 # do we need the math library?
1023 case "${need_libm}" in
1024 yes)
1025   AC_CHECK_LIBM
1026   AC_SUBST(LIBM)
1027   ;;
1028 esac
1029
1030 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
1031 # enough, but on some of those systems, the assert macro relies on requoting
1032 # working properly!
1033 GAS_WORKING_ASSERT
1034
1035 # On some systems, the system header files may not declare malloc, realloc,
1036 # and free.  There are places where gas needs these functions to have been
1037 # declared -- such as when taking their addresses.
1038 gas_test_headers="
1039 #ifdef HAVE_MEMORY_H
1040 #include <memory.h>
1041 #endif
1042 #ifdef HAVE_STRING_H
1043 #include <string.h>
1044 #else
1045 #ifdef HAVE_STRINGS_H
1046 #include <strings.h>
1047 #endif
1048 #endif
1049 #ifdef HAVE_STDLIB_H
1050 #include <stdlib.h>
1051 #endif
1052 #ifdef HAVE_UNISTD_H
1053 #include <unistd.h>
1054 #endif
1055 "
1056 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
1057 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
1058 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
1059 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
1060 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
1061
1062 # Does errno.h declare errno, or do we have to add a separate declaration
1063 # for it?
1064 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
1065 #ifdef HAVE_ERRNO_H
1066 #include <errno.h>
1067 #endif
1068 ])
1069
1070 dnl This must come last.
1071
1072 dnl We used to make symlinks to files in the source directory, but now
1073 dnl we just use the right name for .c files, and create .h files in
1074 dnl the build directory which include the right .h file.  Make sure
1075 dnl the old symlinks don't exist, so that a reconfigure in an existing
1076 dnl directory behaves reasonably.
1077
1078 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
1079 AC_CONFIG_COMMANDS([default],
1080 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1081  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1082  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1083  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1084  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1085  if test "x$cgen_cpu_prefix" != x ; then
1086    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1087  fi
1088
1089  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
1090 [target_cpu_type=${target_cpu_type}
1091  cgen_cpu_prefix=${cgen_cpu_prefix}
1092  obj_format=${obj_format}
1093  te_file=${te_file}])
1094
1095 AC_OUTPUT