gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ISC_POSIX
  13
  14 AM_INIT_AUTOMAKE(gas, 2.10.91)
  15
  16 AM_PROG_LIBTOOL
  17
  18 user_bfd_gas=
  19 AC_ARG_ENABLE(bfd-assembler,
  20 [  --enable-bfd-assembler  use BFD back end for writing object files],
  21 [case "${enableval}" in
  22   yes) need_bfd=yes user_bfd_gas=yes ;;
  23   no)  user_bfd_gas=no ;;
  24   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  25 esac])dnl
  26 AC_ARG_ENABLE(targets,
  27 [    targets            alternative target configurations besides the primary],
  28 [case "${enableval}" in
  29   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  30             ;;
  31   no)       enable_targets= ;;
  32   *)        enable_targets=$enableval ;;
  33 esac])dnl
  34 AC_ARG_ENABLE(commonbfdlib,
  35 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  36 [case "${enableval}" in
  37   yes) commonbfdlib=true ;;
  38   no)  commonbfdlib=false ;;
  39   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  40 esac])dnl
  41
  42 using_cgen=no
  43
  44 build_warnings="-W -Wall"
  45 AC_ARG_ENABLE(build-warnings,
  46 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  47 [case "${enableval}" in
  48   yes)  ;;
  49   no)   build_warnings="-w";;
  50   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  51         build_warnings="${build_warnings} ${t}";;
  52   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  53         build_warnings="${t} ${build_warnings}";;
  54   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  55 esac
  56 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  57   echo "Setting warning flags = $build_warnings" 6>&1
  58 fi])dnl
  59 WARN_CFLAGS=""
  60 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  61     WARN_CFLAGS="${build_warnings}"
  62 fi
  63 AC_SUBST(WARN_CFLAGS)
  64
  65 # Generate a header file
  66 AM_CONFIG_HEADER(config.h:config.in)
  67
  68 # If we are on a DOS filesystem, we must use gdb.ini rather than
  69 # .gdbinit.
  70 GDBINIT=".gdbinit"
  71 case "${host}" in
  72   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
  73     GDBINIT="gdb.ini"
  74     ;;
  75 esac
  76 AC_SUBST(GDBINIT)
  77
  78 te_file=generic
  79
  80 # Makefile target for installing gas in $(tooldir)/bin.
  81 install_tooldir=install-exec-tooldir
  82
  83 canon_targets=""
  84 all_targets=no
  85 if test -n "$enable_targets" ; then
  86   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  87     if test $t = "all"; then
  88       all_targets=yes
  89       continue
  90     fi
  91     result=`$ac_config_sub $t 2>/dev/null`
  92     if test -n "$result" ; then
  93       canon_targets="$canon_targets $result"
  94 #    else
  95 #      # Permit "all", etc.  We don't support it yet though.
  96 #      canon_targets="$canon_targets $t"
  97     fi
  98   done
  99   GAS_UNIQ(canon_targets)
 100 fi
 101
 102 emulations=""
 103
 104 for this_target in $target $canon_targets ; do
 105
 106 changequote(,)dnl
 107     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 108 changequote([,])dnl
 109
 110     # check for architecture variants
 111     arch=
 112     endian=
 113     case ${cpu} in
 114       alpha*)           cpu_type=alpha ;;
 115       armeb)            cpu_type=arm endian=big ;;
 116       arm*)             cpu_type=arm endian=little ;;
 117       armb*)            cpu_type=arm endian=little ;;
 118       armv*l)           cpu_type=arm endian=little ;;
 119       armv*b)           cpu_type=arm endian=big ;;
 120       xscale*)          cpu_type=arm endian=little ;;
 121       strongarm*)       cpu_type=arm endian=little ;;
 122       thumb*)           cpu_type=arm endian=little ;;
 123       hppa*)            cpu_type=hppa ;;
 124 changequote(,)dnl
 125       i[3456]86)        cpu_type=i386 arch=i386;;
 126       x86_64)           cpu_type=i386 arch=x86_64;;
 127       ia64)             cpu_type=ia64 ;;
 128       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 129       m680[012346]0)    cpu_type=m68k ;;
 130 changequote([,])dnl
 131       m68008)           cpu_type=m68k ;;
 132       m683??)           cpu_type=m68k ;;
 133       m5200)            cpu_type=m68k ;;
 134       m8*)              cpu_type=m88k ;;
 135       mips*el)          cpu_type=mips endian=little ;;
 136       mips*)            cpu_type=mips endian=big ;;
 137       pjl*)             cpu_type=pj endian=little ;;
 138       pj*)              cpu_type=pj endian=big ;;
 139       powerpcle*)       cpu_type=ppc endian=little ;;
 140       powerpc*)         cpu_type=ppc endian=big ;;
 141       rs6000*)          cpu_type=ppc ;;
 142       s390x*)           cpu_type=s390 arch=s390x ;;
 143       s390*)            cpu_type=s390 arch=s390 ;;
 144       sparclite*)       cpu_type=sparc arch=sparclite ;;
 145       sparclet*)        cpu_type=sparc arch=sparclet ;;
 146       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 147       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 148       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 149       v850*)            cpu_type=v850 ;;
 150       *)                cpu_type=${cpu} ;;
 151     esac
 152
 153     if test ${this_target} = $target ; then
 154       target_cpu_type=${cpu_type}
 155     elif test ${target_cpu_type} != ${cpu_type} ; then
 156       continue
 157     fi
 158
 159     generic_target=${cpu_type}-$vendor-$os
 160     dev=no
 161     bfd_gas=no
 162     em=generic
 163
 164     # assign object format
 165     case ${generic_target} in
 166       a29k-*-coff)          fmt=coff ;;
 167       a29k-amd-udi)         fmt=coff ;;
 168       a29k-amd-ebmon)       fmt=coff ;;
 169       a29k-nyu-sym1)        fmt=coff ;;
 170       a29k-*-rtems*)        fmt=coff ;;
 171       a29k-*-vxworks*)      fmt=coff ;;
 172
 173       alpha*-*-*vms*)       fmt=evax ;;
 174       alpha*-*-netware*)    fmt=ecoff ;;
 175       alpha*-*-openbsd*)    fmt=ecoff ;;
 176       alpha*-*-osf*)        fmt=ecoff ;;
 177       alpha*-*-linuxecoff*) fmt=ecoff ;;
 178       alpha*-*-linux-gnu*)  fmt=elf em=linux ;;
 179       alpha*-*-netbsd*)     fmt=elf em=nbsd ;;
 180
 181       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 182
 183       arm-*-aout)                       fmt=aout ;;
 184       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 185       arm-*-rtems | thumb-*-rtems)      fmt=elf ;;
 186       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 187       arm*-*-conix*)                    fmt=elf ;;
 188       arm-*-linux*aout*)                fmt=aout em=linux ;;
 189       arm*-*-linux-gnu* | arm*-*-uclinux*)
 190                                         fmt=elf  em=linux ;;
 191       arm-*-netbsd*)                    fmt=aout em=nbsd ;;
 192       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 193       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 194       arm-*-wince)                      fmt=coff em=wince-pe ;;
 195       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 196       arm-*-riscix*)                    fmt=aout em=riscix ;;
 197
 198       avr-*-*)              fmt=elf bfd_gas=yes ;;
 199
 200       cris-*-*)             fmt=multi bfd_gas=yes ;;
 201
 202       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 203       d30v-*-*)             fmt=elf bfd_gas=yes ;;
 204
 205
 206       fr30-*-*)             fmt=elf bfd_gas=yes ;;
 207
 208       hppa-*-linux-gnu*)    case ${cpu} in
 209                                 hppa*64*)
 210                                         fmt=elf em=hppalinux64;;
 211                                 hppa*)
 212                                         fmt=elf em=linux;;
 213                             esac ;;
 214       hppa-*-*elf*)         fmt=elf em=hppa ;;
 215       hppa-*-lites*)        fmt=elf em=hppa ;;
 216       hppa-*-osf*)          fmt=som em=hppa ;;
 217       hppa-*-rtems*)        fmt=elf em=hppa ;;
 218       hppa-*-hpux11*)       case ${cpu} in
 219                                 hppa*64*)
 220                                         fmt=elf em=hppa64 ;;
 221                                 hppa*)
 222                                         fmt=som em=hppa ;;
 223                             esac ;;
 224       hppa-*-hpux*)         fmt=som em=hppa ;;
 225       hppa-*-mpeix*)        fmt=som em=hppa ;;
 226       hppa-*-bsd*)          fmt=som em=hppa ;;
 227       hppa-*-hiux*)         fmt=som em=hppa ;;
 228
 229       h8300-*-rtems*)       fmt=coff ;;
 230       h8300-*-coff)         fmt=coff ;;
 231
 232       i370-*-elf* | i370-*-linux*) fmt=elf ;;
 233       i386-ibm-aix*)        fmt=coff em=i386aix ;;
 234       i386-sequent-bsd*)    fmt=aout em=dynix bfd_gas=yes ;;
 235       i386-*-beospe*)       fmt=coff em=pe bfd_gas=yes ;;
 236       i386-*-beoself* | i386-*-beos*) fmt=elf bfd_gas=yes ;;
 237       i386-*-bsd*)          fmt=aout em=386bsd ;;
 238       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 239       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 240       i386-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes;;
 241       i386-*-linux*aout* | i386-*-linuxoldld)   fmt=aout em=linux ;;
 242       i386-*-linux*coff*)   fmt=coff em=linux ;;
 243       i386-*-linux-gnu*)    fmt=elf em=linux bfd_gas=yes ;;
 244       x86_64-*-linux-gnu*)  fmt=elf em=linux bfd_gas=yes ;;
 245       i386-*-lynxos*)       fmt=coff em=lynx ;;
 246 changequote(,)dnl
 247       i386-*-sysv[45]* | i386-*-solaris* | i386-*-elf)
 248                             fmt=elf bfd_gas=yes ;;
 249       i386-*-freebsdaout* | i386-*-freebsd[12].* | i386-*-freebsd[12])
 250                             fmt=aout em=386bsd ;;
 251 changequote([,])dnl
 252       i386-*-coff | i386-*-sysv* | i386-*-sco3.2v5*coff | i386-*-isc*)
 253                           fmt=coff ;;
 254       i386-*-sco3.2v5*)      fmt=elf
 255                             if test ${this_target} = $target; then
 256                                 AC_DEFINE(SCO_ELF, 1,
 257                                     [Define if defaulting to ELF on SCO 5.])
 258                             fi
 259                             ;;
 260       i386-*-sco3.2*)       fmt=coff ;;
 261       i386-*-vsta)          fmt=aout ;;
 262       i386-*-msdosdjgpp* | i386-*-go32* | i386-go32-rtems*)
 263                             fmt=coff em=go32 bfd_gas=yes
 264                             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 265                             ;;
 266       i386-*-rtemself*)     fmt=elf ;;
 267       i386-*-rtems*)        fmt=coff ;;
 268       i386-*-gnu*)          fmt=elf ;;
 269       i386-*-mach*)
 270                             fmt=aout em=mach bfd_gas=yes ;;
 271       i386-*-msdos*)        fmt=aout ;;
 272       i386-*-moss*)         fmt=elf ;;
 273       i386-*-pe)            fmt=coff em=pe bfd_gas=yes ;;
 274       i386-*-cygwin*)       fmt=coff em=pe bfd_gas=yes ;;
 275       i386-*-interix*)      fmt=coff em=interix bfd_gas=yes ;;
 276       i386-*-mingw32*)      fmt=coff em=pe bfd_gas=yes ;;
 277       i386-*-*nt*)          fmt=coff em=pe bfd_gas=yes ;;
 278       i386-*-vxworks*)      fmt=aout ;;
 279       i386-*-chaos)         fmt=elf ;;
 280       i860-stardent-sysv4* | i860-stardent-elf*)
 281                             fmt=elf bfd_gas=yes endian=little
 282                             AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 283       i960-*-bout)          fmt=bout ;;
 284       i960-*-coff)          fmt=coff em=ic960 ;;
 285       i960-*-rtems*)        fmt=coff em=ic960 ;;
 286       i960-*-nindy*)        fmt=bout ;;
 287       i960-*-vxworks4*)     fmt=bout ;;
 288       i960-*-vxworks5.0)    fmt=bout ;;
 289       i960-*-vxworks5.*)    fmt=coff em=ic960 ;;
 290       i960-*-vxworks*)      fmt=bout ;;
 291       i960-*-elf*)          fmt=elf ;;
 292
 293       ia64-*-elf*)          fmt=elf ;;
 294       ia64-*-linux-gnu*)    fmt=elf em=linux ;;
 295       ia64-*-hpux*)         fmt=elf em=hpux ;;
 296
 297       m32r-*-*)             fmt=elf bfd_gas=yes ;;
 298
 299       m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)fmt=elf bfd_gas=yes ;;
 300
 301       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 302                             fmt=aout em=sun3 ;;
 303       m68k-motorola-sysv*)  fmt=coff em=delta ;;
 304       m68k-bull-sysv3*)     fmt=coff em=dpx2 ;;
 305       m68k-apollo-*)        fmt=coff em=apollo ;;
 306       m68k-*-sysv4*) # must be before -sysv*
 307                             fmt=elf em=svr4 ;;
 308       m68k-*-elf*)          fmt=elf ;;
 309       m68k-*-coff | m68k-*-sysv* | m68k-*-rtems*)
 310                             fmt=coff ;;
 311       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 312       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 313       m68k-*-linux-gnu*)    fmt=elf em=linux ;;
 314       m68k-*-gnu*)          fmt=elf ;;
 315       m68k-*-lynxos*)       fmt=coff em=lynx ;;
 316       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 317       m68k-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 318       m68k-apple-aux*)      fmt=coff em=aux ;;
 319       m68k-*-psos*)         fmt=elf em=psos;;
 320
 321       m88k-motorola-sysv3*) fmt=coff em=delt88 ;;
 322       m88k-*-coff*)         fmt=coff ;;
 323
 324       mcore-*-elf)          fmt=elf bfd_gas=yes ;;
 325       mcore-*-pe)           fmt=coff em=pe bfd_gas=yes ;;
 326
 327       # don't change em like *-*-bsd does
 328       mips-dec-netbsd*)     fmt=elf endian=little ;;
 329       mips-dec-openbsd*)    fmt=elf endian=little ;;
 330       mips-dec-bsd*)        fmt=aout endian=little ;;
 331       mips-sony-bsd*)       fmt=ecoff ;;
 332       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 333       mips-*-ultrix*)       fmt=ecoff endian=little ;;
 334       mips-*-osf*)          fmt=ecoff endian=little ;;
 335       mips-*-ecoff*)        fmt=ecoff ;;
 336       mips-*-ecoff*)        fmt=ecoff ;;
 337       mips-*-pe*)           fmt=coff endian=little em=pe ;;
 338       mips-*-irix6*)        fmt=elf ;;
 339       mips-*-irix5*)        fmt=elf ;;
 340       mips-*-irix*)         fmt=ecoff ;;
 341       mips-*-lnews*)        fmt=ecoff em=lnews ;;
 342       mips-*-riscos*)       fmt=ecoff ;;
 343       mips-*-sysv4*MP*)     fmt=elf em=tmips ;;
 344       mips-*-sysv*)         fmt=ecoff ;;
 345       mips-*-elf* | mips-*-rtems* | mips-*-linux-gnu* | mips-*-gnu* | mips-*-openbsd*)
 346                             fmt=elf ;;
 347       mips-*-vxworks*)      fmt=elf
 348                             AC_DEFINE(MIPS_STABS_ELF, 1,
 349                                 [Use ELF stabs for MIPS, not ECOFF stabs])
 350                             ;;
 351       mn10200-*-*)          fmt=elf bfd_gas=yes ;;
 352       mn10300-*-*)          fmt=elf bfd_gas=yes ;;
 353       pj*)                  fmt=elf ;;
 354       ppc-*-pe | ppc-*-cygwin* | ppc-*-winnt*)
 355                             fmt=coff em=pe ;;
 356       ppc-*-aix*)           fmt=coff ;;
 357       ppc-*-beos*)          fmt=coff ;;
 358       ppc-*-*bsd* | ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 359                             fmt=elf ;;
 360       ppc-*-linux-gnu*)     fmt=elf
 361                             case "$endian" in
 362                             big)  ;;
 363                             *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 364                             esac
 365                             ;;
 366       ppc-*-solaris*)       fmt=elf
 367                             if test ${this_target} = $target; then
 368                                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 369                                 [Define if default target is PowerPC Solaris.])
 370                             fi
 371                             if test x${endian} = xbig; then
 372                                 AC_MSG_ERROR(Solaris must be configured little endian)
 373                             fi
 374                             ;;
 375       ppc-*-rtems*)         fmt=elf ;;
 376       ppc-*-macos* | ppc-*-mpw*)
 377                             fmt=coff em=macos ;;
 378       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 379       ppc-*-vxworks*)       fmt=elf ;;
 380
 381       s390x-*-linux-gnu*)   fmt=elf em=linux ;;
 382       s390-*-linux-gnu*)    fmt=elf em=linux ;;
 383
 384       sh-*-linux*)          fmt=elf em=linux ;;
 385       sh-*-elf*)            fmt=elf ;;
 386       sh-*-coff*)           fmt=coff bfd_gas=yes;;
 387       sh-*-pe*)             fmt=coff em=pe bfd_gas=yes;;
 388       sh-*-rtemself*)       fmt=elf ;;
 389       sh-*-rtems*)          fmt=coff bfd_gas=yes;;
 390
 391       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 392       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 393       ns32k-pc532-openbsd*) fmt=aout em=nbsd532 ;;
 394
 395       sparc-*-rtemsaout*)   fmt=aout ;;
 396       sparc-*-rtemself*)    fmt=elf ;;
 397       sparc-*-rtems*)       fmt=elf ;;
 398       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 399       sparc-*-aout | sparc*-*-vxworks*)
 400                             fmt=aout em=sparcaout ;;
 401       sparc-*-coff)         fmt=coff ;;
 402       sparc-*-linux*aout*)  fmt=aout em=linux ;;
 403       sparc-*-linux-gnu*)   fmt=elf em=linux ;;
 404       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 405       sparc-fujitsu-none)   fmt=aout ;;
 406       sparc-*-elf | sparc-*-sysv4* | sparc-*-solaris*)
 407                             fmt=elf ;;
 408       sparc-*-netbsd*)      em=nbsd bfd_gas=yes
 409                             case ${cpu} in
 410                                 sparc) case ${os} in
 411                                            *elf*) fmt=elf ;;
 412                                            *)     fmt=aout ;;
 413                                        esac ;;
 414                                 sparc64) fmt=elf ;;
 415                             esac
 416                             ;;
 417       sparc-*-openbsd*)     fmt=aout em=nbsd ;;
 418
 419       strongarm-*-coff)     fmt=coff ;;
 420       strongarm-*-elf)      fmt=elf ;;
 421       xscale-*-coff)     fmt=coff ;;
 422       xscale-*-elf)      fmt=elf ;;
 423
 424       tic30-*-*aout*)       fmt=aout bfd_gas=yes ;;
 425       tic30-*-*coff*)       fmt=coff bfd_gas=yes ;;
 426       tic54x-*-* | c54x*-*-*)
 427                             fmt=coff bfd_gas=yes need_libm=yes;;
 428       tic80-*-*)            fmt=coff ;;
 429
 430       v850-*-*)             fmt=elf bfd_gas=yes ;;
 431       v850e-*-*)            fmt=elf bfd_gas=yes ;;
 432       v850ea-*-*)           fmt=elf bfd_gas=yes ;;
 433
 434       vax-*-bsd* | vax-*-ultrix*)
 435                             fmt=aout ;;
 436       vax-*-vms)            fmt=vms ;;
 437
 438
 439       z8k-*-coff | z8k-*-sim)
 440                             fmt=coff ;;
 441
 442       w65-*-*)              fmt=coff ;;
 443
 444       *-*-aout | *-*-scout)
 445                             fmt=aout ;;
 446       *-*-freebsd*)         fmt=elf bfd_gas=yes ;;
 447       *-*-nindy*)
 448                             fmt=bout ;;
 449       *-*-bsd*)
 450                             fmt=aout em=sun3 ;;
 451       *-*-generic)          fmt=generic ;;
 452       *-*-xray | *-*-hms)   fmt=coff ;;
 453       *-*-sim)              fmt=coff ;;
 454       *-*-elf | *-*-sysv4* | *-*-solaris*)
 455                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 456                             fmt=elf dev=yes ;;
 457       *-*-vxworks)          fmt=aout ;;
 458       *-*-netware)          fmt=elf ;;
 459     esac
 460
 461     if test ${this_target} = $target ; then
 462       endian_def=
 463       if test x${endian} = xbig; then
 464         endian_def=1
 465       elif test x${endian} = xlittle; then
 466         endian_def=0
 467       fi
 468       if test x${endian_def} != x; then
 469         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 470                            [Define as 1 if big endian.])
 471       fi
 472     fi
 473
 474     case ${cpu_type}-${fmt} in
 475       alpha*-*) bfd_gas=yes ;;
 476       arm-*)    bfd_gas=yes ;;
 477     # not yet
 478     # i386-aout)        bfd_gas=preferred ;;
 479       ia64*-*)  bfd_gas=yes ;;
 480       mips-*)   bfd_gas=yes ;;
 481       ns32k-*)  bfd_gas=yes ;;
 482       pdp11-*)  bfd_gas=yes ;;
 483       ppc-*)    bfd_gas=yes ;;
 484       sparc-*)  bfd_gas=yes ;;
 485       strongarm-*)      bfd_gas=yes ;;
 486       xscale-*) bfd_gas=yes ;;
 487       *-elf)    bfd_gas=yes ;;
 488       *-ecoff)  bfd_gas=yes ;;
 489       *-som)    bfd_gas=yes ;;
 490     #enable bfd for coff and aout to allow testing if a bfd target is
 491     #the primary target, but not for coff or aout as the primary target
 492       i386-coff)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 493       i386-aout)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 494       *)                ;;
 495     esac
 496
 497 # Other random stuff.
 498
 499     # Do we need the opcodes library?
 500     case ${cpu_type} in
 501       vax | i386 | tic30)
 502         ;;
 503
 504       *)
 505         need_opcodes=yes
 506
 507         case "${enable_shared}" in
 508         yes) shared_opcodes=true ;;
 509         *opcodes*) shared_opcodes=true ;;
 510         *) shared_opcodes=false ;;
 511         esac
 512         if test "${shared_opcodes}" = "true"; then
 513           # A shared libopcodes must be linked against libbfd.
 514           need_bfd=yes
 515         fi
 516         ;;
 517     esac
 518
 519     # Any other special object files needed ?
 520     case ${cpu_type} in
 521       fr30 | m32r)
 522         using_cgen=yes
 523         ;;
 524
 525       m68k)
 526         case ${extra_objects} in
 527         *m68k-parse.o*) ;;
 528         *) extra_objects="$extra_objects m68k-parse.o" ;;
 529         esac
 530         ;;
 531
 532       s390)
 533        if test $this_target = $target ; then
 534           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 535        fi
 536        ;;
 537
 538       mips)
 539         echo ${extra_objects} | grep -s "itbl-parse.o"
 540         if test $? -ne 0 ; then
 541           extra_objects="$extra_objects itbl-parse.o"
 542         fi
 543
 544         echo ${extra_objects} | grep -s "itbl-lex.o"
 545         if test $? -ne 0 ; then
 546           extra_objects="$extra_objects itbl-lex.o"
 547         fi
 548
 549         echo ${extra_objects} | grep -s "itbl-ops.o"
 550         if test $? -ne 0 ; then
 551           extra_objects="$extra_objects itbl-ops.o"
 552         fi
 553         ;;
 554
 555       i386)
 556         if test $this_target = $target ; then
 557           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 558         fi
 559         ;;
 560       sparc)
 561         if test $this_target = $target ; then
 562           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 563         fi
 564         ;;
 565       *)
 566         ;;
 567     esac
 568
 569     if test $using_cgen = yes ; then
 570         case "x${extra_objects}" in
 571         *cgen.o*) ;;
 572         *) extra_objects="$extra_objects cgen.o" ;;
 573         esac
 574     fi
 575
 576 # See if we really can support this configuration with the emulation code.
 577
 578     if test $this_target = $target ; then
 579       primary_bfd_gas=$bfd_gas
 580       obj_format=$fmt
 581       te_file=$em
 582
 583       if test $bfd_gas = no ; then
 584         # Can't support other configurations this way.
 585         break
 586       fi
 587     elif test $bfd_gas = no ; then
 588       # Can't support this configuration.
 589       break
 590     fi
 591
 592 # From target name and format, produce a list of supported emulations.
 593
 594     case ${generic_target}-${fmt} in
 595       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 596       mips-*-linux-gnu*-*) case "$endian" in
 597                         big)    emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 598                         *)      emulation="mipslelf mipsbelf mipself mipslecoff mipsbecoff mipsecoff" ;;
 599                         esac ;;
 600       mips-*-lnews*-ecoff) ;;
 601       mips-*-*-ecoff)   case "$endian" in
 602                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 603                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 604                         esac ;;
 605       mips-*-*-elf)     case "$endian" in
 606                         big)    emulation="mipsbelf mipslelf mipself" ;;
 607                         *)      emulation="mipslelf mipsbelf mipself" ;;
 608                         esac ;;
 609       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 610       # i386-pc-pe-coff != i386-pc-coff.
 611       i386-*-pe-coff)   ;;
 612       # Uncommenting the next line will turn on support for i386 AOUT
 613       # for the default linux configuration
 614       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 615       #
 616       i386-*-aout)      emulation="i386aout" ;;
 617       i386-*-coff)      emulation="i386coff" ;;
 618       i386-*-elf)       emulation="i386elf" ;;
 619
 620       # Always all formats.  Having a.out first makes it the default.
 621       cris-*-*)         emulation="crisaout criself" ;;
 622     esac
 623
 624     emulations="$emulations $emulation"
 625
 626 done
 627
 628 # Turn on all targets if possible
 629 if test ${all_targets} = "yes"; then
 630   case ${target_cpu_type} in
 631   i386)
 632     case ${obj_format} in
 633     aout)
 634       emulations="$emulations i386coff i386elf"
 635       ;;
 636     coff)
 637       emulations="$emulations i386aout i386elf"
 638     ;;
 639     elf)
 640       emulations="$emulations i386aout i386coff"
 641       ;;
 642     esac
 643   ;;
 644   esac
 645 fi
 646
 647 # Assign floating point type.  Most processors with FP support
 648 # IEEE FP.  On those that don't support FP at all, usually IEEE
 649 # is emulated.
 650 case ${target_cpu} in
 651   vax | tahoe ) atof=${target_cpu} ;;
 652   pdp11)        atof=vax ;;
 653   *)            atof=ieee ;;
 654 esac
 655
 656 case "${obj_format}" in
 657   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 658 esac
 659
 660 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 661 cgen_cpu_prefix=""
 662 if test $using_cgen = yes ; then
 663   case ${target_cpu} in
 664     *) cgen_cpu_prefix=${target_cpu} ;;
 665   esac
 666   AC_SUBST(cgen_cpu_prefix)
 667   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 668 fi
 669
 670 dnl
 671 dnl Make sure the desired support files exist.
 672 dnl
 673
 674 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 675   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 676 fi
 677
 678 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 679   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 680 fi
 681
 682 case ${user_bfd_gas}-${primary_bfd_gas} in
 683   yes-yes | no-no)
 684     # We didn't override user's choice.
 685     ;;
 686   no-yes)
 687     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 688     ;;
 689   no-preferred)
 690     primary_bfd_gas=no
 691     ;;
 692   *-preferred)
 693     primary_bfd_gas=yes
 694     ;;
 695   yes-*)
 696     primary_bfd_gas=yes
 697     ;;
 698   -*)
 699     # User specified nothing.
 700     ;;
 701 esac
 702
 703 # Some COFF configurations want these random other flags set.
 704 case ${obj_format} in
 705   coff)
 706     case ${target_cpu_type} in
 707       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 708       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 709       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 710     esac
 711     ;;
 712 esac
 713
 714 # Getting this done right is going to be a bitch.  Each configuration specified
 715 # with --enable-targets=... should be checked for environment, format, cpu, and
 716 # bfd_gas setting.
 717 #
 718 # For each configuration, the necessary object file support code must be linked
 719 # in.  This might be only one, it might be up to four.  The necessary emulation
 720 # code needs to be provided, too.
 721 #
 722 # And then there's "--enable-targets=all"....
 723 #
 724 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 725
 726 formats="${obj_format}"
 727 emfiles=""
 728 EMULATIONS=""
 729 GAS_UNIQ(emulations)
 730 for em in . $emulations ; do
 731   case $em in
 732     .)  continue ;;
 733     mipsbelf | mipslelf | mipself)
 734         fmt=elf   file=mipself ;;
 735     mipsbecoff | mipslecoff | mipsecoff)
 736         fmt=ecoff file=mipsecoff ;;
 737     *coff)
 738         fmt=coff  file=$em ;;
 739     *aout)
 740         fmt=aout file=$em ;;
 741     *elf)
 742         fmt=elf file=$em ;;
 743   esac
 744   formats="$formats $fmt"
 745   emfiles="$emfiles e-$file.o"
 746   EMULATIONS="$EMULATIONS &$em,"
 747 done
 748 GAS_UNIQ(formats)
 749 GAS_UNIQ(emfiles)
 750 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 751   for fmt in $formats ; do
 752     case $fmt in
 753       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 754       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 755       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 756       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 757       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 758       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 759       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 760       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 761       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 762       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 763     esac
 764     extra_objects="$extra_objects obj-$fmt.o"
 765   done
 766   obj_format=multi
 767 fi
 768 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 769   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 770   # e-mips* has more than one emulation per file, e-i386* has just one at the
 771   # moment.  If only one emulation is specified, then don't define
 772   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 773   case "${obj_format}${emfiles}" in
 774     multi* | *mips*)
 775       extra_objects="$extra_objects $emfiles"
 776       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 777   esac
 778 fi
 779 AC_SUBST(extra_objects)
 780 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 781 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 782                    [Default emulation.])
 783
 784 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 785   yes-*-coff)   need_bfd=yes ;;
 786   no-*-coff)    need_bfd=yes
 787                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 788 esac
 789
 790 reject_dev_configs=yes
 791
 792 case ${reject_dev_configs}-${dev} in
 793   yes-yes) # Oops.
 794     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 795     ;;
 796 esac
 797
 798 AC_SUBST(target_cpu_type)
 799 AC_SUBST(obj_format)
 800 AC_SUBST(te_file)
 801 AC_SUBST(install_tooldir)
 802 AC_SUBST(atof)
 803 dnl AC_SUBST(emulation)
 804
 805 case "${primary_bfd_gas}" in
 806   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 807         need_bfd=yes ;;
 808 esac
 809
 810 # do we need the opcodes library?
 811 case "${need_opcodes}" in
 812 yes)
 813   OPCODES_LIB=../opcodes/libopcodes.la
 814   ;;
 815 esac
 816
 817 case "${need_bfd}" in
 818 yes)
 819   BFDLIB=../bfd/libbfd.la
 820   ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 821   ;;
 822 esac
 823
 824 AC_SUBST(BFDLIB)
 825 AC_SUBST(OPCODES_LIB)
 826
 827 AC_SUBST(ALL_OBJ_DEPS)
 828
 829 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 830 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 831 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 832 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 833 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 834
 835 AC_PROG_CC
 836
 837 AC_PROG_YACC
 838 AM_PROG_LEX
 839
 840 ALL_LINGUAS=
 841 CY_GNU_GETTEXT
 842
 843 AM_MAINTAINER_MODE
 844 AC_EXEEXT
 845
 846 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 847
 848 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 849 # people who are not cross-compiling but are compiling cross-assemblers.
 850 AC_MSG_CHECKING(whether compiling a cross-assembler)
 851 if test "${host}" = "${target}"; then
 852   cross_gas=no
 853 else
 854   cross_gas=yes
 855   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 856 fi
 857 AC_MSG_RESULT($cross_gas)
 858
 859 dnl ansidecl.h will deal with const
 860 dnl AC_CONST
 861 AC_FUNC_ALLOCA
 862 AC_C_INLINE
 863
 864 # VMS doesn't have unlink.
 865 AC_CHECK_FUNCS(unlink remove, break)
 866
 867 # Some systems don't have sbrk().
 868 AC_CHECK_FUNCS(sbrk)
 869
 870 # do we need the math library?
 871 case "${need_libm}" in
 872 yes)
 873   AC_CHECK_LIBM
 874   AC_SUBST(LIBM)
 875   ;;
 876 esac
 877
 878 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 879 # enough, but on some of those systems, the assert macro relies on requoting
 880 # working properly!
 881 GAS_WORKING_ASSERT
 882
 883 # On some systems, the system header files may not declare malloc, realloc,
 884 # and free.  There are places where gas needs these functions to have been
 885 # declared -- such as when taking their addresses.
 886 gas_test_headers="
 887 #ifdef HAVE_MEMORY_H
 888 #include <memory.h>
 889 #endif
 890 #ifdef HAVE_STRING_H
 891 #include <string.h>
 892 #else
 893 #ifdef HAVE_STRINGS_H
 894 #include <strings.h>
 895 #endif
 896 #endif
 897 #ifdef HAVE_STDLIB_H
 898 #include <stdlib.h>
 899 #endif
 900 #ifdef HAVE_UNISTD_H
 901 #include <unistd.h>
 902 #endif
 903 "
 904 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 905 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 906 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 907 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 908 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 909
 910 # Does errno.h declare errno, or do we have to add a separate declaration
 911 # for it?
 912 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 913 #ifdef HAVE_ERRNO_H
 914 #include <errno.h>
 915 #endif
 916 ])
 917
 918 dnl This must come last.
 919
 920 dnl We used to make symlinks to files in the source directory, but now
 921 dnl we just use the right name for .c files, and create .h files in
 922 dnl the build directory which include the right .h file.  Make sure
 923 dnl the old symlinks don't exist, so that a reconfigure in an existing
 924 dnl directory behaves reasonably.
 925
 926 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
 927 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 928  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 929  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 930  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 931  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 932  if test "x$cgen_cpu_prefix" != x ; then
 933    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 934  fi
 935
 936  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
 937 [target_cpu_type=${target_cpu_type}
 938  cgen_cpu_prefix=${cgen_cpu_prefix}
 939  obj_format=${obj_format}
 940  te_file=${te_file}])