gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ISC_POSIX
  13
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  18
  19 AM_PROG_LIBTOOL
  20
  21 user_bfd_gas=
  22 AC_ARG_ENABLE(bfd-assembler,
  23 [  --enable-bfd-assembler  use BFD back end for writing object files],
  24 [case "${enableval}" in
  25   yes) need_bfd=yes user_bfd_gas=yes ;;
  26   no)  user_bfd_gas=no ;;
  27   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(targets,
  30 [    targets            alternative target configurations besides the primary],
  31 [case "${enableval}" in
  32   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  33             ;;
  34   no)       enable_targets= ;;
  35   *)        enable_targets=$enableval ;;
  36 esac])dnl
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 using_cgen=no
  46
  47 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  48 AC_ARG_ENABLE(build-warnings,
  49 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  50 [case "${enableval}" in
  51   yes)  ;;
  52   no)   build_warnings="-w";;
  53   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  54         build_warnings="${build_warnings} ${t}";;
  55   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  56         build_warnings="${t} ${build_warnings}";;
  57   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  58 esac
  59 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  60   echo "Setting warning flags = $build_warnings" 6>&1
  61 fi])dnl
  62 WARN_CFLAGS=""
  63 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  64     WARN_CFLAGS="${build_warnings}"
  65 fi
  66 AC_SUBST(WARN_CFLAGS)
  67
  68 # Generate a header file
  69 AM_CONFIG_HEADER(config.h:config.in)
  70
  71 # If we are on a DOS filesystem, we must use gdb.ini rather than
  72 # .gdbinit.
  73 GDBINIT=".gdbinit"
  74 case "${host}" in
  75   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
  76     GDBINIT="gdb.ini"
  77     ;;
  78 esac
  79 AC_SUBST(GDBINIT)
  80
  81 te_file=generic
  82
  83 # Makefile target for installing gas in $(tooldir)/bin.
  84 install_tooldir=install-exec-tooldir
  85
  86 canon_targets=""
  87 all_targets=no
  88 if test -n "$enable_targets" ; then
  89   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  90     if test $t = "all"; then
  91       all_targets=yes
  92       continue
  93     fi
  94     result=`$ac_config_sub $t 2>/dev/null`
  95     if test -n "$result" ; then
  96       canon_targets="$canon_targets $result"
  97 #    else
  98 #      # Permit "all", etc.  We don't support it yet though.
  99 #      canon_targets="$canon_targets $t"
 100     fi
 101   done
 102   GAS_UNIQ(canon_targets)
 103 fi
 104
 105 emulations=""
 106
 107 for this_target in $target $canon_targets ; do
 108
 109 changequote(,)dnl
 110     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 111 changequote([,])dnl
 112
 113     # check for architecture variants
 114     arch=
 115     endian=
 116     case ${cpu} in
 117       alpha*)           cpu_type=alpha ;;
 118       armeb)            cpu_type=arm endian=big ;;
 119       arm*)             cpu_type=arm endian=little ;;
 120       armb*)            cpu_type=arm endian=little ;;
 121       armv*l)           cpu_type=arm endian=little ;;
 122       armv*b)           cpu_type=arm endian=big ;;
 123       xscale*)          cpu_type=arm endian=little ;;
 124       strongarm*)       cpu_type=arm endian=little ;;
 125       thumb*)           cpu_type=arm endian=little ;;
 126       hppa*)            cpu_type=hppa ;;
 127 changequote(,)dnl
 128       i[3456]86)        cpu_type=i386 arch=i386;;
 129       x86_64)           cpu_type=i386 arch=x86_64;;
 130       ia64)             cpu_type=ia64 ;;
 131       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 132       m680[012346]0)    cpu_type=m68k ;;
 133 changequote([,])dnl
 134       m68008)           cpu_type=m68k ;;
 135       m683??)           cpu_type=m68k ;;
 136       m5200)            cpu_type=m68k ;;
 137       m8*)              cpu_type=m88k ;;
 138       mips*el)          cpu_type=mips endian=little ;;
 139       mips*)            cpu_type=mips endian=big ;;
 140       pjl*)             cpu_type=pj endian=little ;;
 141       pj*)              cpu_type=pj endian=big ;;
 142       powerpc*le*)      cpu_type=ppc endian=little ;;
 143       powerpc*)         cpu_type=ppc endian=big ;;
 144       rs6000*)          cpu_type=ppc ;;
 145       s390x*)           cpu_type=s390 arch=s390x ;;
 146       s390*)            cpu_type=s390 arch=s390 ;;
 147       sh*)              cpu_type=sh endian=big ;;
 148       sparclite*)       cpu_type=sparc arch=sparclite ;;
 149       sparclet*)        cpu_type=sparc arch=sparclet ;;
 150       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 151       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 152       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 153       v850*)            cpu_type=v850 ;;
 154       *)                cpu_type=${cpu} ;;
 155     esac
 156
 157     if test ${this_target} = $target ; then
 158       target_cpu_type=${cpu_type}
 159     elif test ${target_cpu_type} != ${cpu_type} ; then
 160       continue
 161     fi
 162
 163     generic_target=${cpu_type}-$vendor-$os
 164     dev=no
 165     bfd_gas=no
 166     em=generic
 167     mips_stabs_elf=
 168
 169     # assign object format
 170     case ${generic_target} in
 171       a29k-*-coff)          fmt=coff ;;
 172       a29k-amd-udi)         fmt=coff ;;
 173       a29k-amd-ebmon)       fmt=coff ;;
 174       a29k-nyu-sym1)        fmt=coff ;;
 175       a29k-*-rtems*)        fmt=coff ;;
 176       a29k-*-vxworks*)      fmt=coff ;;
 177
 178       alpha*-*-*vms*)       fmt=evax ;;
 179       alpha*-*-netware*)    fmt=ecoff ;;
 180       alpha*-*-openbsd*)    fmt=ecoff ;;
 181       alpha*-*-osf*)        fmt=ecoff ;;
 182       alpha*-*-linuxecoff*) fmt=ecoff ;;
 183       alpha*-*-linux-gnu*)  fmt=elf em=linux ;;
 184       alpha*-*-netbsd*)     fmt=elf em=nbsd ;;
 185
 186       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 187
 188       arm-*-aout)                       fmt=aout ;;
 189       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 190       arm-*-rtems | thumb-*-rtems)      fmt=elf ;;
 191       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 192       arm*-*-conix*)                    fmt=elf ;;
 193       arm-*-linux*aout*)                fmt=aout em=linux ;;
 194       arm*-*-linux-gnu* | arm*-*-uclinux*)
 195                                         fmt=elf  em=linux ;;
 196       arm-*-netbsd* | arm-*-openbsd*)   fmt=aout em=nbsd ;;
 197       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 198       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 199       arm-*-wince)                      fmt=coff em=wince-pe ;;
 200       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 201       arm-*-riscix*)                    fmt=aout em=riscix ;;
 202       arm-*-vxworks)                    fmt=coff ;;
 203
 204       avr-*-*)              fmt=elf bfd_gas=yes ;;
 205
 206       cris-*-*)             fmt=multi bfd_gas=yes ;;
 207
 208       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 209       d30v-*-*)             fmt=elf bfd_gas=yes ;;
 210
 211
 212       fr30-*-*)             fmt=elf bfd_gas=yes ;;
 213
 214       hppa-*-linux-gnu*)    case ${cpu} in
 215                                 hppa*64*)
 216                                         fmt=elf em=hppalinux64;;
 217                                 hppa*)
 218                                         fmt=elf em=linux;;
 219                             esac ;;
 220       hppa-*-*elf*)         fmt=elf em=hppa ;;
 221       hppa-*-lites*)        fmt=elf em=hppa ;;
 222       hppa-*-osf*)          fmt=som em=hppa ;;
 223       hppa-*-rtems*)        fmt=elf em=hppa ;;
 224       hppa-*-hpux11*)       case ${cpu} in
 225                                 hppa*64*)
 226                                         fmt=elf em=hppa64 ;;
 227                                 hppa*)
 228                                         fmt=som em=hppa ;;
 229                             esac ;;
 230       hppa-*-hpux*)         fmt=som em=hppa ;;
 231       hppa-*-mpeix*)        fmt=som em=hppa ;;
 232       hppa-*-bsd*)          fmt=som em=hppa ;;
 233       hppa-*-hiux*)         fmt=som em=hppa ;;
 234
 235       h8300-*-rtems*)       fmt=coff ;;
 236       h8300-*-coff)         fmt=coff ;;
 237       h8300-*-elf)          fmt=elf ;;
 238       h8500-*-rtems*)       fmt=coff ;;
 239       h8500-*-coff)         fmt=coff ;;
 240
 241       i370-*-elf* | i370-*-linux*) fmt=elf ;;
 242       i386-ibm-aix*)        fmt=coff em=i386aix ;;
 243       i386-sequent-bsd*)    fmt=aout em=dynix bfd_gas=yes ;;
 244       i386-*-beospe*)       fmt=coff em=pe bfd_gas=yes ;;
 245       i386-*-beoself* | i386-*-beos*) fmt=elf bfd_gas=yes ;;
 246       i386-*-bsd*)          fmt=aout em=386bsd ;;
 247       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 248       i386-*-netbsdelf*)    fmt=elf em=nbsd bfd_gas=yes ;;
 249       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 250       i386-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes;;
 251       i386-*-linux*aout* | i386-*-linux*oldld)   fmt=aout em=linux ;;
 252       i386-*-linux*coff*)   fmt=coff em=linux ;;
 253       i386-*-linux-gnu*)    fmt=elf em=linux bfd_gas=yes ;;
 254       x86_64-*-linux-gnu*)  fmt=elf em=linux bfd_gas=yes ;;
 255       i386-*-lynxos*)       fmt=coff em=lynx ;;
 256 changequote(,)dnl
 257       i386-*-sysv[45]* | i386-*-solaris* | i386-*-elf)
 258                             fmt=elf bfd_gas=yes ;;
 259       i386-*-freebsdaout* | i386-*-freebsd[12].* | i386-*-freebsd[12])
 260                             fmt=aout em=386bsd ;;
 261 changequote([,])dnl
 262       i386-*-coff | i386-*-sysv* | i386-*-sco3.2v5*coff | i386-*-isc*)
 263                           fmt=coff ;;
 264       i386-*-sco3.2v5*)      fmt=elf
 265                             if test ${this_target} = $target; then
 266                                 AC_DEFINE(SCO_ELF, 1,
 267                                     [Define if defaulting to ELF on SCO 5.])
 268                             fi
 269                             ;;
 270       i386-*-sco3.2*)       fmt=coff ;;
 271       i386-*-vsta)          fmt=aout ;;
 272       i386-*-msdosdjgpp* | i386-*-go32* | i386-go32-rtems*)
 273                             fmt=coff em=go32 bfd_gas=yes
 274                             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 275                             ;;
 276       i386-*-rtemself*)     fmt=elf ;;
 277       i386-*-rtemscoff*)    fmt=coff ;;
 278       i386-*-rtems*)        fmt=elf ;;
 279       i386-*-gnu*)          fmt=elf ;;
 280       i386-*-mach*)
 281                             fmt=aout em=mach bfd_gas=yes ;;
 282       i386-*-msdos*)        fmt=aout ;;
 283       i386-*-moss*)         fmt=elf ;;
 284       i386-*-pe)            fmt=coff em=pe bfd_gas=yes ;;
 285       i386-*-cygwin*)       fmt=coff em=pe bfd_gas=yes ;;
 286       i386-*-interix*)      fmt=coff em=interix bfd_gas=yes ;;
 287       i386-*-mingw32*)      fmt=coff em=pe bfd_gas=yes ;;
 288       i386-*-*nt*)          fmt=coff em=pe bfd_gas=yes ;;
 289       i386-*-vxworks*)      fmt=aout ;;
 290       i386-*-chaos)         fmt=elf ;;
 291       i860-stardent-sysv4* | i860-stardent-elf*)
 292                             fmt=elf bfd_gas=yes endian=little
 293                             AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 294       i960-*-bout)          fmt=bout ;;
 295       i960-*-coff)          fmt=coff em=ic960 ;;
 296       i960-*-rtems*)        fmt=coff em=ic960 ;;
 297       i960-*-nindy*)        fmt=bout ;;
 298       i960-*-vxworks4*)     fmt=bout ;;
 299       i960-*-vxworks5.0)    fmt=bout ;;
 300       i960-*-vxworks5.*)    fmt=coff em=ic960 ;;
 301       i960-*-vxworks*)      fmt=bout ;;
 302       i960-*-elf*)          fmt=elf ;;
 303
 304       ia64-*-elf*)          fmt=elf ;;
 305       ia64-*-aix*)          fmt=elf em=ia64aix ;;
 306       ia64-*-linux-gnu*)    fmt=elf em=linux ;;
 307       ia64-*-hpux*)         fmt=elf em=hpux ;;
 308
 309       m32r-*-*)             fmt=elf bfd_gas=yes ;;
 310
 311       m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)fmt=elf bfd_gas=yes ;;
 312
 313       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 314                             fmt=aout em=sun3 ;;
 315       m68k-motorola-sysv*)  fmt=coff em=delta ;;
 316       m68k-bull-sysv3*)     fmt=coff em=dpx2 ;;
 317       m68k-apollo-*)        fmt=coff em=apollo ;;
 318       m68k-*-sysv4*) # must be before -sysv*
 319                             fmt=elf em=svr4 ;;
 320       m68k-*-elf*)          fmt=elf ;;
 321       m68k-*-coff | m68k-*-sysv* | m68k-*-rtemscoff*)
 322                             fmt=coff ;;
 323       m68k-*-rtems*)        fmt=elf ;;
 324       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 325       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 326       m68k-*-linux-gnu*)    fmt=elf em=linux ;;
 327       m68k-*-gnu*)          fmt=elf ;;
 328       m68k-*-lynxos*)       fmt=coff em=lynx ;;
 329       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 330       m68k-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 331       m68k-apple-aux*)      fmt=coff em=aux ;;
 332       m68k-*-psos*)         fmt=elf em=psos;;
 333
 334       m88k-motorola-sysv3*) fmt=coff em=delt88 ;;
 335       m88k-*-coff*)         fmt=coff ;;
 336
 337       mcore-*-elf)          fmt=elf bfd_gas=yes ;;
 338       mcore-*-pe)           fmt=coff em=pe bfd_gas=yes ;;
 339
 340       # don't change em like *-*-bsd does
 341       mips-dec-netbsd*)     fmt=elf endian=little ;;
 342       mips-dec-openbsd*)    fmt=elf endian=little ;;
 343       mips-dec-bsd*)        fmt=aout endian=little ;;
 344       mips-sony-bsd*)       fmt=ecoff ;;
 345       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 346       mips-*-ultrix*)       fmt=ecoff endian=little ;;
 347       mips-*-osf*)          fmt=ecoff endian=little ;;
 348       mips-*-ecoff*)        fmt=ecoff ;;
 349       mips-*-pe*)           fmt=coff endian=little em=pe ;;
 350       mips-*-irix6*)        fmt=elf ;;
 351       mips-*-irix5*)        fmt=elf ;;
 352       mips-*-irix*)         fmt=ecoff ;;
 353       mips-*-lnews*)        fmt=ecoff em=lnews ;;
 354       mips-*-riscos*)       fmt=ecoff ;;
 355       mips*-*-linux*)       fmt=elf em=tmips mips_stabs_elf=y ;;
 356       mips-*-sysv4*MP* | mips-*-gnu*)
 357                             fmt=elf em=tmips ;;
 358       mips-*-sysv*)         fmt=ecoff ;;
 359       mips-*-elf* | mips-*-rtems* | mips-*-openbsd*)
 360                             fmt=elf ;;
 361       mips-*-vxworks*)      fmt=elf mips_stabs_elf=y ;;
 362       mmix-*-*)             fmt=elf bfd_gas=yes ;;
 363       mn10200-*-*)          fmt=elf bfd_gas=yes ;;
 364       mn10300-*-*)          fmt=elf bfd_gas=yes ;;
 365       openrisc-*-*)         fmt=elf bfd_gas=yes ;;
 366       pj*)                  fmt=elf ;;
 367       ppc-*-pe | ppc-*-cygwin* | ppc-*-winnt*)
 368                             fmt=coff em=pe ;;
 369       ppc-*-aix*)           fmt=coff ;;
 370       ppc-*-beos*)          fmt=coff ;;
 371       ppc-*-*bsd* | ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 372                             fmt=elf ;;
 373       ppc-*-linux-gnu*)     fmt=elf
 374                             case "$endian" in
 375                             big)  ;;
 376                             *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 377                             esac
 378                             ;;
 379       ppc-*-solaris*)       fmt=elf
 380                             if test ${this_target} = $target; then
 381                                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 382                                 [Define if default target is PowerPC Solaris.])
 383                             fi
 384                             if test x${endian} = xbig; then
 385                                 AC_MSG_ERROR(Solaris must be configured little endian)
 386                             fi
 387                             ;;
 388       ppc-*-rtems*)         fmt=elf ;;
 389       ppc-*-macos* | ppc-*-mpw*)
 390                             fmt=coff em=macos ;;
 391       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 392       ppc-*-vxworks*)       fmt=elf ;;
 393
 394       s390x-*-linux-gnu*)   fmt=elf em=linux ;;
 395       s390-*-linux-gnu*)    fmt=elf em=linux ;;
 396
 397       sh-*-linux*)          fmt=elf em=linux ;;
 398       sh-*-elf*)            fmt=elf ;;
 399       sh-*-coff*)           fmt=coff bfd_gas=yes;;
 400       sh-*-pe*)             fmt=coff em=pe bfd_gas=yes endian=little ;;
 401       sh-*-rtemself*)       fmt=elf ;;
 402       sh-*-rtems*)          fmt=coff bfd_gas=yes;;
 403
 404       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 405       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 406       ns32k-pc532-openbsd*) fmt=aout em=nbsd532 ;;
 407
 408       sparc-*-rtemsaout*)   fmt=aout ;;
 409       sparc-*-rtemself*)    fmt=elf ;;
 410       sparc-*-rtems*)       fmt=elf ;;
 411       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 412       sparc-*-aout | sparc*-*-vxworks*)
 413                             fmt=aout em=sparcaout ;;
 414       sparc-*-coff)         fmt=coff ;;
 415       sparc-*-linux*aout*)  fmt=aout em=linux ;;
 416       sparc-*-linux-gnu*)   fmt=elf em=linux ;;
 417       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 418       sparc-fujitsu-none)   fmt=aout ;;
 419       sparc-*-elf | sparc-*-sysv4* | sparc-*-solaris*)
 420                             fmt=elf ;;
 421       sparc-*-netbsd*)      em=nbsd bfd_gas=yes
 422                             case ${cpu} in
 423                                 sparc) case ${os} in
 424                                            *elf*) fmt=elf ;;
 425                                            *)     fmt=aout ;;
 426                                        esac ;;
 427                                 sparc64) fmt=elf ;;
 428                             esac
 429                             ;;
 430       sparc-*-openbsd*)     fmt=aout em=nbsd ;;
 431
 432       strongarm-*-coff)     fmt=coff ;;
 433       strongarm-*-elf)      fmt=elf ;;
 434       xscale-*-coff)     fmt=coff ;;
 435       xscale-*-elf)      fmt=elf ;;
 436
 437       tic30-*-*aout*)       fmt=aout bfd_gas=yes ;;
 438       tic30-*-*coff*)       fmt=coff bfd_gas=yes ;;
 439       tic54x-*-* | c54x*-*-*)
 440                             fmt=coff bfd_gas=yes need_libm=yes;;
 441       tic80-*-*)            fmt=coff ;;
 442
 443       v850-*-*)             fmt=elf bfd_gas=yes ;;
 444       v850e-*-*)            fmt=elf bfd_gas=yes ;;
 445       v850ea-*-*)           fmt=elf bfd_gas=yes ;;
 446
 447       vax-*-bsd* | vax-*-ultrix*)
 448                             fmt=aout ;;
 449       vax-*-vms)            fmt=vms ;;
 450
 451
 452       z8k-*-coff | z8k-*-sim)
 453                             fmt=coff ;;
 454
 455       w65-*-*)              fmt=coff ;;
 456
 457       *-*-aout | *-*-scout)
 458                             fmt=aout ;;
 459       *-*-freebsd*)         fmt=elf em=freebsd bfd_gas=yes ;;
 460       *-*-nindy*)
 461                             fmt=bout ;;
 462       *-*-bsd*)
 463                             fmt=aout em=sun3 ;;
 464       *-*-generic)          fmt=generic ;;
 465       *-*-xray | *-*-hms)   fmt=coff ;;
 466       *-*-sim)              fmt=coff ;;
 467       *-*-elf | *-*-sysv4* | *-*-solaris*)
 468                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 469                             fmt=elf dev=yes ;;
 470       *-*-vxworks)          fmt=aout ;;
 471       *-*-netware)          fmt=elf ;;
 472     esac
 473
 474     if test ${this_target} = $target ; then
 475       endian_def=
 476       if test x${endian} = xbig; then
 477         endian_def=1
 478       elif test x${endian} = xlittle; then
 479         endian_def=0
 480       fi
 481       if test x${endian_def} != x; then
 482         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 483                            [Define as 1 if big endian.])
 484       fi
 485     fi
 486
 487     if test x${mips_stabs_elf} != x; then
 488       AC_DEFINE(MIPS_STABS_ELF, 1,
 489                 [Use ELF stabs for MIPS, not ECOFF stabs])
 490     fi
 491
 492     case ${cpu_type}-${fmt} in
 493       alpha*-*) bfd_gas=yes ;;
 494       arm-*)    bfd_gas=yes ;;
 495     # not yet
 496     # i386-aout)        bfd_gas=preferred ;;
 497       ia64*-*)  bfd_gas=yes ;;
 498       mips-*)   bfd_gas=yes ;;
 499       ns32k-*)  bfd_gas=yes ;;
 500       pdp11-*)  bfd_gas=yes ;;
 501       ppc-*)    bfd_gas=yes ;;
 502       sparc-*)  bfd_gas=yes ;;
 503       strongarm-*)      bfd_gas=yes ;;
 504       xscale-*) bfd_gas=yes ;;
 505       *-elf)    bfd_gas=yes ;;
 506       *-ecoff)  bfd_gas=yes ;;
 507       *-som)    bfd_gas=yes ;;
 508     #enable bfd for coff and aout to allow testing if a bfd target is
 509     #the primary target, but not for coff or aout as the primary target
 510       i386-coff)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 511       i386-aout)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 512       *)                ;;
 513     esac
 514
 515 # Other random stuff.
 516
 517     # Do we need the opcodes library?
 518     case ${cpu_type} in
 519       vax | i386 | tic30)
 520         ;;
 521
 522       *)
 523         need_opcodes=yes
 524
 525         case "${enable_shared}" in
 526         yes) shared_opcodes=true ;;
 527         *opcodes*) shared_opcodes=true ;;
 528         *) shared_opcodes=false ;;
 529         esac
 530         if test "${shared_opcodes}" = "true"; then
 531           # A shared libopcodes must be linked against libbfd.
 532           need_bfd=yes
 533         fi
 534         ;;
 535     esac
 536
 537     # Any other special object files needed ?
 538     case ${cpu_type} in
 539       fr30 | m32r | openrisc)
 540         using_cgen=yes
 541         ;;
 542
 543       m68k)
 544         case ${extra_objects} in
 545         *m68k-parse.o*) ;;
 546         *) extra_objects="$extra_objects m68k-parse.o" ;;
 547         esac
 548         ;;
 549
 550       mips)
 551         echo ${extra_objects} | grep -s "itbl-parse.o"
 552         if test $? -ne 0 ; then
 553           extra_objects="$extra_objects itbl-parse.o"
 554         fi
 555
 556         echo ${extra_objects} | grep -s "itbl-lex.o"
 557         if test $? -ne 0 ; then
 558           extra_objects="$extra_objects itbl-lex.o"
 559         fi
 560
 561         echo ${extra_objects} | grep -s "itbl-ops.o"
 562         if test $? -ne 0 ; then
 563           extra_objects="$extra_objects itbl-ops.o"
 564         fi
 565         ;;
 566
 567       i386 | s390 | sparc)
 568         if test $this_target = $target ; then
 569           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 570         fi
 571         ;;
 572       *)
 573         ;;
 574     esac
 575
 576     if test $using_cgen = yes ; then
 577         case "x${extra_objects}" in
 578         *cgen.o*) ;;
 579         *) extra_objects="$extra_objects cgen.o" ;;
 580         esac
 581     fi
 582
 583 # See if we really can support this configuration with the emulation code.
 584
 585     if test $this_target = $target ; then
 586       primary_bfd_gas=$bfd_gas
 587       obj_format=$fmt
 588       te_file=$em
 589
 590       if test $bfd_gas = no ; then
 591         # Can't support other configurations this way.
 592         break
 593       fi
 594     elif test $bfd_gas = no ; then
 595       # Can't support this configuration.
 596       break
 597     fi
 598
 599 # From target name and format, produce a list of supported emulations.
 600
 601     case ${generic_target}-${fmt} in
 602       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 603       mips*-*-linux*-*) case "$endian" in
 604                         big)    emulation="mipsbelf mipslelf mipself" ;;
 605                         *)      emulation="mipslelf mipsbelf mipself" ;;
 606                         esac ;;
 607       mips-*-lnews*-ecoff) ;;
 608       mips-*-*-ecoff)   case "$endian" in
 609                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 610                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 611                         esac ;;
 612       mips-*-*-elf)     case "$endian" in
 613                         big)    emulation="mipsbelf mipslelf mipself" ;;
 614                         *)      emulation="mipslelf mipsbelf mipself" ;;
 615                         esac ;;
 616       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 617       # i386-pc-pe-coff != i386-pc-coff.
 618       i386-*-pe-coff)   ;;
 619       # Uncommenting the next line will turn on support for i386 AOUT
 620       # for the default linux configuration
 621       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 622       #
 623       i386-*-aout)      emulation="i386aout" ;;
 624       i386-*-coff)      emulation="i386coff" ;;
 625       i386-*-elf)       emulation="i386elf" ;;
 626
 627       # Always all formats.  The first stated emulation becomes the default.
 628       cris-*-*aout*)    emulation="crisaout criself" ;;
 629       cris-*-*)         emulation="criself crisaout" ;;
 630     esac
 631
 632     emulations="$emulations $emulation"
 633
 634 done
 635
 636 # Turn on all targets if possible
 637 if test ${all_targets} = "yes"; then
 638   case ${target_cpu_type} in
 639   i386)
 640     case ${obj_format} in
 641     aout)
 642       emulations="$emulations i386coff i386elf"
 643       ;;
 644     coff)
 645       emulations="$emulations i386aout i386elf"
 646     ;;
 647     elf)
 648       emulations="$emulations i386aout i386coff"
 649       ;;
 650     esac
 651   ;;
 652   esac
 653 fi
 654
 655 # Assign floating point type.  Most processors with FP support
 656 # IEEE FP.  On those that don't support FP at all, usually IEEE
 657 # is emulated.
 658 case ${target_cpu} in
 659   vax | tahoe ) atof=${target_cpu} ;;
 660   pdp11)        atof=vax ;;
 661   *)            atof=ieee ;;
 662 esac
 663
 664 case "${obj_format}" in
 665   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 666 esac
 667
 668 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 669 cgen_cpu_prefix=""
 670 if test $using_cgen = yes ; then
 671   case ${target_cpu} in
 672     *) cgen_cpu_prefix=${target_cpu} ;;
 673   esac
 674   AC_SUBST(cgen_cpu_prefix)
 675   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 676 fi
 677
 678 dnl
 679 dnl Make sure the desired support files exist.
 680 dnl
 681
 682 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 683   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 684 fi
 685
 686 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 687   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 688 fi
 689
 690 case ${user_bfd_gas}-${primary_bfd_gas} in
 691   yes-yes | no-no)
 692     # We didn't override user's choice.
 693     ;;
 694   no-yes)
 695     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 696     ;;
 697   no-preferred)
 698     primary_bfd_gas=no
 699     ;;
 700   *-preferred)
 701     primary_bfd_gas=yes
 702     ;;
 703   yes-*)
 704     primary_bfd_gas=yes
 705     ;;
 706   -*)
 707     # User specified nothing.
 708     ;;
 709 esac
 710
 711 # Some COFF configurations want these random other flags set.
 712 case ${obj_format} in
 713   coff)
 714     case ${target_cpu_type} in
 715       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 716       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 717       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 718     esac
 719     ;;
 720 esac
 721
 722 # Getting this done right is going to be a bitch.  Each configuration specified
 723 # with --enable-targets=... should be checked for environment, format, cpu, and
 724 # bfd_gas setting.
 725 #
 726 # For each configuration, the necessary object file support code must be linked
 727 # in.  This might be only one, it might be up to four.  The necessary emulation
 728 # code needs to be provided, too.
 729 #
 730 # And then there's "--enable-targets=all"....
 731 #
 732 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 733
 734 formats="${obj_format}"
 735 emfiles=""
 736 EMULATIONS=""
 737 GAS_UNIQ(emulations)
 738 for em in . $emulations ; do
 739   case $em in
 740     .)  continue ;;
 741     mipsbelf | mipslelf | mipself)
 742         fmt=elf   file=mipself ;;
 743     mipsbecoff | mipslecoff | mipsecoff)
 744         fmt=ecoff file=mipsecoff ;;
 745     *coff)
 746         fmt=coff  file=$em ;;
 747     *aout)
 748         fmt=aout file=$em ;;
 749     *elf)
 750         fmt=elf file=$em ;;
 751   esac
 752   formats="$formats $fmt"
 753   emfiles="$emfiles e-$file.o"
 754   EMULATIONS="$EMULATIONS &$em,"
 755 done
 756 GAS_UNIQ(formats)
 757 GAS_UNIQ(emfiles)
 758 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 759   for fmt in $formats ; do
 760     case $fmt in
 761       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 762       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 763       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 764       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 765       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 766       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 767       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 768       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 769       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 770       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 771     esac
 772     extra_objects="$extra_objects obj-$fmt.o"
 773   done
 774   obj_format=multi
 775 fi
 776 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 777   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 778   # e-mips* has more than one emulation per file, e-i386* has just one at the
 779   # moment.  If only one emulation is specified, then don't define
 780   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 781   case "${obj_format}${emfiles}" in
 782     multi* | *mips*)
 783       extra_objects="$extra_objects $emfiles"
 784       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 785   esac
 786 fi
 787 AC_SUBST(extra_objects)
 788 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 789 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 790                    [Default emulation.])
 791
 792 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 793   yes-*-coff)   need_bfd=yes ;;
 794   no-*-coff)    need_bfd=yes
 795                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 796 esac
 797
 798 reject_dev_configs=yes
 799
 800 case ${reject_dev_configs}-${dev} in
 801   yes-yes) # Oops.
 802     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 803     ;;
 804 esac
 805
 806 AC_SUBST(target_cpu_type)
 807 AC_SUBST(obj_format)
 808 AC_SUBST(te_file)
 809 AC_SUBST(install_tooldir)
 810 AC_SUBST(atof)
 811 dnl AC_SUBST(emulation)
 812
 813 case "${primary_bfd_gas}" in
 814   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 815         need_bfd=yes ;;
 816 esac
 817
 818 # do we need the opcodes library?
 819 case "${need_opcodes}" in
 820 yes)
 821   OPCODES_LIB=../opcodes/libopcodes.la
 822   ;;
 823 esac
 824
 825 case "${need_bfd}" in
 826 yes)
 827   BFDLIB=../bfd/libbfd.la
 828   ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 829   ;;
 830 esac
 831
 832 AC_SUBST(BFDLIB)
 833 AC_SUBST(OPCODES_LIB)
 834
 835 AC_SUBST(ALL_OBJ_DEPS)
 836
 837 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 838 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 839 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 840 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 841 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 842
 843 AC_PROG_CC
 844
 845 AC_PROG_YACC
 846 AM_PROG_LEX
 847
 848 ALL_LINGUAS=
 849 CY_GNU_GETTEXT
 850
 851 AM_MAINTAINER_MODE
 852 AC_EXEEXT
 853
 854 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 855
 856 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 857 # people who are not cross-compiling but are compiling cross-assemblers.
 858 AC_MSG_CHECKING(whether compiling a cross-assembler)
 859 if test "${host}" = "${target}"; then
 860   cross_gas=no
 861 else
 862   cross_gas=yes
 863   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 864 fi
 865 AC_MSG_RESULT($cross_gas)
 866
 867 dnl ansidecl.h will deal with const
 868 dnl AC_CONST
 869 AC_FUNC_ALLOCA
 870 AC_C_INLINE
 871
 872 # VMS doesn't have unlink.
 873 AC_CHECK_FUNCS(unlink remove, break)
 874
 875 # Some systems don't have sbrk().
 876 AC_CHECK_FUNCS(sbrk)
 877
 878 # do we need the math library?
 879 case "${need_libm}" in
 880 yes)
 881   AC_CHECK_LIBM
 882   AC_SUBST(LIBM)
 883   ;;
 884 esac
 885
 886 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 887 # enough, but on some of those systems, the assert macro relies on requoting
 888 # working properly!
 889 GAS_WORKING_ASSERT
 890
 891 # On some systems, the system header files may not declare malloc, realloc,
 892 # and free.  There are places where gas needs these functions to have been
 893 # declared -- such as when taking their addresses.
 894 gas_test_headers="
 895 #ifdef HAVE_MEMORY_H
 896 #include <memory.h>
 897 #endif
 898 #ifdef HAVE_STRING_H
 899 #include <string.h>
 900 #else
 901 #ifdef HAVE_STRINGS_H
 902 #include <strings.h>
 903 #endif
 904 #endif
 905 #ifdef HAVE_STDLIB_H
 906 #include <stdlib.h>
 907 #endif
 908 #ifdef HAVE_UNISTD_H
 909 #include <unistd.h>
 910 #endif
 911 "
 912 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 913 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 914 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 915 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 916 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 917
 918 # Does errno.h declare errno, or do we have to add a separate declaration
 919 # for it?
 920 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 921 #ifdef HAVE_ERRNO_H
 922 #include <errno.h>
 923 #endif
 924 ])
 925
 926 dnl This must come last.
 927
 928 dnl We used to make symlinks to files in the source directory, but now
 929 dnl we just use the right name for .c files, and create .h files in
 930 dnl the build directory which include the right .h file.  Make sure
 931 dnl the old symlinks don't exist, so that a reconfigure in an existing
 932 dnl directory behaves reasonably.
 933
 934 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
 935 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 936  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 937  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 938  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 939  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 940  if test "x$cgen_cpu_prefix" != x ; then
 941    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 942  fi
 943
 944  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
 945 [target_cpu_type=${target_cpu_type}
 946  cgen_cpu_prefix=${cgen_cpu_prefix}
 947  obj_format=${obj_format}
 948  te_file=${te_file}])