gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.57)
   9 AC_INIT(as.h)
  10
  11 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  12 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  13 dnl gas/ instead of gas/../.
  14 AC_CONFIG_AUX_DIR(..)
  15 AC_CANONICAL_SYSTEM
  16 AC_ISC_POSIX
  17
  18 changequote(,)dnl
  19 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  20 changequote([,])dnl
  21 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  22
  23 AM_PROG_LIBTOOL
  24
  25 AC_ARG_ENABLE(targets,
  26 [    targets            alternative target configurations besides the primary],
  27 [case "${enableval}" in
  28   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  29             ;;
  30   no)       enable_targets= ;;
  31   *)        enable_targets=$enableval ;;
  32 esac])dnl
  33 AC_ARG_ENABLE(commonbfdlib,
  34 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  35 [case "${enableval}" in
  36   yes) commonbfdlib=true ;;
  37   no)  commonbfdlib=false ;;
  38   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  39 esac])dnl
  40
  41 using_cgen=no
  42
  43 AM_BINUTILS_WARNINGS
  44
  45 # Generate a header file
  46 AM_CONFIG_HEADER(config.h:config.in)
  47
  48 # If we are on a DOS filesystem, we must use gdb.ini rather than
  49 # .gdbinit.
  50 case "${host}" in
  51   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  52     GDBINIT="gdb.ini"
  53     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  54     ;;
  55   *)
  56     GDBINIT=".gdbinit"
  57     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  58     ;;
  59 esac
  60 AC_SUBST(GDBINIT)
  61
  62 #We need this for the host.  BOUT header is in host order.
  63 AC_C_BIGENDIAN
  64
  65 te_file=generic
  66
  67 # Makefile target for installing gas in $(tooldir)/bin.
  68 install_tooldir=install-exec-tooldir
  69
  70 canon_targets=""
  71 all_targets=no
  72 if test -n "$enable_targets" ; then
  73   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  74     if test $t = "all"; then
  75       all_targets=yes
  76       continue
  77     fi
  78     result=`$ac_config_sub $t 2>/dev/null`
  79     if test -n "$result" ; then
  80       canon_targets="$canon_targets $result"
  81 #    else
  82 #      # Permit "all", etc.  We don't support it yet though.
  83 #      canon_targets="$canon_targets $t"
  84     fi
  85   done
  86   GAS_UNIQ(canon_targets)
  87 fi
  88
  89 emulations=""
  90
  91 for this_target in $target $canon_targets ; do
  92
  93     targ=${this_target}
  94     . ${srcdir}/configure.tgt
  95
  96     case ${target_cpu} in
  97       crisv32)
  98         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
  99                            [Default CRIS architecture.])
 100         ;;
 101     esac
 102
 103     if test ${this_target} = $target ; then
 104       target_cpu_type=${cpu_type}
 105     elif test ${target_cpu_type} != ${cpu_type} ; then
 106       continue
 107     fi
 108
 109     generic_target=${cpu_type}-${target_vendor}-${target_os}
 110     case ${generic_target} in
 111       i386-*-sco3.2v5*)
 112         if test ${this_target} = $target; then
 113           AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 114         fi
 115         ;;
 116
 117       i386-*-msdosdjgpp* \
 118       | i386-*-go32* \
 119       | i386-go32-rtems*)
 120         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 121         ;;
 122
 123       i860-*-*)
 124         AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress)
 125         ;;
 126
 127       mips-sony-bsd*)
 128         ;;
 129       mips-*-bsd*)
 130         AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.)
 131         ;;
 132
 133       ppc-*-aix5.*)
 134         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 135                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 136         ;;
 137       ppc-*-linux-*)
 138         case "$endian" in
 139           big)  ;;
 140           *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 141         esac
 142         ;;
 143       ppc-*-solaris*)
 144         if test ${this_target} = $target; then
 145           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 146                     [Define if default target is PowerPC Solaris.])
 147         fi
 148         if test x${endian} = xbig; then
 149           AC_MSG_ERROR(Solaris must be configured little endian)
 150         fi
 151         ;;
 152
 153       sh*-*-symbianelf*)
 154         AC_DEFINE(TARGET_SYMBIAN, 1, [Define if target is Symbian OS.])
 155         ;;
 156     esac
 157
 158     if test ${this_target} = $target ; then
 159       endian_def=
 160       if test x${endian} = xbig; then
 161         endian_def=1
 162       elif test x${endian} = xlittle; then
 163         endian_def=0
 164       fi
 165       if test x${endian_def} != x; then
 166         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 167                            [Define as 1 if big endian.])
 168       fi
 169     fi
 170
 171 # Other random stuff.
 172
 173     case ${cpu_type} in
 174       mips)
 175         # Set mips_cpu to the name of the default CPU.
 176         case ${target_cpu} in
 177           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 178             mips_cpu=from-abi
 179             ;;
 180           mipsisa32 | mipsisa32el)
 181             mips_cpu=mips32
 182             ;;
 183           mipsisa32r2 | mipsisa32r2el)
 184             mips_cpu=mips32r2
 185             ;;
 186           mipsisa64 | mipsisa64el)
 187             mips_cpu=mips64
 188             ;;
 189           mipsisa64r2 | mipsisa64r2el)
 190             mips_cpu=mips64r2
 191             ;;
 192           mipstx39 | mipstx39el)
 193             mips_cpu=r3900
 194             ;;
 195           mips64vr | mips64vrel)
 196             mips_cpu=vr4100
 197             ;;
 198           mipsisa32r2* | mipsisa64r2*)
 199 changequote(,)dnl
 200             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 201 changequote([,])dnl
 202             ;;
 203           mips64* | mipsisa64* | mipsisa32*)
 204 changequote(,)dnl
 205             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 206 changequote([,])dnl
 207             ;;
 208           *)
 209             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 210             ;;
 211         esac
 212         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 213         # binaries.  It's a GNU extension that some OSes don't understand.
 214         # The value only matters on ELF targets.
 215         case ${target} in
 216           *-*-irix*)
 217             use_e_mips_abi_o32=0
 218             ;;
 219           *)
 220             use_e_mips_abi_o32=1
 221             ;;
 222         esac
 223         # Decide whether to generate 32-bit or 64-bit code by default.
 224         # Used to resolve -march=from-abi when an embedded ABI is selected.
 225         case ${target} in
 226           mips64*-*-* | mipsisa64*-*-*)
 227             mips_default_64bit=1
 228             ;;
 229           *)
 230             mips_default_64bit=0
 231             ;;
 232         esac
 233         # Decide which ABI to target by default.
 234         case ${target} in
 235           mips64*-linux* | mips-sgi-irix6*)
 236             mips_default_abi=N32_ABI
 237             ;;
 238           mips*-linux*)
 239             mips_default_abi=O32_ABI
 240             ;;
 241           mips64*-openbsd*)
 242             mips_default_abi=N64_ABI
 243             ;;
 244           *)
 245             mips_default_abi=NO_ABI
 246             ;;
 247         esac
 248         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 249                            [Default CPU for MIPS targets. ])
 250         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 251                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 252         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 253                            [Generate 64-bit code by default on MIPS targets. ])
 254         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 255                            [Choose a default ABI for MIPS targets. ])
 256         ;;
 257     esac
 258
 259     # Do we need the opcodes library?
 260     case ${cpu_type} in
 261       vax | i386 | tic30)
 262         ;;
 263
 264       *)
 265         need_opcodes=yes
 266
 267         case "${enable_shared}" in
 268         yes) shared_opcodes=true ;;
 269         *opcodes*) shared_opcodes=true ;;
 270         *) shared_opcodes=false ;;
 271         esac
 272         ;;
 273     esac
 274
 275     # Any other special object files needed ?
 276     case ${cpu_type} in
 277       fr30 | ip2k | iq2000 | m32r | openrisc)
 278         using_cgen=yes
 279         ;;
 280
 281       m32c)
 282         using_cgen=yes
 283         ;;
 284       frv)
 285         using_cgen=yes
 286         ;;
 287       m68k)
 288         case ${extra_objects} in
 289         *m68k-parse.o*) ;;
 290         *) extra_objects="$extra_objects m68k-parse.o" ;;
 291         esac
 292         ;;
 293
 294       mips)
 295         echo ${extra_objects} | grep -s "itbl-parse.o"
 296         if test $? -ne 0 ; then
 297           extra_objects="$extra_objects itbl-parse.o"
 298         fi
 299
 300         echo ${extra_objects} | grep -s "itbl-lex.o"
 301         if test $? -ne 0 ; then
 302           extra_objects="$extra_objects itbl-lex.o"
 303         fi
 304
 305         echo ${extra_objects} | grep -s "itbl-ops.o"
 306         if test $? -ne 0 ; then
 307           extra_objects="$extra_objects itbl-ops.o"
 308         fi
 309         ;;
 310
 311       ms1)
 312         using_cgen=yes
 313         ;;
 314
 315       i386 | s390 | sparc)
 316         if test $this_target = $target ; then
 317           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 318         fi
 319         ;;
 320
 321       xstormy16)
 322         using_cgen=yes
 323         ;;
 324
 325       xtensa)
 326         echo ${extra_objects} | grep -s "xtensa-relax.o"
 327         if test $? -ne 0 ; then
 328           extra_objects="$extra_objects xtensa-relax.o"
 329         fi
 330         ;;
 331
 332       *)
 333         ;;
 334     esac
 335
 336     if test $using_cgen = yes ; then
 337         case "x${extra_objects}" in
 338         *cgen.o*) ;;
 339         *) extra_objects="$extra_objects cgen.o" ;;
 340         esac
 341     fi
 342
 343 # See if we really can support this configuration with the emulation code.
 344
 345     if test $this_target = $target ; then
 346       obj_format=$fmt
 347       te_file=$em
 348     fi
 349
 350 # From target name and format, produce a list of supported emulations.
 351
 352     case ${generic_target}-${fmt} in
 353       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 354       mips*-*-linux*-*) case "$endian" in
 355                         big)    emulation="mipsbelf mipslelf mipself" ;;
 356                         *)      emulation="mipslelf mipsbelf mipself" ;;
 357                         esac ;;
 358       mips-*-lnews*-ecoff) ;;
 359       mips-*-*-ecoff)   case "$endian" in
 360                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 361                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 362                         esac ;;
 363       mips-*-*-elf)     case "$endian" in
 364                         big)    emulation="mipsbelf mipslelf mipself" ;;
 365                         *)      emulation="mipslelf mipsbelf mipself" ;;
 366                         esac ;;
 367       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 368       # i386-pc-pe-coff != i386-pc-coff.
 369       i386-*-pe-coff)   ;;
 370       # Uncommenting the next line will turn on support for i386 AOUT
 371       # for the default linux configuration
 372       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 373       #
 374       i386-*-aout)      emulation="i386aout" ;;
 375       i386-*-coff)      emulation="i386coff" ;;
 376       i386-*-elf)       emulation="i386elf" ;;
 377
 378       # Always all formats.  The first stated emulation becomes the default.
 379       cris-*-*aout*)    emulation="crisaout criself" ;;
 380       cris-*-*)         emulation="criself crisaout" ;;
 381     esac
 382
 383     emulations="$emulations $emulation"
 384
 385 done
 386
 387 # Turn on all targets if possible
 388 if test ${all_targets} = "yes"; then
 389   case ${target_cpu_type} in
 390   i386)
 391     case ${obj_format} in
 392     aout)
 393       emulations="$emulations i386coff i386elf"
 394       ;;
 395     coff)
 396       emulations="$emulations i386aout i386elf"
 397     ;;
 398     elf)
 399       emulations="$emulations i386aout i386coff"
 400       ;;
 401     esac
 402   ;;
 403   esac
 404 fi
 405
 406 # Assign floating point type.  Most processors with FP support
 407 # IEEE FP.  On those that don't support FP at all, usually IEEE
 408 # is emulated.
 409 case ${target_cpu} in
 410   vax | tahoe ) atof=${target_cpu} ;;
 411   pdp11)        atof=vax ;;
 412   *)            atof=ieee ;;
 413 esac
 414
 415 case "${obj_format}" in
 416   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 417 esac
 418
 419 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 420 cgen_cpu_prefix=""
 421 if test $using_cgen = yes ; then
 422   case ${target_cpu} in
 423     *) cgen_cpu_prefix=${target_cpu} ;;
 424   esac
 425   AC_SUBST(cgen_cpu_prefix)
 426   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 427 fi
 428
 429 dnl
 430 dnl Make sure the desired support files exist.
 431 dnl
 432
 433 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 434   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 435 fi
 436
 437 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 438   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 439 fi
 440
 441 # Some COFF configurations want these random other flags set.
 442 case ${obj_format} in
 443   coff)
 444     case ${target_cpu_type} in
 445       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 446       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 447       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 448     esac
 449     ;;
 450 esac
 451
 452 # Getting this done right is going to be a bitch.  Each configuration specified
 453 # with --enable-targets=... should be checked for environment, format, cpu
 454 # setting.
 455 #
 456 # For each configuration, the necessary object file support code must be linked
 457 # in.  This might be only one, it might be up to four.  The necessary emulation
 458 # code needs to be provided, too.
 459 #
 460 # And then there's "--enable-targets=all"....
 461 #
 462 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 463
 464 formats="${obj_format}"
 465 emfiles=""
 466 EMULATIONS=""
 467 GAS_UNIQ(emulations)
 468 for em in . $emulations ; do
 469   case $em in
 470     .)  continue ;;
 471     mipsbelf | mipslelf | mipself)
 472         fmt=elf   file=mipself ;;
 473     mipsbecoff | mipslecoff | mipsecoff)
 474         fmt=ecoff file=mipsecoff ;;
 475     *coff)
 476         fmt=coff  file=$em ;;
 477     *aout)
 478         fmt=aout file=$em ;;
 479     *elf)
 480         fmt=elf file=$em ;;
 481   esac
 482   formats="$formats $fmt"
 483   emfiles="$emfiles e-$file.o"
 484   EMULATIONS="$EMULATIONS &$em,"
 485 done
 486 GAS_UNIQ(formats)
 487 GAS_UNIQ(emfiles)
 488 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 489   for fmt in $formats ; do
 490     case $fmt in
 491       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 492       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 493       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 494       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 495       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 496       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 497       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 498       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 499     esac
 500     extra_objects="$extra_objects obj-$fmt.o"
 501   done
 502   obj_format=multi
 503 fi
 504 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 505   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 506   # e-mips* has more than one emulation per file, e-i386* has just one at the
 507   # moment.  If only one emulation is specified, then don't define
 508   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 509   case "${obj_format}${emfiles}" in
 510     multi* | *mips*)
 511       extra_objects="$extra_objects $emfiles"
 512       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 513   esac
 514 fi
 515 AC_SUBST(extra_objects)
 516 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 517 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 518                    [Default emulation.])
 519
 520 reject_dev_configs=yes
 521
 522 case ${reject_dev_configs}-${dev} in
 523   yes-yes) # Oops.
 524     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 525     ;;
 526 esac
 527
 528 AC_SUBST(target_cpu_type)
 529 AC_SUBST(obj_format)
 530 AC_SUBST(te_file)
 531 AC_SUBST(install_tooldir)
 532 AC_SUBST(atof)
 533 dnl AC_SUBST(emulation)
 534
 535 # do we need the opcodes library?
 536 case "${need_opcodes}" in
 537 yes)
 538   OPCODES_LIB=../opcodes/libopcodes.la
 539   ;;
 540 esac
 541
 542 BFDLIB=../bfd/libbfd.la
 543 BFDVER_H=../bfd/bfdver.h
 544 ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 545
 546 AC_SUBST(BFDLIB)
 547 AC_SUBST(OPCODES_LIB)
 548
 549 AC_SUBST(BFDVER_H)
 550 AC_SUBST(ALL_OBJ_DEPS)
 551
 552 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 553 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 554 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 555 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 556 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 557
 558 AC_PROG_CC
 559
 560 AC_PROG_YACC
 561 AM_PROG_LEX
 562
 563 ALL_LINGUAS="fr tr es rw"
 564 CY_GNU_GETTEXT
 565
 566 AM_MAINTAINER_MODE
 567 AC_EXEEXT
 568
 569 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 570
 571 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 572 # people who are not cross-compiling but are compiling cross-assemblers.
 573 AC_MSG_CHECKING(whether compiling a cross-assembler)
 574 if test "${host}" = "${target}"; then
 575   cross_gas=no
 576 else
 577   cross_gas=yes
 578   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 579 fi
 580 AC_MSG_RESULT($cross_gas)
 581
 582 dnl ansidecl.h will deal with const
 583 dnl AC_CONST
 584 AC_FUNC_ALLOCA
 585 AC_C_INLINE
 586
 587 # VMS doesn't have unlink.
 588 AC_CHECK_FUNCS(unlink remove, break)
 589
 590 # Some systems don't have sbrk().
 591 AC_CHECK_FUNCS(sbrk)
 592
 593 # do we need the math library?
 594 case "${need_libm}" in
 595 yes)
 596   AC_CHECK_LIBM
 597   AC_SUBST(LIBM)
 598   ;;
 599 esac
 600
 601 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 602 # enough, but on some of those systems, the assert macro relies on requoting
 603 # working properly!
 604 GAS_WORKING_ASSERT
 605
 606 # On some systems, the system header files may not declare malloc, realloc,
 607 # and free.  There are places where gas needs these functions to have been
 608 # declared -- such as when taking their addresses.
 609 gas_test_headers="
 610 #ifdef HAVE_MEMORY_H
 611 #include <memory.h>
 612 #endif
 613 #ifdef HAVE_STRING_H
 614 #include <string.h>
 615 #else
 616 #ifdef HAVE_STRINGS_H
 617 #include <strings.h>
 618 #endif
 619 #endif
 620 #ifdef HAVE_STDLIB_H
 621 #include <stdlib.h>
 622 #endif
 623 #ifdef HAVE_UNISTD_H
 624 #include <unistd.h>
 625 #endif
 626 "
 627
 628 # Does errno.h declare errno, or do we have to add a separate declaration
 629 # for it?
 630 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 631 #ifdef HAVE_ERRNO_H
 632 #include <errno.h>
 633 #endif
 634 ])
 635
 636 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 637 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
 638 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 639 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
 640 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
 641 if test $gas_cv_decl_getopt_unistd_h = yes; then
 642   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 643             [Is the prototype for getopt in <unistd.h> in the expected format?])
 644 fi
 645
 646 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 647 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
 648 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 649 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 650 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 651 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 652
 653 dnl This must come last.
 654
 655 dnl We used to make symlinks to files in the source directory, but now
 656 dnl we just use the right name for .c files, and create .h files in
 657 dnl the build directory which include the right .h file.  Make sure
 658 dnl the old symlinks don't exist, so that a reconfigure in an existing
 659 dnl directory behaves reasonably.
 660
 661 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 662 AC_CONFIG_COMMANDS([default],
 663 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 664  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 665  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 666  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 667  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 668  if test "x$cgen_cpu_prefix" != x ; then
 669    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 670  fi
 671
 672  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
 673 [target_cpu_type=${target_cpu_type}
 674  cgen_cpu_prefix=${cgen_cpu_prefix}
 675  obj_format=${obj_format}
 676  te_file=${te_file}])
 677
 678 AC_OUTPUT