gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 AC_PREREQ(2.5)dnl v2.5 needed for --bindir et al
   8 AC_INIT(as.h)dnl
   9 dnl
  10 user_bfd_gas=
  11 AC_ARG_ENABLE(bfd-assembler,
  12 [  --enable-bfd-assembler  use BFD back end for writing object files],
  13 [case "${enableval}" in
  14   yes) need_bfd=yes user_bfd_gas=yes ;;
  15   no)  user_bfd_gas=no ;;
  16   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  17 esac])dnl
  18 AC_ARG_ENABLE(targets,
  19 [    targets            alternative target configurations besides the primary],
  20 [case "${enableval}" in
  21   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  22             ;;
  23   no)       enable_targets= ;;
  24   *)        enable_targets=$enableval ;;
  25 esac])dnl
  26 AC_ARG_ENABLE(shared,
  27 [  --enable-shared         build shared BFD library],
  28 [case "${enableval}" in
  29   yes) shared=true shared_bfd=true shared_opcodes=true ;;
  30   no)  shared=false ;;
  31   *bfd*opcodes*) shared=true shared_bfd=true shared_opcodes=true ;;
  32   *opcodes*bfd*) shared=true shared_bfd=true shared_opcodes=true ;;
  33   *bfd*) shared=true shared_bfd=true ;;
  34   *opcodes*) shared=true shared_opcodes=true ;;
  35   *) shared=false ;;
  36 esac])dnl
  37
  38 # Generate a header file -- gets more post-processing by Makefile later.
  39 AC_CONFIG_HEADER(conf)
  40
  41 dnl For recursion to work right, this must be an absolute pathname.
  42 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  43 AC_CANONICAL_SYSTEM
  44 AC_ARG_PROGRAM
  45
  46 te_file=generic
  47
  48 canon_targets=""
  49 if test -n "$enable_targets" ; then
  50   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  51     result=`$ac_config_sub $t 2>/dev/null`
  52     if test -n "$result" ; then
  53       canon_targets="$canon_targets $result"
  54 #    else
  55 #      # Permit "all", etc.  We don't support it yet though.
  56 #      canon_targets="$canon_targets $t"
  57     fi
  58   done
  59   GAS_UNIQ(canon_targets)
  60 fi
  61
  62 emulations=""
  63
  64 for this_target in $target $canon_targets ; do
  65
  66     eval `echo $this_target | sed 's/^\(.*\)-\(.*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
  67
  68     # check for architecture variants
  69     case ${cpu} in
  70       armeb)            cpu_type=arm endian=big ;;
  71       arm*)             cpu_type=arm endian=little ;;
  72       hppa*)            cpu_type=hppa ;;
  73 changequote(,)dnl
  74       i[456]86)         cpu_type=i386 ;;
  75       m680[012346]0)    cpu_type=m68k ;;
  76       m68008)           cpu_type=m68k ;;
  77       m683??)           cpu_type=m68k ;;
  78 changequote([,])dnl
  79       m8*)              cpu_type=m88k ;;
  80       mips*el)          cpu_type=mips endian=little;;
  81       mips*)            cpu_type=mips endian=big ;;
  82       powerpcle*)       cpu_type=ppc endian=little ;;
  83       powerpc*)         cpu_type=ppc endian=big ;;
  84       rs6000*)          cpu_type=ppc ;;
  85       sparc64)          cpu_type=sparc want_sparc_v9=true ;;
  86       sparc*)           cpu_type=sparc ;;
  87       *)                cpu_type=${cpu} ;;
  88     esac
  89
  90     if test ${this_target} = $target ; then
  91       target_cpu_type=${cpu_type}
  92     elif test ${target_cpu_type} != ${cpu_type} ; then
  93       continue
  94     fi
  95
  96     targ=${cpu_type}
  97     generic_target=${cpu_type}-$vendor-$os
  98     dev=no
  99     bfd_gas=no
 100     em=generic
 101
 102     # assign object format
 103     case ${generic_target} in
 104       a29k-*-coff)          fmt=coff targ=ebmon29k ;;
 105       a29k-amd-udi)         fmt=coff targ=ebmon29k ;;
 106       a29k-amd-ebmon)       fmt=coff targ=ebmon29k ;;
 107       a29k-nyu-sym1)        fmt=coff targ=ebmon29k ;;
 108       a29k-*-vxworks*)      fmt=coff ;;
 109
 110       alpha-*-netware*)     fmt=ecoff ;;
 111       alpha-*-osf*)         fmt=ecoff ;;
 112       alpha-*-linuxecoff*)  fmt=ecoff ;;
 113       alpha-*-linux*)       fmt=elf em=linux ;;
 114
 115 # start-sanitize-arc
 116       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 117 # end-sanitize-arc
 118
 119       arm-*-riscix*)        fmt=aout targ=arm-lit ;;
 120       arm-*-aout)           fmt=aout
 121                             case "$endian" in
 122                               big)      targ=arm-big ;;
 123                               *)        targ=arm-lit ;;
 124                             esac
 125                             ;;
 126       arm-*-coff)           fmt=coff ;;
 127       arm-*-riscix*)        fmt=aout ;;
 128       arm-*-pe)             fmt=coff targ=armcoff em=pe ;;
 129
 130       hppa-*-*elf*)         fmt=elf em=hppa ;;
 131       hppa-*-lites*)        fmt=elf em=hppa ;;
 132       hppa-*-osf*)          fmt=som em=hppa ;;
 133       hppa-*-hpux*)         fmt=som em=hppa ;;
 134       hppa-*-bsd*)          fmt=som em=hppa ;;
 135       hppa-*-hiux*)         fmt=som em=hppa ;;
 136
 137       h8300-*-coff)         fmt=coff ;;
 138
 139       i386-ibm-aix*)        fmt=coff targ=i386coff
 140                              em=i386aix ;;
 141       i386-*-bsd*)          fmt=aout em=386bsd ;;
 142       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 143       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 144       i386-*-linux*aout* | i386-*-linuxoldld)   fmt=aout em=linux ;;
 145       i386-*-linux*coff*)   fmt=coff em=linux
 146                              targ=i386coff ;;
 147       i386-*-linux*)        fmt=elf em=linux ;;
 148       i386-*-lynxos*)       fmt=coff targ=i386coff
 149                              em=lynx ;;
 150       i386-*-sysv4* | i386-*-solaris* | i386-*-elf | i386-*-freebsdelf*)
 151                             fmt=elf ;;
 152       i386-*-sco*elf*)      fmt=elf targ=sco5 ;;
 153       i386-*-coff | i386-*-sysv* | i386-*-sco* | i386-*-isc*)
 154                             fmt=coff targ=i386coff ;;
 155       i386-*-vsta)          fmt=aout ;;
 156       i386-*-go32)          fmt=coff targ=i386coff ;;
 157       i386-*-rtems*)        fmt=coff targ=i386coff ;;
 158       i386-*-gnu*)          fmt=elf ;;
 159       i386-*-mach*)
 160                             fmt=aout em=mach bfd_gas=yes ;;
 161       i386-*-msdos*)        fmt=aout ;;
 162       i386-*-moss*)         fmt=elf ;;
 163       i386-*-pe)            fmt=coff targ=i386coff em=pe ;;
 164       i386-*-cygwin32)      fmt=coff targ=i386coff em=pe ;;
 165       i386-*-*nt)           fmt=coff targ=i386coff em=pe ;;
 166       i960-*-bout)          fmt=bout ;;
 167       i960-*-coff)          fmt=coff em=ic960 targ=ic960coff ;;
 168       i960-*-rtems*)        fmt=coff em=ic960 targ=ic960coff ;;
 169       i960-*-nindy*)        fmt=bout ;;
 170       i960-*-vxworks4*)     fmt=bout ;;
 171       i960-*-vxworks5.0)    fmt=bout ;;
 172       i960-*-vxworks5.*)    fmt=coff em=ic960 targ=ic960coff ;;
 173       i960-*-vxworks*)      fmt=bout ;;
 174
 175       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 176                             fmt=aout em=sun3 ;;
 177       m68k-motorola-sysv*)  fmt=coff targ=m68kcoff em=delta ;;
 178       m68k-bull-sysv3*)     fmt=coff targ=m68kcoff em=dpx2 ;;
 179       m68k-apollo-*)        fmt=coff targ=apollo em=apollo ;;
 180       m68k-*-sysv4 | m68k-*-elf) # must be before -sysv*
 181                             fmt=elf ;;
 182       m68k-*-coff | m68k-*-sysv* | m68k-*-rtems*)
 183                             fmt=coff targ=m68kcoff ;;
 184       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 185       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 186       m68k-*-linux*)        fmt=elf em=linux ;;
 187       m68k-*-lynxos*)       fmt=coff targ=m68kcoff
 188                              em=lynx ;;
 189       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 190       m68k-apple-aux*)      fmt=coff targ=m68kcoff em=aux ;;
 191       m68k-*-psos*)         fmt=elf em=psos;;
 192
 193       m88k-motorola-sysv3*) fmt=coff targ=m88kcoff em=delt88 ;;
 194       m88k-*-coff*)         fmt=coff targ=m88kcoff ;;
 195
 196       # don't change em like *-*-bsd does
 197       mips-dec-netbsd*)     fmt=elf targ=mips-lit endian=little ;;
 198       mips-dec-bsd*)        fmt=aout targ=mips-lit ;;
 199       mips-sony-bsd*)       fmt=ecoff targ=mips-big ;;
 200       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 201       mips-*-ultrix*)       fmt=ecoff targ=mips-lit endian=little ;;
 202       mips-*-ecoff*)        fmt=ecoff
 203                             case "$endian" in
 204                             big) targ=mips-big ;;
 205                             *)   targ=mips-lit ;;
 206                             esac
 207                             ;;
 208       mips-*-ecoff*)        fmt=ecoff targ=mips-big ;;
 209       mips-*-gnu*)          fmt=aout
 210                             case "$endian" in
 211                             big) targ=mips-big ;;
 212                             *)   targ=mips-lit ;;
 213                             esac
 214                             ;;
 215       mips-*-irix5*)        fmt=elf targ=mips-big ;;
 216       mips-*-irix*)         fmt=ecoff targ=mips-big ;;
 217       mips-*-riscos*)       fmt=ecoff targ=mips-big ;;
 218       mips-*-sysv*)         fmt=ecoff targ=mips-big ;;
 219       mips-*-elf*)          fmt=elf
 220                             case "$endian" in
 221                             big) targ=mips-big ;;
 222                             *)   targ=mips-lit ;;
 223                             esac
 224                             ;;
 225       ppc-*-pe | ppc-*-cygwin32 | ppc-*-winnt*)
 226                             fmt=coff em=pe
 227                             case "$endian" in
 228                             big) targ=ppc-big ;;
 229                             *)   targ=ppc-lit ;;
 230                             esac
 231                             ;;
 232       ppc-*-aix*)           fmt=coff ;;
 233       ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 234                             fmt=elf
 235                             case "$endian" in
 236                             big)  targ=ppc-big ;;
 237                             *)    targ=ppc-lit ;;
 238                             esac
 239                             ;;
 240       ppc-*-linux*)         fmt=elf
 241                             case "$endian" in
 242                             big)  targ=ppc-big ;;
 243                             *)    AC_MSG_ERROR(Linux must be configured big endian) ;;
 244                             esac
 245                             ;;
 246       ppc-*-solaris*)       fmt=elf
 247                             case "$endian" in
 248                             big)  AC_MSG_ERROR(Solaris must be configured little endian) ;;
 249                             *)    targ=ppc-sol ;;
 250                             esac
 251                             ;;
 252       ppc-*-rtems*)
 253                             fmt=elf
 254                             case "$endian" in
 255                             big)  targ=ppc-big ;;
 256                             *)    targ=ppc-lit ;;
 257                             esac
 258                             ;;
 259       ppc-*-macos* | ppc-*-mpw*)
 260                             fmt=coff em=macos ;;
 261       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 262
 263       sh-*-coff)            fmt=coff ;;
 264
 265       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 266       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 267
 268       sparc-*-rtems*)       fmt=aout ;;
 269       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 270       sparc-*-aout | sparc*-*-vxworks*)
 271                             fmt=aout ;;
 272       sparc-*-coff)         fmt=coff ;;
 273       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 274       sparc-fujitsu-none)   fmt=aout ;;
 275       sparc-*-elf | sparc-*-solaris*)
 276                             fmt=elf ;;
 277       sparc-*-netbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 278
 279       vax-*-bsd* | vax-*-ultrix*)
 280                             fmt=aout ;;
 281       vax-*-vms)            fmt=vms ;;
 282
 283       z8k-*-coff | z8k-*-sim)
 284                             fmt=coff ;;
 285
 286       w65-*-*)              fmt=coff ;;
 287
 288       *-*-aout | *-*-scout)
 289                             fmt=aout ;;
 290       *-*-nindy*)
 291                             fmt=bout ;;
 292       *-*-bsd*)
 293                             fmt=aout em=sun3 ;;
 294       *-*-generic)          fmt=generic ;;
 295       *-*-xray | *-*-hms)   fmt=coff ;;
 296       *-*-sim)              fmt=coff ;;
 297       *-*-elf | *-*-sysv4* | *-*-solaris*)
 298                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 299                             fmt=elf dev=yes ;;
 300       *-*-vxworks)          fmt=aout ;;
 301       *-*-netware)          fmt=elf ;;
 302     esac
 303
 304     case ${cpu_type}-${fmt} in
 305       alpha-*)  bfd_gas=yes ;;
 306       arm-*)    bfd_gas=yes ;;
 307     # not yet
 308     # i386-aout)        bfd_gas=preferred ;;
 309       mips-*)   bfd_gas=yes ;;
 310       ns32k-*)  bfd_gas=yes ;;
 311       ppc-*)    bfd_gas=yes ;;
 312       sparc-*)  bfd_gas=yes ;;
 313       *-elf)    bfd_gas=yes ;;
 314       *-ecoff)  bfd_gas=yes ;;
 315       *-som)    bfd_gas=yes ;;
 316       *)                ;;
 317     esac
 318
 319 # Other random stuff.
 320
 321     # do we need the opcodes library?
 322     case ${cpu_type} in
 323       vax | i386)
 324         ;;
 325       *)
 326         need_opcodes=yes
 327         if test "${shared_opcodes}" = "true"; then
 328           # A shared libopcodes must be linked against libbfd.
 329           need_bfd=yes
 330         fi
 331         ;;
 332     esac
 333
 334     test -n "$want_sparc_v9" && AC_DEFINE(SPARC_V9)
 335
 336     case ${cpu}-${vendor}-${os} in
 337       sparc64-*-elf*) AC_DEFINE(SPARC_ARCH64) ;;
 338     esac
 339
 340     case ${cpu_type} in
 341       m68k)
 342         case ${extra_objects} in
 343         *m68k-parse.o*) ;;
 344         *) extra_objects="$extra_objects m68k-parse.o" ;;
 345         esac
 346         ;;
 347     esac
 348
 349 # See if we really can support this configuration with the emulation code.
 350
 351     if test $this_target = $target ; then
 352       primary_bfd_gas=$bfd_gas
 353       obj_format=$fmt
 354       gas_target=$targ
 355       te_file=$em
 356
 357       if test $bfd_gas = no ; then
 358         # Can't support other configurations this way.
 359         break
 360       fi
 361     elif test $bfd_gas = no ; then
 362       # Can't support this configuration.
 363       break
 364     fi
 365
 366 # From target name and format, produce a list of supported emulations.
 367
 368     case ${generic_target}-${fmt} in
 369       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 370       mips-*-*-ecoff)   case "$endian" in
 371                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 372                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 373                         esac ;;
 374       mips-*-*-elf)     case "$endian" in
 375                         big)    emulation="mipsbelf mipslelf mipself" ;;
 376                         *)      emulation="mipslelf mipsbelf mipself" ;;
 377                         esac ;;
 378     esac
 379
 380     emulations="$emulations $emulation"
 381
 382 done
 383
 384 # Assign floating point type.  Most processors with FP support
 385 # IEEE FP.  On those that don't support FP at all, usually IEEE
 386 # is emulated.
 387 case ${target_cpu} in
 388   vax | tahoe ) atof=${target_cpu} ;;
 389   *)            atof=ieee ;;
 390 esac
 391
 392 case "${obj_format}" in
 393   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 394 esac
 395
 396 dnl
 397 dnl Make sure the desired support files exist.
 398 dnl
 399
 400 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 401   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 402 fi
 403
 404 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 405   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 406 fi
 407
 408 # and target makefile frag
 409
 410 target_frag=${srcdir}/config/${gas_target}.mt
 411 if test ! -r ${target_frag}; then
 412   target_frag=/dev/null # ick! but subst_file can't be conditionalized
 413 fi
 414 AC_SUBST_FILE(target_frag)
 415
 416 case ${user_bfd_gas}-${primary_bfd_gas} in
 417   yes-yes | no-no)
 418     # We didn't override user's choice.
 419     ;;
 420   no-yes)
 421     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 422     ;;
 423   no-preferred)
 424     primary_bfd_gas=no
 425     ;;
 426   *-preferred)
 427     primary_bfd_gas=yes
 428     ;;
 429   yes-*)
 430     primary_bfd_gas=yes
 431     ;;
 432   -*)
 433     # User specified nothing.
 434     ;;
 435 esac
 436
 437 # Some COFF configurations want these random other flags set.
 438 case ${obj_format} in
 439   coff)
 440     case ${target_cpu_type} in
 441       i386) AC_DEFINE(I386COFF) ;;
 442       m68k) AC_DEFINE(M68KCOFF) ;;
 443       m88k) AC_DEFINE(M88KCOFF) ;;
 444     esac
 445     ;;
 446 esac
 447
 448 # Getting this done right is going to be a bitch.  Each configuration specified
 449 # with --enable-targets=... should be checked for environment, format, cpu, and
 450 # bfd_gas setting.
 451 #
 452 # For each configuration, the necessary object file support code must be linked
 453 # in.  This might be only one, it might be up to four.  The necessary emulation
 454 # code needs to be provided, too.
 455 #
 456 # And then there's "--enable-targets=all"....
 457 #
 458 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 459
 460 formats="${obj_format}"
 461 emfiles=""
 462 EMULATIONS=""
 463 GAS_UNIQ(emulations)
 464 for em in . $emulations ; do
 465   case $em in
 466     .)  continue ;;
 467     mipsbelf | mipslelf)
 468         fmt=elf   file=mipself ;;
 469     mipsbecoff | mipslecoff)
 470         fmt=ecoff file=mipsecoff ;;
 471   esac
 472   formats="$formats $fmt"
 473   emfiles="$emfiles e-$file.o"
 474   EMULATIONS="$EMULATIONS &$em,"
 475 done
 476 GAS_UNIQ(formats)
 477 GAS_UNIQ(emfiles)
 478 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 479   for fmt in $formats ; do
 480     case $fmt in
 481       aout)     AC_DEFINE(OBJ_MAYBE_AOUT)    ;;
 482       bout)     AC_DEFINE(OBJ_MAYBE_BOUT)    ;;
 483       coff)     AC_DEFINE(OBJ_MAYBE_COFF)    ;;
 484       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF)   ;;
 485       elf)      AC_DEFINE(OBJ_MAYBE_ELF)     ;;
 486       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC) ;;
 487       hp300)    AC_DEFINE(OBJ_MAYBE_HP300)   ;;
 488       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE)    ;;
 489       som)      AC_DEFINE(OBJ_MAYBE_SOM)     ;;
 490       vms)      AC_DEFINE(OBJ_MAYBE_VMS)     ;;
 491     esac
 492     extra_objects="$extra_objects obj-$fmt.o"
 493   done
 494   obj_format=multi
 495 fi
 496 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 497   te_file=multi
 498   extra_objects="$extra_objects $emfiles"
 499   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 500   AC_DEFINE(USE_EMULATIONS)
 501 fi
 502 AC_SUBST(extra_objects)
 503 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS)
 504 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION")
 505
 506 files="config/tc-${target_cpu_type}.c config/tc-${target_cpu_type}.h \
 507         config/obj-${obj_format}.h config/obj-${obj_format}.c \
 508         config/te-${te_file}.h config/atof-${atof}.c \
 509         $extra_files"
 510 links="targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c \
 511         $extra_links"
 512
 513 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 514   yes-*-coff)   need_bfd=yes ;;
 515   no-*-coff)    need_bfd=yes
 516                 AC_DEFINE(MANY_SEGMENTS) ;;
 517 esac
 518
 519 reject_dev_configs=yes
 520
 521 case ${reject_dev_configs}-${dev} in
 522   yes-yes) # Oops.
 523     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 524     ;;
 525 esac
 526
 527 AC_SUBST(target_cpu_type)
 528 AC_SUBST(obj_format)
 529 AC_SUBST(atof)
 530 dnl AC_SUBST(emulation)
 531
 532 AC_LINK_FILES($files, $links)
 533
 534 case "${primary_bfd_gas}" in
 535   yes)  AC_DEFINE(BFD_ASSEMBLER)
 536         need_bfd=yes ;;
 537 esac
 538
 539 # do we need the opcodes library?
 540 case "${need_opcodes}" in
 541 yes)
 542   OPCODES_DEP=../opcodes/libopcodes.a
 543   OPCODES_LIB='-L../opcodes -lopcodes'
 544
 545   # We need to handle some special cases for shared libraries.
 546   case "${host}" in
 547   *-*-sunos*)
 548     # On SunOS, we must link against the name we are going to install,
 549     # not -lbfd, since SunOS does not support SONAME.
 550     if test "${shared_opcodes}" = "true"; then
 551       OPCODES_LIB='-L../opcodes -l`echo opcodes | sed '"'"'$(program_transform_name)'"'"'`'
 552     fi
 553     ;;
 554   alpha*-*-osf*)
 555     # On Alpha OSF/1, the native linker searches all the -L
 556     # directories for any LIB.so files, and only then searches for any
 557     # LIB.a files.  That means that if there is an installed
 558     # libbfd.so, but this build is not done with --enable-shared, the
 559     # link will wind up being against the install libbfd.so rather
 560     # than the newly built libbfd.  To avoid this, we must explicitly
 561     # link against libbfd.a when --enable-shared is not used.
 562     if test "${shared_opcodes}" != "true"; then
 563       OPCODES_LIB='../opcodes/libopcodes.a'
 564     fi
 565     ;;
 566   esac
 567   ;;
 568 esac
 569 AC_SUBST(OPCODES_DEP)
 570 AC_SUBST(OPCODES_LIB)
 571
 572 case "${need_bfd}" in
 573 yes)
 574   BFDDEP=../bfd/libbfd.a
 575   BFDLIB='-L../bfd -lbfd'
 576   ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 577
 578   # We need to handle some special cases for shared libraries
 579   case "${host}" in
 580   *-*-sunos*)
 581     # On SunOS, we must link against the name we are going to install,
 582     # not -lbfd, since SunOS does not support SONAME.
 583     if test "${shared_bfd}" = "true"; then
 584       BFDLIB='-L../bfd -l`echo bfd | sed '"'"'$(program_transform_name)'"'"'`'
 585     fi
 586     ;;
 587   alpha*-*-osf*)
 588     # On Alpha OSF/1, the native linker searches all the -L
 589     # directories for any LIB.so files, and only then searches for any
 590     # LIB.a files.  That means that if there is an installed
 591     # libbfd.so, but this build is not done with --enable-shared, the
 592     # link will wind up being against the install libbfd.so rather
 593     # than the newly built libbfd.  To avoid this, we must explicitly
 594     # link against libbfd.a when --enable-shared is not used.
 595     if test "${shared_bfd}" != "true"; then
 596       BFDLIB='../bfd/libbfd.a'
 597     fi
 598     ;;
 599   esac
 600   ;;
 601 esac
 602 AC_SUBST(BFDDEP)
 603 AC_SUBST(BFDLIB)
 604 AC_SUBST(ALL_OBJ_DEPS)
 605
 606 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}")
 607 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}")
 608 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}")
 609 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}")
 610 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}")
 611
 612 AC_PROG_CC
 613 AC_PROG_INSTALL
 614
 615 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 616
 617 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 618 # people who are not cross-compiling but are compiling cross-assemblers.
 619 AC_MSG_CHECKING(whether compiling a cross-assembler)
 620 if test "${host}" = "${target}"; then
 621   cross_gas=no
 622 else
 623   cross_gas=yes
 624   AC_DEFINE(CROSS_COMPILE)
 625 fi
 626 AC_MSG_RESULT($cross_gas)
 627
 628 dnl ansidecl.h will deal with const
 629 dnl AC_CONST
 630 AC_FUNC_ALLOCA
 631 AC_C_INLINE
 632
 633 # VMS doesn't have unlink.
 634 AC_CHECK_FUNCS(unlink remove, break)
 635
 636 # Some systems don't have sbrk().
 637 AC_CHECK_FUNCS(sbrk)
 638
 639 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 640 # enough, but on some of those systems, the assert macro relies on requoting
 641 # working properly!
 642 GAS_WORKING_ASSERT
 643
 644 # On some systems, the system header files may not declare malloc, realloc,
 645 # and free.  There are places where gas needs these functions to have been
 646 # declared -- such as when taking their addresses.
 647 gas_test_headers="
 648 #ifdef HAVE_MEMORY_H
 649 #include <memory.h>
 650 #endif
 651 #ifdef HAVE_STRING_H
 652 #include <string.h>
 653 #endif
 654 #ifdef HAVE_STDLIB_H
 655 #include <stdlib.h>
 656 #endif
 657 #ifdef HAVE_UNISTD_H
 658 #include <unistd.h>
 659 #endif
 660 "
 661 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 662 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 663
 664 # Does errno.h declare errno, or do we have to add a separate declaration
 665 # for it?
 666 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 667 #ifdef HAVE_ERRNO_H
 668 #include <errno.h>
 669 #endif
 670 ])
 671
 672 HLDFLAGS=
 673 RPATH_ENVVAR=LD_LIBRARY_PATH
 674 # If we have shared libraries, try to set rpath reasonably.
 675 if test "${shared}" = "true"; then
 676   case "${host}" in
 677   *-*-hpux*)
 678     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 679     RPATH_ENVVAR=SHLIB_PATH
 680     ;;
 681   *-*-irix5*)
 682     HLDFLAGS='-Wl,-rpath,$(libdir)'
 683     ;;
 684   *-*-linux*aout*)
 685     ;;
 686   *-*-linux*)
 687     HLDFLAGS='-Wl,-rpath,$(libdir)'
 688     ;;
 689   *-*-sysv4* | *-*-solaris*)
 690     HLDFLAGS='-R $(libdir)'
 691     ;;
 692   esac
 693 fi
 694
 695 # On SunOS, if the linker supports the -rpath option, use it to
 696 # prevent ../bfd and ../opcodes from being included in the run time
 697 # search path.
 698 case "${host}" in
 699   *-*-sunos*)
 700     echo 'main () { }' > conftest.c
 701     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 702     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 703       :
 704     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 705       :
 706     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 707       :
 708     elif test "${shared}" = "true"; then
 709       HLDFLAGS='-Wl,-rpath=$(libdir)'
 710     else
 711       HLDFLAGS='-Wl,-rpath='
 712     fi
 713     rm -f conftest.t conftest.c conftest
 714     ;;
 715 esac
 716 AC_SUBST(HLDFLAGS)
 717 AC_SUBST(RPATH_ENVVAR)
 718
 719 dnl This must come last.
 720 AC_OUTPUT(Makefile doc/Makefile .gdbinit:gdbinit.in)