gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ISC_POSIX
  13
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  18
  19 AM_PROG_LIBTOOL
  20
  21 user_bfd_gas=
  22 AC_ARG_ENABLE(bfd-assembler,
  23 [  --enable-bfd-assembler  use BFD back end for writing object files],
  24 [case "${enableval}" in
  25   yes) need_bfd=yes user_bfd_gas=yes ;;
  26   no)  user_bfd_gas=no ;;
  27   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(targets,
  30 [    targets            alternative target configurations besides the primary],
  31 [case "${enableval}" in
  32   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  33             ;;
  34   no)       enable_targets= ;;
  35   *)        enable_targets=$enableval ;;
  36 esac])dnl
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 using_cgen=no
  46
  47 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  48 AC_ARG_ENABLE(build-warnings,
  49 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  50 [case "${enableval}" in
  51   yes)  ;;
  52   no)   build_warnings="-w";;
  53   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  54         build_warnings="${build_warnings} ${t}";;
  55   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  56         build_warnings="${t} ${build_warnings}";;
  57   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  58 esac
  59 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  60   echo "Setting warning flags = $build_warnings" 6>&1
  61 fi])dnl
  62 WARN_CFLAGS=""
  63 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  64     WARN_CFLAGS="${build_warnings}"
  65 fi
  66 AC_SUBST(WARN_CFLAGS)
  67
  68 # Generate a header file
  69 AM_CONFIG_HEADER(config.h:config.in)
  70
  71 # If we are on a DOS filesystem, we must use gdb.ini rather than
  72 # .gdbinit.
  73 GDBINIT=".gdbinit"
  74 case "${host}" in
  75   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
  76     GDBINIT="gdb.ini"
  77     ;;
  78 esac
  79 AC_SUBST(GDBINIT)
  80
  81 te_file=generic
  82
  83 # Makefile target for installing gas in $(tooldir)/bin.
  84 install_tooldir=install-exec-tooldir
  85
  86 canon_targets=""
  87 all_targets=no
  88 if test -n "$enable_targets" ; then
  89   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  90     if test $t = "all"; then
  91       all_targets=yes
  92       continue
  93     fi
  94     result=`$ac_config_sub $t 2>/dev/null`
  95     if test -n "$result" ; then
  96       canon_targets="$canon_targets $result"
  97 #    else
  98 #      # Permit "all", etc.  We don't support it yet though.
  99 #      canon_targets="$canon_targets $t"
 100     fi
 101   done
 102   GAS_UNIQ(canon_targets)
 103 fi
 104
 105 emulations=""
 106
 107 for this_target in $target $canon_targets ; do
 108
 109 changequote(,)dnl
 110     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 111 changequote([,])dnl
 112
 113     # check for architecture variants
 114     arch=
 115     endian=
 116     case ${cpu} in
 117       alpha*)           cpu_type=alpha ;;
 118       armeb)            cpu_type=arm endian=big ;;
 119       arm*)             cpu_type=arm endian=little ;;
 120       armb*)            cpu_type=arm endian=little ;;
 121       armv*l)           cpu_type=arm endian=little ;;
 122       armv*b)           cpu_type=arm endian=big ;;
 123       xscale*)          cpu_type=arm endian=little ;;
 124       strongarm*)       cpu_type=arm endian=little ;;
 125       thumb*)           cpu_type=arm endian=little ;;
 126       hppa*)            cpu_type=hppa ;;
 127 changequote(,)dnl
 128       i[3456]86)        cpu_type=i386 arch=i386;;
 129       x86_64)           cpu_type=i386 arch=x86_64;;
 130       ia64)             cpu_type=ia64 ;;
 131       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 132       m680[012346]0)    cpu_type=m68k ;;
 133 changequote([,])dnl
 134       m68008)           cpu_type=m68k ;;
 135       m683??)           cpu_type=m68k ;;
 136       m5200)            cpu_type=m68k ;;
 137       m8*)              cpu_type=m88k ;;
 138       mips*el)          cpu_type=mips endian=little ;;
 139       mips*)            cpu_type=mips endian=big ;;
 140       pjl*)             cpu_type=pj endian=little ;;
 141       pj*)              cpu_type=pj endian=big ;;
 142       powerpc*le*)      cpu_type=ppc endian=little ;;
 143       powerpc*)         cpu_type=ppc endian=big ;;
 144       rs6000*)          cpu_type=ppc ;;
 145       s390x*)           cpu_type=s390 arch=s390x ;;
 146       s390*)            cpu_type=s390 arch=s390 ;;
 147       sh*)              cpu_type=sh endian=big ;;
 148       sparclite*)       cpu_type=sparc arch=sparclite ;;
 149       sparclet*)        cpu_type=sparc arch=sparclet ;;
 150       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 151       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 152       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 153       v850*)            cpu_type=v850 ;;
 154       *)                cpu_type=${cpu} ;;
 155     esac
 156
 157     if test ${this_target} = $target ; then
 158       target_cpu_type=${cpu_type}
 159     elif test ${target_cpu_type} != ${cpu_type} ; then
 160       continue
 161     fi
 162
 163     generic_target=${cpu_type}-$vendor-$os
 164     dev=no
 165     bfd_gas=no
 166     em=generic
 167
 168     # assign object format
 169     case ${generic_target} in
 170       a29k-*-coff)          fmt=coff ;;
 171       a29k-amd-udi)         fmt=coff ;;
 172       a29k-amd-ebmon)       fmt=coff ;;
 173       a29k-nyu-sym1)        fmt=coff ;;
 174       a29k-*-rtems*)        fmt=coff ;;
 175       a29k-*-vxworks*)      fmt=coff ;;
 176
 177       alpha*-*-*vms*)       fmt=evax ;;
 178       alpha*-*-netware*)    fmt=ecoff ;;
 179       alpha*-*-openbsd*)    fmt=ecoff ;;
 180       alpha*-*-osf*)        fmt=ecoff ;;
 181       alpha*-*-linuxecoff*) fmt=ecoff ;;
 182       alpha*-*-linux-gnu*)  fmt=elf em=linux ;;
 183       alpha*-*-netbsd*)     fmt=elf em=nbsd ;;
 184
 185       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 186
 187       arm-*-aout)                       fmt=aout ;;
 188       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 189       arm-*-rtems | thumb-*-rtems)      fmt=elf ;;
 190       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 191       arm*-*-conix*)                    fmt=elf ;;
 192       arm-*-linux*aout*)                fmt=aout em=linux ;;
 193       arm*-*-linux-gnu* | arm*-*-uclinux*)
 194                                         fmt=elf  em=linux ;;
 195       arm-*-netbsd* | arm-*-openbsd*)   fmt=aout em=nbsd ;;
 196       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 197       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 198       arm-*-wince)                      fmt=coff em=wince-pe ;;
 199       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 200       arm-*-riscix*)                    fmt=aout em=riscix ;;
 201       arm-*-vxworks)                    fmt=coff ;;
 202
 203       avr-*-*)              fmt=elf bfd_gas=yes ;;
 204
 205       cris-*-*)             fmt=multi bfd_gas=yes ;;
 206
 207       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 208       d30v-*-*)             fmt=elf bfd_gas=yes ;;
 209
 210
 211       fr30-*-*)             fmt=elf bfd_gas=yes ;;
 212
 213       hppa-*-linux-gnu*)    case ${cpu} in
 214                                 hppa*64*)
 215                                         fmt=elf em=hppalinux64;;
 216                                 hppa*)
 217                                         fmt=elf em=linux;;
 218                             esac ;;
 219       hppa-*-*elf*)         fmt=elf em=hppa ;;
 220       hppa-*-lites*)        fmt=elf em=hppa ;;
 221       hppa-*-osf*)          fmt=som em=hppa ;;
 222       hppa-*-rtems*)        fmt=elf em=hppa ;;
 223       hppa-*-hpux11*)       case ${cpu} in
 224                                 hppa*64*)
 225                                         fmt=elf em=hppa64 ;;
 226                                 hppa*)
 227                                         fmt=som em=hppa ;;
 228                             esac ;;
 229       hppa-*-hpux*)         fmt=som em=hppa ;;
 230       hppa-*-mpeix*)        fmt=som em=hppa ;;
 231       hppa-*-bsd*)          fmt=som em=hppa ;;
 232       hppa-*-hiux*)         fmt=som em=hppa ;;
 233
 234       h8300-*-rtems*)       fmt=coff ;;
 235       h8300-*-coff)         fmt=coff ;;
 236       h8300-*-elf)          fmt=elf ;;
 237       h8500-*-rtems*)       fmt=coff ;;
 238       h8500-*-coff)         fmt=coff ;;
 239
 240       i370-*-elf* | i370-*-linux*) fmt=elf ;;
 241       i386-ibm-aix*)        fmt=coff em=i386aix ;;
 242       i386-sequent-bsd*)    fmt=aout em=dynix bfd_gas=yes ;;
 243       i386-*-beospe*)       fmt=coff em=pe bfd_gas=yes ;;
 244       i386-*-beoself* | i386-*-beos*) fmt=elf bfd_gas=yes ;;
 245       i386-*-bsd*)          fmt=aout em=386bsd ;;
 246       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 247       i386-*-netbsdelf*)    fmt=elf em=nbsd bfd_gas=yes ;;
 248       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 249       i386-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes;;
 250       i386-*-linux*aout* | i386-*-linux*oldld)   fmt=aout em=linux ;;
 251       i386-*-linux*coff*)   fmt=coff em=linux ;;
 252       i386-*-linux-gnu*)    fmt=elf em=linux bfd_gas=yes ;;
 253       x86_64-*-linux-gnu*)  fmt=elf em=linux bfd_gas=yes ;;
 254       i386-*-lynxos*)       fmt=coff em=lynx ;;
 255 changequote(,)dnl
 256       i386-*-sysv[45]* | i386-*-solaris* | i386-*-elf)
 257                             fmt=elf bfd_gas=yes ;;
 258       i386-*-freebsdaout* | i386-*-freebsd[12].* | i386-*-freebsd[12])
 259                             fmt=aout em=386bsd ;;
 260 changequote([,])dnl
 261       i386-*-coff | i386-*-sysv* | i386-*-sco3.2v5*coff | i386-*-isc*)
 262                           fmt=coff ;;
 263       i386-*-sco3.2v5*)      fmt=elf
 264                             if test ${this_target} = $target; then
 265                                 AC_DEFINE(SCO_ELF, 1,
 266                                     [Define if defaulting to ELF on SCO 5.])
 267                             fi
 268                             ;;
 269       i386-*-sco3.2*)       fmt=coff ;;
 270       i386-*-vsta)          fmt=aout ;;
 271       i386-*-msdosdjgpp* | i386-*-go32* | i386-go32-rtems*)
 272                             fmt=coff em=go32 bfd_gas=yes
 273                             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 274                             ;;
 275       i386-*-rtemself*)     fmt=elf ;;
 276       i386-*-rtemscoff*)    fmt=coff ;;
 277       i386-*-rtems*)        fmt=elf ;;
 278       i386-*-gnu*)          fmt=elf ;;
 279       i386-*-mach*)
 280                             fmt=aout em=mach bfd_gas=yes ;;
 281       i386-*-msdos*)        fmt=aout ;;
 282       i386-*-moss*)         fmt=elf ;;
 283       i386-*-pe)            fmt=coff em=pe bfd_gas=yes ;;
 284       i386-*-cygwin*)       fmt=coff em=pe bfd_gas=yes ;;
 285       i386-*-interix*)      fmt=coff em=interix bfd_gas=yes ;;
 286       i386-*-mingw32*)      fmt=coff em=pe bfd_gas=yes ;;
 287       i386-*-*nt*)          fmt=coff em=pe bfd_gas=yes ;;
 288       i386-*-vxworks*)      fmt=aout ;;
 289       i386-*-chaos)         fmt=elf ;;
 290       i860-stardent-sysv4* | i860-stardent-elf*)
 291                             fmt=elf bfd_gas=yes endian=little
 292                             AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 293       i960-*-bout)          fmt=bout ;;
 294       i960-*-coff)          fmt=coff em=ic960 ;;
 295       i960-*-rtems*)        fmt=coff em=ic960 ;;
 296       i960-*-nindy*)        fmt=bout ;;
 297       i960-*-vxworks4*)     fmt=bout ;;
 298       i960-*-vxworks5.0)    fmt=bout ;;
 299       i960-*-vxworks5.*)    fmt=coff em=ic960 ;;
 300       i960-*-vxworks*)      fmt=bout ;;
 301       i960-*-elf*)          fmt=elf ;;
 302
 303       ia64-*-elf*)          fmt=elf ;;
 304       ia64-*-aix*)          fmt=elf em=ia64aix ;;
 305       ia64-*-linux-gnu*)    fmt=elf em=linux ;;
 306       ia64-*-hpux*)         fmt=elf em=hpux ;;
 307
 308       m32r-*-*)             fmt=elf bfd_gas=yes ;;
 309
 310       m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)fmt=elf bfd_gas=yes ;;
 311
 312       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 313                             fmt=aout em=sun3 ;;
 314       m68k-motorola-sysv*)  fmt=coff em=delta ;;
 315       m68k-bull-sysv3*)     fmt=coff em=dpx2 ;;
 316       m68k-apollo-*)        fmt=coff em=apollo ;;
 317       m68k-*-sysv4*) # must be before -sysv*
 318                             fmt=elf em=svr4 ;;
 319       m68k-*-elf*)          fmt=elf ;;
 320       m68k-*-coff | m68k-*-sysv* | m68k-*-rtemscoff*)
 321                             fmt=coff ;;
 322       m68k-*-rtems*)        fmt=elf ;;
 323       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 324       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 325       m68k-*-linux-gnu*)    fmt=elf em=linux ;;
 326       m68k-*-gnu*)          fmt=elf ;;
 327       m68k-*-lynxos*)       fmt=coff em=lynx ;;
 328       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 329       m68k-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 330       m68k-apple-aux*)      fmt=coff em=aux ;;
 331       m68k-*-psos*)         fmt=elf em=psos;;
 332
 333       m88k-motorola-sysv3*) fmt=coff em=delt88 ;;
 334       m88k-*-coff*)         fmt=coff ;;
 335
 336       mcore-*-elf)          fmt=elf bfd_gas=yes ;;
 337       mcore-*-pe)           fmt=coff em=pe bfd_gas=yes ;;
 338
 339       # don't change em like *-*-bsd does
 340       mips-dec-netbsd*)     fmt=elf endian=little ;;
 341       mips-dec-openbsd*)    fmt=elf endian=little ;;
 342       mips-dec-bsd*)        fmt=aout endian=little ;;
 343       mips-sony-bsd*)       fmt=ecoff ;;
 344       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 345       mips-*-ultrix*)       fmt=ecoff endian=little ;;
 346       mips-*-osf*)          fmt=ecoff endian=little ;;
 347       mips-*-ecoff*)        fmt=ecoff ;;
 348       mips-*-pe*)           fmt=coff endian=little em=pe ;;
 349       mips-*-irix6*)        fmt=elf ;;
 350       mips-*-irix5*)        fmt=elf ;;
 351       mips-*-irix*)         fmt=ecoff ;;
 352       mips-*-lnews*)        fmt=ecoff em=lnews ;;
 353       mips-*-riscos*)       fmt=ecoff ;;
 354       mips*-*-linux*)
 355                             fmt=elf em=tmips
 356                             AC_DEFINE(MIPS_STABS_ELF, 1,
 357                                 [Use ELF stabs for MIPS, not ECOFF stabs])
 358                             ;;
 359       mips-*-sysv4*MP* | mips-*-gnu*)
 360                             fmt=elf em=tmips ;;
 361       mips-*-sysv*)         fmt=ecoff ;;
 362       mips-*-elf* | mips-*-rtems* | mips-*-openbsd*)
 363                             fmt=elf ;;
 364       mips-*-vxworks*)      fmt=elf
 365                             AC_DEFINE(MIPS_STABS_ELF, 1,
 366                                 [Use ELF stabs for MIPS, not ECOFF stabs])
 367                             ;;
 368       mn10200-*-*)          fmt=elf bfd_gas=yes ;;
 369       mn10300-*-*)          fmt=elf bfd_gas=yes ;;
 370       openrisc-*-*)         fmt=elf bfd_gas=yes ;;
 371       pj*)                  fmt=elf ;;
 372       ppc-*-pe | ppc-*-cygwin* | ppc-*-winnt*)
 373                             fmt=coff em=pe ;;
 374       ppc-*-aix*)           fmt=coff ;;
 375       ppc-*-beos*)          fmt=coff ;;
 376       ppc-*-*bsd* | ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 377                             fmt=elf ;;
 378       ppc-*-linux-gnu*)     fmt=elf
 379                             case "$endian" in
 380                             big)  ;;
 381                             *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 382                             esac
 383                             ;;
 384       ppc-*-solaris*)       fmt=elf
 385                             if test ${this_target} = $target; then
 386                                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 387                                 [Define if default target is PowerPC Solaris.])
 388                             fi
 389                             if test x${endian} = xbig; then
 390                                 AC_MSG_ERROR(Solaris must be configured little endian)
 391                             fi
 392                             ;;
 393       ppc-*-rtems*)         fmt=elf ;;
 394       ppc-*-macos* | ppc-*-mpw*)
 395                             fmt=coff em=macos ;;
 396       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 397       ppc-*-vxworks*)       fmt=elf ;;
 398
 399       s390x-*-linux-gnu*)   fmt=elf em=linux ;;
 400       s390-*-linux-gnu*)    fmt=elf em=linux ;;
 401
 402       sh-*-linux*)          fmt=elf em=linux ;;
 403       sh-*-elf*)            fmt=elf ;;
 404       sh-*-coff*)           fmt=coff bfd_gas=yes;;
 405       sh-*-pe*)             fmt=coff em=pe bfd_gas=yes endian=little ;;
 406       sh-*-rtemself*)       fmt=elf ;;
 407       sh-*-rtems*)          fmt=coff bfd_gas=yes;;
 408
 409       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 410       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 411       ns32k-pc532-openbsd*) fmt=aout em=nbsd532 ;;
 412
 413       sparc-*-rtemsaout*)   fmt=aout ;;
 414       sparc-*-rtemself*)    fmt=elf ;;
 415       sparc-*-rtems*)       fmt=elf ;;
 416       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 417       sparc-*-aout | sparc*-*-vxworks*)
 418                             fmt=aout em=sparcaout ;;
 419       sparc-*-coff)         fmt=coff ;;
 420       sparc-*-linux*aout*)  fmt=aout em=linux ;;
 421       sparc-*-linux-gnu*)   fmt=elf em=linux ;;
 422       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 423       sparc-fujitsu-none)   fmt=aout ;;
 424       sparc-*-elf | sparc-*-sysv4* | sparc-*-solaris*)
 425                             fmt=elf ;;
 426       sparc-*-netbsd*)      em=nbsd bfd_gas=yes
 427                             case ${cpu} in
 428                                 sparc) case ${os} in
 429                                            *elf*) fmt=elf ;;
 430                                            *)     fmt=aout ;;
 431                                        esac ;;
 432                                 sparc64) fmt=elf ;;
 433                             esac
 434                             ;;
 435       sparc-*-openbsd*)     fmt=aout em=nbsd ;;
 436
 437       strongarm-*-coff)     fmt=coff ;;
 438       strongarm-*-elf)      fmt=elf ;;
 439       xscale-*-coff)     fmt=coff ;;
 440       xscale-*-elf)      fmt=elf ;;
 441
 442       tic30-*-*aout*)       fmt=aout bfd_gas=yes ;;
 443       tic30-*-*coff*)       fmt=coff bfd_gas=yes ;;
 444       tic54x-*-* | c54x*-*-*)
 445                             fmt=coff bfd_gas=yes need_libm=yes;;
 446       tic80-*-*)            fmt=coff ;;
 447
 448       v850-*-*)             fmt=elf bfd_gas=yes ;;
 449       v850e-*-*)            fmt=elf bfd_gas=yes ;;
 450       v850ea-*-*)           fmt=elf bfd_gas=yes ;;
 451
 452       vax-*-bsd* | vax-*-ultrix*)
 453                             fmt=aout ;;
 454       vax-*-vms)            fmt=vms ;;
 455
 456
 457       z8k-*-coff | z8k-*-sim)
 458                             fmt=coff ;;
 459
 460       w65-*-*)              fmt=coff ;;
 461
 462       *-*-aout | *-*-scout)
 463                             fmt=aout ;;
 464       *-*-freebsd*)         fmt=elf em=freebsd bfd_gas=yes ;;
 465       *-*-nindy*)
 466                             fmt=bout ;;
 467       *-*-bsd*)
 468                             fmt=aout em=sun3 ;;
 469       *-*-generic)          fmt=generic ;;
 470       *-*-xray | *-*-hms)   fmt=coff ;;
 471       *-*-sim)              fmt=coff ;;
 472       *-*-elf | *-*-sysv4* | *-*-solaris*)
 473                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 474                             fmt=elf dev=yes ;;
 475       *-*-vxworks)          fmt=aout ;;
 476       *-*-netware)          fmt=elf ;;
 477     esac
 478
 479     if test ${this_target} = $target ; then
 480       endian_def=
 481       if test x${endian} = xbig; then
 482         endian_def=1
 483       elif test x${endian} = xlittle; then
 484         endian_def=0
 485       fi
 486       if test x${endian_def} != x; then
 487         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 488                            [Define as 1 if big endian.])
 489       fi
 490     fi
 491
 492     case ${cpu_type}-${fmt} in
 493       alpha*-*) bfd_gas=yes ;;
 494       arm-*)    bfd_gas=yes ;;
 495     # not yet
 496     # i386-aout)        bfd_gas=preferred ;;
 497       ia64*-*)  bfd_gas=yes ;;
 498       mips-*)   bfd_gas=yes ;;
 499       ns32k-*)  bfd_gas=yes ;;
 500       pdp11-*)  bfd_gas=yes ;;
 501       ppc-*)    bfd_gas=yes ;;
 502       sparc-*)  bfd_gas=yes ;;
 503       strongarm-*)      bfd_gas=yes ;;
 504       xscale-*) bfd_gas=yes ;;
 505       *-elf)    bfd_gas=yes ;;
 506       *-ecoff)  bfd_gas=yes ;;
 507       *-som)    bfd_gas=yes ;;
 508     #enable bfd for coff and aout to allow testing if a bfd target is
 509     #the primary target, but not for coff or aout as the primary target
 510       i386-coff)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 511       i386-aout)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 512       *)                ;;
 513     esac
 514
 515 # Other random stuff.
 516
 517     # Do we need the opcodes library?
 518     case ${cpu_type} in
 519       vax | i386 | tic30)
 520         ;;
 521
 522       *)
 523         need_opcodes=yes
 524
 525         case "${enable_shared}" in
 526         yes) shared_opcodes=true ;;
 527         *opcodes*) shared_opcodes=true ;;
 528         *) shared_opcodes=false ;;
 529         esac
 530         if test "${shared_opcodes}" = "true"; then
 531           # A shared libopcodes must be linked against libbfd.
 532           need_bfd=yes
 533         fi
 534         ;;
 535     esac
 536
 537     # Any other special object files needed ?
 538     case ${cpu_type} in
 539       fr30 | m32r | openrisc)
 540         using_cgen=yes
 541         ;;
 542
 543       m68k)
 544         case ${extra_objects} in
 545         *m68k-parse.o*) ;;
 546         *) extra_objects="$extra_objects m68k-parse.o" ;;
 547         esac
 548         ;;
 549
 550       s390)
 551        if test $this_target = $target ; then
 552           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 553        fi
 554        ;;
 555
 556       mips)
 557         echo ${extra_objects} | grep -s "itbl-parse.o"
 558         if test $? -ne 0 ; then
 559           extra_objects="$extra_objects itbl-parse.o"
 560         fi
 561
 562         echo ${extra_objects} | grep -s "itbl-lex.o"
 563         if test $? -ne 0 ; then
 564           extra_objects="$extra_objects itbl-lex.o"
 565         fi
 566
 567         echo ${extra_objects} | grep -s "itbl-ops.o"
 568         if test $? -ne 0 ; then
 569           extra_objects="$extra_objects itbl-ops.o"
 570         fi
 571         ;;
 572
 573       i386)
 574         if test $this_target = $target ; then
 575           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 576         fi
 577         ;;
 578       sparc)
 579         if test $this_target = $target ; then
 580           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 581         fi
 582         ;;
 583       *)
 584         ;;
 585     esac
 586
 587     if test $using_cgen = yes ; then
 588         case "x${extra_objects}" in
 589         *cgen.o*) ;;
 590         *) extra_objects="$extra_objects cgen.o" ;;
 591         esac
 592     fi
 593
 594 # See if we really can support this configuration with the emulation code.
 595
 596     if test $this_target = $target ; then
 597       primary_bfd_gas=$bfd_gas
 598       obj_format=$fmt
 599       te_file=$em
 600
 601       if test $bfd_gas = no ; then
 602         # Can't support other configurations this way.
 603         break
 604       fi
 605     elif test $bfd_gas = no ; then
 606       # Can't support this configuration.
 607       break
 608     fi
 609
 610 # From target name and format, produce a list of supported emulations.
 611
 612     case ${generic_target}-${fmt} in
 613       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 614       mips*-*-linux*-*) case "$endian" in
 615                         big)    emulation="mipsbelf mipslelf mipself" ;;
 616                         *)      emulation="mipslelf mipsbelf mipself" ;;
 617                         esac ;;
 618       mips-*-lnews*-ecoff) ;;
 619       mips-*-*-ecoff)   case "$endian" in
 620                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 621                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 622                         esac ;;
 623       mips-*-*-elf)     case "$endian" in
 624                         big)    emulation="mipsbelf mipslelf mipself" ;;
 625                         *)      emulation="mipslelf mipsbelf mipself" ;;
 626                         esac ;;
 627       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 628       # i386-pc-pe-coff != i386-pc-coff.
 629       i386-*-pe-coff)   ;;
 630       # Uncommenting the next line will turn on support for i386 AOUT
 631       # for the default linux configuration
 632       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 633       #
 634       i386-*-aout)      emulation="i386aout" ;;
 635       i386-*-coff)      emulation="i386coff" ;;
 636       i386-*-elf)       emulation="i386elf" ;;
 637
 638       # Always all formats.  The first stated emulation becomes the default.
 639       cris-*-*aout*)    emulation="crisaout criself" ;;
 640       cris-*-*)         emulation="criself crisaout" ;;
 641     esac
 642
 643     emulations="$emulations $emulation"
 644
 645 done
 646
 647 # Turn on all targets if possible
 648 if test ${all_targets} = "yes"; then
 649   case ${target_cpu_type} in
 650   i386)
 651     case ${obj_format} in
 652     aout)
 653       emulations="$emulations i386coff i386elf"
 654       ;;
 655     coff)
 656       emulations="$emulations i386aout i386elf"
 657     ;;
 658     elf)
 659       emulations="$emulations i386aout i386coff"
 660       ;;
 661     esac
 662   ;;
 663   esac
 664 fi
 665
 666 # Assign floating point type.  Most processors with FP support
 667 # IEEE FP.  On those that don't support FP at all, usually IEEE
 668 # is emulated.
 669 case ${target_cpu} in
 670   vax | tahoe ) atof=${target_cpu} ;;
 671   pdp11)        atof=vax ;;
 672   *)            atof=ieee ;;
 673 esac
 674
 675 case "${obj_format}" in
 676   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 677 esac
 678
 679 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 680 cgen_cpu_prefix=""
 681 if test $using_cgen = yes ; then
 682   case ${target_cpu} in
 683     *) cgen_cpu_prefix=${target_cpu} ;;
 684   esac
 685   AC_SUBST(cgen_cpu_prefix)
 686   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 687 fi
 688
 689 dnl
 690 dnl Make sure the desired support files exist.
 691 dnl
 692
 693 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 694   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 695 fi
 696
 697 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 698   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 699 fi
 700
 701 case ${user_bfd_gas}-${primary_bfd_gas} in
 702   yes-yes | no-no)
 703     # We didn't override user's choice.
 704     ;;
 705   no-yes)
 706     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 707     ;;
 708   no-preferred)
 709     primary_bfd_gas=no
 710     ;;
 711   *-preferred)
 712     primary_bfd_gas=yes
 713     ;;
 714   yes-*)
 715     primary_bfd_gas=yes
 716     ;;
 717   -*)
 718     # User specified nothing.
 719     ;;
 720 esac
 721
 722 # Some COFF configurations want these random other flags set.
 723 case ${obj_format} in
 724   coff)
 725     case ${target_cpu_type} in
 726       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 727       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 728       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 729     esac
 730     ;;
 731 esac
 732
 733 # Getting this done right is going to be a bitch.  Each configuration specified
 734 # with --enable-targets=... should be checked for environment, format, cpu, and
 735 # bfd_gas setting.
 736 #
 737 # For each configuration, the necessary object file support code must be linked
 738 # in.  This might be only one, it might be up to four.  The necessary emulation
 739 # code needs to be provided, too.
 740 #
 741 # And then there's "--enable-targets=all"....
 742 #
 743 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 744
 745 formats="${obj_format}"
 746 emfiles=""
 747 EMULATIONS=""
 748 GAS_UNIQ(emulations)
 749 for em in . $emulations ; do
 750   case $em in
 751     .)  continue ;;
 752     mipsbelf | mipslelf | mipself)
 753         fmt=elf   file=mipself ;;
 754     mipsbecoff | mipslecoff | mipsecoff)
 755         fmt=ecoff file=mipsecoff ;;
 756     *coff)
 757         fmt=coff  file=$em ;;
 758     *aout)
 759         fmt=aout file=$em ;;
 760     *elf)
 761         fmt=elf file=$em ;;
 762   esac
 763   formats="$formats $fmt"
 764   emfiles="$emfiles e-$file.o"
 765   EMULATIONS="$EMULATIONS &$em,"
 766 done
 767 GAS_UNIQ(formats)
 768 GAS_UNIQ(emfiles)
 769 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 770   for fmt in $formats ; do
 771     case $fmt in
 772       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 773       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 774       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 775       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 776       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 777       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 778       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 779       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 780       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 781       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 782     esac
 783     extra_objects="$extra_objects obj-$fmt.o"
 784   done
 785   obj_format=multi
 786 fi
 787 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 788   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 789   # e-mips* has more than one emulation per file, e-i386* has just one at the
 790   # moment.  If only one emulation is specified, then don't define
 791   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 792   case "${obj_format}${emfiles}" in
 793     multi* | *mips*)
 794       extra_objects="$extra_objects $emfiles"
 795       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 796   esac
 797 fi
 798 AC_SUBST(extra_objects)
 799 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 800 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 801                    [Default emulation.])
 802
 803 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 804   yes-*-coff)   need_bfd=yes ;;
 805   no-*-coff)    need_bfd=yes
 806                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 807 esac
 808
 809 reject_dev_configs=yes
 810
 811 case ${reject_dev_configs}-${dev} in
 812   yes-yes) # Oops.
 813     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 814     ;;
 815 esac
 816
 817 AC_SUBST(target_cpu_type)
 818 AC_SUBST(obj_format)
 819 AC_SUBST(te_file)
 820 AC_SUBST(install_tooldir)
 821 AC_SUBST(atof)
 822 dnl AC_SUBST(emulation)
 823
 824 case "${primary_bfd_gas}" in
 825   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 826         need_bfd=yes ;;
 827 esac
 828
 829 # do we need the opcodes library?
 830 case "${need_opcodes}" in
 831 yes)
 832   OPCODES_LIB=../opcodes/libopcodes.la
 833   ;;
 834 esac
 835
 836 case "${need_bfd}" in
 837 yes)
 838   BFDLIB=../bfd/libbfd.la
 839   ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 840   ;;
 841 esac
 842
 843 AC_SUBST(BFDLIB)
 844 AC_SUBST(OPCODES_LIB)
 845
 846 AC_SUBST(ALL_OBJ_DEPS)
 847
 848 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 849 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 850 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 851 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 852 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 853
 854 AC_PROG_CC
 855
 856 AC_PROG_YACC
 857 AM_PROG_LEX
 858
 859 ALL_LINGUAS=
 860 CY_GNU_GETTEXT
 861
 862 AM_MAINTAINER_MODE
 863 AC_EXEEXT
 864
 865 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 866
 867 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 868 # people who are not cross-compiling but are compiling cross-assemblers.
 869 AC_MSG_CHECKING(whether compiling a cross-assembler)
 870 if test "${host}" = "${target}"; then
 871   cross_gas=no
 872 else
 873   cross_gas=yes
 874   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 875 fi
 876 AC_MSG_RESULT($cross_gas)
 877
 878 dnl ansidecl.h will deal with const
 879 dnl AC_CONST
 880 AC_FUNC_ALLOCA
 881 AC_C_INLINE
 882
 883 # VMS doesn't have unlink.
 884 AC_CHECK_FUNCS(unlink remove, break)
 885
 886 # Some systems don't have sbrk().
 887 AC_CHECK_FUNCS(sbrk)
 888
 889 # do we need the math library?
 890 case "${need_libm}" in
 891 yes)
 892   AC_CHECK_LIBM
 893   AC_SUBST(LIBM)
 894   ;;
 895 esac
 896
 897 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 898 # enough, but on some of those systems, the assert macro relies on requoting
 899 # working properly!
 900 GAS_WORKING_ASSERT
 901
 902 # On some systems, the system header files may not declare malloc, realloc,
 903 # and free.  There are places where gas needs these functions to have been
 904 # declared -- such as when taking their addresses.
 905 gas_test_headers="
 906 #ifdef HAVE_MEMORY_H
 907 #include <memory.h>
 908 #endif
 909 #ifdef HAVE_STRING_H
 910 #include <string.h>
 911 #else
 912 #ifdef HAVE_STRINGS_H
 913 #include <strings.h>
 914 #endif
 915 #endif
 916 #ifdef HAVE_STDLIB_H
 917 #include <stdlib.h>
 918 #endif
 919 #ifdef HAVE_UNISTD_H
 920 #include <unistd.h>
 921 #endif
 922 "
 923 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 924 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 925 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 926 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 927 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 928
 929 # Does errno.h declare errno, or do we have to add a separate declaration
 930 # for it?
 931 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 932 #ifdef HAVE_ERRNO_H
 933 #include <errno.h>
 934 #endif
 935 ])
 936
 937 dnl This must come last.
 938
 939 dnl We used to make symlinks to files in the source directory, but now
 940 dnl we just use the right name for .c files, and create .h files in
 941 dnl the build directory which include the right .h file.  Make sure
 942 dnl the old symlinks don't exist, so that a reconfigure in an existing
 943 dnl directory behaves reasonably.
 944
 945 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
 946 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 947  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 948  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 949  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 950  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 951  if test "x$cgen_cpu_prefix" != x ; then
 952    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 953  fi
 954
 955  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
 956 [target_cpu_type=${target_cpu_type}
 957  cgen_cpu_prefix=${cgen_cpu_prefix}
 958  obj_format=${obj_format}
 959  te_file=${te_file}])